<h2>Editing File: /usr/share/perl5/vendor_perl/perlfaq8.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perlfaq8 - System Interaction

=head1 VERSION

version 5.20180605

=head1 DESCRIPTION

This section of the Perl FAQ covers questions involving operating
system interaction. Topics include interprocess communication (IPC),
control over the user-interface (keyboard, screen and pointing
devices), and most anything else not related to data manipulation.

Read the FAQs and documentation specific to the port of perl to your
operating system (eg, L&lt;perlvms&gt;, L&lt;perlplan9&gt;, ...). These should
contain more detailed information on the vagaries of your perl.

=head2 How do I find out which operating system I'm running under?

The C&lt;$^O&gt; variable (C&lt;$OSNAME&gt; if you use C&lt;English&gt;) contains an
indication of the name of the operating system (not its release
number) that your perl binary was built for.

=head2 How come exec() doesn't return?
X&lt;exec&gt; X&lt;system&gt; X&lt;fork&gt; X&lt;open&gt; X&lt;pipe&gt;

(contributed by brian d foy)

The C&lt;exec&gt; function's job is to turn your process into another
command and never to return. If that's not what you want to do, don't
use C&lt;exec&gt;. :)

If you want to run an external command and still keep your Perl process
going, look at a piped C&lt;open&gt;, C&lt;fork&gt;, or C&lt;system&gt;.

=head2 How do I do fancy stuff with the keyboard/screen/mouse?

How you access/control keyboards, screens, and pointing devices
(&quot;mice&quot;) is system-dependent. Try the following modules:

=over 4

=item Keyboard

    Term::Cap               Standard perl distribution
    Term::ReadKey           CPAN
    Term::ReadLine::Gnu     CPAN
    Term::ReadLine::Perl    CPAN
    Term::Screen            CPAN

=item Screen

    Term::Cap               Standard perl distribution
    Curses                  CPAN
    Term::ANSIColor         CPAN

=item Mouse

    Tk                      CPAN
    Wx                      CPAN
    Gtk2                    CPAN
    Qt4                     kdebindings4 package

=back

Some of these specific cases are shown as examples in other answers
in this section of the perlfaq.

=head2 How do I print something out in color?

In general, you don't, because you don't know whether
the recipient has a color-aware display device. If you
know that they have an ANSI terminal that understands
color, you can use the L&lt;Term::ANSIColor&gt; module from CPAN:

    use Term::ANSIColor;
    print color(&quot;red&quot;), &quot;Stop!\n&quot;, color(&quot;reset&quot;);
    print color(&quot;green&quot;), &quot;Go!\n&quot;, color(&quot;reset&quot;);

Or like this:

    use Term::ANSIColor qw(:constants);
    print RED, &quot;Stop!\n&quot;, RESET;
    print GREEN, &quot;Go!\n&quot;, RESET;

=head2 How do I read just one key without waiting for a return key?

Controlling input buffering is a remarkably system-dependent matter.
On many systems, you can just use the B&lt;stty&gt; command as shown in
L&lt;perlfunc/getc&gt;, but as you see, that's already getting you into
portability snags.

    open(TTY, &quot;+&lt;/dev/tty&quot;) or die &quot;no tty: $!&quot;;
    system &quot;stty  cbreak &lt;/dev/tty &gt;/dev/tty 2&gt;&amp;1&quot;;
    $key = getc(TTY);        # perhaps this works
    # OR ELSE
    sysread(TTY, $key, 1);    # probably this does
    system &quot;stty -cbreak &lt;/dev/tty &gt;/dev/tty 2&gt;&amp;1&quot;;

The L&lt;Term::ReadKey&gt; module from CPAN offers an easy-to-use interface that
should be more efficient than shelling out to B&lt;stty&gt; for each key.
It even includes limited support for Windows.

    use Term::ReadKey;
    ReadMode('cbreak');
    $key = ReadKey(0);
    ReadMode('normal');

However, using the code requires that you have a working C compiler
and can use it to build and install a CPAN module. Here's a solution
using the standard L&lt;POSIX&gt; module, which is already on your system
(assuming your system supports POSIX).

    use HotKey;
    $key = readkey();

And here's the C&lt;HotKey&gt; module, which hides the somewhat mystifying calls
to manipulate the POSIX termios structures.

    # HotKey.pm
    package HotKey;

    use strict;
    use warnings;

    use parent 'Exporter';
    our @EXPORT = qw(cbreak cooked readkey);

    use POSIX qw(:termios_h);
    my ($term, $oterm, $echo, $noecho, $fd_stdin);

    $fd_stdin = fileno(STDIN);
    $term     = POSIX::Termios-&gt;new();
    $term-&gt;getattr($fd_stdin);
    $oterm     = $term-&gt;getlflag();

    $echo     = ECHO | ECHOK | ICANON;
    $noecho   = $oterm &amp; ~$echo;

    sub cbreak {
        $term-&gt;setlflag($noecho);  # ok, so i don't want echo either
        $term-&gt;setcc(VTIME, 1);
        $term-&gt;setattr($fd_stdin, TCSANOW);
    }

    sub cooked {
        $term-&gt;setlflag($oterm);
        $term-&gt;setcc(VTIME, 0);
        $term-&gt;setattr($fd_stdin, TCSANOW);
    }

    sub readkey {
        my $key = '';
        cbreak();
        sysread(STDIN, $key, 1);
        cooked();
        return $key;
    }

    END { cooked() }

    1;

=head2 How do I check whether input is ready on the keyboard?

The easiest way to do this is to read a key in nonblocking mode with the
L&lt;Term::ReadKey&gt; module from CPAN, passing it an argument of -1 to indicate
not to block:

    use Term::ReadKey;

    ReadMode('cbreak');

    if (defined (my $char = ReadKey(-1)) ) {
        # input was waiting and it was $char
    } else {
        # no input was waiting
    }

    ReadMode('normal');                  # restore normal tty settings

=head2 How do I clear the screen?

(contributed by brian d foy)

To clear the screen, you just have to print the special sequence
that tells the terminal to clear the screen. Once you have that
sequence, output it when you want to clear the screen.

You can use the L&lt;Term::ANSIScreen&gt; module to get the special
sequence. Import the C&lt;cls&gt; function (or the C&lt;:screen&gt; tag):

    use Term::ANSIScreen qw(cls);
    my $clear_screen = cls();

    print $clear_screen;

The L&lt;Term::Cap&gt; module can also get the special sequence if you want
to deal with the low-level details of terminal control. The C&lt;Tputs&gt;
method returns the string for the given capability:

    use Term::Cap;

    my $terminal = Term::Cap-&gt;Tgetent( { OSPEED =&gt; 9600 } );
    my $clear_screen = $terminal-&gt;Tputs('cl');

    print $clear_screen;

