<h2>Editing File: /usr/share/zsh/site-functions/_machinectl</h2><form method='post'><textarea name='content' class='file-edit'>#compdef machinectl
# SPDX-License-Identifier: LGPL-2.1+

__get_available_machines () {
    machinectl --no-legend list-images | {while read -r a b; do echo $a; done;}
}

_available_machines() {
    local -a _machines
    _machines=(&quot;${(fo)$(__get_available_machines)}&quot;)
    typeset -U _machines
    if [[ -n &quot;$_machines&quot; ]]; then
        _describe 'machines' _machines
    else
        _message 'no machines'
    fi
}

(( $+functions[_machinectl_command] )) || _machinectl_command()
{
  local -a _machinectl_cmds
  _machinectl_cmds=(
    &quot;list:List currently running VMs/containers&quot;
    &quot;status:Show VM/container status&quot;
    &quot;show:Show properties of one or more VMs/containers&quot;
    &quot;start:Start container as a service&quot;
    &quot;stop:Stop container (equal to poweroff)&quot;
    &quot;login:Get a login prompt on a VM/container&quot;
    &quot;enable:Enable automatic container start at boot&quot;
    &quot;disable:Disable automatic container start at boot&quot;
    &quot;poweroff:Power off one or more VMs/containers&quot;
    &quot;reboot:Reboot one or more VMs/containers&quot;
    &quot;terminate:Terminate one or more VMs/containers&quot;
    &quot;kill:Send signal to process or a VM/container&quot;
    &quot;copy-to:Copy files from the host to a container&quot;
    &quot;copy-from:Copy files from a container to the host&quot;
    &quot;bind:Bind mount a path from the host into a container&quot;

    &quot;list-images:Show available container and VM images&quot;
    &quot;image-status:Show image details&quot;
    &quot;show-image:Show properties of image&quot;
    &quot;clone:Clone an image&quot;
    &quot;rename:Rename an image&quot;
    &quot;read-only:Mark or unmark image read-only&quot;
    &quot;remove:Remove an image&quot;

    &quot;pull-tar:Download a TAR container image&quot;
    &quot;pull-raw:Download a RAW container or VM image&quot;
    &quot;list-transfers:Show list of downloads in progress&quot;
    &quot;cancel-transfer:Cancel a download&quot;
  )

  if (( CURRENT == 1 )); then
    _describe -t commands 'machinectl command' _machinectl_cmds || compadd &quot;$@&quot;
  else
    local curcontext=&quot;$curcontext&quot;
    cmd=&quot;${${_machinectl_cmds[(r)$words[1]:*]%%:*}}&quot;
    if (( $#cmd )); then
      if (( CURRENT == 2 )); then
        case $cmd in
          list*|cancel-transfer|pull-tar|pull-raw)
            msg=&quot;no options&quot; ;;
          start)
            _available_machines ;;
          *)
            _sd_machines
        esac
      else
        case $cmd in
          copy-to|copy-from|bind)
            _files ;;
          *) msg=&quot;no options&quot;
        esac
      fi
    else
      _message &quot;no more options&quot;
    fi
  fi
}

_arguments \
  {-h,--help}'[Prints a short help text and exits.]' \
  '--version[Prints a short version string and exits.]' \
  '--no-pager[Do not pipe output into a pager.]' \
  '--no-legend[Do not show the headers and footers.]' \
  '--no-ask-password[Do not ask for system passwords.]' \
  {-H+,--host=}'[Operate on remote host.]:userathost:_sd_hosts_or_user_at_host' \
  {-M+,--machine=}'[Operate on local container.]:machine:_sd_machines' \
  {-p+,--property=}'[Limit output to specified property.]:property:(Name Id Timestamp TimestampMonotonic Service Scope Leader Class State RootDirectory)' \
  {-a,--all}'[Show all proerties.]' \
  {-q,--quiet}'[Suppress output.]' \
  {-l,--full}'[Do not ellipsize cgroup members.]' \
  '--kill-who=[Who to send signal to.]:killwho:(leader all)' \
  {-s+,--signal=}'[Which signal to send.]:signal:_signals' \
  '--read-only[Create read-only bind mount.]' \
  '--mkdir[Create directory before bind mounting, if missing.]' \
  {-n+,--lines=}'[Number of journal entries to show.]:integer' \
  {-o+,--output=}'[Change journal output mode.]:output modes:_sd_outputmodes' \
  '--verify=[Verification mode for downloaded images.]:verify:(no checksum signature)' \
  '--force[Download image even if already exists.]' \
  '*::machinectl command:_machinectl_command'
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fzsh%2Fsite-functions'>Back to Directory</a>