<h2>Editing File: /usr/share/vim/vim80/syntax/erlang.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim syntax file
&quot; Language:     Erlang (http://www.erlang.org)
&quot; Maintainer:   Csaba Hoch &lt;csaba.hoch@gmail.com&gt;
&quot; Contributor:  Adam Rutkowski &lt;hq@mtod.org&gt;
&quot; Last Update:  2017-Mar-05
&quot; License:      Vim license
&quot; URL:          https://github.com/vim-erlang/vim-erlang-runtime

&quot; Acknowledgements: This script was originally created by Kresimir Marzic [1].
&quot; The script was then revamped by Csaba Hoch [2]. During the revamp, the new
&quot; highlighting style and some code was taken from the Erlang syntax script
&quot; that is part of vimerl [3], created by Oscar Hellström [4] and improved by
&quot; Ricardo Catalinas Jiménez [5].

&quot; [1]: Kreąimir Marľić (Kresimir Marzic) &lt;kmarzic@fly.srk.fer.hr&gt;
&quot; [2]: Csaba Hoch &lt;csaba.hoch@gmail.com&gt;
&quot; [3]: https://github.com/jimenezrick/vimerl
&quot; [4]: Oscar Hellström &lt;oscar@oscarh.net&gt; (http://oscar.hellstrom.st)
&quot; [5]: Ricardo Catalinas Jiménez &lt;jimenezrick@gmail.com&gt;

&quot; Customization:
&quot;
&quot; To use the old highlighting style, add this to your .vimrc:
&quot;
&quot;     let g:erlang_old_style_highlight = 1
&quot;
&quot; To highlight further module attributes, add them to
&quot; ~/.vim/after/syntax/erlang.vim:
&quot;
&quot;     syn keyword erlangAttribute myattr1 myattr2 contained

&quot; quit when a syntax file was already loaded
if exists(&quot;b:current_syntax&quot;)
    finish
endif

let s:cpo_save = &amp;cpo
set cpo&amp;vim

&quot; Case sensitive
syn case match

setlocal iskeyword+=$,@-@

&quot; Comments
syn match erlangComment           '%.*$' contains=erlangCommentAnnotation,erlangTodo
syn match erlangCommentAnnotation ' \@&lt;=@\%(clear\|docfile\|end\|headerfile\|todo\|TODO\|type\|author\|copyright\|doc\|reference\|see\|since\|title\|version\|deprecated\|hidden\|private\|equiv\|spec\|throws\)' contained
syn match erlangCommentAnnotation /`[^']*'/ contained
syn keyword erlangTodo            TODO FIXME XXX contained

&quot; Numbers (minimum base is 2, maximum is 36.)
syn match erlangNumberInteger '\&lt;\d\+\&gt;'
syn match erlangNumberInteger '\&lt;\%([2-9]\|[12]\d\|3[0-6]\)\+#[[:alnum:]]\+\&gt;'
syn match erlangNumberFloat   '\&lt;\d\+\.\d\+\%([eE][+-]\=\d\+\)\=\&gt;'

&quot; Strings, atoms, characters
syn region erlangString            start=/&quot;/ end=/&quot;/ contains=erlangStringModifier
syn region erlangQuotedAtom        start=/'/ end=/'/ contains=erlangQuotedAtomModifier
syn match erlangStringModifier     '\\\%(\o\{1,3}\|x\x\x\|x{\x\+}\|\^.\|.\)\|\~\%([ni~]\|\%(-\=\d\+\|\*\)\=\.\=\%(\*\|\d\+\)\=\%(\..\)\=[tl]*[cfegswpWPBX#bx+]\)' contained
syn match erlangQuotedAtomModifier '\\\%(\o\{1,3}\|x\x\x\|x{\x\+}\|\^.\|.\)' contained
syn match erlangModifier           '\$\%([^\\]\|\\\%(\o\{1,3}\|x\x\x\|x{\x\+}\|\^.\|.\)\)'

&quot; Operators, separators
syn match erlangOperator   '==\|=:=\|/=\|=/=\|&lt;\|=&lt;\|&gt;\|&gt;=\|=&gt;\|:=\|++\|--\|=\|!\|&lt;-\|+\|-\|\*\|\/'
syn keyword erlangOperator div rem or xor bor bxor bsl bsr and band not bnot andalso orelse
syn match erlangBracket    '{\|}\|\[\|]\||\|||'
syn match erlangPipe       '|'
syn match erlangRightArrow '-&gt;'

&quot; Atoms, function calls (order is important)
syn match erlangAtom           '\&lt;\l[[:alnum:]_@]*' contains=erlangBoolean
syn keyword erlangBoolean      true false contained
syn match erlangLocalFuncCall  '\&lt;\a[[:alnum:]_@]*\&gt;\%(\%(\s\|\n\|%.*\n\)*(\)\@=' contains=erlangBIF
syn match erlangLocalFuncRef   '\&lt;\a[[:alnum:]_@]*\&gt;\%(\%(\s\|\n\|%.*\n\)*/\)\@='
syn match erlangGlobalFuncCall '\&lt;\%(\a[[:alnum:]_@]*\%(\s\|\n\|%.*\n\)*\.\%(\s\|\n\|%.*\n\)*\)*\a[[:alnum:]_@]*\%(\s\|\n\|%.*\n\)*:\%(\s\|\n\|%.*\n\)*\a[[:alnum:]_@]*\&gt;\%(\%(\s\|\n\|%.*\n\)*(\)\@=' contains=erlangComment,erlangVariable
syn match erlangGlobalFuncRef  '\&lt;\%(\a[[:alnum:]_@]*\%(\s\|\n\|%.*\n\)*\.\%(\s\|\n\|%.*\n\)*\)*\a[[:alnum:]_@]*\%(\s\|\n\|%.*\n\)*:\%(\s\|\n\|%.*\n\)*\a[[:alnum:]_@]*\&gt;\%(\%(\s\|\n\|%.*\n\)*/\)\@=' contains=erlangComment,erlangVariable

&quot; Variables, macros, records, maps
syn match erlangVariable '\&lt;[A-Z_][[:alnum:]_@]*'
syn match erlangMacro    '??\=[[:alnum:]_@]\+'
syn match erlangMacro    '\%(-define(\)\@&lt;=[[:alnum:]_@]\+'
syn match erlangMap      '#'
syn match erlangRecord   '#\s*\l[[:alnum:]_@]*'
syn region erlangQuotedRecord        start=/#\s*'/ end=/'/ contains=erlangQuotedAtomModifier

&quot; Shebang (this line has to be after the ErlangMap)
syn match erlangShebang  '^#!.*'

&quot; Bitstrings
syn match erlangBitType '\%(\/\%(\s\|\n\|%.*\n\)*\)\@&lt;=\%(integer\|float\|binary\|bytes\|bitstring\|bits\|binary\|utf8\|utf16\|utf32\|signed\|unsigned\|big\|little\|native\|unit\)\%(\%(\s\|\n\|%.*\n\)*-\%(\s\|\n\|%.*\n\)*\%(integer\|float\|binary\|bytes\|bitstring\|bits\|binary\|utf8\|utf16\|utf32\|signed\|unsigned\|big\|little\|native\|unit\)\)*' contains=erlangComment

&quot; Constants and Directives
syn match erlangUnknownAttribute '^\s*-\%(\s\|\n\|%.*\n\)*\l[[:alnum:]_@]*' contains=erlangComment
syn match erlangAttribute '^\s*-\%(\s\|\n\|%.*\n\)*\%(behaviou\=r\|compile\|export\(_type\)\=\|file\|import\|module\|author\|copyright\|doc\|vsn\|on_load\)\&gt;' contains=erlangComment
syn match erlangInclude   '^\s*-\%(\s\|\n\|%.*\n\)*\%(include\|include_lib\)\&gt;' contains=erlangComment
syn match erlangRecordDef '^\s*-\%(\s\|\n\|%.*\n\)*record\&gt;' contains=erlangComment
syn match erlangDefine    '^\s*-\%(\s\|\n\|%.*\n\)*\%(define\|undef\)\&gt;' contains=erlangComment
syn match erlangPreCondit '^\s*-\%(\s\|\n\|%.*\n\)*\%(ifdef\|ifndef\|else\|endif\)\&gt;' contains=erlangComment
syn match erlangType      '^\s*-\%(\s\|\n\|%.*\n\)*\%(spec\|type\|opaque\|callback\)\&gt;' contains=erlangComment

&quot; Keywords
syn keyword erlangKeyword after begin case catch cond end fun if let of
syn keyword erlangKeyword receive when try

&quot; Build-in-functions (BIFs)
syn keyword erlangBIF abs alive apply atom_to_binary atom_to_list contained
syn keyword erlangBIF binary_part binary_to_atom contained
syn keyword erlangBIF binary_to_existing_atom binary_to_float contained
syn keyword erlangBIF binary_to_integer bitstring_to_list contained
syn keyword erlangBIF binary_to_list binary_to_term bit_size contained
syn keyword erlangBIF byte_size check_old_code check_process_code contained
syn keyword erlangBIF concat_binary date delete_module demonitor contained
syn keyword erlangBIF disconnect_node element erase error exit contained
syn keyword erlangBIF float float_to_binary float_to_list contained
syn keyword erlangBIF garbage_collect get get_keys group_leader contained
syn keyword erlangBIF halt hd integer_to_binary integer_to_list contained
syn keyword erlangBIF iolist_to_binary iolist_size is_alive contained
syn keyword erlangBIF is_atom is_binary is_bitstring is_boolean contained
syn keyword erlangBIF is_float is_function is_integer is_list contained
syn keyword erlangBIF is_number is_pid is_port is_process_alive contained
syn keyword erlangBIF is_record is_reference is_tuple length link contained
syn keyword erlangBIF list_to_atom list_to_binary contained
syn keyword erlangBIF list_to_bitstring list_to_existing_atom contained
syn keyword erlangBIF list_to_float list_to_integer list_to_pid contained
syn keyword erlangBIF list_to_tuple load_module make_ref max min contained
syn keyword erlangBIF module_loaded monitor monitor_node node contained
syn keyword erlangBIF nodes now open_port pid_to_list port_close contained
syn keyword erlangBIF port_command port_connect pre_loaded contained
syn keyword erlangBIF process_flag process_flag process_info contained
syn keyword erlangBIF process purge_module put register registered contained
syn keyword erlangBIF round self setelement size spawn spawn_link contained
syn keyword erlangBIF spawn_monitor spawn_opt split_binary contained
syn keyword erlangBIF statistics term_to_binary throw time tl contained
syn keyword erlangBIF trunc tuple_size tuple_to_list unlink contained
syn keyword erlangBIF unregister whereis contained

&quot; Sync at the beginning of functions: if this is not used, multiline string
&quot; are not always recognized, and the indentation script cannot use the
&quot; &quot;searchpair&quot; (because it would not always skip strings and comments when
&quot; looking for keywords and opening parens/brackets).
syn sync match erlangSync grouphere NONE &quot;^[a-z]\s*(&quot;
let b:erlang_syntax_synced = 1

&quot; Define the default highlighting. See &quot;:help group-name&quot; for the groups and
&quot; their colors.

let s:old_style = (exists(&quot;g:erlang_old_style_highlight&quot;) &amp;&amp;
                  \g:erlang_old_style_highlight == 1)


&quot; Comments
hi def link erlangComment Comment
hi def link erlangCommentAnnotation Special
hi def link erlangTodo Todo
hi def link erlangShebang Comment

&quot; Numbers
hi def link erlangNumberInteger Number
hi def link erlangNumberFloat Float

&quot; Strings, atoms, characters
hi def link erlangString String

if s:old_style
hi def link erlangQuotedAtom Type
else
hi def link erlangQuotedAtom String
endif

hi def link erlangStringModifier Special
hi def link erlangQuotedAtomModifier Special
hi def link erlangModifier Special

&quot; Operators, separators
hi def link erlangOperator Operator
hi def link erlangRightArrow Operator
if s:old_style
hi def link erlangBracket Normal
hi def link erlangPipe Normal
else
hi def link erlangBracket Delimiter
hi def link erlangPipe Delimiter
endif

&quot; Atoms, functions, variables, macros
if s:old_style
hi def link erlangAtom Normal
hi def link erlangLocalFuncCall Normal
hi def link erlangLocalFuncRef Normal
hi def link erlangGlobalFuncCall Function
hi def link erlangGlobalFuncRef Function
hi def link erlangVariable Normal
hi def link erlangMacro Normal
hi def link erlangRecord Normal
hi def link erlangQuotedRecord Normal
hi def link erlangMap Normal
else
hi def link erlangAtom String
hi def link erlangLocalFuncCall Normal
hi def link erlangLocalFuncRef Normal
hi def link erlangGlobalFuncCall Normal
hi def link erlangGlobalFuncRef Normal
hi def link erlangVariable Identifier
hi def link erlangMacro Macro
hi def link erlangRecord Structure
hi def link erlangQuotedRecord Structure
hi def link erlangMap Structure
endif

&quot; Bitstrings
if !s:old_style
hi def link erlangBitType Type
endif

&quot; Constants and Directives
if s:old_style
hi def link erlangAttribute Type
hi def link erlangMacroDef Type
hi def link erlangUnknownAttribute Normal
hi def link erlangInclude Type
hi def link erlangRecordDef Type
hi def link erlangDefine Type
hi def link erlangPreCondit Type
hi def link erlangType Type
else
hi def link erlangAttribute Keyword
hi def link erlangMacroDef Macro
hi def link erlangUnknownAttribute Normal
hi def link erlangInclude Include
hi def link erlangRecordDef Keyword
hi def link erlangDefine Define
hi def link erlangPreCondit PreCondit
hi def link erlangType Type
endif

&quot; Keywords
hi def link erlangKeyword Keyword

&quot; Build-in-functions (BIFs)
hi def link erlangBIF Function

if s:old_style
hi def link erlangBoolean Statement
hi def link erlangExtra Statement
hi def link erlangSignal Statement
else
hi def link erlangBoolean Boolean
hi def link erlangExtra Statement
hi def link erlangSignal Statement
endif


let b:current_syntax = &quot;erlang&quot;

let &amp;cpo = s:cpo_save
unlet s:cpo_save

&quot; vim: sw=2 et
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fsyntax'>Back to Directory</a>