On Windows, you can use the L&lt;Win32::Console&gt; module. After creating
an object for the output filehandle you want to affect, call the
C&lt;Cls&gt; method:

    Win32::Console;

    my $OUT = Win32::Console-&gt;new(STD_OUTPUT_HANDLE);
    my $clear_string = $OUT-&gt;Cls;

    print $clear_screen;

If you have a command-line program that does the job, you can call
it in backticks to capture whatever it outputs so you can use it
later:

    my $clear_string = `clear`;

    print $clear_string;

=head2 How do I get the screen size?

If you have L&lt;Term::ReadKey&gt; module installed from CPAN,
you can use it to fetch the width and height in characters
and in pixels:

    use Term::ReadKey;
    my ($wchar, $hchar, $wpixels, $hpixels) = GetTerminalSize();

This is more portable than the raw C&lt;ioctl&gt;, but not as
illustrative:

    require 'sys/ioctl.ph';
    die &quot;no TIOCGWINSZ &quot; unless defined &amp;TIOCGWINSZ;
    open(my $tty_fh, &quot;+&lt;/dev/tty&quot;)                     or die &quot;No tty: $!&quot;;
    unless (ioctl($tty_fh, &amp;TIOCGWINSZ, $winsize='')) {
        die sprintf &quot;$0: ioctl TIOCGWINSZ (%08x: $!)\n&quot;, &amp;TIOCGWINSZ;
    }
    my ($row, $col, $xpixel, $ypixel) = unpack('S4', $winsize);
    print &quot;(row,col) = ($row,$col)&quot;;
    print &quot;  (xpixel,ypixel) = ($xpixel,$ypixel)&quot; if $xpixel || $ypixel;
    print &quot;\n&quot;;

=head2 How do I ask the user for a password?

(This question has nothing to do with the web. See a different
FAQ for that.)

There's an example of this in L&lt;perlfunc/crypt&gt;). First, you put the
terminal into &quot;no echo&quot; mode, then just read the password normally.
You may do this with an old-style C&lt;ioctl()&gt; function, POSIX terminal
control (see L&lt;POSIX&gt; or its documentation the Camel Book), or a call
to the B&lt;stty&gt; program, with varying degrees of portability.

You can also do this for most systems using the L&lt;Term::ReadKey&gt; module
from CPAN, which is easier to use and in theory more portable.

    use Term::ReadKey;

    ReadMode('noecho');
    my $password = ReadLine(0);

=head2 How do I read and write the serial port?

This depends on which operating system your program is running on. In
the case of Unix, the serial ports will be accessible through files in
C&lt;/dev&gt;; on other systems, device names will doubtless differ.
Several problem areas common to all device interaction are the
following:

=over 4

=item lockfiles

Your system may use lockfiles to control multiple access. Make sure
you follow the correct protocol. Unpredictable behavior can result
from multiple processes reading from one device.

=item open mode

If you expect to use both read and write operations on the device,
you'll have to open it for update (see L&lt;perlfunc/&quot;open&quot;&gt; for
details). You may wish to open it without running the risk of
blocking by using C&lt;sysopen()&gt; and C&lt;O_RDWR|O_NDELAY|O_NOCTTY&gt; from the
L&lt;Fcntl&gt; module (part of the standard perl distribution). See
L&lt;perlfunc/&quot;sysopen&quot;&gt; for more on this approach.

=item end of line

Some devices will be expecting a &quot;\r&quot; at the end of each line rather
than a &quot;\n&quot;. In some ports of perl, &quot;\r&quot; and &quot;\n&quot; are different from
their usual (Unix) ASCII values of &quot;\015&quot; and &quot;\012&quot;. You may have to
give the numeric values you want directly, using octal (&quot;\015&quot;), hex
(&quot;0x0D&quot;), or as a control-character specification (&quot;\cM&quot;).

    print DEV &quot;atv1\012&quot;;    # wrong, for some devices
    print DEV &quot;atv1\015&quot;;    # right, for some devices

Even though with normal text files a &quot;\n&quot; will do the trick, there is
still no unified scheme for terminating a line that is portable
between Unix, DOS/Win, and Macintosh, except to terminate I&lt;ALL&gt; line
ends with &quot;\015\012&quot;, and strip what you don't need from the output.
This applies especially to socket I/O and autoflushing, discussed
next.

=item flushing output

If you expect characters to get to your device when you C&lt;print()&gt; them,
you'll want to autoflush that filehandle. You can use C&lt;select()&gt;
and the C&lt;$|&gt; variable to control autoflushing (see L&lt;perlvar/$E&lt;verbar&gt;&gt;
and L&lt;perlfunc/select&gt;, or L&lt;perlfaq5&gt;, &quot;How do I flush/unbuffer an
output filehandle? Why must I do this?&quot;):

    my $old_handle = select($dev_fh);
    $| = 1;
    select($old_handle);

You'll also see code that does this without a temporary variable, as in

    select((select($deb_handle), $| = 1)[0]);

Or if you don't mind pulling in a few thousand lines
of code just because you're afraid of a little C&lt;$|&gt; variable:

    use IO::Handle;
    $dev_fh-&gt;autoflush(1);

As mentioned in the previous item, this still doesn't work when using
socket I/O between Unix and Macintosh. You'll need to hard code your
line terminators, in that case.

=item non-blocking input

If you are doing a blocking C&lt;read()&gt; or C&lt;sysread()&gt;, you'll have to
arrange for an alarm handler to provide a timeout (see
L&lt;perlfunc/alarm&gt;). If you have a non-blocking open, you'll likely
have a non-blocking read, which means you may have to use a 4-arg
C&lt;select()&gt; to determine whether I/O is ready on that device (see
L&lt;perlfunc/&quot;select&quot;&gt;.

=back

While trying to read from his caller-id box, the notorious Jamie
Zawinski C&lt;&lt; &lt;jwz@netscape.com&gt; &gt;&gt;, after much gnashing of teeth and
fighting with C&lt;sysread&gt;, C&lt;sysopen&gt;, POSIX's C&lt;tcgetattr&gt; business,
and various other functions that go bump in the night, finally came up
with this:

    sub open_modem {
        use IPC::Open2;
        my $stty = `/bin/stty -g`;
        open2( \*MODEM_IN, \*MODEM_OUT, &quot;cu -l$modem_device -s2400 2&gt;&amp;1&quot;);
        # starting cu hoses /dev/tty's stty settings, even when it has
        # been opened on a pipe...
        system(&quot;/bin/stty $stty&quot;);
        $_ = &lt;MODEM_IN&gt;;
        chomp;
        if ( !m/^Connected/ ) {
            print STDERR &quot;$0: cu printed `$_' instead of `Connected'\n&quot;;
        }
    }

=head2 How do I decode encrypted password files?

You spend lots and lots of money on dedicated hardware, but this is
bound to get you talked about.

Seriously, you can't if they are Unix password files--the Unix
password system employs one-way encryption. It's more like hashing
than encryption. The best you can do is check whether something else
hashes to the same string. You can't turn a hash back into the
original string. Programs like Crack can forcibly (and intelligently)
try to guess passwords, but don't (can't) guarantee quick success.

