<h2>Editing File: /usr/share/perl5/vendor_perl/bigrat.pm</h2><form method='post'><textarea name='content' class='file-edit'>package bigrat;

use 5.010;
use strict;
use warnings;

our $VERSION = '0.49';

use Exporter;
our @ISA            = qw( bigint );
our @EXPORT_OK      = qw( PI e bpi bexp hex oct );
our @EXPORT         = qw( inf NaN );

use overload;
use bigint ();

##############################################################################

BEGIN {
    *inf = \&amp;bigint::inf;
    *NaN = \&amp;bigint::NaN;
    *hex = \&amp;bigint::hex;
    *oct = \&amp;bigint::oct;
}

# These are all alike, and thus faked by AUTOLOAD

my @faked = qw/round_mode accuracy precision div_scale/;
our ($AUTOLOAD, $_lite);        # _lite for testsuite

sub AUTOLOAD {
    my $name = $AUTOLOAD;

    $name =~ s/.*:://;          # split package
    no strict 'refs';
    foreach my $n (@faked) {
        if ($n eq $name) {
            *{&quot;bigrat::$name&quot;} =
              sub {
                  my $self = shift;
                  no strict 'refs';
                  if (defined $_[0]) {
                      Math::BigInt-&gt;$name($_[0]);
                      Math::BigFloat-&gt;$name($_[0]);
                      return Math::BigRat-&gt;$name($_[0]);
                  }
                  return Math::BigInt-&gt;$name();
              };
            return &amp;$name;
        }
    }

    # delayed load of Carp and avoid recursion
    require Carp;
    Carp::croak (&quot;Can't call bigrat\-\&gt;$name, not a valid method&quot;);
}

sub unimport {
    $^H{bigrat} = undef;        # no longer in effect
    overload::remove_constant('binary', '', 'float', '', 'integer');
}

sub in_effect {
    my $level = shift || 0;
    my $hinthash = (caller($level))[10];
    $hinthash-&gt;{bigrat};
}

#############################################################################

sub import {
    my $self = shift;

    # see also bignum-&gt;import() for additional comments

    $^H{bigrat} = 1;                            # we are in effect

    # for newer Perls always override hex() and oct() with a lexical version:
    if ($] &gt; 5.009004) {
        bigint::_override();
    }
    # some defaults
    my $lib      = '';
    my $lib_kind = 'try';
    my $upgrade  = 'Math::BigFloat';

    my @import = (':constant');                 # drive it w/ constant
    my @a = @_;
    my $l = scalar @_;
    my $j = 0;
    my ($a, $p);
    my ($ver, $trace);                          # version? trace?
    for (my $i = 0; $i &lt; $l ; $i++, $j++) {
        if ($_[$i] eq 'upgrade') {
            # this causes upgrading
            $upgrade = $_[$i + 1];              # or undef to disable
            my $s = 2;
            $s = 1 if @a - $j &lt; 2;  # avoid &quot;can not modify non-existent...&quot;
            splice @a, $j, $s;
            $j -= $s;
        }
        elsif ($_[$i] =~ /^(l|lib|try|only)$/) {
            # this causes a different low lib to take care...
            $lib_kind = $1;
            $lib_kind = 'lib' if $lib_kind eq 'l';
            $lib = $_[$i + 1] || '';
            my $s = 2;
            $s = 1 if @a - $j &lt; 2;  # avoid &quot;can not modify non-existent...&quot;
            splice @a, $j, $s;
            $j -= $s;
            $i++;
        }
        elsif ($_[$i] =~ /^(a|accuracy)$/) {
            $a = $_[$i + 1];
            my $s = 2;
            $s = 1 if @a - $j &lt; 2;  # avoid &quot;can not modify non-existent...&quot;
            splice @a, $j, $s;
            $j -= $s;
            $i++;
        }
        elsif ($_[$i] =~ /^(p|precision)$/) {
            $p = $_[$i + 1];
            my $s = 2;
            $s = 1 if @a - $j &lt; 2;  # avoid &quot;can not modify non-existent...&quot;
            splice @a, $j, $s;
            $j -= $s;
            $i++;
        }
        elsif ($_[$i] =~ /^(v|version)$/) {
            $ver = 1;
            splice @a, $j, 1;
            $j--;
        }
        elsif ($_[$i] =~ /^(t|trace)$/) {
            $trace = 1;
            splice @a, $j, 1;
            $j--;
        }
        elsif ($_[$i] !~ /^(PI|e|bpi|bexp|hex|oct)\z/) {
            die (&quot;unknown option $_[$i]&quot;);
        }
    }
    my $class;
    $_lite = 0;                                 # using M::BI::L ?
    if ($trace) {
        require Math::BigInt::Trace;
        $class   = 'Math::BigInt::Trace';
        $upgrade = 'Math::BigFloat::Trace';
    }
    else {
        # see if we can find Math::BigInt::Lite
        if (!defined $a &amp;&amp; !defined $p) {       # rounding won't work to well
            local @INC = @INC;
            pop @INC if $INC[-1] eq '.';
            if (eval { require Math::BigInt::Lite; 1 }) {
                @import = ();                   # :constant in Lite, not MBI
                Math::BigInt::Lite-&gt;import(':constant');
                $_lite = 1;                     # signal okay
            }
        }
        require Math::BigInt if $_lite == 0;    # not already loaded?
        $class = 'Math::BigInt';                # regardless of MBIL or not
    }
    push @import, $lib_kind =&gt; $lib if $lib ne '';
    # Math::BigInt::Trace or plain Math::BigInt
    $class-&gt;import(@import, upgrade =&gt; $upgrade);

    require Math::BigFloat;
    Math::BigFloat-&gt;import(upgrade =&gt; 'Math::BigRat', ':constant');
    require Math::BigRat;
    Math::BigRat-&gt;import(@import);

    bigrat-&gt;accuracy($a)  if defined $a;
    bigrat-&gt;precision($p) if defined $p;
    if ($ver) {
        print &quot;bigrat\t\t\t v$VERSION\n&quot;;
        print &quot;Math::BigInt::Lite\t v$Math::BigInt::Lite::VERSION\n&quot; if $_lite;
        print &quot;Math::BigInt\t\t v$Math::BigInt::VERSION&quot;;
        my $config = Math::BigInt-&gt;config();
        print &quot; lib =&gt; $config-&gt;{lib} v$config-&gt;{lib_version}\n&quot;;
        print &quot;Math::BigFloat\t\t v$Math::BigFloat::VERSION\n&quot;;
        print &quot;Math::BigRat\t\t v$Math::BigRat::VERSION\n&quot;;
        exit;
    }

    # Take care of octal/hexadecimal constants
    overload::constant binary =&gt;
        sub {
            bigint::_binary_constant(shift);
          };

    # if another big* was already loaded:
    my ($package) = caller();

    no strict 'refs';
    if (!defined *{&quot;${package}::inf&quot;}) {
        $self-&gt;export_to_level(1, $self, @a);   # export inf and NaN
    }
}

