<h2>Editing File: /usr/share/vim/vim80/indent/r.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim indent file
&quot; Language:	R
&quot; Author:	Jakson Alves de Aquino &lt;jalvesaq@gmail.com&gt;
&quot; Homepage:     https://github.com/jalvesaq/R-Vim-runtime
&quot; Last Change:	Thu Feb 18, 2016  06:32AM


&quot; Only load this indent file when no other was loaded.
if exists(&quot;b:did_indent&quot;)
  finish
endif
let b:did_indent = 1

setlocal indentkeys=0{,0},:,!^F,o,O,e
setlocal indentexpr=GetRIndent()

&quot; Only define the function once.
if exists(&quot;*GetRIndent&quot;)
  finish
endif

&quot; Options to make the indentation more similar to Emacs/ESS:
if !exists(&quot;g:r_indent_align_args&quot;)
  let g:r_indent_align_args = 1
endif
if !exists(&quot;g:r_indent_ess_comments&quot;)
  let g:r_indent_ess_comments = 0
endif
if !exists(&quot;g:r_indent_comment_column&quot;)
  let g:r_indent_comment_column = 40
endif
if ! exists(&quot;g:r_indent_ess_compatible&quot;)
  let g:r_indent_ess_compatible = 0
endif
if ! exists(&quot;g:r_indent_op_pattern&quot;)
  let g:r_indent_op_pattern = '\(&amp;\||\|+\|-\|\*\|/\|=\|\~\|%\|-&gt;\)\s*$'
endif

