<h2>Editing File: /usr/share/perl5/vendor_perl/TAP/Parser/Result.pm</h2><form method='post'><textarea name='content' class='file-edit'>package TAP::Parser::Result;

use strict;
use warnings;

use base 'TAP::Object';

BEGIN {

    # make is_* methods
    my @attrs = qw( plan pragma test comment bailout version unknown yaml );
    no strict 'refs';
    for my $token (@attrs) {
        my $method = &quot;is_$token&quot;;
        *$method = sub { return $token eq shift-&gt;type };
    }
}

##############################################################################

=head1 NAME

TAP::Parser::Result - Base class for TAP::Parser output objects

=head1 VERSION

Version 3.42

=cut

our $VERSION = '3.42';

=head1 SYNOPSIS

  # abstract class - not meant to be used directly
  # see TAP::Parser::ResultFactory for preferred usage

  # directly:
  use TAP::Parser::Result;
  my $token  = {...};
  my $result = TAP::Parser::Result-&gt;new( $token );

=head2 DESCRIPTION

This is a simple base class used by L&lt;TAP::Parser&gt; to store objects that
represent the current bit of test output data from TAP (usually a single
line).  Unless you're subclassing, you probably won't need to use this module
directly.

=head2 METHODS

=head3 C&lt;new&gt;

  # see TAP::Parser::ResultFactory for preferred usage

  # to use directly:
  my $result = TAP::Parser::Result-&gt;new($token);

Returns an instance the appropriate class for the test token passed in.

=cut

# new() implementation provided by TAP::Object

sub _initialize {
    my ( $self, $token ) = @_;
    if ($token) {

       # assign to a hash slice to make a shallow copy of the token.
       # I guess we could assign to the hash as (by default) there are not
       # contents, but that seems less helpful if someone wants to subclass us
        @{$self}{ keys %$token } = values %$token;
    }
    return $self;
}

##############################################################################

=head2 Boolean methods

The following methods all return a boolean value and are to be overridden in
the appropriate subclass.

=over 4

=item * C&lt;is_plan&gt;

Indicates whether or not this is the test plan line.

 1..3

=item * C&lt;is_pragma&gt;

Indicates whether or not this is a pragma line.

 pragma +strict

=item * C&lt;is_test&gt;

Indicates whether or not this is a test line.

 ok 1 Is OK!

=item * C&lt;is_comment&gt;

Indicates whether or not this is a comment.

 # this is a comment

=item * C&lt;is_bailout&gt;

Indicates whether or not this is bailout line.

 Bail out! We're out of dilithium crystals.

=item * C&lt;is_version&gt;

Indicates whether or not this is a TAP version line.

 TAP version 4

=item * C&lt;is_unknown&gt;

Indicates whether or not the current line could be parsed.

 ... this line is junk ...

=item * C&lt;is_yaml&gt;

Indicates whether or not this is a YAML chunk.

=back

=cut

##############################################################################

=head3 C&lt;raw&gt;

  print $result-&gt;raw;

Returns the original line of text which was parsed.

=cut

sub raw { shift-&gt;{raw} }

##############################################################################

=head3 C&lt;type&gt;

  my $type = $result-&gt;type;

Returns the &quot;type&quot; of a token, such as C&lt;comment&gt; or C&lt;test&gt;.

=cut

sub type { shift-&gt;{type} }

##############################################################################

=head3 C&lt;as_string&gt;

  print $result-&gt;as_string;

Prints a string representation of the token.  This might not be the exact
output, however.  Tests will have test numbers added if not present, TODO and
SKIP directives will be capitalized and, in general, things will be cleaned
up.  If you need the original text for the token, see the C&lt;raw&gt; method.

=cut

sub as_string { shift-&gt;{raw} }

##############################################################################

=head3 C&lt;is_ok&gt;

  if ( $result-&gt;is_ok ) { ... }

Reports whether or not a given result has passed.  Anything which is B&lt;not&gt; a
test result returns true.  This is merely provided as a convenient shortcut.

=cut

sub is_ok {1}

##############################################################################

=head3 C&lt;passed&gt;

Deprecated.  Please use C&lt;is_ok&gt; instead.

=cut

sub passed {
    warn 'passed() is deprecated.  Please use &quot;is_ok()&quot;';
    shift-&gt;is_ok;
}

##############################################################################

=head3 C&lt;has_directive&gt;

  if ( $result-&gt;has_directive ) {
     ...
  }

Indicates whether or not the given result has a TODO or SKIP directive.

=cut

sub has_directive {
    my $self = shift;
    return ( $self-&gt;has_todo || $self-&gt;has_skip );
}

##############################################################################

=head3 C&lt;has_todo&gt;

 if ( $result-&gt;has_todo ) {
     ...
 }

Indicates whether or not the given result has a TODO directive.

=cut

sub has_todo { 'TODO' eq ( shift-&gt;{directive} || '' ) }

##############################################################################

=head3 C&lt;has_skip&gt;

 if ( $result-&gt;has_skip ) {
     ...
 }

Indicates whether or not the given result has a SKIP directive.

=cut

sub has_skip { 'SKIP' eq ( shift-&gt;{directive} || '' ) }

=head3 C&lt;set_directive&gt;

Set the directive associated with this token. Used internally to fake
TODO tests.

=cut

sub set_directive {
    my ( $self, $dir ) = @_;
    $self-&gt;{directive} = $dir;
}

1;

=head1 SUBCLASSING

Please see L&lt;TAP::Parser/SUBCLASSING&gt; for a subclassing overview.

Remember: if you want your subclass to be automatically used by the parser,
you'll have to register it with L&lt;TAP::Parser::ResultFactory/register_type&gt;.

If you're creating a completely new result I&lt;type&gt;, you'll probably need to
subclass L&lt;TAP::Parser::Grammar&gt; too, or else it'll never get used.

=head2 Example

  package MyResult;

  use strict;

  use base 'TAP::Parser::Result';

  # register with the factory:
  TAP::Parser::ResultFactory-&gt;register_type( 'my_type' =&gt; __PACKAGE__ );

  sub as_string { 'My results all look the same' }

=head1 SEE ALSO

L&lt;TAP::Object&gt;,
L&lt;TAP::Parser&gt;,
L&lt;TAP::Parser::ResultFactory&gt;,
L&lt;TAP::Parser::Result::Bailout&gt;,
L&lt;TAP::Parser::Result::Comment&gt;,
L&lt;TAP::Parser::Result::Plan&gt;,
L&lt;TAP::Parser::Result::Pragma&gt;,
L&lt;TAP::Parser::Result::Test&gt;,
L&lt;TAP::Parser::Result::Unknown&gt;,
L&lt;TAP::Parser::Result::Version&gt;,
L&lt;TAP::Parser::Result::YAML&gt;,

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FTAP%2FParser'>Back to Directory</a>