<h2>Editing File: /usr/share/vim/vim80/pack/dist/opt/editexisting/plugin/editexisting.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim Plugin:	Edit the file with an existing Vim if possible
&quot; Maintainer:	Bram Moolenaar
&quot; Last Change:	2016 Mar 28

&quot; To use add &quot;:packadd! editexisting&quot; in your vimrc file.

&quot; This plugin serves two purposes:
&quot; 1. On startup, if we were invoked with one file name argument and the file
&quot;    is not modified then try to find another Vim instance that is editing
&quot;    this file.  If there is one then bring it to the foreground and exit.
&quot; 2. When a file is edited and a swap file exists for it, try finding that
&quot;    other Vim and bring it to the foreground.  Requires Vim 7, because it
&quot;    uses the SwapExists autocommand event.

&quot; Function that finds the Vim instance that is editing &quot;filename&quot; and brings
&quot; it to the foreground.
func s:EditElsewhere(filename)
  let fname_esc = substitute(a:filename, &quot;'&quot;, &quot;''&quot;, &quot;g&quot;)

  let servers = serverlist()
  while servers != ''
    &quot; Get next server name in &quot;servername&quot;; remove it from &quot;servers&quot;.
    let i = match(servers, &quot;\n&quot;)
    if i == -1
      let servername = servers
      let servers = ''
    else
      let servername = strpart(servers, 0, i)
      let servers = strpart(servers, i + 1)
    endif

    &quot; Skip ourselves.
    if servername ==? v:servername
      continue
    endif

    &quot; Check if this server is editing our file.
    if remote_expr(servername, &quot;bufloaded('&quot; . fname_esc . &quot;')&quot;)
      &quot; Yes, bring it to the foreground.
      if has(&quot;win32&quot;)
	call remote_foreground(servername)
      endif
      call remote_expr(servername, &quot;foreground()&quot;)

      if remote_expr(servername, &quot;exists('*EditExisting')&quot;)
	&quot; Make sure the file is visible in a window (not hidden).
	&quot; If v:swapcommand exists and is set, send it to the server.
	if exists(&quot;v:swapcommand&quot;)
	  let c = substitute(v:swapcommand, &quot;'&quot;, &quot;''&quot;, &quot;g&quot;)
	  call remote_expr(servername, &quot;EditExisting('&quot; . fname_esc . &quot;', '&quot; . c . &quot;')&quot;)
	else
	  call remote_expr(servername, &quot;EditExisting('&quot; . fname_esc . &quot;', '')&quot;)
	endif
      endif

      if !(has('vim_starting') &amp;&amp; has('gui_running') &amp;&amp; has('gui_win32'))
	&quot; Tell the user what is happening.  Not when the GUI is starting
	&quot; though, it would result in a message box.
	echomsg &quot;File is being edited by &quot; . servername
	sleep 2
      endif
      return 'q'
    endif
  endwhile
  return ''
endfunc

&quot; When the plugin is loaded and there is one file name argument: Find another
&quot; Vim server that is editing this file right now.
if argc() == 1 &amp;&amp; !&amp;modified
  if s:EditElsewhere(expand(&quot;%:p&quot;)) == 'q'
    quit
  endif
endif

&quot; Setup for handling the situation that an existing swap file is found.
try
  au! SwapExists * let v:swapchoice = s:EditElsewhere(expand(&quot;&lt;afile&gt;:p&quot;))
catch
  &quot; Without SwapExists we don't do anything for &quot;:edit&quot; commands
endtry

&quot; Function used on the server to make the file visible and possibly execute a
&quot; command.
func! EditExisting(fname, command)
  &quot; Get the window number of the file in the current tab page.
  let winnr = bufwinnr(a:fname)
  if winnr &lt;= 0
    &quot; Not found, look in other tab pages.
    let bufnr = bufnr(a:fname)
    for i in range(tabpagenr('$'))
      if index(tabpagebuflist(i + 1), bufnr) &gt;= 0
	&quot; Make this tab page the current one and find the window number.
	exe 'tabnext ' . (i + 1)
	let winnr = bufwinnr(a:fname)
	break
      endif
    endfor
  endif

  if winnr &gt; 0
    exe winnr . &quot;wincmd w&quot;
  elseif exists('*fnameescape')
    exe &quot;split &quot; . fnameescape(a:fname)
  else
    exe &quot;split &quot; . escape(a:fname, &quot; \t\n*?[{`$\\%#'\&quot;|!&lt;&quot;)
  endif

  if a:command != ''
    exe &quot;normal! &quot; . a:command
  endif

  redraw
endfunc
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fpack%2Fdist%2Fopt%2Feditexisting%2Fplugin'>Back to Directory</a>