<h2>Editing File: /usr/share/vim/vim80/syntax/j.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim syntax file
&quot; Language:	J
&quot; Maintainer:	David Bürgin &lt;676c7473@gmail.com&gt;
&quot; URL:		https://github.com/glts/vim-j
&quot; Last Change:	2015-01-11

if exists('b:current_syntax')
  finish
endif

let s:save_cpo = &amp;cpo
set cpo&amp;vim

syntax case match
syntax sync minlines=100

syntax cluster jStdlibItems contains=jStdlibNoun,jStdlibAdverb,jStdlibConjunction,jStdlibVerb
syntax cluster jPrimitiveItems contains=jNoun,jAdverb,jConjunction,jVerb,jCopula

syntax match jControl /\&lt;\%(assert\|break\|case\|catch[dt]\=\|continue\|do\|else\%(if\)\=\|end\|fcase\|for\|if\|return\|select\|throw\|try\|whil\%(e\|st\)\)\./
syntax match jControl /\&lt;\%(for\|goto\|label\)_\a\k*\./

&quot; Standard library names. A few names need to be defined with &quot;:syntax match&quot;
&quot; because they would otherwise take precedence over the corresponding jControl
&quot; and jDefineExpression items.
syntax keyword jStdlibNoun ARGV BINPATH CR CRLF DEL Debug EAV EMPTY FF FHS IF64 IFIOS IFJCDROID IFJHS IFQT IFRASPI IFUNIX IFWIN IFWINCE IFWINE IFWOW64 JB01 JBOXED JCHAR JCMPX JFL JINT JPTR JSIZES JSTR JTYPES JVERSION LF LF2 TAB UNAME UNXLIB dbhelp libjqt
syntax keyword jStdlibAdverb define each every fapplylines inv inverse items leaf rows rxapply rxmerge table
syntax keyword jStdlibConjunction bind cuts def on
syntax keyword jStdlibVerb AND Endian IFDEF OR XOR anddf android_exec_am android_exec_host andunzip apply boxopen boxxopen bx calendar cd cdcb cder cderx cdf charsub chopstring cleartags clear coclass cocreate cocurrent codestroy coerase cofind cofindv cofullname coinfo coinsert compare coname conames conew conl conouns conounsx copath copathnl copathnlx coreset costate cut cutLF cutopen cutpara datatype dbctx dberm dberr dbg dbjmp dblocals dblxq dblxs dbnxt dbq dbr dbret dbrr dbrrx dbrun dbs dbsig dbsq dbss dbst dbstack dbstk dbstop dbstopme dbstopnext dbstops dbtrace dbview deb debc delstring detab dfh dir dircompare dircompares dirfind dirpath dirss dirssrplc dirtree dirused dlb dltb dltbs dquote drop dropafter dropto dtb dtbs echo empty endian erase evtloop exit expand f2utf8 fappend fappends fboxname fc fcompare fcompares fcopynew fdir ferase fetch fexist fexists fgets file2url fixdotdot fliprgb fmakex foldpara foldtext fpathcreate fpathname fputs fread freadblock freadr freads frename freplace fsize fss fssrplc fstamp fstringreplace ftype fview fwrite fwritenew fwrites getalpha getargs getdate getenv getqtbin hfd hostpathsep ic install iospath isatty isotimestamp isutf8 jcwdpath joinstring jpath jpathsep jsystemdefs launch list ljust load loadd loadtags mema memf memr memw nameclass namelist names nc nl pick quote require rjust rplc rxE rxall rxcomp rxcut rxeq rxerror rxfirst rxfree rxfrom rxhandles rxin rxindex rxinfo rxmatch rxmatches rxrplc rxutf8 script scriptd scripts setalpha setbreak shell show sign sminfo smoutput sort split splitnostring splitstring ss startupandroid startupconsole startupide stderr stdin stdout stringreplace symdat symget symset ta tagcp tagopen tagselect take takeafter taketo timespacex timestamp timex tmoutput toCRLF toHOST toJ todate todayno tolower topara toupper tsdiff tsrep tstamp type ucp ucpcount unxlib usleep utf8 uucp valdate wcsize weekday weeknumber weeksinyear winpathsep xedit
syntax match jStdlibNoun /\&lt;\%(adverb\|conjunction\|dyad\|monad\|noun\|verb\)\&gt;/
syntax match jStdlibVerb /\&lt;\%(Note\|\%(assert\|break\|do\)\.\@!\)\&gt;/

