<h2>Editing File: /usr/share/vim/vim80/indent/vim.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim indent file
&quot; Language:	Vim script
&quot; Maintainer:	Bram Moolenaar &lt;Bram@vim.org&gt;
&quot; Last Change:	2016 Jun 27

&quot; Only load this indent file when no other was loaded.
if exists(&quot;b:did_indent&quot;)
  finish
endif
let b:did_indent = 1

setlocal indentexpr=GetVimIndent()
setlocal indentkeys+==end,=else,=cat,=fina,=END,0\\

let b:undo_indent = &quot;setl indentkeys&lt; indentexpr&lt;&quot;

&quot; Only define the function once.
if exists(&quot;*GetVimIndent&quot;)
  finish
endif
let s:keepcpo= &amp;cpo
set cpo&amp;vim

function GetVimIndent()
  let ignorecase_save = &amp;ignorecase
  try
    let &amp;ignorecase = 0
    return GetVimIndentIntern()
  finally
    let &amp;ignorecase = ignorecase_save
  endtry
endfunc

function GetVimIndentIntern()
  &quot; Find a non-blank line above the current line.
  let lnum = prevnonblank(v:lnum - 1)

  &quot; If the current line doesn't start with '\' and below a line that starts
  &quot; with '\', use the indent of the line above it.
  let cur_text = getline(v:lnum)
  if cur_text !~ '^\s*\\'
    while lnum &gt; 0 &amp;&amp; getline(lnum) =~ '^\s*\\'
      let lnum = lnum - 1
    endwhile
  endif

  &quot; At the start of the file use zero indent.
  if lnum == 0
    return 0
  endif
  let prev_text = getline(lnum)

  &quot; Add a 'shiftwidth' after :if, :while, :try, :catch, :finally, :function
  &quot; and :else.  Add it three times for a line that starts with '\' after
  &quot; a line that doesn't (or g:vim_indent_cont if it exists).
  let ind = indent(lnum)
  if cur_text =~ '^\s*\\' &amp;&amp; v:lnum &gt; 1 &amp;&amp; prev_text !~ '^\s*\\'
    if exists(&quot;g:vim_indent_cont&quot;)
      let ind = ind + g:vim_indent_cont
    else
      let ind = ind + shiftwidth() * 3
    endif
  elseif prev_text =~ '^\s*aug\%[roup]\s\+' &amp;&amp; prev_text !~ '^\s*aug\%[roup]\s\+[eE][nN][dD]\&gt;'
    let ind = ind + shiftwidth()
  else
    &quot; A line starting with :au does not increment/decrement indent.
    if prev_text !~ '^\s*au\%[tocmd]'
      let i = match(prev_text, '\(^\||\)\s*\(if\|wh\%[ile]\|for\|try\|cat\%[ch]\|fina\%[lly]\|fu\%[nction]\|el\%[seif]\)\&gt;')
      if i &gt;= 0
	let ind += shiftwidth()
	if strpart(prev_text, i, 1) == '|' &amp;&amp; has('syntax_items')
	      \ &amp;&amp; synIDattr(synID(lnum, i, 1), &quot;name&quot;) =~ '\(Comment\|String\)$'
	  let ind -= shiftwidth()
	endif
      endif
    endif
  endif

  &quot; If the previous line contains an &quot;end&quot; after a pipe, but not in an &quot;:au&quot;
  &quot; command.  And not when there is a backslash before the pipe.
  &quot; And when syntax HL is enabled avoid a match inside a string.
  let i = match(prev_text, '[^\\]|\s*\(ene\@!\)')
  if i &gt; 0 &amp;&amp; prev_text !~ '^\s*au\%[tocmd]'
    if !has('syntax_items') || synIDattr(synID(lnum, i + 2, 1), &quot;name&quot;) !~ '\(Comment\|String\)$'
      let ind = ind - shiftwidth()
    endif
  endif


  &quot; Subtract a 'shiftwidth' on a :endif, :endwhile, :catch, :finally, :endtry,
  &quot; :endfun, :else and :augroup END.
  if cur_text =~ '^\s*\(ene\@!\|cat\|fina\|el\|aug\%[roup]\s\+[eE][nN][dD]\)'
    let ind = ind - shiftwidth()
  endif

  return ind
endfunction

let &amp;cpo = s:keepcpo
unlet s:keepcpo

&quot; vim:sw=2
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent'>Back to Directory</a>