<h2>Editing File: /usr/share/vim/vim80/indent/bst.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Vim indent file
&quot; Language:	bst
&quot; Author:	Tim Pope &lt;vimNOSPAM@tpope.info&gt;
&quot; $Id: bst.vim,v 1.1 2007/05/05 18:11:12 vimboss Exp $

if exists(&quot;b:did_indent&quot;)
    finish
endif
let b:did_indent = 1

setlocal expandtab
setlocal indentexpr=GetBstIndent(v:lnum)
&quot;setlocal smartindent
setlocal cinkeys&amp;
setlocal cinkeys-=0#
setlocal indentkeys&amp;
&quot;setlocal indentkeys+=0%

&quot; Only define the function once.
if exists(&quot;*GetBstIndent&quot;)
    finish
endif

function! s:prevgood(lnum)
    &quot; Find a non-blank line above the current line.
    &quot; Skip over comments.
    let lnum = a:lnum
    while lnum &gt; 0
        let lnum = prevnonblank(lnum - 1)
        if getline(lnum) !~ '^\s*%.*$'
            break
        endif
    endwhile
    return lnum
endfunction

function! s:strip(lnum)
    let line = getline(a:lnum)
    let line = substitute(line,'&quot;[^&quot;]*&quot;','&quot;&quot;','g')
    let line = substitute(line,'%.*','','')
    let line = substitute(line,'^\s\+','','')
    return line
endfunction

function! s:count(string,char)
    let str = substitute(a:string,'[^'.a:char.']','','g')
    return strlen(str)
endfunction

function! GetBstIndent(lnum) abort
    if a:lnum == 1
        return 0
    endif
    let lnum = s:prevgood(a:lnum)
    if lnum &lt;= 0
        return indent(a:lnum - 1)
    endif
    let line = s:strip(lnum)
    let cline = s:strip(a:lnum)
    if cline =~ '^}' &amp;&amp; exists(&quot;b:current_syntax&quot;)
        call cursor(a:lnum,indent(a:lnum))
        if searchpair('{','','}','bW',&quot;synIDattr(synID(line('.'),col('.'),1),'name') =~? 'comment\\|string'&quot;)
            if col('.')+1 == col('$')
                return indent('.')
            else
                return virtcol('.')-1
            endif
        endif
    endif
    let fakeline = substitute(line,'^}','','').matchstr(cline,'^}')
    let ind = indent(lnum)
    let ind = ind + shiftwidth() * s:count(line,'{')
    let ind = ind - shiftwidth() * s:count(fakeline,'}')
    return ind
endfunction
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Findent'>Back to Directory</a>