If you're worried about users selecting bad passwords, you should
proactively check when they try to change their password (by modifying
L&lt;passwd(1)&gt;, for example).

=head2 How do I start a process in the background?

(contributed by brian d foy)

There's not a single way to run code in the background so you don't
have to wait for it to finish before your program moves on to other
tasks. Process management depends on your particular operating system,
and many of the techniques are covered in L&lt;perlipc&gt;.

Several CPAN modules may be able to help, including L&lt;IPC::Open2&gt; or
L&lt;IPC::Open3&gt;, L&lt;IPC::Run&gt;, L&lt;Parallel::Jobs&gt;,
L&lt;Parallel::ForkManager&gt;, L&lt;POE&gt;, L&lt;Proc::Background&gt;, and
L&lt;Win32::Process&gt;. There are many other modules you might use, so
check those namespaces for other options too.

If you are on a Unix-like system, you might be able to get away with a
system call where you put an C&lt;&amp;&gt; on the end of the command:

    system(&quot;cmd &amp;&quot;)

You can also try using C&lt;fork&gt;, as described in L&lt;perlfunc&gt; (although
this is the same thing that many of the modules will do for you).

=over 4

=item STDIN, STDOUT, and STDERR are shared

Both the main process and the backgrounded one (the &quot;child&quot; process)
share the same STDIN, STDOUT and STDERR filehandles. If both try to
access them at once, strange things can happen. You may want to close
or reopen these for the child. You can get around this with
C&lt;open&gt;ing a pipe (see L&lt;perlfunc/&quot;open&quot;&gt;) but on some systems this
means that the child process cannot outlive the parent.

=item Signals

You'll have to catch the SIGCHLD signal, and possibly SIGPIPE too.
SIGCHLD is sent when the backgrounded process finishes. SIGPIPE is
sent when you write to a filehandle whose child process has closed (an
untrapped SIGPIPE can cause your program to silently die). This is
not an issue with C&lt;system(&quot;cmd&amp;&quot;)&gt;.

=item Zombies

You have to be prepared to &quot;reap&quot; the child process when it finishes.

    $SIG{CHLD} = sub { wait };

    $SIG{CHLD} = 'IGNORE';

You can also use a double fork. You immediately C&lt;wait()&gt; for your
first child, and the init daemon will C&lt;wait()&gt; for your grandchild once
it exits.

    unless ($pid = fork) {
        unless (fork) {
            exec &quot;what you really wanna do&quot;;
            die &quot;exec failed!&quot;;
        }
        exit 0;
    }
    waitpid($pid, 0);

See L&lt;perlipc/&quot;Signals&quot;&gt; for other examples of code to do this.
Zombies are not an issue with C&lt;system(&quot;prog &amp;&quot;)&gt;.

=back

=head2 How do I trap control characters/signals?

You don't actually &quot;trap&quot; a control character. Instead, that character
generates a signal which is sent to your terminal's currently
foregrounded process group, which you then trap in your process.
Signals are documented in L&lt;perlipc/&quot;Signals&quot;&gt; and the
section on &quot;Signals&quot; in the Camel.

You can set the values of the C&lt;%SIG&gt; hash to be the functions you want
to handle the signal. After perl catches the signal, it looks in C&lt;%SIG&gt;
for a key with the same name as the signal, then calls the subroutine
value for that key.

    # as an anonymous subroutine

    $SIG{INT} = sub { syswrite(STDERR, &quot;ouch\n&quot;, 5 ) };

    # or a reference to a function

    $SIG{INT} = \&amp;ouch;

    # or the name of the function as a string

    $SIG{INT} = &quot;ouch&quot;;

Perl versions before 5.8 had in its C source code signal handlers which
would catch the signal and possibly run a Perl function that you had set
in C&lt;%SIG&gt;. This violated the rules of signal handling at that level
causing perl to dump core. Since version 5.8.0, perl looks at C&lt;%SIG&gt;
B&lt;after&gt; the signal has been caught, rather than while it is being caught.
Previous versions of this answer were incorrect.

=head2 How do I modify the shadow password file on a Unix system?

If perl was installed correctly and your shadow library was written
properly, the C&lt;getpw*()&gt; functions described in L&lt;perlfunc&gt; should in
theory provide (read-only) access to entries in the shadow password
file. To change the file, make a new shadow password file (the format
varies from system to system--see L&lt;passwd(1)&gt; for specifics) and use
C&lt;pwd_mkdb(8)&gt; to install it (see L&lt;pwd_mkdb(8)&gt; for more details).

=head2 How do I set the time and date?

Assuming you're running under sufficient permissions, you should be
able to set the system-wide date and time by running the C&lt;date(1)&gt;
program. (There is no way to set the time and date on a per-process
basis.)  This mechanism will work for Unix, MS-DOS, Windows, and NT;
the VMS equivalent is C&lt;set time&gt;.

However, if all you want to do is change your time zone, you can
probably get away with setting an environment variable:

    $ENV{TZ} = &quot;MST7MDT&quot;;           # Unixish
    $ENV{'SYS$TIMEZONE_DIFFERENTIAL'}=&quot;-5&quot; # vms
    system('trn', 'comp.lang.perl.misc');

=head2 How can I sleep() or alarm() for under a second?
X&lt;Time::HiRes&gt; X&lt;BSD::Itimer&gt; X&lt;sleep&gt; X&lt;select&gt;

If you want finer granularity than the 1 second that the C&lt;sleep()&gt;
function provides, the easiest way is to use the C&lt;select()&gt; function as
documented in L&lt;perlfunc/&quot;select&quot;&gt;. Try the L&lt;Time::HiRes&gt; and
the L&lt;BSD::Itimer&gt; modules (available from CPAN, and starting from
Perl 5.8 L&lt;Time::HiRes&gt; is part of the standard distribution).

=head2 How can I measure time under a second?
X&lt;Time::HiRes&gt; X&lt;BSD::Itimer&gt; X&lt;sleep&gt; X&lt;select&gt;

(contributed by brian d foy)

The L&lt;Time::HiRes&gt; module (part of the standard distribution as of
Perl 5.8) measures time with the C&lt;gettimeofday()&gt; system call, which
returns the time in microseconds since the epoch. If you can't install
L&lt;Time::HiRes&gt; for older Perls and you are on a Unixish system, you
may be able to call C&lt;gettimeofday(2)&gt; directly. See
L&lt;perlfunc/syscall&gt;.

=head2 How can I do an atexit() or setjmp()/longjmp()? (Exception handling)

You can use the C&lt;END&gt; block to simulate C&lt;atexit()&gt;. Each package's
C&lt;END&gt; block is called when the program or thread ends. See the L&lt;perlmod&gt;
manpage for more details about C&lt;END&gt; blocks.