&quot; Numbers. Matching J numbers is difficult. In fact, the job cannot be done
&quot; with regular expressions alone. Below is a sketch of the pattern used. It
&quot; accepts most well-formed numbers and rejects most of the ill-formed ones.
&quot; See http://www.jsoftware.com/help/dictionary/dcons.htm for reference.
&quot;
&quot; &quot;double1&quot; and &quot;double2&quot; patterns:
&quot;     (_?\d+(\.\d*)?|_\.\d+)([eE]_?\d+)?
&quot;     (_?\d+(\.\d*)?|_\.\d+|\.\d+)([eE]_?\d+)?
&quot;
&quot; &quot;rational1&quot; and &quot;rational2&quot; patterns:
&quot;     \k&lt;double1&gt;(r\k&lt;double2&gt;)?|__?
&quot;     \k&lt;double2&gt;(r\k&lt;double2&gt;)?|__?
&quot;
&quot; &quot;complex1&quot; and &quot;complex2&quot; patterns:
&quot;     \k&lt;rational1&gt;((j|a[dr])\k&lt;rational2&gt;)?
&quot;     \k&lt;rational2&gt;((j|a[dr])\k&lt;rational2&gt;)?
&quot;
&quot; &quot;basevalue&quot; pattern:
&quot;     _?[0-9a-z]+(\.[0-9a-z]*)?|_?\.[0-9a-z]+
&quot;
&quot; all numbers:
&quot;     \b\k&lt;complex1&gt;([px]\k&lt;complex2&gt;)?(b\k&lt;basevalue&gt;)?(?![0-9A-Za-z_.])
syntax match jNumber /\&lt;_\.[0-9A-Za-z_.]\@!/
syntax match jNumber /\&lt;_\=\d\+x[0-9A-Za-z_.]\@!/
syntax match jNumber /\&lt;\%(__\=r_\=\d\+\|_\=\d\+r__\=\)[0-9A-Za-z_.]\@!/
syntax match jNumber /\&lt;\%(\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\)\%([eE]_\=\d\+\)\=\%(r\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\|\.\d\+\)\%([eE]_\=\d\+\)\=\)\=\|__\=\)\%(\%(j\|a[dr]\)\%(\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\|\.\d\+\)\%([eE]_\=\d\+\)\=\%(r\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\|\.\d\+\)\%([eE]_\=\d\+\)\=\)\=\|__\=\)\)\=\%([px]\%(\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\|\.\d\+\)\%([eE]_\=\d\+\)\=\%(r\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\|\.\d\+\)\%([eE]_\=\d\+\)\=\)\=\|__\=\)\%(\%(j\|a[dr]\)\%(\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\|\.\d\+\)\%([eE]_\=\d\+\)\=\%(r\%(_\=\d\+\%(\.\d*\)\=\|_\.\d\+\|\.\d\+\)\%([eE]_\=\d\+\)\=\)\=\|__\=\)\)\=\)\=\%(b\%(_\=[0-9a-z]\+\%(\.[0-9a-z]*\)\=\|_\=\.[0-9a-z]\+\)\)\=[0-9A-Za-z_.]\@!/

syntax region jString oneline start=/'/ skip=/''/ end=/'/

syntax keyword jArgument contained x y u v m n

