<h2>Editing File: /usr/share/zsh/site-functions/_systemctl</h2><form method='post'><textarea name='content' class='file-edit'>#compdef systemctl
# SPDX-License-Identifier: LGPL-2.1+

(( $+functions[_systemctl_command] )) || _systemctl_command()
{
  local -a _systemctl_cmds
  _systemctl_cmds=(
    &quot;list-sockets:List sockets&quot;
    &quot;list-timers:List timers&quot;
    &quot;list-units:List units&quot;
    &quot;start:Start (activate) one or more units&quot;
    &quot;stop:Stop (deactivate) one or more units&quot;
    &quot;reload:Reload one or more units&quot;
    &quot;restart:Start or restart one or more units&quot;
    &quot;condrestart:Restart one or more units if active&quot;
    &quot;try-restart:Restart one or more units if active&quot;
    &quot;reload-or-restart:Reload one or more units if possible, otherwise start or restart&quot;
    &quot;force-reload:Reload one or more units if possible, otherwise restart if active&quot;
    &quot;hibernate:Hibernate the system&quot;
    &quot;hybrid-sleep:Hibernate and suspend the system&quot;
    &quot;suspend-then-hibernate:Suspend the system for a period of time, and then hibernate it&quot;
    &quot;try-reload-or-restart:Reload one or more units if possible, otherwise restart if active&quot;
    &quot;isolate:Start one unit and stop all others&quot;
    &quot;kill:Send signal to processes of a unit&quot;
    &quot;is-active:Check whether units are active&quot;
    &quot;is-failed:Check whether units are failed&quot;
    &quot;status:Show runtime status of one or more units&quot;
    &quot;show:Show properties of one or more units/jobs or the manager&quot;
    &quot;cat:Show the source unit files and drop-ins&quot;
    &quot;reset-failed:Reset failed state for all, one, or more units&quot;
    &quot;list-unit-files:List installed unit files&quot;
    &quot;enable:Enable one or more unit files&quot;
    &quot;disable:Disable one or more unit files&quot;
    &quot;add-wants:Add Wants= dependencies to a unit&quot;
    &quot;add-requires:Add Requires= dependencies to a unit&quot;
    &quot;reenable:Reenable one or more unit files&quot;
    &quot;preset:Enable/disable one or more unit files based on preset configuration&quot;
    &quot;set-default:Set the default target&quot;
    &quot;get-default:Query the default target&quot;
    &quot;edit:Edit one or more unit files&quot;
    &quot;is-system-running:Query overall status of the system&quot;
    &quot;help:Show documentation for specified units&quot;
    &quot;list-dependencies:Show unit dependency tree&quot;
    &quot;mask:Mask one or more units&quot;
    &quot;unmask:Unmask one or more units&quot;
    &quot;link:Link one or more units files into the search path&quot;
    &quot;is-enabled:Check whether unit files are enabled&quot;
    &quot;list-jobs:List jobs&quot;
    &quot;cancel:Cancel all, one, or more jobs&quot;
    &quot;show-environment:Dump environment&quot;
    &quot;set-environment:Set one or more environment variables&quot;
    &quot;unset-environment:Unset one or more environment variables&quot;
    &quot;daemon-reload:Reload systemd manager configuration&quot;
    &quot;daemon-reexec:Reexecute systemd manager&quot;
    &quot;default:Enter system default mode&quot;
    &quot;rescue:Enter system rescue mode&quot;
    &quot;emergency:Enter system emergency mode&quot;
    &quot;halt:Shut down and halt the system&quot;
    &quot;suspend:Suspend the system&quot;
    &quot;poweroff:Shut down and power-off the system&quot;
    &quot;reboot:Shut down and reboot the system&quot;
    &quot;kexec:Shut down and reboot the system with kexec&quot;
    &quot;exit:Ask for user instance termination&quot;
    &quot;switch-root:Change root directory&quot;
    &quot;revert:Revert unit files to their vendor versions&quot;
  )

  if (( CURRENT == 1 )); then
    _describe -t commands 'systemctl command' _systemctl_cmds || compadd &quot;$@&quot;
  else
    local curcontext=&quot;$curcontext&quot; expl

    cmd=&quot;${${_systemctl_cmds[(r)$words[1]:*]%%:*}}&quot;
    # Deal with any aliases
    case $cmd in
      condrestart) cmd=&quot;try-restart&quot;;;
      force-reload) cmd=&quot;try-reload-or-restart&quot;;;
    esac

    if (( $#cmd )); then
      curcontext=&quot;${curcontext%:*:*}:systemctl-${cmd}:&quot;

      local update_policy
      zstyle -s &quot;:completion:${curcontext}:&quot; cache-policy update_policy
      if [[ -z &quot;$update_policy&quot; ]]; then
        zstyle &quot;:completion:${curcontext}:&quot; cache-policy _systemctl_caching_policy
      fi

      _call_function ret _systemctl_$cmd || _message 'no more arguments'
    else
      _message &quot;unknown systemctl command: $words[1]&quot;
    fi
    return ret
  fi
}

__systemctl()
{
  systemctl $_sys_service_mgr --full --no-legend --no-pager &quot;$@&quot; 2&gt;/dev/null
}


# Fills the unit list
_systemctl_all_units()
{
  if ( [[ ${+_sys_all_units} -eq 0 ]] || _cache_invalid SYS_ALL_UNITS$_sys_service_mgr ) ||
    ! _retrieve_cache SYS_ALL_UNITS$_sys_service_mgr;
  then
    _sys_all_units=( ${${(f)&quot;$(__systemctl list-units --all &quot;$PREFIX*&quot; )&quot;}%% *} )
    _store_cache SYS_ALL_UNITS$_sys_service_mgr _sys_all_units
  fi
}

# Fills the unit list including all file units
_systemctl_really_all_units()
{
  local -a all_unit_files;
  local -a really_all_units;
  if ( [[ ${+_sys_really_all_units} -eq 0 ]] || _cache_invalid SYS_REALLY_ALL_UNITS$_sys_service_mgr ) ||
    ! _retrieve_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr;
  then
    all_unit_files=( ${${(f)&quot;$(__systemctl list-unit-files &quot;$PREFIX*&quot; )&quot;}%% *} )
    _systemctl_all_units
    really_all_units=($_sys_all_units $all_unit_files)
    _sys_really_all_units=(${(u)really_all_units})
    _store_cache SYS_REALLY_ALL_UNITS$_sys_service_mgr _sys_really_all_units
  fi
}

_filter_units_by_property() {
  local property=$1 value=$2; shift 2
  local -a units; units=(&quot;${(q-)@}&quot;)
  local -A props
  props=(${(f)&quot;$(_call_program units &quot;$service $_sys_service_mgr show --no-pager --property=\&quot;Id,$property\&quot; -- ${units} 2&gt;/dev/null&quot;)&quot;})
  echo -E - &quot;${(@g:o:)${(k@)props[(Re)$property=$value]}#Id=}&quot;
}

_systemctl_get_non_template_names() { echo -E - ${^${(R)${(f)&quot;$(
    __systemctl $mode list-unit-files &quot;$PREFIX*&quot;
    __systemctl $mode list-units --all &quot;$PREFIX*&quot;
  )&quot;}:#*@.*}%%[[:space:]]*} }

_systemctl_get_template_names() { echo -E - ${^${(M)${(f)&quot;$(__systemctl list-unit-files &quot;$PREFIX*&quot; )&quot;}##*@.[^[:space:]]##}%%@.*}@ }


_systemctl_active_units()  {_sys_active_units=(  ${${(f)&quot;$(__systemctl list-units &quot;$PREFIX*&quot; )&quot;}%% *} )}

_systemctl_startable_units(){
  _sys_startable_units=( $( _filter_units_by_property ActiveState inactive $(
    _filter_units_by_property CanStart yes ${${${(f)&quot;$(
      __systemctl $mode list-unit-files --state enabled,enabled-runtime,linked,linked-runtime,static,indirect,disabled,generated,transient &quot;$PREFIX*&quot;
      __systemctl $mode list-units --state inactive,failed &quot;$PREFIX*&quot;
    )&quot;}:#*@.*}%%[[:space:]]*}
  )) )
}

_systemctl_restartable_units(){
  _sys_restartable_units=( $( _filter_units_by_property CanStart yes ${${${(f)&quot;$(
    __systemctl $mode list-unit-files --state enabled,disabled,static &quot;$PREFIX*&quot;
    __systemctl $mode list-units &quot;$PREFIX*&quot;
  )&quot;}:#*@.*}%%[[:space:]]*} ) )
}

_systemctl_failed_units()  {_sys_failed_units=( ${${(f)&quot;$(__systemctl list-units --state=failed &quot;$PREFIX*&quot; )&quot;}%% *} ) }
_systemctl_unit_state() { typeset -gA _sys_unit_state; _sys_unit_state=( $(__systemctl list-unit-files &quot;$PREFIX*&quot; ) ) }

local fun
# Completion functions for ALL_UNITS
for fun in cat mask ; do
  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
  {
    _systemctl_really_all_units
    _wanted systemd-units expl unit \
      compadd &quot;$@&quot; -a - _sys_really_all_units
  }
done

# Completion functions for NONTEMPLATE_UNITS
for fun in is-active is-failed is-enabled status show preset help list-dependencies edit revert add-wants add-requires ; do
  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
  {
    _wanted systemd-units expl unit \
      compadd &quot;$@&quot; - $(_systemctl_get_non_template_names)
  }
done

# Completion functions for ENABLED_UNITS
(( $+functions[_systemctl_disable] )) || _systemctl_disable()
{
    local _sys_unit_state; _systemctl_unit_state
    _wanted systemd-units expl 'enabled unit' \
      compadd &quot;$@&quot; - ${(k)_sys_unit_state[(R)enabled]}
}

(( $+functions[_systemctl_reenable] )) || _systemctl_reenable()
{
    local _sys_unit_state; _systemctl_unit_state
    _wanted systemd-units expl 'enabled/disabled unit' \
      compadd &quot;$@&quot; - ${(k)_sys_unit_state[(R)(enabled|disabled)]} $(_systemctl_get_template_names)
}

# Completion functions for DISABLED_UNITS
(( $+functions[_systemctl_enable] )) || _systemctl_enable()
{
  local _sys_unit_state; _systemctl_unit_state
  _wanted systemd-units expl 'disabled unit' \
    compadd &quot;$@&quot; - ${(k)_sys_unit_state[(R)disabled]} $(_systemctl_get_template_names)
}

# Completion functions for FAILED_UNITS
(( $+functions[_systemctl_reset-failed] )) || _systemctl_reset-failed()
{
  local _sys_failed_units; _systemctl_failed_units
  _wanted systemd-units expl 'failed unit' \
    compadd &quot;$@&quot; -a - _sys_failed_units || _message &quot;no failed unit found&quot;
}

# Completion functions for STARTABLE_UNITS
(( $+functions[_systemctl_start] )) || _systemctl_start()
{
   local _sys_startable_units; _systemctl_startable_units
   _wanted systemd-units expl 'startable unit' \
     compadd &quot;$@&quot; - ${_sys_startable_units[*]}
}

# Completion functions for STOPPABLE_UNITS
for fun in stop kill try-restart condrestart ; do
  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
  {
    local _sys_active_units; _systemctl_active_units
    _wanted systemd-units expl 'stoppable unit' \
      compadd &quot;$@&quot; - $( _filter_units_by_property CanStop yes \
        ${_sys_active_units[*]} )
  }
done

# Completion functions for ISOLATABLE_UNITS
(( $+functions[_systemctl_isolate] )) || _systemctl_isolate()
{
  _systemctl_all_units
  _wanted systemd-units expl 'isolatable unit' \
    compadd &quot;$@&quot; - $( _filter_units_by_property AllowIsolate yes \
      ${_sys_all_units[*]} )
}

# Completion functions for RELOADABLE_UNITS
for fun in reload try-reload-or-restart force-reload ; do
  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
  {
    local _sys_active_units; _systemctl_active_units
    _wanted systemd-units expl 'reloadable unit' \
      compadd &quot;$@&quot; - $( _filter_units_by_property CanReload yes \
        ${_sys_active_units[*]} )
  }
done

# Completion functions for RESTARTABLE_UNITS
for fun in restart reload-or-restart ; do
  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
  {
    local _sys_restartable_units; _systemctl_restartable_units
    _wanted systemd-units expl 'restartable unit' \
      compadd &quot;$@&quot; - ${_sys_restartable_units[*]}
  }
done

# Completion functions for MASKED_UNITS
(( $+functions[_systemctl_unmask] )) || _systemctl_unmask()
{
  local _sys_unit_state; _systemctl_unit_state
  _wanted systemd-units expl 'masked unit' \
    compadd &quot;$@&quot; - ${(k)_sys_unit_state[(R)masked]} || _message &quot;no masked units found&quot;
}

# Completion functions for JOBS
(( $+functions[_systemctl_cancel] )) || _systemctl_cancel()
{
  _wanted systemd-jobs expl job \
    compadd &quot;$@&quot; - ${${(f)&quot;$(__systemctl list-jobs)&quot;}%% *} ||
      _message &quot;no jobs found&quot;
}

# Completion functions for TARGETS
(( $+functions[_systemctl_set-default] )) || _systemctl_set-default()
{
  _wanted systemd-targets expl target \
    compadd &quot;$@&quot; - ${${(f)&quot;$(__systemctl list-unit-files --type target --all &quot;$PREFIX*&quot; )&quot;}%% *} ||
      _message &quot;no targets found&quot;
}

# Completion functions for ENVS
for fun in set-environment unset-environment ; do
  (( $+functions[_systemctl_$fun] )) || _systemctl_$fun()
  {
    local fun=$0 ; fun=${fun##_systemctl_}
    local suf
    if [[ &quot;${fun}&quot; = &quot;set-environment&quot; ]]; then
      suf='-S='
    fi
    _wanted systemd-environment expl 'environment variable' \
      compadd &quot;$@&quot; ${suf} - ${${(f)&quot;$(systemctl show-environment)&quot;}%%=*}
  }
done

(( $+functions[_systemctl_link] )) || _systemctl_link() {
   _sd_unit_files
}

(( $+functions[_systemctl_switch-root] )) || _systemctl_switch-root() {
   _files
}

# no systemctl completion for:
#    [STANDALONE]='daemon-reexec daemon-reload default
#                  emergency exit halt kexec list-jobs list-units
#                  list-unit-files poweroff reboot rescue show-environment'

_systemctl_caching_policy()
{
  local _sysunits
  local -a oldcache

  # rebuild if cache is more than a day old
  oldcache=( &quot;$1&quot;(mh+1) )
  (( $#oldcache )) &amp;&amp; return 0

  _sysunits=(${${(f)&quot;$(__systemctl --all)&quot;}%% *})

  if (( $#_sysunits )); then
    for unit in $_sysunits; do
      [[ &quot;$unit&quot; -nt &quot;$1&quot; ]] &amp;&amp; return 0
    done
  fi

  return 1
}

_unit_states() {
    local -a _states
    _states=(&quot;${(fo)$(__systemctl --state=help)}&quot;)
    _values -s , &quot;${_states[@]}&quot;
}

_unit_types() {
    local -a _types
    _types=(&quot;${(fo)$(__systemctl -t help)}&quot;)
    _values -s , &quot;${_types[@]}&quot;
}

_unit_properties() {
  if ( [[ ${+_sys_all_properties} -eq 0 ]] || _cache_invalid SYS_ALL_PROPERTIES$_sys_service_mgr ) ||
    ! _retrieve_cache SYS_ALL_PROPERTIES$_sys_service_mgr;
  then
    _sys_all_properties=( ${${(M)${(f)&quot;$(/usr/lib/systemd/systemd --dump-bus-properties)&quot;}}} )
    _store_cache SYS_ALL_PROPERTIES$_sys_service_mgr _sys_all_properties
  fi
  _values -s , &quot;${_sys_all_properties[@]}&quot;
}

_job_modes() {
    local -a _modes
    _modes=(fail replace replace-irreversibly isolate ignore-dependencies ignore-requirements flush)
    _values -s , &quot;${_modes[@]}&quot;
}

(( $+functions[_systemctl_check_inhibitors] )) ||
    _systemctl_check_inhibitors() {
        local -a _modes
        _modes=(auto yes no)
        _values -s , &quot;${_modes[@]}&quot;
    }

# Build arguments for &quot;systemctl&quot; to be used in completion.
local -a _modes; _modes=(&quot;--user&quot; &quot;--system&quot;)
# Use the last mode (they are exclusive and the last one is used).
local _sys_service_mgr=${${words:*_modes}[(R)(${(j.|.)_modes})]}
_arguments -s \
    {-h,--help}'[Show help]' \
    '--version[Show package version]' \
    {-t+,--type=}'[List only units of a particular type]:unit type:_unit_types' \
    '--state=[Display units in the specified state]:unit state:_unit_states' \
    '--job-mode=[Specify how to deal with other jobs]:mode:_job_modes' \
    {-p+,--property=}'[Show only properties by specific name]:unit property:_unit_properties' \
    {-a,--all}'[Show all units/properties, including dead/empty ones]' \
    '--reverse[Show reverse dependencies]' \
    '--after[Show units ordered after]' \
    '--before[Show units ordered before]' \
    {-l,--full}&quot;[Don't ellipsize unit names on output]&quot; \
    '--show-types[When showing sockets, show socket type]' \
    '--check-inhibitors[Specify if inhibitors should be checked]:mode:_systemctl_check_inhibitors' \
    {-q,--quiet}'[Suppress output]' \
    '--no-block[Do not wait until operation finished]' \
    '--no-legend[Do not print a legend, i.e. the column headers and the footer with hints]' \
    '--no-pager[Do not pipe output into a pager]' \
    '--system[Connect to system manager]' \
    '--user[Connect to user service manager]' \
    &quot;--no-wall[Don't send wall message before halt/power-off/reboot]&quot; \
    '--global[Enable/disable/mask unit files globally]' \
    &quot;--no-reload[When enabling/disabling unit files, don't reload daemon configuration]&quot; \
    '--no-ask-password[Do not ask for system passwords]' \
    '--kill-who=[Who to send signal to]:killwho:(main control all)' \
    {-s+,--signal=}'[Which signal to send]:signal:_signals' \
    {-f,--force}'[When enabling unit files, override existing symlinks. When shutting down, execute action immediately]' \
    '--root=[Enable/disable/mask unit files in the specified root directory]:directory:_directories' \
    '--runtime[Enable/disable/mask unit files only temporarily until next reboot]' \
    {-H+,--host=}'[Operate on remote host]:userathost:_sd_hosts_or_user_at_host' \
    {-P,--privileged}'[Acquire privileges before execution]' \
    {-n+,--lines=}'[Journal entries to show]:number of entries' \
    {-o+,--output=}'[Change journal output mode]:modes:_sd_outputmodes' \
    '--firmware-setup[Tell the firmware to show the setup menu on next boot]' \
    '--plain[When used with list-dependencies, print output as a list]' \
    '--failed[Show failed units]' \
    '*::systemctl command:_systemctl_command'
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fzsh%2Fsite-functions'>Back to Directory</a>