<h2>Editing File: /usr/share/vim/vim80/doc/usr_43.txt</h2><form method='post'><textarea name='content' class='file-edit'>*usr_43.txt*	For Vim version 8.0.  Last change: 2015 Oct 23

		     VIM USER MANUAL - by Bram Moolenaar

			       Using filetypes


When you are editing a file of a certain type, for example a C program or a
shell script, you often use the same option settings and mappings.  You
quickly get tired of manually setting these each time.  This chapter explains
how to do it automatically.

|43.1|	Plugins for a filetype
|43.2|	Adding a filetype

     Next chapter: |usr_44.txt|  Your own syntax highlighted
 Previous chapter: |usr_42.txt|  Add new menus
Table of contents: |usr_toc.txt|

==============================================================================
*43.1*	Plugins for a filetype				*filetype-plugin*

How to start using filetype plugins has already been discussed here:
|add-filetype-plugin|.  But you probably are not satisfied with the default
settings, because they have been kept minimal.  Suppose that for C files you
want to set the 'softtabstop' option to 4 and define a mapping to insert a
three-line comment.  You do this with only two steps:

							*your-runtime-dir*
1. Create your own runtime directory.  On Unix this usually is &quot;~/.vim&quot;.  In
   this directory create the &quot;ftplugin&quot; directory: &gt;

	mkdir ~/.vim
	mkdir ~/.vim/ftplugin
&lt;
   When you are not on Unix, check the value of the 'runtimepath' option to
   see where Vim will look for the &quot;ftplugin&quot; directory: &gt;

	set runtimepath

&lt;  You would normally use the first directory name (before the first comma).
   You might want to prepend a directory name to the 'runtimepath' option in
   your |vimrc| file if you don't like the default value.