&quot; Primitives. Order is significant both within the patterns and among
&quot; &quot;:syntax match&quot; statements. Refer to &quot;Parts of speech&quot; in the J dictionary.
syntax match jNoun /\&lt;a[.:]/
syntax match jAdverb /[}~]\|[/\\]\.\=\|\&lt;\%([Mbft]\.\|t:\)/
syntax match jConjunction /&quot;\|`:\=\|[.:@&amp;][.:]\=\|&amp;\.:\|\&lt;\%([dDHT]\.\|[DLS]:\)/
syntax match jVerb /[=!\]]\|[\^?]\.\=\|[;[]:\=\|{\.\|[_/\\]:\|[&lt;&gt;+*\-%$|,#][.:]\=\|[~}&quot;][.:]\|{\%[::]\|\&lt;\%([ACeEiIjLor]\.\|p\.\.\=\|[ipqsux]:\|0:\|_\=[1-9]:\)/
syntax match jCopula /=[.:]/
syntax match jConjunction /;\.\|\^:\|![.:]/

&quot; Explicit noun definition. The difficulty is that the define expression can
&quot; occur in the middle of a line but the jNounDefine region must only start on
&quot; the next line. The trick is to split the problem into two regions and link
&quot; them with &quot;nextgroup=&quot;. The fold wrapper provides syntax folding.
syntax region jNounDefineFold
    \ matchgroup=NONE start=/\%(\%(\%(^\s*Note\)\|\&lt;\%(0\|noun\)\s\+\%(\:\s*0\|def\s\+0\|define\)\)\&gt;\)\@=/
    \ keepend matchgroup=NONE end=/^\s*)\s*$/
    \ contains=jNounDefineStart
    \ fold
syntax region jNounDefineStart
    \ matchgroup=jDefineExpression start=/\%(\%(^\s*Note\)\|\&lt;\%(0\|noun\)\s\+\%(\:\s*0\|def\s\+0\|define\)\)\&gt;/
    \ keepend matchgroup=NONE end=/$/
    \ contains=@jStdlibItems,@jPrimitiveItems,jNumber,jString,jParenGroup,jParen,jComment
    \ contained oneline skipempty nextgroup=jDefineEnd,jNounDefine
&quot; These two items must have &quot;contained&quot;, which allows them to match only after
&quot; jNounDefineStart thanks to the &quot;nextgroup=&quot; above.
syntax region jNounDefine
    \ matchgroup=NONE start=/^/
    \ matchgroup=jDefineEnd end=/^\s*)\s*$/
    \ contained
&quot; This match is necessary in case of an empty noun definition
syntax match jDefineEnd contained /^\s*)\s*$/

&quot; Explicit verb, adverb, and conjunction definition
syntax region jDefine
    \ matchgroup=jDefineExpression start=/\&lt;\%([1-4]\|13\|adverb\|conjunction\|verb\|monad\|dyad\)\s\+\%(:\s*0\|def\s\+0\|define\)\&gt;/
    \ matchgroup=jDefineEnd end=/^\s*)\s*$/
    \ contains=jControl,@jStdlibItems,@jPrimitiveItems,jNumber,jString,jArgument,jParenGroup,jParen,jComment,jDefineMonadDyad
    \ fold
syntax match jDefineMonadDyad contained /^\s*:\s*$/

&quot; Paired parentheses. When a jDefineExpression such as &quot;3 : 0&quot; is
&quot; parenthesised it will erroneously extend jParenGroup to span over the whole
&quot; definition body. This situation receives a special treatment here.
syntax match jParen /(\%(\s*\%([0-4]\|13\|noun\|adverb\|conjunction\|verb\|monad\|dyad\)\s\+\%(:\s*0\|def\s\+0\|define\)\s*)\)\@=/
syntax match jParen contained /\%((\s*\%([0-4]\|13\|noun\|adverb\|conjunction\|verb\|monad\|dyad\)\s\+\%(:\s*0\|def\s\+0\|define\)\s*\)\@&lt;=)/
syntax region jParenGroup
    \ matchgroup=jParen start=/(\%(\s*\%([0-4]\|13\|noun\|adverb\|conjunction\|verb\|monad\|dyad\)\s\+\%(:\s*0\|def\s\+0\|define\)\&gt;\)\@!/
    \ matchgroup=jParen end=/)/
    \ oneline transparent

syntax keyword jTodo contained TODO FIXME XXX
syntax match jComment /\&lt;NB\..*$/ contains=jTodo,@Spell

syntax match jSharpBang /\%^#!.*$/

highlight default link jControl           Statement
highlight default link jStdlibNoun        Identifier
highlight default link jStdlibAdverb      Function
highlight default link jStdlibConjunction Function
highlight default link jStdlibVerb        Function
highlight default link jString            String
highlight default link jNumber            Number
highlight default link jNoun              Constant
highlight default link jAdverb            Normal
highlight default link jConjunction       Normal
highlight default link jVerb              Normal
highlight default link jCopula            Normal
highlight default link jArgument          Identifier
highlight default link jParen             Delimiter

highlight default link jDefineExpression  Define
highlight default link jDefineMonadDyad   Delimiter
highlight default link jDefineEnd         Delimiter
highlight default link jNounDefine        Normal

highlight default link jTodo              Todo
highlight default link jComment           Comment
highlight default link jSharpBang         PreProc

let b:current_syntax = 'j'

let &amp;cpo = s:save_cpo
unlet s:save_cpo
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fsyntax'>Back to Directory</a>