For example, you can use this to make sure your filter program managed
to finish its output without filling up the disk:

    END {
        close(STDOUT) || die &quot;stdout close failed: $!&quot;;
    }

The C&lt;END&gt; block isn't called when untrapped signals kill the program,
though, so if you use C&lt;END&gt; blocks you should also use

    use sigtrap qw(die normal-signals);

Perl's exception-handling mechanism is its C&lt;eval()&gt; operator. You
can use C&lt;eval()&gt; as C&lt;setjmp&gt; and C&lt;die()&gt; as C&lt;longjmp&gt;. For
details of this, see the section on signals, especially the time-out
handler for a blocking C&lt;flock()&gt; in L&lt;perlipc/&quot;Signals&quot;&gt; or the
section on &quot;Signals&quot; in I&lt;Programming Perl&gt;.

If exception handling is all you're interested in, use one of the
many CPAN modules that handle exceptions, such as L&lt;Try::Tiny&gt;.

If you want the C&lt;atexit()&gt; syntax (and an C&lt;rmexit()&gt; as well), try the
C&lt;AtExit&gt; module available from CPAN.

=head2 Why doesn't my sockets program work under System V (Solaris)? What does the error message &quot;Protocol not supported&quot; mean?

Some Sys-V based systems, notably Solaris 2.X, redefined some of the
standard socket constants. Since these were constant across all
architectures, they were often hardwired into perl code. The proper
way to deal with this is to &quot;use Socket&quot; to get the correct values.

Note that even though SunOS and Solaris are binary compatible, these
values are different. Go figure.

=head2 How can I call my system's unique C functions from Perl?

In most cases, you write an external module to do it--see the answer
to &quot;Where can I learn about linking C with Perl? [h2xs, xsubpp]&quot;.
However, if the function is a system call, and your system supports
C&lt;syscall()&gt;, you can use the C&lt;syscall&gt; function (documented in
L&lt;perlfunc&gt;).

Remember to check the modules that came with your distribution, and
CPAN as well--someone may already have written a module to do it. On
Windows, try L&lt;Win32::API&gt;. On Macs, try L&lt;Mac::Carbon&gt;. If no module
has an interface to the C function, you can inline a bit of C in your
Perl source with L&lt;Inline::C&gt;.

=head2 Where do I get the include files to do ioctl() or syscall()?