sub PI () { Math::BigFloat-&gt;new('3.141592653589793238462643383279502884197'); }
sub e  () { Math::BigFloat-&gt;new('2.718281828459045235360287471352662497757'); }

sub bpi ($) {
    local $Math::BigFloat::upgrade;
    Math::BigFloat-&gt;bpi(@_);
}

sub bexp ($$) {
    local $Math::BigFloat::upgrade;
    my $x = Math::BigFloat-&gt;new($_[0]);
    $x-&gt;bexp($_[1]);
}

1;

__END__

=pod

=head1 NAME

bigrat - Transparent BigNumber/BigRational support for Perl

=head1 SYNOPSIS

  use bigrat;

  print 2 + 4.5,&quot;\n&quot;;                   # BigFloat 6.5
  print 1/3 + 1/4,&quot;\n&quot;;                 # produces 7/12

  {
    no bigrat;
    print 1/3,&quot;\n&quot;;                     # 0.33333...
  }

  # Import into current package:
  use bigrat qw/hex oct/;
  print hex(&quot;0x1234567890123490&quot;),&quot;\n&quot;;
  print oct(&quot;01234567890123490&quot;),&quot;\n&quot;;

=head1 DESCRIPTION

All operators (including basic math operations) are overloaded. Integer and
floating-point constants are created as proper BigInts or BigFloats,
respectively.

Other than L&lt;bignum&gt;, this module upgrades to Math::BigRat, meaning that
instead of 2.5 you will get 2+1/2 as output.

=head2 Modules Used

C&lt;bigrat&gt; is just a thin wrapper around various modules of the Math::BigInt
family. Think of it as the head of the family, who runs the shop, and orders
the others to do the work.

The following modules are currently used by bignum:

        Math::BigInt::Lite      (for speed, and only if it is loadable)
        Math::BigInt
        Math::BigFloat
        Math::BigRat

=head2 Math Library

Math with the numbers is done (by default) by a module called
Math::BigInt::Calc. This is equivalent to saying:

        use bigrat lib =&gt; 'Calc';

