<h2>Editing File: /usr/share/vim/vim80/indent/liquid.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim indent file
&quot; Language:     Liquid
&quot; Maintainer:   Tim Pope &lt;vimNOSPAM@tpope.org&gt;
&quot; Last Change:	2017 Jun 13

if exists('b:did_indent')
  finish
endif

set indentexpr=
if exists('b:liquid_subtype')
  exe 'runtime! indent/'.b:liquid_subtype.'.vim'
else
  runtime! indent/html.vim
endif
unlet! b:did_indent

if &amp;l:indentexpr == ''
  if &amp;l:cindent
    let &amp;l:indentexpr = 'cindent(v:lnum)'
  else
    let &amp;l:indentexpr = 'indent(prevnonblank(v:lnum-1))'
  endif
endif
let b:liquid_subtype_indentexpr = &amp;l:indentexpr

let b:did_indent = 1

setlocal indentexpr=GetLiquidIndent()
setlocal indentkeys=o,O,*&lt;Return&gt;,&lt;&gt;&gt;,{,},0),0],o,O,!^F,=end,=endif,=endunless,=endifchanged,=endcase,=endfor,=endtablerow,=endcapture,=else,=elsif,=when,=empty

&quot; Only define the function once.
if exists('*GetLiquidIndent')
  finish
endif

function! s:count(string,pattern)
  let string = substitute(a:string,'\C'.a:pattern,&quot;\n&quot;,'g')
  return strlen(substitute(string,&quot;[^\n]&quot;,'','g'))
endfunction

function! GetLiquidIndent(...)
  if a:0 &amp;&amp; a:1 == '.'
    let v:lnum = line('.')
  elseif a:0 &amp;&amp; a:1 =~ '^\d'
    let v:lnum = a:1
  endif
  let vcol = col('.')
  call cursor(v:lnum,1)
  exe &quot;let ind = &quot;.b:liquid_subtype_indentexpr
  let lnum = prevnonblank(v:lnum-1)
  let line = getline(lnum)
  let cline = getline(v:lnum)
  let line  = substitute(line,'\C^\%(\s*{%\s*end\w*\s*%}\)\+','','')
  let line .= matchstr(cline,'\C^\%(\s*{%\s*end\w*\s*%}\)\+')
  let cline = substitute(cline,'\C^\%(\s*{%\s*end\w*\s*%}\)\+','','')
  let sw = shiftwidth()
  let ind += sw * s:count(line,'{%\s*\%(if\|elsif\|else\|unless\|ifchanged\|case\|when\|for\|empty\|tablerow\|capture\)\&gt;')
  let ind -= sw * s:count(line,'{%\s*end\%(if\|unless\|ifchanged\|case\|for\|tablerow\|capture\)\&gt;')
  let ind -= sw * s:count(cline,'{%\s*\%(elsif\|else\|when\|empty\)\&gt;')
  let ind -= sw * s:count(cline,'{%\s*end\w*$')
  return ind
endfunction
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent'>Back to Directory</a>