Historically, these would be generated by the L&lt;h2ph&gt; tool, part of the
standard perl distribution. This program converts C&lt;cpp(1)&gt; directives
in C header files to files containing subroutine definitions, like
C&lt;SYS_getitimer()&gt;, which you can use as arguments to your functions.
It doesn't work perfectly, but it usually gets most of the job done.
Simple files like F&lt;errno.h&gt;, F&lt;syscall.h&gt;, and F&lt;socket.h&gt; were fine,
but the hard ones like F&lt;ioctl.h&gt; nearly always need to be hand-edited.
Here's how to install the *.ph files:

    1. Become the super-user
    2. cd /usr/include
    3. h2ph *.h */*.h

If your system supports dynamic loading, for reasons of portability and
sanity you probably ought to use L&lt;h2xs&gt; (also part of the standard perl
distribution). This tool converts C header files to Perl extensions.
See L&lt;perlxstut&gt; for how to get started with L&lt;h2xs&gt;.

If your system doesn't support dynamic loading, you still probably
ought to use L&lt;h2xs&gt;. See L&lt;perlxstut&gt; and L&lt;ExtUtils::MakeMaker&gt; for
more information (in brief, just use B&lt;make perl&gt; instead of a plain
B&lt;make&gt; to rebuild perl with a new static extension).

=head2 Why do setuid perl scripts complain about kernel problems?

Some operating systems have bugs in the kernel that make setuid
scripts inherently insecure. Perl gives you a number of options
(described in L&lt;perlsec&gt;) to work around such systems.

=head2 How can I open a pipe both to and from a command?

The L&lt;IPC::Open2&gt; module (part of the standard perl distribution) is
an easy-to-use approach that internally uses C&lt;pipe()&gt;, C&lt;fork()&gt;, and
C&lt;exec()&gt; to do the job. Make sure you read the deadlock warnings in
its documentation, though (see L&lt;IPC::Open2&gt;). See
L&lt;perlipc/&quot;Bidirectional Communication with Another Process&quot;&gt; and
L&lt;perlipc/&quot;Bidirectional Communication with Yourself&quot;&gt;

You may also use the L&lt;IPC::Open3&gt; module (part of the standard perl
distribution), but be warned that it has a different order of
arguments from L&lt;IPC::Open2&gt; (see L&lt;IPC::Open3&gt;).

=head2 Why can't I get the output of a command with system()?

You're confusing the purpose of C&lt;system()&gt; and backticks (``). C&lt;system()&gt;
runs a command and returns exit status information (as a 16 bit value:
the low 7 bits are the signal the process died from, if any, and
the high 8 bits are the actual exit value). Backticks (``) run a
command and return what it sent to STDOUT.

    my $exit_status   = system(&quot;mail-users&quot;);
    my $output_string = `ls`;

=head2 How can I capture STDERR from an external command?

There are three basic ways of running external commands:

    system $cmd;        # using system()
    my $output = `$cmd`;        # using backticks (``)
    open (my $pipe_fh, &quot;$cmd |&quot;);    # using open()

With C&lt;system()&gt;, both STDOUT and STDERR will go the same place as the
script's STDOUT and STDERR, unless the C&lt;system()&gt; command redirects them.
Backticks and C&lt;open()&gt; read B&lt;only&gt; the STDOUT of your command.

You can also use the C&lt;open3()&gt; function from L&lt;IPC::Open3&gt;. Benjamin
Goldberg provides some sample code:

To capture a program's STDOUT, but discard its STDERR:

    use IPC::Open3;
    use File::Spec;
    my $in = '';
    open(NULL, &quot;&gt;&quot;, File::Spec-&gt;devnull);
    my $pid = open3($in, \*PH, &quot;&gt;&amp;NULL&quot;, &quot;cmd&quot;);
    while( &lt;PH&gt; ) { }
    waitpid($pid, 0);

To capture a program's STDERR, but discard its STDOUT:

    use IPC::Open3;
    use File::Spec;
    my $in = '';
    open(NULL, &quot;&gt;&quot;, File::Spec-&gt;devnull);
    my $pid = open3($in, &quot;&gt;&amp;NULL&quot;, \*PH, &quot;cmd&quot;);
    while( &lt;PH&gt; ) { }
    waitpid($pid, 0);

To capture a program's STDERR, and let its STDOUT go to our own STDERR:

    use IPC::Open3;
    my $in = '';
    my $pid = open3($in, &quot;&gt;&amp;STDERR&quot;, \*PH, &quot;cmd&quot;);
    while( &lt;PH&gt; ) { }
    waitpid($pid, 0);

To read both a command's STDOUT and its STDERR separately, you can
redirect them to temp files, let the command run, then read the temp
files:

    use IPC::Open3;
    use IO::File;
    my $in = '';
    local *CATCHOUT = IO::File-&gt;new_tmpfile;
    local *CATCHERR = IO::File-&gt;new_tmpfile;
    my $pid = open3($in, &quot;&gt;&amp;CATCHOUT&quot;, &quot;&gt;&amp;CATCHERR&quot;, &quot;cmd&quot;);
    waitpid($pid, 0);
    seek $_, 0, 0 for \*CATCHOUT, \*CATCHERR;
    while( &lt;CATCHOUT&gt; ) {}
    while( &lt;CATCHERR&gt; ) {}

But there's no real need for B&lt;both&gt; to be tempfiles... the following
should work just as well, without deadlocking:

    use IPC::Open3;
    my $in = '';
    use IO::File;
    local *CATCHERR = IO::File-&gt;new_tmpfile;
    my $pid = open3($in, \*CATCHOUT, &quot;&gt;&amp;CATCHERR&quot;, &quot;cmd&quot;);
    while( &lt;CATCHOUT&gt; ) {}
    waitpid($pid, 0);
    seek CATCHERR, 0, 0;
    while( &lt;CATCHERR&gt; ) {}

And it'll be faster, too, since we can begin processing the program's
stdout immediately, rather than waiting for the program to finish.

With any of these, you can change file descriptors before the call:

    open(STDOUT, &quot;&gt;logfile&quot;);
    system(&quot;ls&quot;);

or you can use Bourne shell file-descriptor redirection:

    $output = `$cmd 2&gt;some_file`;
    open (PIPE, &quot;cmd 2&gt;some_file |&quot;);

You can also use file-descriptor redirection to make STDERR a
duplicate of STDOUT:

    $output = `$cmd 2&gt;&amp;1`;
    open (PIPE, &quot;cmd 2&gt;&amp;1 |&quot;);

Note that you I&lt;cannot&gt; simply open STDERR to be a dup of STDOUT
in your Perl program and avoid calling the shell to do the redirection.
This doesn't work:

    open(STDERR, &quot;&gt;&amp;STDOUT&quot;);
    $alloutput = `cmd args`;  # stderr still escapes

This fails because the C&lt;open()&gt; makes STDERR go to where STDOUT was
going at the time of the C&lt;open()&gt;. The backticks then make STDOUT go to
a string, but don't change STDERR (which still goes to the old
STDOUT).

Note that you I&lt;must&gt; use Bourne shell (C&lt;sh(1)&gt;) redirection syntax in
backticks, not C&lt;csh(1)&gt;!  Details on why Perl's C&lt;system()&gt; and backtick
and pipe opens all use the Bourne shell are in the
F&lt;versus/csh.whynot&gt; article in the &quot;Far More Than You Ever Wanted To
Know&quot; collection in L&lt;http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz&gt; . To
capture a command's STDERR and STDOUT together:

    $output = `cmd 2&gt;&amp;1`;                       # either with backticks
    $pid = open(PH, &quot;cmd 2&gt;&amp;1 |&quot;);              # or with an open pipe
    while (&lt;PH&gt;) { }                            #    plus a read

To capture a command's STDOUT but discard its STDERR:

    $output = `cmd 2&gt;/dev/null`;                # either with backticks
    $pid = open(PH, &quot;cmd 2&gt;/dev/null |&quot;);       # or with an open pipe
    while (&lt;PH&gt;) { }                            #    plus a read

To capture a command's STDERR but discard its STDOUT:

    $output = `cmd 2&gt;&amp;1 1&gt;/dev/null`;           # either with backticks
    $pid = open(PH, &quot;cmd 2&gt;&amp;1 1&gt;/dev/null |&quot;);  # or with an open pipe
    while (&lt;PH&gt;) { }                            #    plus a read

To exchange a command's STDOUT and STDERR in order to capture the STDERR
but leave its STDOUT to come out our old STDERR:

    $output = `cmd 3&gt;&amp;1 1&gt;&amp;2 2&gt;&amp;3 3&gt;&amp;-`;        # either with backticks
    $pid = open(PH, &quot;cmd 3&gt;&amp;1 1&gt;&amp;2 2&gt;&amp;3 3&gt;&amp;-|&quot;);# or with an open pipe
    while (&lt;PH&gt;) { }                            #    plus a read

To read both a command's STDOUT and its STDERR separately, it's easiest
to redirect them separately to files, and then read from those files
when the program is done:

    system(&quot;program args 1&gt;program.stdout 2&gt;program.stderr&quot;);

Ordering is important in all these examples. That's because the shell
processes file descriptor redirections in strictly left to right order.

    system(&quot;prog args 1&gt;tmpfile 2&gt;&amp;1&quot;);
    system(&quot;prog args 2&gt;&amp;1 1&gt;tmpfile&quot;);

The first command sends both standard out and standard error to the
temporary file. The second command sends only the old standard output
there, and the old standard error shows up on the old standard out.

=head2 Why doesn't open() return an error when a pipe open fails?

If the second argument to a piped C&lt;open()&gt; contains shell
metacharacters, perl C&lt;fork()&gt;s, then C&lt;exec()&gt;s a shell to decode the
metacharacters and eventually run the desired program. If the program
couldn't be run, it's the shell that gets the message, not Perl. All
your Perl program can find out is whether the shell itself could be
successfully started. You can still capture the shell's STDERR and
check it for error messages. See L&lt;&quot;How can I capture STDERR from an
external command?&quot;&gt; elsewhere in this document, or use the
L&lt;IPC::Open3&gt; module.

If there are no shell metacharacters in the argument of C&lt;open()&gt;, Perl
runs the command directly, without using the shell, and can correctly
report whether the command started.

=head2 What's wrong with using backticks in a void context?

Strictly speaking, nothing. Stylistically speaking, it's not a good
way to write maintainable code. Perl has several operators for
running external commands. Backticks are one; they collect the output
from the command for use in your program. The C&lt;system&gt; function is
another; it doesn't do this.

Writing backticks in your program sends a clear message to the readers
of your code that you wanted to collect the output of the command.
Why send a clear message that isn't true?

Consider this line:

    `cat /etc/termcap`;

You forgot to check C&lt;$?&gt; to see whether the program even ran
correctly. Even if you wrote

    print `cat /etc/termcap`;

this code could and probably should be written as

    system(&quot;cat /etc/termcap&quot;) == 0
    or die &quot;cat program failed!&quot;;

which will echo the cat command's output as it is generated, instead
of waiting until the program has completed to print it out. It also
checks the return value.

C&lt;system&gt; also provides direct control over whether shell wildcard
processing may take place, whereas backticks do not.

=head2 How can I call backticks without shell processing?

This is a bit tricky. You can't simply write the command
like this:

    @ok = `grep @opts '$search_string' @filenames`;

As of Perl 5.8.0, you can use C&lt;open()&gt; with multiple arguments.
Just like the list forms of C&lt;system()&gt; and C&lt;exec()&gt;, no shell
escapes happen.

    open( GREP, &quot;-|&quot;, 'grep', @opts, $search_string, @filenames );
    chomp(@ok = &lt;GREP&gt;);
    close GREP;

You can also:

    my @ok = ();
    if (open(GREP, &quot;-|&quot;)) {
        while (&lt;GREP&gt;) {
            chomp;
            push(@ok, $_);
        }
        close GREP;
    } else {
        exec 'grep', @opts, $search_string, @filenames;
    }

Just as with C&lt;system()&gt;, no shell escapes happen when you C&lt;exec()&gt; a
list. Further examples of this can be found in L&lt;perlipc/&quot;Safe Pipe
Opens&quot;&gt;.

Note that if you're using Windows, no solution to this vexing issue is
even possible. Even though Perl emulates C&lt;fork()&gt;, you'll still be
stuck, because Windows does not have an argc/argv-style API.

=head2 Why can't my script read from STDIN after I gave it EOF (^D on Unix, ^Z on MS-DOS)?

This happens only if your perl is compiled to use stdio instead of
perlio, which is the default. Some (maybe all?) stdios set error and
eof flags that you may need to clear. The L&lt;POSIX&gt; module defines
C&lt;clearerr()&gt; that you can use. That is the technically correct way to
do it. Here are some less reliable workarounds:

=over 4

=item 1

Try keeping around the seekpointer and go there, like this:

    my $where = tell($log_fh);
    seek($log_fh, $where, 0);

=item 2

If that doesn't work, try seeking to a different part of the file and
then back.

=item 3

If that doesn't work, try seeking to a different part of
the file, reading something, and then seeking back.

=item 4

If that doesn't work, give up on your stdio package and use sysread.

=back

=head2 How can I convert my shell script to perl?

Learn Perl and rewrite it. Seriously, there's no simple converter.
Things that are awkward to do in the shell are easy to do in Perl, and
this very awkwardness is what would make a shell-&gt;perl converter
nigh-on impossible to write. By rewriting it, you'll think about what
you're really trying to do, and hopefully will escape the shell's
pipeline datastream paradigm, which while convenient for some matters,
causes many inefficiencies.

=head2 Can I use perl to run a telnet or ftp session?

Try the L&lt;Net::FTP&gt;, L&lt;TCP::Client&gt;, and L&lt;Net::Telnet&gt; modules
(available from CPAN).
L&lt;http://www.cpan.org/scripts/netstuff/telnet.emul.shar&gt; will also help
for emulating the telnet protocol, but L&lt;Net::Telnet&gt; is quite
probably easier to use.

If all you want to do is pretend to be telnet but don't need
the initial telnet handshaking, then the standard dual-process
approach will suffice:

    use IO::Socket;             # new in 5.004
    my $handle = IO::Socket::INET-&gt;new('www.perl.com:80')
        or die &quot;can't connect to port 80 on www.perl.com $!&quot;;
    $handle-&gt;autoflush(1);
    if (fork()) {               # XXX: undef means failure
        select($handle);
        print while &lt;STDIN&gt;;    # everything from stdin to socket
    } else {
        print while &lt;$handle&gt;;  # everything from socket to stdout
    }
    close $handle;
    exit;

=head2 How can I write expect in Perl?

Once upon a time, there was a library called F&lt;chat2.pl&gt; (part of the
standard perl distribution), which never really got finished. If you
find it somewhere, I&lt;don't use it&gt;. These days, your best bet is to
look at the L&lt;Expect&gt; module available from CPAN, which also requires two
other modules from CPAN, L&lt;IO::Pty&gt; and L&lt;IO::Stty&gt;.

=head2 Is there a way to hide perl's command line from programs such as &quot;ps&quot;?

First of all note that if you're doing this for security reasons (to
avoid people seeing passwords, for example) then you should rewrite
your program so that critical information is never given as an
argument. Hiding the arguments won't make your program completely
secure.

To actually alter the visible command line, you can assign to the
variable $0 as documented in L&lt;perlvar&gt;. This won't work on all
operating systems, though. Daemon programs like sendmail place their
state there, as in:

    $0 = &quot;orcus [accepting connections]&quot;;

=head2 I {changed directory, modified my environment} in a perl script. How come the change disappeared when I exited the script? How do I get my changes to be visible?

=over 4

=item Unix

In the strictest sense, it can't be done--the script executes as a
different process from the shell it was started from. Changes to a
process are not reflected in its parent--only in any children
created after the change. There is shell magic that may allow you to
fake it by C&lt;eval()&gt;ing the script's output in your shell; check out the
comp.unix.questions FAQ for details.

=back

=head2 How do I close a process's filehandle without waiting for it to complete?

Assuming your system supports such things, just send an appropriate signal
to the process (see L&lt;perlfunc/&quot;kill&quot;&gt;). It's common to first send a TERM
signal, wait a little bit, and then send a KILL signal to finish it off.

=head2 How do I fork a daemon process?

If by daemon process you mean one that's detached (disassociated from
its tty), then the following process is reported to work on most
Unixish systems. Non-Unix users should check their Your_OS::Process
module for other solutions.

=over 4

=item *

Open /dev/tty and use the TIOCNOTTY ioctl on it. See L&lt;tty(1)&gt;
for details. Or better yet, you can just use the C&lt;POSIX::setsid()&gt;
function, so you don't have to worry about process groups.

=item *

Change directory to /

=item *

Reopen STDIN, STDOUT, and STDERR so they're not connected to the old
tty.

=item *

Background yourself like this:

    fork &amp;&amp; exit;

=back

The L&lt;Proc::Daemon&gt; module, available from CPAN, provides a function to
perform these actions for you.

=head2 How do I find out if I'm running interactively or not?

(contributed by brian d foy)

This is a difficult question to answer, and the best answer is
only a guess.

What do you really want to know? If you merely want to know if one of
your filehandles is connected to a terminal, you can try the C&lt;-t&gt;
file test:

    if( -t STDOUT ) {
        print &quot;I'm connected to a terminal!\n&quot;;
    }

However, you might be out of luck if you expect that means there is a
real person on the other side. With the L&lt;Expect&gt; module, another
program can pretend to be a person. The program might even come close
to passing the Turing test.

The L&lt;IO::Interactive&gt; module does the best it can to give you an
answer. Its C&lt;is_interactive&gt; function returns an output filehandle;
that filehandle points to standard output if the module thinks the
session is interactive. Otherwise, the filehandle is a null handle
that simply discards the output:

    use IO::Interactive;

    print { is_interactive } &quot;I might go to standard output!\n&quot;;

This still doesn't guarantee that a real person is answering your
prompts or reading your output.

If you want to know how to handle automated testing for your
distribution, you can check the environment. The CPAN
Testers, for instance, set the value of C&lt;AUTOMATED_TESTING&gt;:

    unless( $ENV{AUTOMATED_TESTING} ) {
        print &quot;Hello interactive tester!\n&quot;;
    }

=head2 How do I timeout a slow event?

Use the C&lt;alarm()&gt; function, probably in conjunction with a signal
handler, as documented in L&lt;perlipc/&quot;Signals&quot;&gt; and the section on
&quot;Signals&quot; in the Camel. You may instead use the more flexible
L&lt;Sys::AlarmCall&gt; module available from CPAN.

The C&lt;alarm()&gt; function is not implemented on all versions of Windows.
Check the documentation for your specific version of Perl.

=head2 How do I set CPU limits?
X&lt;BSD::Resource&gt; X&lt;limit&gt; X&lt;CPU&gt;

(contributed by Xho)

Use the L&lt;BSD::Resource&gt; module from CPAN. As an example:

    use BSD::Resource;
    setrlimit(RLIMIT_CPU,10,20) or die $!;

This sets the soft and hard limits to 10 and 20 seconds, respectively.
After 10 seconds of time spent running on the CPU (not &quot;wall&quot; time),
the process will be sent a signal (XCPU on some systems) which, if not
trapped, will cause the process to terminate. If that signal is
trapped, then after 10 more seconds (20 seconds in total) the process
will be killed with a non-trappable signal.

See the L&lt;BSD::Resource&gt; and your systems documentation for the gory
details.

=head2 How do I avoid zombies on a Unix system?

Use the reaper code from L&lt;perlipc/&quot;Signals&quot;&gt; to call C&lt;wait()&gt; when a
SIGCHLD is received, or else use the double-fork technique described
in L&lt;perlfaq8/&quot;How do I start a process in the background?&quot;&gt;.

=head2 How do I use an SQL database?

The L&lt;DBI&gt; module provides an abstract interface to most database
servers and types, including Oracle, DB2, Sybase, mysql, Postgresql,
ODBC, and flat files. The DBI module accesses each database type
through a database driver, or DBD. You can see a complete list of
available drivers on CPAN: L&lt;http://www.cpan.org/modules/by-module/DBD/&gt; .
You can read more about DBI on L&lt;http://dbi.perl.org/&gt; .

Other modules provide more specific access: L&lt;Win32::ODBC&gt;, L&lt;Alzabo&gt;,
C&lt;iodbc&gt;, and others found on CPAN Search: L&lt;https://metacpan.org/&gt; .

=head2 How do I make a system() exit on control-C?

You can't. You need to imitate the C&lt;system()&gt; call (see L&lt;perlipc&gt; for
sample code) and then have a signal handler for the INT signal that
passes the signal on to the subprocess. Or you can check for it:

    $rc = system($cmd);
    if ($rc &amp; 127) { die &quot;signal death&quot; }

=head2 How do I open a file without blocking?

If you're lucky enough to be using a system that supports
non-blocking reads (most Unixish systems do), you need only to use the
C&lt;O_NDELAY&gt; or C&lt;O_NONBLOCK&gt; flag from the C&lt;Fcntl&gt; module in conjunction with
C&lt;sysopen()&gt;:

    use Fcntl;
    sysopen(my $fh, &quot;/foo/somefile&quot;, O_WRONLY|O_NDELAY|O_CREAT, 0644)
        or die &quot;can't open /foo/somefile: $!&quot;:

=head2 How do I tell the difference between errors from the shell and perl?

(answer contributed by brian d foy)

When you run a Perl script, something else is running the script for you,
and that something else may output error messages. The script might
emit its own warnings and error messages. Most of the time you cannot
tell who said what.

You probably cannot fix the thing that runs perl, but you can change how
perl outputs its warnings by defining a custom warning and die functions.

Consider this script, which has an error you may not notice immediately.

    #!/usr/locl/bin/perl

    print &quot;Hello World\n&quot;;

I get an error when I run this from my shell (which happens to be
bash). That may look like perl forgot it has a C&lt;print()&gt; function,
but my shebang line is not the path to perl, so the shell runs the
script, and I get the error.

    $ ./test
    ./test: line 3: print: command not found

A quick and dirty fix involves a little bit of code, but this may be all
you need to figure out the problem.

    #!/usr/bin/perl -w

    BEGIN {
        $SIG{__WARN__} = sub{ print STDERR &quot;Perl: &quot;, @_; };
        $SIG{__DIE__}  = sub{ print STDERR &quot;Perl: &quot;, @_; exit 1};
    }

    $a = 1 + undef;
    $x / 0;
    __END__

The perl message comes out with &quot;Perl&quot; in front. The C&lt;BEGIN&gt; block
works at compile time so all of the compilation errors and warnings
get the &quot;Perl:&quot; prefix too.

    Perl: Useless use of division (/) in void context at ./test line 9.
    Perl: Name &quot;main::a&quot; used only once: possible typo at ./test line 8.
    Perl: Name &quot;main::x&quot; used only once: possible typo at ./test line 9.
    Perl: Use of uninitialized value in addition (+) at ./test line 8.
    Perl: Use of uninitialized value in division (/) at ./test line 9.
    Perl: Illegal division by zero at ./test line 9.
    Perl: Illegal division by zero at -e line 3.

If I don't see that &quot;Perl:&quot;, it's not from perl.

You could also just know all the perl errors, and although there are
some people who may know all of them, you probably don't. However, they
all should be in the L&lt;perldiag&gt; manpage. If you don't find the error in
there, it probably isn't a perl error.

Looking up every message is not the easiest way, so let perl to do it
for you. Use the diagnostics pragma with turns perl's normal messages
into longer discussions on the topic.

    use diagnostics;

If you don't get a paragraph or two of expanded discussion, it
might not be perl's message.

=head2 How do I install a module from CPAN?

(contributed by brian d foy)

The easiest way is to have a module also named CPAN do it for you by using
the C&lt;cpan&gt; command that comes with Perl. You can give it a list of modules
to install:

    $ cpan IO::Interactive Getopt::Whatever

If you prefer C&lt;CPANPLUS&gt;, it's just as easy:

    $ cpanp i IO::Interactive Getopt::Whatever

If you want to install a distribution from the current directory, you can
tell C&lt;CPAN.pm&gt; to install C&lt;.&gt; (the full stop):

    $ cpan .

See the documentation for either of those commands to see what else
you can do.

If you want to try to install a distribution by yourself, resolving
all dependencies on your own, you follow one of two possible build
paths.

For distributions that use I&lt;Makefile.PL&gt;:

    $ perl Makefile.PL
    $ make test install

For distributions that use I&lt;Build.PL&gt;:

    $ perl Build.PL
    $ ./Build test
    $ ./Build install

Some distributions may need to link to libraries or other third-party
code and their build and installation sequences may be more complicated.
Check any I&lt;README&gt; or I&lt;INSTALL&gt; files that you may find.

=head2 What's the difference between require and use?

(contributed by brian d foy)

Perl runs C&lt;require&gt; statement at run-time. Once Perl loads, compiles,
and runs the file, it doesn't do anything else. The C&lt;use&gt; statement
is the same as a C&lt;require&gt; run at compile-time, but Perl also calls the
C&lt;import&gt; method for the loaded package. These two are the same:

    use MODULE qw(import list);

    BEGIN {
        require MODULE;
        MODULE-&gt;import(import list);
    }

However, you can suppress the C&lt;import&gt; by using an explicit, empty
import list. Both of these still happen at compile-time:

    use MODULE ();

    BEGIN {
        require MODULE;
    }

Since C&lt;use&gt; will also call the C&lt;import&gt; method, the actual value
for C&lt;MODULE&gt; must be a bareword. That is, C&lt;use&gt; cannot load files
by name, although C&lt;require&gt; can:

    require &quot;$ENV{HOME}/lib/Foo.pm&quot;; # no @INC searching!

See the entry for C&lt;use&gt; in L&lt;perlfunc&gt; for more details.

=head2 How do I keep my own module/library directory?

When you build modules, tell Perl where to install the modules.

If you want to install modules for your own use, the easiest way might
be L&lt;local::lib&gt;, which you can download from CPAN. It sets various
installation settings for you, and uses those same settings within
your programs.

If you want more flexibility, you need to configure your CPAN client
for your particular situation.

For C&lt;Makefile.PL&gt;-based distributions, use the INSTALL_BASE option
when generating Makefiles:

    perl Makefile.PL INSTALL_BASE=/mydir/perl

You can set this in your C&lt;CPAN.pm&gt; configuration so modules
automatically install in your private library directory when you use
the CPAN.pm shell:

    % cpan
    cpan&gt; o conf makepl_arg INSTALL_BASE=/mydir/perl
    cpan&gt; o conf commit

For C&lt;Build.PL&gt;-based distributions, use the --install_base option:

    perl Build.PL --install_base /mydir/perl

You can configure C&lt;CPAN.pm&gt; to automatically use this option too:

    % cpan
    cpan&gt; o conf mbuild_arg &quot;--install_base /mydir/perl&quot;
    cpan&gt; o conf commit

INSTALL_BASE tells these tools to put your modules into
F&lt;/mydir/perl/lib/perl5&gt;. See L&lt;How do I add a directory to my
include path (@INC) at runtime?&gt; for details on how to run your newly
installed modules.

There is one caveat with INSTALL_BASE, though, since it acts
differently from the PREFIX and LIB settings that older versions of
L&lt;ExtUtils::MakeMaker&gt; advocated. INSTALL_BASE does not support
installing modules for multiple versions of Perl or different
architectures under the same directory. You should consider whether you
really want that and, if you do, use the older PREFIX and LIB
settings. See the L&lt;ExtUtils::Makemaker&gt; documentation for more details.

=head2 How do I add the directory my program lives in to the module/library search path?

(contributed by brian d foy)

If you know the directory already, you can add it to C&lt;@INC&gt; as you would
for any other directory. You might &lt;use lib&gt; if you know the directory
at compile time:

    use lib $directory;

The trick in this task is to find the directory. Before your script does
anything else (such as a C&lt;chdir&gt;), you can get the current working
directory with the C&lt;Cwd&gt; module, which comes with Perl:

    BEGIN {
        use Cwd;
        our $directory = cwd;
    }

    use lib $directory;

You can do a similar thing with the value of C&lt;$0&gt;, which holds the
script name. That might hold a relative path, but C&lt;rel2abs&gt; can turn
it into an absolute path. Once you have the

    BEGIN {
        use File::Spec::Functions qw(rel2abs);
        use File::Basename qw(dirname);

        my $path   = rel2abs( $0 );
        our $directory = dirname( $path );
    }

    use lib $directory;

The L&lt;FindBin&gt; module, which comes with Perl, might work. It finds the
directory of the currently running script and puts it in C&lt;$Bin&gt;, which
you can then use to construct the right library path:

    use FindBin qw($Bin);

You can also use L&lt;local::lib&gt; to do much of the same thing. Install
modules using L&lt;local::lib&gt;'s settings then use the module in your
program:

     use local::lib; # sets up a local lib at ~/perl5

See the L&lt;local::lib&gt; documentation for more details.

=head2 How do I add a directory to my include path (@INC) at runtime?

Here are the suggested ways of modifying your include path, including
environment variables, run-time switches, and in-code statements:

=over 4

=item the C&lt;PERLLIB&gt; environment variable

    $ export PERLLIB=/path/to/my/dir
    $ perl program.pl

=item the C&lt;PERL5LIB&gt; environment variable

    $ export PERL5LIB=/path/to/my/dir
    $ perl program.pl

=item the C&lt;perl -Idir&gt; command line flag

    $ perl -I/path/to/my/dir program.pl

=item the C&lt;lib&gt; pragma:

    use lib &quot;$ENV{HOME}/myown_perllib&quot;;

=item the L&lt;local::lib&gt; module:

    use local::lib;

    use local::lib &quot;~/myown_perllib&quot;;

=back

The last is particularly useful because it knows about machine-dependent
architectures. The C&lt;lib.pm&gt; pragmatic module was first
included with the 5.002 release of Perl.

=head2 Where are modules installed?

Modules are installed on a case-by-case basis (as provided by the methods
described in the previous section), and in the operating system. All of these
paths are stored in @INC, which you can display with the one-liner

    perl -e 'print join(&quot;\n&quot;,@INC,&quot;&quot;)'

The same information is displayed at the end of the output from the command

    perl -V

To find out where a module's source code is located, use

    perldoc -l Encode

to display the path to the module. In some cases (for example, the C&lt;AutoLoader&gt;
module), this command will show the path to a separate C&lt;pod&gt; file; the module
itself should be in the same directory, with a 'pm' file extension.

=head2 What is socket.ph and where do I get it?

It's a Perl 4 style file defining values for system networking
constants. Sometimes it is built using L&lt;h2ph&gt; when Perl is installed,
but other times it is not. Modern programs should use C&lt;use Socket;&gt;
instead.

=head1 AUTHOR AND COPYRIGHT

Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and
other authors as noted. All rights reserved.

This documentation is free; you can redistribute it and/or modify it
under the same terms as Perl itself.

Irrespective of its distribution, all code examples in this file
are hereby placed into the public domain. You are permitted and
encouraged to use this code in your own programs for fun
or for profit as you see fit. A simple comment in the code giving
credit would be courteous but is not required.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl'>Back to Directory</a>