<h2>Editing File: /usr/share/vim/vim80/indent/clojure.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim indent file
&quot; Language:     Clojure
&quot; Author:       Meikel Brandmeyer &lt;mb@kotka.de&gt;
&quot; URL:          http://kotka.de/projects/clojure/vimclojure.html
&quot;
&quot; Maintainer:   Sung Pae &lt;self@sungpae.com&gt;
&quot; URL:          https://github.com/guns/vim-clojure-static
&quot; License:      Same as Vim
&quot; Last Change:  18 July 2016

if exists(&quot;b:did_indent&quot;)
	finish
endif
let b:did_indent = 1

let s:save_cpo = &amp;cpo
set cpo&amp;vim

let b:undo_indent = 'setlocal autoindent&lt; smartindent&lt; expandtab&lt; softtabstop&lt; shiftwidth&lt; indentexpr&lt; indentkeys&lt;'

setlocal noautoindent nosmartindent
setlocal softtabstop=2 shiftwidth=2 expandtab
setlocal indentkeys=!,o,O

if exists(&quot;*searchpairpos&quot;)

	if !exists('g:clojure_maxlines')
		let g:clojure_maxlines = 100
	endif

	if !exists('g:clojure_fuzzy_indent')
		let g:clojure_fuzzy_indent = 1
	endif

	if !exists('g:clojure_fuzzy_indent_patterns')
		let g:clojure_fuzzy_indent_patterns = ['^with', '^def', '^let']
	endif

	if !exists('g:clojure_fuzzy_indent_blacklist')
		let g:clojure_fuzzy_indent_blacklist = ['-fn$', '\v^with-%(meta|out-str|loading-context)$']
	endif

	if !exists('g:clojure_special_indent_words')
		let g:clojure_special_indent_words = 'deftype,defrecord,reify,proxy,extend-type,extend-protocol,letfn'
	endif

	if !exists('g:clojure_align_multiline_strings')
		let g:clojure_align_multiline_strings = 0
	endif

	if !exists('g:clojure_align_subforms')
		let g:clojure_align_subforms = 0
	endif

	function! s:syn_id_name()
		return synIDattr(synID(line(&quot;.&quot;), col(&quot;.&quot;), 0), &quot;name&quot;)
	endfunction

	function! s:ignored_region()
		return s:syn_id_name() =~? '\vstring|regex|comment|character'
	endfunction

	function! s:current_char()
		return getline('.')[col('.')-1]
	endfunction

	function! s:current_word()
		return getline('.')[col('.')-1 : searchpos('\v&gt;', 'n', line('.'))[1]-2]
	endfunction

	function! s:is_paren()
		return s:current_char() =~# '\v[\(\)\[\]\{\}]' &amp;&amp; !s:ignored_region()
	endfunction

	&quot; Returns 1 if string matches a pattern in 'patterns', which may be a
	&quot; list of patterns, or a comma-delimited string of implicitly anchored
	&quot; patterns.
	function! s:match_one(patterns, string)
		let list = type(a:patterns) == type([])
		           \ ? a:patterns
		           \ : map(split(a:patterns, ','), '&quot;^&quot; . v:val . &quot;$&quot;')
		for pat in list
			if a:string =~# pat | return 1 | endif
		endfor
	endfunction

	function! s:match_pairs(open, close, stopat)
		&quot; Stop only on vector and map [ resp. {. Ignore the ones in strings and
		&quot; comments.
		if a:stopat == 0
			let stopat = max([line(&quot;.&quot;) - g:clojure_maxlines, 0])
		else
			let stopat = a:stopat
		endif

		let pos = searchpairpos(a:open, '', a:close, 'bWn', &quot;!s:is_paren()&quot;, stopat)
		return [pos[0], col(pos)]
	endfunction

	function! s:clojure_check_for_string_worker()
		&quot; Check whether there is the last character of the previous line is
		&quot; highlighted as a string. If so, we check whether it's a &quot;. In this
		&quot; case we have to check also the previous character. The &quot; might be the
		&quot; closing one. In case the we are still in the string, we search for the
		&quot; opening &quot;. If this is not found we take the indent of the line.
		let nb = prevnonblank(v:lnum - 1)

		if nb == 0
			return -1
		endif

		call cursor(nb, 0)
		call cursor(0, col(&quot;$&quot;) - 1)
		if s:syn_id_name() !~? &quot;string&quot;
			return -1
		endif

		&quot; This will not work for a &quot; in the first column...
		if s:current_char() == '&quot;'
			call cursor(0, col(&quot;$&quot;) - 2)
			if s:syn_id_name() !~? &quot;string&quot;
				return -1
			endif
			if s:current_char() != '\\'
				return -1
			endif
			call cursor(0, col(&quot;$&quot;) - 1)
		endif

		let p = searchpos('\(^\|[^\\]\)\zs&quot;', 'bW')

		if p != [0, 0]
			return p[1] - 1
		endif

		return indent(&quot;.&quot;)
	endfunction

	function! s:check_for_string()
		let pos = getpos('.')
		try
			let val = s:clojure_check_for_string_worker()
		finally
			call setpos('.', pos)
		endtry
		return val
	endfunction

	function! s:strip_namespace_and_macro_chars(word)
		return substitute(a:word, &quot;\\v%(.*/|[#'`~@^,]*)(.*)&quot;, '\1', '')
	endfunction

	function! s:clojure_is_method_special_case_worker(position)
		&quot; Find the next enclosing form.
		call search('\S', 'Wb')

		&quot; Special case: we are at a '(('.
		if s:current_char() == '('
			return 0
		endif
		call cursor(a:position)

		let next_paren = s:match_pairs('(', ')', 0)

		&quot; Special case: we are now at toplevel.
		if next_paren == [0, 0]
			return 0
		endif
		call cursor(next_paren)

		call search('\S', 'W')
		let w = s:strip_namespace_and_macro_chars(s:current_word())
		if g:clojure_special_indent_words =~# '\V\&lt;' . w . '\&gt;'
			return 1
		endif

		return 0
	endfunction

	function! s:is_method_special_case(position)
		let pos = getpos('.')
		try
			let val = s:clojure_is_method_special_case_worker(a:position)
		finally
			call setpos('.', pos)
		endtry
		return val
	endfunction

	&quot; Check if form is a reader conditional, that is, it is prefixed by #?
	&quot; or @#?
	function! s:is_reader_conditional_special_case(position)
		if getline(a:position[0])[a:position[1] - 3 : a:position[1] - 2] == &quot;#?&quot;
			return 1
		endif

		return 0
	endfunction

	&quot; Returns 1 for opening brackets, -1 for _anything else_.
	function! s:bracket_type(char)
		return stridx('([{', a:char) &gt; -1 ? 1 : -1
	endfunction

	&quot; Returns: [opening-bracket-lnum, indent]
	function! s:clojure_indent_pos()
		&quot; Get rid of special case.
		if line(&quot;.&quot;) == 1
			return [0, 0]
		endif

		&quot; We have to apply some heuristics here to figure out, whether to use
		&quot; normal lisp indenting or not.
		let i = s:check_for_string()
		if i &gt; -1
			return [0, i + !!g:clojure_align_multiline_strings]
		endif

		call cursor(0, 1)

		&quot; Find the next enclosing [ or {. We can limit the second search
		&quot; to the line, where the [ was found. If no [ was there this is
		&quot; zero and we search for an enclosing {.
		let paren = s:match_pairs('(', ')', 0)
		let bracket = s:match_pairs('\[', '\]', paren[0])
		let curly = s:match_pairs('{', '}', bracket[0])

		&quot; In case the curly brace is on a line later then the [ or - in
		&quot; case they are on the same line - in a higher column, we take the
		&quot; curly indent.
		if curly[0] &gt; bracket[0] || curly[1] &gt; bracket[1]
			if curly[0] &gt; paren[0] || curly[1] &gt; paren[1]
				return curly
			endif
		endif

		&quot; If the curly was not chosen, we take the bracket indent - if
		&quot; there was one.
		if bracket[0] &gt; paren[0] || bracket[1] &gt; paren[1]
			return bracket
		endif

		&quot; There are neither { nor [ nor (, ie. we are at the toplevel.
		if paren == [0, 0]
			return paren
		endif

		&quot; Now we have to reimplement lispindent. This is surprisingly easy, as
		&quot; soon as one has access to syntax items.
		&quot;
		&quot; - Check whether we are in a special position after a word in
		&quot;   g:clojure_special_indent_words. These are special cases.
		&quot; - Get the next keyword after the (.
		&quot; - If its first character is also a (, we have another sexp and align
		&quot;   one column to the right of the unmatched (.
		&quot; - In case it is in lispwords, we indent the next line to the column of
		&quot;   the ( + sw.
		&quot; - If not, we check whether it is last word in the line. In that case
		&quot;   we again use ( + sw for indent.
		&quot; - In any other case we use the column of the end of the word + 2.
		call cursor(paren)

		if s:is_method_special_case(paren)
			return [paren[0], paren[1] + shiftwidth() - 1]
		endif

		if s:is_reader_conditional_special_case(paren)
			return paren
		endif

		&quot; In case we are at the last character, we use the paren position.
		if col(&quot;$&quot;) - 1 == paren[1]
			return paren
		endif

		&quot; In case after the paren is a whitespace, we search for the next word.
		call cursor(0, col('.') + 1)
		if s:current_char() == ' '
			call search('\v\S', 'W')
		endif

		&quot; If we moved to another line, there is no word after the (. We
		&quot; use the ( position for indent.
		if line(&quot;.&quot;) &gt; paren[0]
			return paren
		endif

		&quot; We still have to check, whether the keyword starts with a (, [ or {.
		&quot; In that case we use the ( position for indent.
		let w = s:current_word()
		if s:bracket_type(w[0]) == 1
			return paren
		endif

		&quot; Test words without namespace qualifiers and leading reader macro
		&quot; metacharacters.
		&quot;
		&quot; e.g. clojure.core/defn and #'defn should both indent like defn.
		let ww = s:strip_namespace_and_macro_chars(w)

		if &amp;lispwords =~# '\V\&lt;' . ww . '\&gt;'
			return [paren[0], paren[1] + shiftwidth() - 1]
		endif

		if g:clojure_fuzzy_indent
			\ &amp;&amp; !s:match_one(g:clojure_fuzzy_indent_blacklist, ww)
			\ &amp;&amp; s:match_one(g:clojure_fuzzy_indent_patterns, ww)
			return [paren[0], paren[1] + shiftwidth() - 1]
		endif

		call search('\v\_s', 'cW')
		call search('\v\S', 'W')
		if paren[0] &lt; line(&quot;.&quot;)
			return [paren[0], paren[1] + (g:clojure_align_subforms ? 0 : shiftwidth() - 1)]
		endif

		call search('\v\S', 'bW')
		return [line('.'), col('.') + 1]
	endfunction

	function! GetClojureIndent()
		let lnum = line('.')
		let orig_lnum = lnum
		let orig_col = col('.')
		let [opening_lnum, indent] = s:clojure_indent_pos()

		&quot; Account for multibyte characters
		if opening_lnum &gt; 0
			let indent -= indent - virtcol([opening_lnum, indent])
		endif

		&quot; Return if there are no previous lines to inherit from
		if opening_lnum &lt; 1 || opening_lnum &gt;= lnum - 1
			call cursor(orig_lnum, orig_col)
			return indent
		endif

		let bracket_count = 0

		&quot; Take the indent of the first previous non-white line that is
		&quot; at the same sexp level. cf. src/misc1.c:get_lisp_indent()
		while 1
			let lnum = prevnonblank(lnum - 1)
			let col = 1

			if lnum &lt;= opening_lnum
				break
			endif

			call cursor(lnum, col)

			&quot; Handle bracket counting edge case
			if s:is_paren()
				let bracket_count += s:bracket_type(s:current_char())
			endif

			while 1
				if search('\v[(\[{}\])]', '', lnum) &lt; 1
					break
				elseif !s:ignored_region()
					let bracket_count += s:bracket_type(s:current_char())
				endif
			endwhile

			if bracket_count == 0
				&quot; Check if this is part of a multiline string
				call cursor(lnum, 1)
				if s:syn_id_name() !~? '\vstring|regex'
					call cursor(orig_lnum, orig_col)
					return indent(lnum)
				endif
			endif
		endwhile

		call cursor(orig_lnum, orig_col)
		return indent
	endfunction

	setlocal indentexpr=GetClojureIndent()

else

	&quot; In case we have searchpairpos not available we fall back to
	&quot; normal lisp indenting.
	setlocal indentexpr=
	setlocal lisp
	let b:undo_indent .= '| setlocal lisp&lt;'

endif

let &amp;cpo = s:save_cpo
unlet! s:save_cpo

&quot; vim:sts=8:sw=8:ts=8:noet
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent'>Back to Directory</a>