<h2>Editing File: /usr/share/vim/vim80/autoload/rust.vim</h2><form method='post'><textarea name='content' class='file-edit'>&quot; Author: Kevin Ballard
&quot; Description: Helper functions for Rust commands/mappings
&quot; Last Modified: May 27, 2014
&quot; For bugs, patches and license go to https://github.com/rust-lang/rust.vim

&quot; Jump {{{1

function! rust#Jump(mode, function) range
	let cnt = v:count1
	normal! m'
	if a:mode ==# 'v'
		norm! gv
	endif
	let foldenable = &amp;foldenable
	set nofoldenable
	while cnt &gt; 0
		execute &quot;call &lt;SID&gt;Jump_&quot; . a:function . &quot;()&quot;
		let cnt = cnt - 1
	endwhile
	let &amp;foldenable = foldenable
endfunction

function! s:Jump_Back()
	call search('{', 'b')
	keepjumps normal! w99[{
endfunction

function! s:Jump_Forward()
	normal! j0
	call search('{', 'b')
	keepjumps normal! w99[{%
	call search('{')
endfunction

&quot; Run {{{1

function! rust#Run(bang, args)
	let args = s:ShellTokenize(a:args)
	if a:bang
		let idx = index(l:args, '--')
		if idx != -1
			let rustc_args = idx == 0 ? [] : l:args[:idx-1]
			let args = l:args[idx+1:]
		else
			let rustc_args = l:args
			let args = []
		endif
	else
		let rustc_args = []
	endif

	let b:rust_last_rustc_args = l:rustc_args
	let b:rust_last_args = l:args

	call s:WithPath(function(&quot;s:Run&quot;), rustc_args, args)
endfunction

function! s:Run(dict, rustc_args, args)
	let exepath = a:dict.tmpdir.'/'.fnamemodify(a:dict.path, ':t:r')
	if has('win32')
		let exepath .= '.exe'
	endif

	let relpath = get(a:dict, 'tmpdir_relpath', a:dict.path)
	let rustc_args = [relpath, '-o', exepath] + a:rustc_args

	let rustc = exists(&quot;g:rustc_path&quot;) ? g:rustc_path : &quot;rustc&quot;

	let pwd = a:dict.istemp ? a:dict.tmpdir : ''
	let output = s:system(pwd, shellescape(rustc) . &quot; &quot; . join(map(rustc_args, 'shellescape(v:val)')))
	if output != ''
		echohl WarningMsg
		echo output
		echohl None
	endif
	if !v:shell_error
		exe '!' . shellescape(exepath) . &quot; &quot; . join(map(a:args, 'shellescape(v:val)'))
	endif
endfunction

&quot; Expand {{{1

function! rust#Expand(bang, args)
	let args = s:ShellTokenize(a:args)
	if a:bang &amp;&amp; !empty(l:args)
		let pretty = remove(l:args, 0)
	else
		let pretty = &quot;expanded&quot;
	endif
	call s:WithPath(function(&quot;s:Expand&quot;), pretty, args)
endfunction

function! s:Expand(dict, pretty, args)
	try
		let rustc = exists(&quot;g:rustc_path&quot;) ? g:rustc_path : &quot;rustc&quot;

		if a:pretty =~? '^\%(everybody_loops$\|flowgraph=\)'
			let flag = '--xpretty'
		else
			let flag = '--pretty'
		endif
		let relpath = get(a:dict, 'tmpdir_relpath', a:dict.path)
		let args = [relpath, '-Z', 'unstable-options', l:flag, a:pretty] + a:args
		let pwd = a:dict.istemp ? a:dict.tmpdir : ''
		let output = s:system(pwd, shellescape(rustc) . &quot; &quot; . join(map(args, 'shellescape(v:val)')))
		if v:shell_error
			echohl WarningMsg
			echo output
			echohl None
		else
			new
			silent put =output
			1
			d
			setl filetype=rust
			setl buftype=nofile
			setl bufhidden=hide
			setl noswapfile
			&quot; give the buffer a nice name
			let suffix = 1
			let basename = fnamemodify(a:dict.path, ':t:r')
			while 1
				let bufname = basename
				if suffix &gt; 1 | let bufname .= ' ('.suffix.')' | endif
				let bufname .= '.pretty.rs'
				if bufexists(bufname)
					let suffix += 1
					continue
				endif
				exe 'silent noautocmd keepalt file' fnameescape(bufname)
				break
			endwhile
		endif
	endtry
endfunction

function! rust#CompleteExpand(lead, line, pos)
	if a:line[: a:pos-1] =~ '^RustExpand!\s*\S*$'
		&quot; first argument and it has a !
		let list = [&quot;normal&quot;, &quot;expanded&quot;, &quot;typed&quot;, &quot;expanded,identified&quot;, &quot;flowgraph=&quot;, &quot;everybody_loops&quot;]
		if !empty(a:lead)
			call filter(list, &quot;v:val[:len(a:lead)-1] == a:lead&quot;)
		endif
		return list
	endif

	return glob(escape(a:lead, &quot;*?[&quot;) . '*', 0, 1)
endfunction

&quot; Emit {{{1

function! rust#Emit(type, args)
	let args = s:ShellTokenize(a:args)
	call s:WithPath(function(&quot;s:Emit&quot;), a:type, args)
endfunction

function! s:Emit(dict, type, args)
	try
		let output_path = a:dict.tmpdir.'/output'

		let rustc = exists(&quot;g:rustc_path&quot;) ? g:rustc_path : &quot;rustc&quot;

		let relpath = get(a:dict, 'tmpdir_relpath', a:dict.path)
		let args = [relpath, '--emit', a:type, '-o', output_path] + a:args
		let pwd = a:dict.istemp ? a:dict.tmpdir : ''
		let output = s:system(pwd, shellescape(rustc) . &quot; &quot; . join(map(args, 'shellescape(v:val)')))
		if output != ''
			echohl WarningMsg
			echo output
			echohl None
		endif
		if !v:shell_error
			new
			exe 'silent keepalt read' fnameescape(output_path)
			1
			d
			if a:type == &quot;llvm-ir&quot;
				setl filetype=llvm
				let extension = 'll'
			elseif a:type == &quot;asm&quot;
				setl filetype=asm
				let extension = 's'
			endif
			setl buftype=nofile
			setl bufhidden=hide
			setl noswapfile
			if exists('l:extension')
				&quot; give the buffer a nice name
				let suffix = 1
				let basename = fnamemodify(a:dict.path, ':t:r')
				while 1
					let bufname = basename
					if suffix &gt; 1 | let bufname .= ' ('.suffix.')' | endif
					let bufname .= '.'.extension
					if bufexists(bufname)
						let suffix += 1
						continue
					endif
					exe 'silent noautocmd keepalt file' fnameescape(bufname)
					break
				endwhile
			endif
		endif
	endtry
endfunction

&quot; Utility functions {{{1

&quot; Invokes func(dict, ...)
&quot; Where {dict} is a dictionary with the following keys:
&quot;   'path' - The path to the file
&quot;   'tmpdir' - The path to a temporary directory that will be deleted when the
&quot;              function returns.
&quot;   'istemp' - 1 if the path is a file inside of {dict.tmpdir} or 0 otherwise.
&quot; If {istemp} is 1 then an additional key is provided:
&quot;   'tmpdir_relpath' - The {path} relative to the {tmpdir}.
&quot;
&quot; {dict.path} may be a path to a file inside of {dict.tmpdir} or it may be the
&quot; existing path of the current buffer. If the path is inside of {dict.tmpdir}
&quot; then it is guaranteed to have a '.rs' extension.
function! s:WithPath(func, ...)
	let buf = bufnr('')
	let saved = {}
	let dict = {}
	try
		let saved.write = &amp;write
		set write
		let dict.path = expand('%')
		let pathisempty = empty(dict.path)

		&quot; Always create a tmpdir in case the wrapped command wants it
		let dict.tmpdir = tempname()
		call mkdir(dict.tmpdir)

		if pathisempty || !saved.write
			let dict.istemp = 1
			&quot; if we're doing this because of nowrite, preserve the filename
			if !pathisempty
				let filename = expand('%:t:r').&quot;.rs&quot;
			else
				let filename = 'unnamed.rs'
			endif
			let dict.tmpdir_relpath = filename
			let dict.path = dict.tmpdir.'/'.filename

			let saved.mod = &amp;mod
			set nomod

			silent exe 'keepalt write! ' . fnameescape(dict.path)
			if pathisempty
				silent keepalt 0file
			endif
		else
			let dict.istemp = 0
			update
		endif

		call call(a:func, [dict] + a:000)
	finally
		if bufexists(buf)
			for [opt, value] in items(saved)
				silent call setbufvar(buf, '&amp;'.opt, value)
				unlet value &quot; avoid variable type mismatches
			endfor
		endif
		if has_key(dict, 'tmpdir') | silent call s:RmDir(dict.tmpdir) | endif
	endtry
endfunction

function! rust#AppendCmdLine(text)
	call setcmdpos(getcmdpos())
	let cmd = getcmdline() . a:text
	return cmd
endfunction

&quot; Tokenize the string according to sh parsing rules
function! s:ShellTokenize(text)
	&quot; states:
	&quot; 0: start of word
	&quot; 1: unquoted
	&quot; 2: unquoted backslash
	&quot; 3: double-quote
	&quot; 4: double-quoted backslash
	&quot; 5: single-quote
	let l:state = 0
	let l:current = ''
	let l:args = []
	for c in split(a:text, '\zs')
		if l:state == 0 || l:state == 1 &quot; unquoted
			if l:c ==# ' '
				if l:state == 0 | continue | endif
				call add(l:args, l:current)
				let l:current = ''
				let l:state = 0
			elseif l:c ==# '\'
				let l:state = 2
			elseif l:c ==# '&quot;'
				let l:state = 3
			elseif l:c ==# &quot;'&quot;
				let l:state = 5
			else
				let l:current .= l:c
				let l:state = 1
			endif
		elseif l:state == 2 &quot; unquoted backslash
			if l:c !=# &quot;\n&quot; &quot; can it even be \n?
				let l:current .= l:c
			endif
			let l:state = 1
		elseif l:state == 3 &quot; double-quote
			if l:c ==# '\'
				let l:state = 4
			elseif l:c ==# '&quot;'
				let l:state = 1
			else
				let l:current .= l:c
			endif
		elseif l:state == 4 &quot; double-quoted backslash
			if stridx('$`&quot;\', l:c) &gt;= 0
				let l:current .= l:c
			elseif l:c ==# &quot;\n&quot; &quot; is this even possible?
				&quot; skip it
			else
				let l:current .= '\'.l:c
			endif
			let l:state = 3
		elseif l:state == 5 &quot; single-quoted
			if l:c == &quot;'&quot;
				let l:state = 1
			else
				let l:current .= l:c
			endif
		endif
	endfor
	if l:state != 0
		call add(l:args, l:current)
	endif
	return l:args
endfunction

function! s:RmDir(path)
	&quot; sanity check; make sure it's not empty, /, or $HOME
	if empty(a:path)
		echoerr 'Attempted to delete empty path'
		return 0
	elseif a:path == '/' || a:path == $HOME
		echoerr 'Attempted to delete protected path: ' . a:path
		return 0
	endif
	return system(&quot;rm -rf &quot; . shellescape(a:path))
endfunction

&quot; Executes {cmd} with the cwd set to {pwd}, without changing Vim's cwd.
&quot; If {pwd} is the empty string then it doesn't change the cwd.
function! s:system(pwd, cmd)
	let cmd = a:cmd
	if !empty(a:pwd)
		let cmd = 'cd ' . shellescape(a:pwd) . ' &amp;&amp; ' . cmd
	endif
	return system(cmd)
endfunction

&quot; Playpen Support {{{1
&quot; Parts of gist.vim by Yasuhiro Matsumoto &lt;mattn.jp@gmail.com&gt; reused
&quot; gist.vim available under the BSD license, available at
&quot; http://github.com/mattn/gist-vim
function! s:has_webapi()
    if !exists(&quot;*webapi#http#post&quot;)
	try
	    call webapi#http#post()
	catch
	endtry
    endif
    return exists(&quot;*webapi#http#post&quot;)
endfunction

function! rust#Play(count, line1, line2, ...) abort
    redraw

    let l:rust_playpen_url = get(g:, 'rust_playpen_url', 'https://play.rust-lang.org/')
    let l:rust_shortener_url = get(g:, 'rust_shortener_url', 'https://is.gd/')

    if !s:has_webapi()
	echohl ErrorMsg | echomsg ':RustPlay depends on webapi.vim (https://github.com/mattn/webapi-vim)' | echohl None
	return
    endif

    let bufname = bufname('%')
    if a:count &lt; 1
	let content = join(getline(a:line1, a:line2), &quot;\n&quot;)
    else
	let save_regcont = @&quot;
	let save_regtype = getregtype('&quot;')
	silent! normal! gvy
	let content = @&quot;
	call setreg('&quot;', save_regcont, save_regtype)
    endif

    let body = l:rust_playpen_url.&quot;?code=&quot;.webapi#http#encodeURI(content)

    if strlen(body) &gt; 5000
	echohl ErrorMsg | echomsg 'Buffer too large, max 5000 encoded characters ('.strlen(body).')' | echohl None
	return
    endif

    let payload = &quot;format=simple&amp;url=&quot;.webapi#http#encodeURI(body)
    let res = webapi#http#post(l:rust_shortener_url.'create.php', payload, {})
    let url = res.content

    redraw | echomsg 'Done: '.url
endfunction

&quot; }}}1

&quot; vim: set noet sw=8 ts=8:
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fvim%2Fvim80%2Fautoload'>Back to Directory</a>