You can change this by using:

        use bignum lib =&gt; 'GMP';

The following would first try to find Math::BigInt::Foo, then
Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:

        use bigrat lib =&gt; 'Foo,Math::BigInt::Bar';

Using C&lt;lib&gt; warns if none of the specified libraries can be found and
L&lt;Math::BigInt&gt; did fall back to one of the default libraries.
To suppress this warning, use C&lt;try&gt; instead:

        use bignum try =&gt; 'GMP';

If you want the code to die instead of falling back, use C&lt;only&gt; instead:

        use bignum only =&gt; 'GMP';

Please see respective module documentation for further details.

=head2 Sign

The sign is either '+', '-', 'NaN', '+inf' or '-inf'.

A sign of 'NaN' is used to represent the result when input arguments are not
numbers or as a result of 0/0. '+inf' and '-inf' represent plus respectively
minus infinity. You will get '+inf' when dividing a positive number by 0, and
'-inf' when dividing any negative number by 0.

=head2 Methods

Since all numbers are not objects, you can use all functions that are part of
the BigInt or BigFloat API. It is wise to use only the bxxx() notation, and not
the fxxx() notation, though. This makes you independent on the fact that the
underlying object might morph into a different class than BigFloat.

=over 2

=item inf()

A shortcut to return Math::BigInt-&gt;binf(). Useful because Perl does not always
handle bareword C&lt;inf&gt; properly.

=item NaN()

A shortcut to return Math::BigInt-&gt;bnan(). Useful because Perl does not always
handle bareword C&lt;NaN&gt; properly.

=item e

        # perl -Mbigrat=e -wle 'print e'

Returns Euler's number C&lt;e&gt;, aka exp(1).

=item PI

        # perl -Mbigrat=PI -wle 'print PI'

Returns PI.

=item bexp()

        bexp($power,$accuracy);

Returns Euler's number C&lt;e&gt; raised to the appropriate power, to
the wanted accuracy.

Example:

        # perl -Mbigrat=bexp -wle 'print bexp(1,80)'

=item bpi()

        bpi($accuracy);

Returns PI to the wanted accuracy.

Example:

        # perl -Mbigrat=bpi -wle 'print bpi(80)'

=item upgrade()

Return the class that numbers are upgraded to, is in fact returning
C&lt;$Math::BigInt::upgrade&gt;.

=item in_effect()

        use bigrat;

        print &quot;in effect\n&quot; if bigrat::in_effect;       # true
        {
          no bigrat;
          print &quot;in effect\n&quot; if bigrat::in_effect;     # false
        }

Returns true or false if C&lt;bigrat&gt; is in effect in the current scope.

This method only works on Perl v5.9.4 or later.

=back

=head2 MATH LIBRARY

Math with the numbers is done (by default) by a module called

=head2 Caveat

But a warning is in order. When using the following to make a copy of a number,
only a shallow copy will be made.

        $x = 9; $y = $x;
        $x = $y = 7;

If you want to make a real copy, use the following:

        $y = $x-&gt;copy();

Using the copy or the original with overloaded math is okay, e.g. the
following work:

        $x = 9; $y = $x;
        print $x + 1, &quot; &quot;, $y,&quot;\n&quot;;     # prints 10 9

but calling any method that modifies the number directly will result in
B&lt;both&gt; the original and the copy being destroyed:

        $x = 9; $y = $x;
        print $x-&gt;badd(1), &quot; &quot;, $y,&quot;\n&quot;;        # prints 10 10

        $x = 9; $y = $x;
        print $x-&gt;binc(1), &quot; &quot;, $y,&quot;\n&quot;;        # prints 10 10

        $x = 9; $y = $x;
        print $x-&gt;bmul(2), &quot; &quot;, $y,&quot;\n&quot;;        # prints 18 18

Using methods that do not modify, but testthe contents works:

        $x = 9; $y = $x;
        $z = 9 if $x-&gt;is_zero();                # works fine

See the documentation about the copy constructor and C&lt;=&gt; in overload, as
well as the documentation in BigInt for further details.

=head2 Options

bignum recognizes some options that can be passed while loading it via use.
The options can (currently) be either a single letter form, or the long form.
The following options exist:

=over 2

=item a or accuracy

This sets the accuracy for all math operations. The argument must be greater
than or equal to zero. See Math::BigInt's bround() function for details.

        perl -Mbigrat=a,50 -le 'print sqrt(20)'

Note that setting precision and accuracy at the same time is not possible.

=item p or precision

