<h2>Editing File: /usr/share/vim/vim80/indent/perl.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim indent file
&quot; Language:      Perl 5
&quot; Maintainer:    vim-perl &lt;vim-perl@googlegroups.com&gt;
&quot; Homepage:      http://github.com/vim-perl/vim-perl
&quot; Bugs/requests: http://github.com/vim-perl/vim-perl/issues
&quot; Last Change:   2017-01-04

&quot; Suggestions and improvements by :
&quot;   Aaron J. Sherman (use syntax for hints)
&quot;   Artem Chuprina (play nice with folding)

&quot; TODO things that are not or not properly indented (yet) :
&quot; - Continued statements
&quot;     print &quot;foo&quot;,
&quot;       &quot;bar&quot;;
&quot;     print &quot;foo&quot;
&quot;       if bar();
&quot; - Multiline regular expressions (m//x)
&quot; (The following probably needs modifying the perl syntax file)
&quot; - qw() lists
&quot; - Heredocs with terminators that don't match \I\i*

&quot; Only load this indent file when no other was loaded.
if exists(&quot;b:did_indent&quot;)
    finish
endif
let b:did_indent = 1

&quot; Is syntax highlighting active ?
let b:indent_use_syntax = has(&quot;syntax&quot;)

setlocal indentexpr=GetPerlIndent()
setlocal indentkeys+=0=,0),0],0=or,0=and
if !b:indent_use_syntax
    setlocal indentkeys+=0=EO
endif

let s:cpo_save = &amp;cpo
set cpo-=C

function! GetPerlIndent()

    &quot; Get the line to be indented
    let cline = getline(v:lnum)

    &quot; Indent POD markers to column 0
    if cline =~ '^\s*=\L\@!'
        return 0
    endif

    &quot; Get current syntax item at the line's first char
    let csynid = ''
    if b:indent_use_syntax
        let csynid = synIDattr(synID(v:lnum,1,0),&quot;name&quot;)
    endif

    &quot; Don't reindent POD and heredocs
    if csynid == &quot;perlPOD&quot; || csynid == &quot;perlHereDoc&quot; || csynid =~ &quot;^pod&quot;
        return indent(v:lnum)
    endif

    &quot; Indent end-of-heredocs markers to column 0
    if b:indent_use_syntax
        &quot; Assumes that an end-of-heredoc marker matches \I\i* to avoid
        &quot; confusion with other types of strings
        if csynid == &quot;perlStringStartEnd&quot; &amp;&amp; cline =~ '^\I\i*$'
            return 0
        endif
    else
        &quot; Without syntax hints, assume that end-of-heredocs markers begin with EO
        if cline =~ '^\s*EO'
            return 0
        endif
    endif

    &quot; Now get the indent of the previous perl line.

    &quot; Find a non-blank line above the current line.
    let lnum = prevnonblank(v:lnum - 1)
    &quot; Hit the start of the file, use zero indent.
    if lnum == 0
        return 0
    endif
    let line = getline(lnum)
    let ind = indent(lnum)
    &quot; Skip heredocs, POD, and comments on 1st column
    if b:indent_use_syntax
        let skippin = 2
        while skippin
            let synid = synIDattr(synID(lnum,1,0),&quot;name&quot;)
            if (synid == &quot;perlStringStartEnd&quot; &amp;&amp; line =~ '^\I\i*$')
                        \ || (skippin != 2 &amp;&amp; synid == &quot;perlPOD&quot;)
                        \ || (skippin != 2 &amp;&amp; synid == &quot;perlHereDoc&quot;)
                        \ || synid == &quot;perlComment&quot;
                        \ || synid =~ &quot;^pod&quot;
                let lnum = prevnonblank(lnum - 1)
                if lnum == 0
                    return 0
                endif
                let line = getline(lnum)
                let ind = indent(lnum)
                let skippin = 1
            else
                let skippin = 0
            endif
        endwhile
    else
        if line =~ &quot;^EO&quot;
            let lnum = search(&quot;&lt;&lt;[\&quot;']\\=EO&quot;, &quot;bW&quot;)
            let line = getline(lnum)
            let ind = indent(lnum)
        endif
    endif

    &quot; Indent blocks enclosed by {}, (), or []
    if b:indent_use_syntax
        &quot; Find a real opening brace
        &quot; NOTE: Unlike Perl character classes, we do NOT need to escape the
        &quot; closing brackets with a backslash.  Doing so just puts a backslash
        &quot; in the character class and causes sorrow.  Instead, put the closing
        &quot; bracket as the first character in the class.
        let braceclass = '[][(){}]'
        let bracepos = match(line, braceclass, matchend(line, '^\s*[])}]'))
        while bracepos != -1
            let synid = synIDattr(synID(lnum, bracepos + 1, 0), &quot;name&quot;)
            &quot; If the brace is highlighted in one of those groups, indent it.
            &quot; 'perlHereDoc' is here only to handle the case '&amp;foo(&lt;&lt;EOF)'.
            if synid == &quot;&quot;
                        \ || synid == &quot;perlMatchStartEnd&quot;
                        \ || synid == &quot;perlHereDoc&quot;
                        \ || synid == &quot;perlBraces&quot;
                        \ || synid == &quot;perlStatementIndirObj&quot;
                        \ || synid =~ &quot;^perlFiledescStatement&quot;
                        \ || synid =~ '^perl\(Sub\|Block\|Package\)Fold'
                let brace = strpart(line, bracepos, 1)
                if brace == '(' || brace == '{' || brace == '['
                    let ind = ind + shiftwidth()
                else
                    let ind = ind - shiftwidth()
                endif
            endif
            let bracepos = match(line, braceclass, bracepos + 1)
        endwhile
        let bracepos = matchend(cline, '^\s*[])}]')
        if bracepos != -1
            let synid = synIDattr(synID(v:lnum, bracepos, 0), &quot;name&quot;)
            if synid == &quot;&quot;
                        \ || synid == &quot;perlMatchStartEnd&quot;
                        \ || synid == &quot;perlBraces&quot;
                        \ || synid == &quot;perlStatementIndirObj&quot;
                        \ || synid =~ '^perl\(Sub\|Block\|Package\)Fold'
                let ind = ind - shiftwidth()
            endif
        endif
    else
        if line =~ '[{[(]\s*\(#[^])}]*\)\=$'
            let ind = ind + shiftwidth()
        endif
        if cline =~ '^\s*[])}]'
            let ind = ind - shiftwidth()
        endif
    endif

    &quot; Indent lines that begin with 'or' or 'and'
    if cline =~ '^\s*\(or\|and\)\&gt;'
        if line !~ '^\s*\(or\|and\)\&gt;'
            let ind = ind + shiftwidth()
        endif
    elseif line =~ '^\s*\(or\|and\)\&gt;'
        let ind = ind - shiftwidth()
    endif

    return ind

endfunction

let &amp;cpo = s:cpo_save
unlet s:cpo_save

&quot; vim:ts=8:sts=4:sw=4:expandtab:ft=vim
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent'>Back to Directory</a>