function s:RDelete_quotes(line)
  let i = 0
  let j = 0
  let line1 = &quot;&quot;
  let llen = strlen(a:line)
  while i &lt; llen
    if a:line[i] == '&quot;'
      let i += 1
      let line1 = line1 . 's'
      while !(a:line[i] == '&quot;' &amp;&amp; ((i &gt; 1 &amp;&amp; a:line[i-1] == '\' &amp;&amp; a:line[i-2] == '\') || a:line[i-1] != '\')) &amp;&amp; i &lt; llen
        let i += 1
      endwhile
      if a:line[i] == '&quot;'
        let i += 1
      endif
    else
      if a:line[i] == &quot;'&quot;
        let i += 1
        let line1 = line1 . 's'
        while !(a:line[i] == &quot;'&quot; &amp;&amp; ((i &gt; 1 &amp;&amp; a:line[i-1] == '\' &amp;&amp; a:line[i-2] == '\') || a:line[i-1] != '\')) &amp;&amp; i &lt; llen
          let i += 1
        endwhile
        if a:line[i] == &quot;'&quot;
          let i += 1
        endif
      else
        if a:line[i] == &quot;`&quot;
          let i += 1
          let line1 = line1 . 's'
          while a:line[i] != &quot;`&quot; &amp;&amp; i &lt; llen
            let i += 1
          endwhile
          if a:line[i] == &quot;`&quot;
            let i += 1
          endif
        endif
      endif
    endif
    if i == llen
      break
    endif
    let line1 = line1 . a:line[i]
    let j += 1
    let i += 1
  endwhile
  return line1
endfunction

&quot; Convert foo(bar()) int foo()
function s:RDelete_parens(line)
  if s:Get_paren_balance(a:line, &quot;(&quot;, &quot;)&quot;) != 0
    return a:line
  endif
  let i = 0
  let j = 0
  let line1 = &quot;&quot;
  let llen = strlen(a:line)
  while i &lt; llen
    let line1 = line1 . a:line[i]
    if a:line[i] == '('
      let nop = 1
      while nop &gt; 0 &amp;&amp; i &lt; llen
        let i += 1
        if a:line[i] == ')'
          let nop -= 1
        else
          if a:line[i] == '('
            let nop += 1
          endif
        endif
      endwhile
      let line1 = line1 . a:line[i]
    endif
    let i += 1
  endwhile
  return line1
endfunction

function! s:Get_paren_balance(line, o, c)
  let line2 = substitute(a:line, a:o, &quot;&quot;, &quot;g&quot;)
  let openp = strlen(a:line) - strlen(line2)
  let line3 = substitute(line2, a:c, &quot;&quot;, &quot;g&quot;)
  let closep = strlen(line2) - strlen(line3)
  return openp - closep
endfunction

function! s:Get_matching_brace(linenr, o, c, delbrace)
  let line = SanitizeRLine(getline(a:linenr))
  if a:delbrace == 1
    let line = substitute(line, '{$', &quot;&quot;, &quot;&quot;)
  endif
  let pb = s:Get_paren_balance(line, a:o, a:c)
  let i = a:linenr
  while pb != 0 &amp;&amp; i &gt; 1
    let i -= 1
    let pb += s:Get_paren_balance(SanitizeRLine(getline(i)), a:o, a:c)
  endwhile
  return i
endfunction

&quot; This function is buggy because there 'if's without 'else'
&quot; It must be rewritten relying more on indentation
function! s:Get_matching_if(linenr, delif)
  let line = SanitizeRLine(getline(a:linenr))
  if a:delif
    let line = substitute(line, &quot;if&quot;, &quot;&quot;, &quot;g&quot;)
  endif
  let elsenr = 0
  let i = a:linenr
  let ifhere = 0
  while i &gt; 0
    let line2 = substitute(line, '\&lt;else\&gt;', &quot;xxx&quot;, &quot;g&quot;)
    let elsenr += strlen(line) - strlen(line2)
    if line =~ '.*\s*if\s*()' || line =~ '.*\s*if\s*()'
      let elsenr -= 1
      if elsenr == 0
        let ifhere = i
        break
      endif
    endif
    let i -= 1
    let line = SanitizeRLine(getline(i))
  endwhile
  if ifhere
    return ifhere
  else
    return a:linenr
  endif
endfunction

function! s:Get_last_paren_idx(line, o, c, pb)
  let blc = a:pb
  let line = substitute(a:line, '\t', s:curtabstop, &quot;g&quot;)
  let theidx = -1
  let llen = strlen(line)
  let idx = 0
  while idx &lt; llen
    if line[idx] == a:o
      let blc -= 1
      if blc == 0
        let theidx = idx
      endif
    else
      if line[idx] == a:c
        let blc += 1
      endif
    endif
    let idx += 1
  endwhile
  return theidx + 1
endfunction

&quot; Get previous relevant line. Search back until getting a line that isn't
&quot; comment or blank
function s:Get_prev_line(lineno)
  let lnum = a:lineno - 1
  let data = getline( lnum )
  while lnum &gt; 0 &amp;&amp; (data =~ '^\s*#' || data =~ '^\s*$')
    let lnum = lnum - 1
    let data = getline( lnum )
  endwhile
  return lnum
endfunction

&quot; This function is also used by r-plugin/common_global.vim
&quot; Delete from '#' to the end of the line, unless the '#' is inside a string.
function SanitizeRLine(line)
  let newline = s:RDelete_quotes(a:line)
  let newline = s:RDelete_parens(newline)
  let newline = substitute(newline, '#.*', &quot;&quot;, &quot;&quot;)
  let newline = substitute(newline, '\s*$', &quot;&quot;, &quot;&quot;)
  if &amp;filetype == &quot;rhelp&quot; &amp;&amp; newline =~ '^\\method{.*}{.*}(.*'
    let newline = substitute(newline, '^\\method{\(.*\)}{.*}', '\1', &quot;&quot;)
  endif
  return newline
endfunction

function GetRIndent()

  let clnum = line(&quot;.&quot;)    &quot; current line

  let cline = getline(clnum)
  if cline =~ '^\s*#'
    if g:r_indent_ess_comments == 1
      if cline =~ '^\s*###'
        return 0
      endif
      if cline !~ '^\s*##'
        return g:r_indent_comment_column
      endif
    endif
  endif

  let cline = SanitizeRLine(cline)

  if cline =~ '^\s*}' || cline =~ '^\s*}\s*)$'
    let indline = s:Get_matching_brace(clnum, '{', '}', 1)
    if indline &gt; 0 &amp;&amp; indline != clnum
      let iline = SanitizeRLine(getline(indline))
      if s:Get_paren_balance(iline, &quot;(&quot;, &quot;)&quot;) == 0 || iline =~ '(\s*{$'
        return indent(indline)
      else
        let indline = s:Get_matching_brace(indline, '(', ')', 1)
        return indent(indline)
      endif
    endif
  endif

  &quot; Find the first non blank line above the current line
  let lnum = s:Get_prev_line(clnum)
  &quot; Hit the start of the file, use zero indent.
  if lnum == 0
    return 0
  endif

  let line = SanitizeRLine(getline(lnum))

  if &amp;filetype == &quot;rhelp&quot;
    if cline =~ '^\\dontshow{' || cline =~ '^\\dontrun{' || cline =~ '^\\donttest{' || cline =~ '^\\testonly{'
      return 0
    endif
    if line =~ '^\\examples{' || line =~ '^\\usage{' || line =~ '^\\dontshow{' || line =~ '^\\dontrun{' || line =~ '^\\donttest{' || line =~ '^\\testonly{'
      return 0
    endif
  endif

  if &amp;filetype == &quot;rnoweb&quot; &amp;&amp; line =~ &quot;^&lt;&lt;.*&gt;&gt;=&quot;
    return 0
  endif

  if cline =~ '^\s*{' &amp;&amp; s:Get_paren_balance(cline, '{', '}') &gt; 0
    if g:r_indent_ess_compatible &amp;&amp; line =~ ')$'
      let nlnum = lnum
      let nline = line
      while s:Get_paren_balance(nline, '(', ')') &lt; 0
        let nlnum = s:Get_prev_line(nlnum)
        let nline = SanitizeRLine(getline(nlnum)) . nline
      endwhile
      if nline =~ '^\s*function\s*(' &amp;&amp; indent(nlnum) == shiftwidth()
        return 0
      endif
    endif
    if s:Get_paren_balance(line, &quot;(&quot;, &quot;)&quot;) == 0
      return indent(lnum)
    endif
  endif

  &quot; line is an incomplete command:
  if line =~ '\&lt;\(if\|while\|for\|function\)\s*()$' || line =~ '\&lt;else$' || line =~ '&lt;-$' || line =~ '-&gt;$'
    return indent(lnum) + shiftwidth()
  endif

  &quot; Deal with () and []

  let pb = s:Get_paren_balance(line, '(', ')')

  if line =~ '^\s*{$' || line =~ '(\s*{' || (pb == 0 &amp;&amp; (line =~ '{$' || line =~ '(\s*{$'))
    return indent(lnum) + shiftwidth()
  endif

  let s:curtabstop = repeat(' ', &amp;tabstop)

  if g:r_indent_align_args == 1
    if pb &gt; 0 &amp;&amp; line =~ '{$'
      return s:Get_last_paren_idx(line, '(', ')', pb) + shiftwidth()
    endif

    let bb = s:Get_paren_balance(line, '[', ']')

    if pb &gt; 0
      if &amp;filetype == &quot;rhelp&quot;
        let ind = s:Get_last_paren_idx(line, '(', ')', pb)
      else
        let ind = s:Get_last_paren_idx(getline(lnum), '(', ')', pb)
      endif
      return ind
    endif

    if pb &lt; 0 &amp;&amp; line =~ '.*[,&amp;|\-\*+&lt;&gt;]$'
      let lnum = s:Get_prev_line(lnum)
      while pb &lt; 1 &amp;&amp; lnum &gt; 0
        let line = SanitizeRLine(getline(lnum))
        let line = substitute(line, '\t', s:curtabstop, &quot;g&quot;)
        let ind = strlen(line)
        while ind &gt; 0
          if line[ind] == ')'
            let pb -= 1
          else
            if line[ind] == '('
              let pb += 1
            endif
          endif
          if pb == 1
            return ind + 1
          endif
          let ind -= 1
        endwhile
        let lnum -= 1
      endwhile
      return 0
    endif

    if bb &gt; 0
      let ind = s:Get_last_paren_idx(getline(lnum), '[', ']', bb)
      return ind
    endif
  endif

  let post_block = 0
  if line =~ '}$' &amp;&amp; s:Get_paren_balance(line, '{', '}') &lt; 0
    let lnum = s:Get_matching_brace(lnum, '{', '}', 0)
    let line = SanitizeRLine(getline(lnum))
    if lnum &gt; 0 &amp;&amp; line =~ '^\s*{'
      let lnum = s:Get_prev_line(lnum)
      let line = SanitizeRLine(getline(lnum))
    endif
    let pb = s:Get_paren_balance(line, '(', ')')
    let post_block = 1
  endif

  &quot; Indent after operator pattern
  let olnum = s:Get_prev_line(lnum)
  let oline = getline(olnum)
  if olnum &gt; 0
    if line =~ g:r_indent_op_pattern &amp;&amp; s:Get_paren_balance(line, &quot;(&quot;, &quot;)&quot;) == 0
      if oline =~ g:r_indent_op_pattern &amp;&amp; s:Get_paren_balance(line, &quot;(&quot;, &quot;)&quot;) == 0
        return indent(lnum)
      else
        return indent(lnum) + shiftwidth()
      endif
    else
      if oline =~ g:r_indent_op_pattern &amp;&amp; s:Get_paren_balance(line, &quot;(&quot;, &quot;)&quot;) == 0
        return indent(lnum) - shiftwidth()
      endif
    endif
  endif

  let post_fun = 0
  if pb &lt; 0 &amp;&amp; line !~ ')\s*[,&amp;|\-\*+&lt;&gt;]$'
    let post_fun = 1
    while pb &lt; 0 &amp;&amp; lnum &gt; 0
      let lnum -= 1
      let linepiece = SanitizeRLine(getline(lnum))
      let pb += s:Get_paren_balance(linepiece, &quot;(&quot;, &quot;)&quot;)
      let line = linepiece . line
    endwhile
    if line =~ '{$' &amp;&amp; post_block == 0
      return indent(lnum) + shiftwidth()
    endif

    &quot; Now we can do some tests again
    if cline =~ '^\s*{'
      return indent(lnum)
    endif
    if post_block == 0
      let newl = SanitizeRLine(line)
      if newl =~ '\&lt;\(if\|while\|for\|function\)\s*()$' || newl =~ '\&lt;else$' || newl =~ '&lt;-$'
        return indent(lnum) + shiftwidth()
      endif
    endif
  endif

  if cline =~ '^\s*else'
    if line =~ '&lt;-\s*if\s*()'
      return indent(lnum) + shiftwidth()
    else
      if line =~ '\&lt;if\s*()'
        return indent(lnum)
      else
        return indent(lnum) - shiftwidth()
      endif
    endif
  endif

  let bb = s:Get_paren_balance(line, '[', ']')
  if bb &lt; 0 &amp;&amp; line =~ '.*]'
    while bb &lt; 0 &amp;&amp; lnum &gt; 0
      let lnum -= 1
      let linepiece = SanitizeRLine(getline(lnum))
      let bb += s:Get_paren_balance(linepiece, &quot;[&quot;, &quot;]&quot;)
      let line = linepiece . line
    endwhile
    let line = s:RDelete_parens(line)
  endif

  let plnum = s:Get_prev_line(lnum)
  let ppost_else = 0
  if plnum &gt; 0
    let pline = SanitizeRLine(getline(plnum))
    let ppost_block = 0
    if pline =~ '}$'
      let ppost_block = 1
      let plnum = s:Get_matching_brace(plnum, '{', '}', 0)
      let pline = SanitizeRLine(getline(plnum))
      if pline =~ '^\s*{$' &amp;&amp; plnum &gt; 0
        let plnum = s:Get_prev_line(plnum)
        let pline = SanitizeRLine(getline(plnum))
      endif
    endif

    if pline =~ 'else$'
      let ppost_else = 1
      let plnum = s:Get_matching_if(plnum, 0)
      let pline = SanitizeRLine(getline(plnum))
    endif

    if pline =~ '^\s*else\s*if\s*('
      let pplnum = s:Get_prev_line(plnum)
      let ppline = SanitizeRLine(getline(pplnum))
      while ppline =~ '^\s*else\s*if\s*(' || ppline =~ '^\s*if\s*()\s*\S$'
        let plnum = pplnum
        let pline = ppline
        let pplnum = s:Get_prev_line(plnum)
        let ppline = SanitizeRLine(getline(pplnum))
      endwhile
      while ppline =~ '\&lt;\(if\|while\|for\|function\)\s*()$' || ppline =~ '\&lt;else$' || ppline =~ '&lt;-$'
        let plnum = pplnum
        let pline = ppline
        let pplnum = s:Get_prev_line(plnum)
        let ppline = SanitizeRLine(getline(pplnum))
      endwhile
    endif

    let ppb = s:Get_paren_balance(pline, '(', ')')
    if ppb &lt; 0 &amp;&amp; (pline =~ ')\s*{$' || pline =~ ')$')
      while ppb &lt; 0 &amp;&amp; plnum &gt; 0
        let plnum -= 1
        let linepiece = SanitizeRLine(getline(plnum))
        let ppb += s:Get_paren_balance(linepiece, &quot;(&quot;, &quot;)&quot;)
        let pline = linepiece . pline
      endwhile
      let pline = s:RDelete_parens(pline)
    endif
  endif

  let ind = indent(lnum)

  if g:r_indent_align_args == 0 &amp;&amp; pb != 0
    let ind += pb * shiftwidth()
    return ind
  endif

  if g:r_indent_align_args == 0 &amp;&amp; bb != 0
    let ind += bb * shiftwidth()
    return ind
  endif

  if plnum &gt; 0
    let pind = indent(plnum)
  else
    let pind = 0
  endif

  if ind == pind || (ind == (pind  + shiftwidth()) &amp;&amp; pline =~ '{$' &amp;&amp; ppost_else == 0)
    return ind
  endif

  let pline = getline(plnum)
  let pbb = s:Get_paren_balance(pline, '[', ']')

  while pind &lt; ind &amp;&amp; plnum &gt; 0 &amp;&amp; ppb == 0 &amp;&amp; pbb == 0
    let ind = pind
    let plnum = s:Get_prev_line(plnum)
    let pline = getline(plnum)
    let ppb = s:Get_paren_balance(pline, '(', ')')
    let pbb = s:Get_paren_balance(pline, '[', ']')
    while pline =~ '^\s*else'
      let plnum = s:Get_matching_if(plnum, 1)
      let pline = getline(plnum)
      let ppb = s:Get_paren_balance(pline, '(', ')')
      let pbb = s:Get_paren_balance(pline, '[', ']')
    endwhile
    let pind = indent(plnum)
    if ind == (pind  + shiftwidth()) &amp;&amp; pline =~ '{$'
      return ind
    endif
  endwhile

  return ind

endfunction

&quot; vim: sw=2
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent'>Back to Directory</a>