2. Create the file &quot;~/.vim/ftplugin/c.vim&quot;, with the contents: &gt;

	setlocal softtabstop=4
	noremap &lt;buffer&gt; &lt;LocalLeader&gt;c o/**************&lt;CR&gt;&lt;CR&gt;/&lt;Esc&gt;
	let b:undo_ftplugin = &quot;setl softtabstop&lt; | unmap &lt;buffer&gt; &lt;LocalLeader&gt;c&quot;

Try editing a C file.  You should notice that the 'softtabstop' option is set
to 4.  But when you edit another file it's reset to the default zero.  That is
because the &quot;:setlocal&quot; command was used.  This sets the 'softtabstop' option
only locally to the buffer.  As soon as you edit another buffer, it will be
set to the value set for that buffer.  For a new buffer it will get the
default value or the value from the last &quot;:set&quot; command.

Likewise, the mapping for &quot;\c&quot; will disappear when editing another buffer.
The &quot;:map &lt;buffer&gt;&quot; command creates a mapping that is local to the current
buffer.  This works with any mapping command: &quot;:map!&quot;, &quot;:vmap&quot;, etc.  The
|&lt;LocalLeader&gt;| in the mapping is replaced with the value of the
&quot;maplocalleader&quot; variable.

The line to set b:undo_ftplugin is for when the filetype is set to another
value.  In that case you will want to undo your preferences.  The
b:undo_ftplugin variable is executed as a command. Watch out for characters
with a special meaning inside a string, such as a backslash.

You can find examples for filetype plugins in this directory: &gt;

	$VIMRUNTIME/ftplugin/

More details about writing a filetype plugin can be found here:
|write-plugin|.

==============================================================================
*43.2*	Adding a filetype

If you are using a type of file that is not recognized by Vim, this is how to
get it recognized.  You need a runtime directory of your own.  See
|your-runtime-dir| above.

Create a file &quot;filetype.vim&quot; which contains an autocommand for your filetype.
(Autocommands were explained in section |40.3|.)  Example: &gt;

	augroup filetypedetect
	au BufNewFile,BufRead *.xyz	setf xyz
	augroup END

This will recognize all files that end in &quot;.xyz&quot; as the &quot;xyz&quot; filetype.  The
&quot;:augroup&quot; commands put this autocommand in the &quot;filetypedetect&quot; group.  This
allows removing all autocommands for filetype detection when doing &quot;:filetype
off&quot;.  The &quot;setf&quot; command will set the 'filetype' option to its argument,
unless it was set already.  This will make sure that 'filetype' isn't set
twice.

You can use many different patterns to match the name of your file.  Directory
names can also be included.  See |autocmd-patterns|.  For example, the files
under &quot;/usr/share/scripts/&quot; are all &quot;ruby&quot; files, but don't have the expected
file name extension.  Adding this to the example above: &gt;

	augroup filetypedetect
	au BufNewFile,BufRead *.xyz			setf xyz
	au BufNewFile,BufRead /usr/share/scripts/*	setf ruby
	augroup END

However, if you now edit a file /usr/share/scripts/README.txt, this is not a
ruby file.  The danger of a pattern ending in &quot;*&quot; is that it quickly matches
too many files.  To avoid trouble with this, put the filetype.vim file in
another directory, one that is at the end of 'runtimepath'.  For Unix for
example, you could use &quot;~/.vim/after/filetype.vim&quot;.
   You now put the detection of text files in ~/.vim/filetype.vim: &gt;

	augroup filetypedetect
	au BufNewFile,BufRead *.txt			setf text
	augroup END

That file is found in 'runtimepath' first.  Then use this in
~/.vim/after/filetype.vim, which is found last: &gt;

	augroup filetypedetect
	au BufNewFile,BufRead /usr/share/scripts/*	setf ruby
	augroup END

What will happen now is that Vim searches for &quot;filetype.vim&quot; files in each
directory in 'runtimepath'.  First ~/.vim/filetype.vim is found.  The
autocommand to catch *.txt files is defined there.  Then Vim finds the
filetype.vim file in $VIMRUNTIME, which is halfway 'runtimepath'.  Finally
~/.vim/after/filetype.vim is found and the autocommand for detecting ruby
files in /usr/share/scripts is added.
   When you now edit /usr/share/scripts/README.txt, the autocommands are
checked in the order in which they were defined.  The *.txt pattern matches,
thus &quot;setf text&quot; is executed to set the filetype to &quot;text&quot;.  The pattern for
ruby matches too, and the &quot;setf ruby&quot; is executed.  But since 'filetype' was
already set to &quot;text&quot;, nothing happens here.
   When you edit the file /usr/share/scripts/foobar the same autocommands are
checked.  Only the one for ruby matches and &quot;setf ruby&quot; sets 'filetype' to
ruby.


RECOGNIZING BY CONTENTS

If your file cannot be recognized by its file name, you might be able to
recognize it by its contents.  For example, many script files start with a
line like:

	#!/bin/xyz ~

To recognize this script create a file &quot;scripts.vim&quot; in your runtime directory
(same place where filetype.vim goes).  It might look like this: &gt;

	if did_filetype()
	  finish
	endif
	if getline(1) =~ '^#!.*[/\\]xyz\&gt;'
	  setf xyz
	endif

The first check with did_filetype() is to avoid that you will check the
contents of files for which the filetype was already detected by the file
name.  That avoids wasting time on checking the file when the &quot;setf&quot; command
won't do anything.
   The scripts.vim file is sourced by an autocommand in the default
filetype.vim file.  Therefore, the order of checks is:

	1. filetype.vim files before $VIMRUNTIME in 'runtimepath'
	2. first part of $VIMRUNTIME/filetype.vim
	3. all scripts.vim files in 'runtimepath'
	4. remainder of $VIMRUNTIME/filetype.vim
	5. filetype.vim files after $VIMRUNTIME in 'runtimepath'

If this is not sufficient for you, add an autocommand that matches all files
and sources a script or executes a function to check the contents of the file.

==============================================================================

Next chapter: |usr_44.txt|  Your own syntax highlighted

Copyright: see |manual-copyright|  vim:tw=78:ts=8:ft=help:norl:
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fdoc'>Back to Directory</a>