<h2>Editing File: /usr/share/perl5/vendor_perl/TAP/Parser/Multiplexer.pm</h2><form method='post'><textarea name='content' class='file-edit'>package TAP::Parser::Multiplexer;

use strict;
use warnings;

use IO::Select;

use base 'TAP::Object';

use constant IS_WIN32 =&gt; $^O =~ /^(MS)?Win32$/;
use constant IS_VMS =&gt; $^O eq 'VMS';
use constant SELECT_OK =&gt; !( IS_VMS || IS_WIN32 );

=head1 NAME

TAP::Parser::Multiplexer - Multiplex multiple TAP::Parsers

=head1 VERSION

Version 3.42

=cut

our $VERSION = '3.42';

=head1 SYNOPSIS

    use TAP::Parser::Multiplexer;

    my $mux = TAP::Parser::Multiplexer-&gt;new;
    $mux-&gt;add( $parser1, $stash1 );
    $mux-&gt;add( $parser2, $stash2 );
    while ( my ( $parser, $stash, $result ) = $mux-&gt;next ) {
        # do stuff
    }

=head1 DESCRIPTION

C&lt;TAP::Parser::Multiplexer&gt; gathers input from multiple TAP::Parsers.
Internally it calls select on the input file handles for those parsers
to wait for one or more of them to have input available.

See L&lt;TAP::Harness&gt; for an example of its use.

=head1 METHODS

=head2 Class Methods

=head3 C&lt;new&gt;

    my $mux = TAP::Parser::Multiplexer-&gt;new;

Returns a new C&lt;TAP::Parser::Multiplexer&gt; object.

=cut

# new() implementation supplied by TAP::Object

sub _initialize {
    my $self = shift;
    $self-&gt;{select} = IO::Select-&gt;new;
    $self-&gt;{avid}   = [];                # Parsers that can't select
    $self-&gt;{count}  = 0;
    return $self;
}

##############################################################################

=head2 Instance Methods

=head3 C&lt;add&gt;

  $mux-&gt;add( $parser, $stash );

Add a TAP::Parser to the multiplexer. C&lt;$stash&gt; is an optional opaque
reference that will be returned from C&lt;next&gt; along with the parser and
the next result.

=cut

sub add {
    my ( $self, $parser, $stash ) = @_;

    if ( SELECT_OK &amp;&amp; ( my @handles = $parser-&gt;get_select_handles ) ) {
        my $sel = $self-&gt;{select};

        # We have to turn handles into file numbers here because by
        # the time we want to remove them from our IO::Select they
        # will already have been closed by the iterator.
        my @filenos = map { fileno $_ } @handles;
        for my $h (@handles) {
            $sel-&gt;add( [ $h, $parser, $stash, @filenos ] );
        }

        $self-&gt;{count}++;
    }
    else {
        push @{ $self-&gt;{avid} }, [ $parser, $stash ];
    }
}

=head3 C&lt;parsers&gt;

  my $count   = $mux-&gt;parsers;

Returns the number of parsers. Parsers are removed from the multiplexer
when their input is exhausted.

=cut

sub parsers {
    my $self = shift;
    return $self-&gt;{count} + scalar @{ $self-&gt;{avid} };
}

sub _iter {
    my $self = shift;

    my $sel   = $self-&gt;{select};
    my $avid  = $self-&gt;{avid};
    my @ready = ();

    return sub {

        # Drain all the non-selectable parsers first
        if (@$avid) {
            my ( $parser, $stash ) = @{ $avid-&gt;[0] };
            my $result = $parser-&gt;next;
            shift @$avid unless defined $result;
            return ( $parser, $stash, $result );
        }

        unless (@ready) {
            return unless $sel-&gt;count;
            @ready = $sel-&gt;can_read;
        }

        my ( $h, $parser, $stash, @handles ) = @{ shift @ready };
        my $result = $parser-&gt;next;

        unless ( defined $result ) {
            $sel-&gt;remove(@handles);
            $self-&gt;{count}--;

            # Force another can_read - we may now have removed a handle
            # thought to have been ready.
            @ready = ();
        }

        return ( $parser, $stash, $result );
    };
}

=head3 C&lt;next&gt;

Return a result from the next available parser. Returns a list
containing the parser from which the result came, the stash that
corresponds with that parser and the result.

    my ( $parser, $stash, $result ) = $mux-&gt;next;

If C&lt;$result&gt; is undefined the corresponding parser has reached the end
of its input (and will automatically be removed from the multiplexer).

When all parsers are exhausted an empty list will be returned.

    if ( my ( $parser, $stash, $result ) = $mux-&gt;next ) {
        if ( ! defined $result ) {
            # End of this parser
        }
        else {
            # Process result
        }
    }
    else {
        # All parsers finished
    }

=cut

sub next {
    my $self = shift;
    return ( $self-&gt;{_iter} ||= $self-&gt;_iter )-&gt;();
}

=head1 See Also

L&lt;TAP::Parser&gt;

L&lt;TAP::Harness&gt;

=cut

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FTAP%2FParser'>Back to Directory</a>