This sets the precision for all math operations. The argument can be any
integer. Negative values mean a fixed number of digits after the dot, while
a positive value rounds to this digit left from the dot. 0 or 1 mean round to
integer. See Math::BigInt's bfround() function for details.

        perl -Mbigrat=p,-50 -le 'print sqrt(20)'

Note that setting precision and accuracy at the same time is not possible.

=item t or trace

This enables a trace mode and is primarily for debugging bignum or
Math::BigInt/Math::BigFloat.

=item l or lib

Load a different math lib, see L&lt;MATH LIBRARY&gt;.

        perl -Mbigrat=l,GMP -e 'print 2 ** 512'

Currently there is no way to specify more than one library on the command
line. This means the following does not work:

        perl -Mbignum=l,GMP,Pari -e 'print 2 ** 512'

This will be hopefully fixed soon ;)

=item hex

Override the built-in hex() method with a version that can handle big
numbers. This overrides it by exporting it to the current package. Under
Perl v5.10.0 and higher, this is not so necessary, as hex() is lexically
overridden in the current scope whenever the bigrat pragma is active.

=item oct

Override the built-in oct() method with a version that can handle big
numbers. This overrides it by exporting it to the current package. Under
Perl v5.10.0 and higher, this is not so necessary, as oct() is lexically
overridden in the current scope whenever the bigrat pragma is active.

=item v or version

This prints out the name and version of all modules used and then exits.

        perl -Mbigrat=v

=back

=head1 CAVEATS

=over 2

=item Operator vs literal overloading

C&lt;bigrat&gt; works by overloading handling of integer and floating point
literals, converting them to L&lt;Math::BigInt&gt; or L&lt;Math::BigRat&gt;
objects.

This means that arithmetic involving only string values or string
literals will be performed using Perl's built-in operators.

For example:

    use bigrat;
    my $x = &quot;900000000000000009&quot;;
    my $y = &quot;900000000000000007&quot;;
    print $x - $y;

will output C&lt;0&gt; on default 32-bit builds, since C&lt;bigrat&gt; never sees
the string literals.  To ensure the expression is all treated as
C&lt;Math::BigInt&gt; or C&lt;Math::BigRat&gt; objects, use a literal number in
the expression:

    print +(0+$x) - $y;

=item in_effect()

This method only works on Perl v5.9.4 or later.

=item hex()/oct()

C&lt;bigint&gt; overrides these routines with versions that can also handle
big integer values. Under Perl prior to version v5.9.4, however, this
will not happen unless you specifically ask for it with the two
import tags &quot;hex&quot; and &quot;oct&quot; - and then it will be global and cannot be
disabled inside a scope with &quot;no bigint&quot;:

        use bigint qw/hex oct/;

        print hex(&quot;0x1234567890123456&quot;);
        {
                no bigint;
                print hex(&quot;0x1234567890123456&quot;);
        }

The second call to hex() will warn about a non-portable constant.

Compare this to:

        use bigint;

        # will warn only under Perl older than v5.9.4
        print hex(&quot;0x1234567890123456&quot;);

=back

=head1 EXAMPLES

        perl -Mbigrat -le 'print sqrt(33)'
        perl -Mbigrat -le 'print 2*255'
        perl -Mbigrat -le 'print 4.5+2*255'
        perl -Mbigrat -le 'print 3/7 + 5/7 + 8/3'
        perl -Mbigrat -le 'print 12-&gt;is_odd()';
        perl -Mbignum=l,GMP -le 'print 7 ** 7777'

=head1 BUGS

For information about bugs and how to report them, see the BUGS section in the
documentation available with the perldoc command.

    perldoc bignum

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc bigrat

For more information, see the SUPPORT section in the documentation available
with the perldoc command.

    perldoc bignum

=head1 LICENSE

This program is free software; you may redistribute it and/or modify it under
the same terms as Perl itself.

=head1 SEE ALSO

L&lt;bignum&gt; and L&lt;bigint&gt;.

L&lt;Math::BigInt&gt;, L&lt;Math::BigFloat&gt;, L&lt;Math::BigRat&gt; and L&lt;Math::Big&gt; as well as
L&lt;Math::BigInt::FastCalc&gt;, L&lt;Math::BigInt::Pari&gt; and L&lt;Math::BigInt::GMP&gt;.

=head1 AUTHORS

=over 4

=item *

(C) by Tels L&lt;http://bloodgate.com/&gt; in early 2002 - 2007.

=item *

Peter John Acklam E&lt;lt&gt;pjacklam@gmail.com&lt;gt&gt;, 2014-.

=back

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl'>Back to Directory</a>