<h2>Editing File: /usr/share/perl5/vendor_perl/TAP/Formatter/Color.pm</h2><form method='post'><textarea name='content' class='file-edit'>package TAP::Formatter::Color;

use strict;
use warnings;

use constant IS_WIN32 =&gt; ( $^O =~ /^(MS)?Win32$/ );

use base 'TAP::Object';

my $NO_COLOR;

BEGIN {
    $NO_COLOR = 0;

    eval 'require Term::ANSIColor';
    if ($@) {
        $NO_COLOR = $@;
    };
    if (IS_WIN32) {
        eval 'use Win32::Console::ANSI';
        if ($@) {
            $NO_COLOR = $@;
        }
    };

    if ($NO_COLOR) {
        *set_color = sub { };
    } else {
        *set_color = sub {
            my ( $self, $output, $color ) = @_;
            $output-&gt;( Term::ANSIColor::color($color) );
        };
    }
}

=head1 NAME

TAP::Formatter::Color - Run Perl test scripts with color

=head1 VERSION

Version 3.42

=cut

our $VERSION = '3.42';

=head1 DESCRIPTION

Note that this harness is I&lt;experimental&gt;.  You may not like the colors I've
chosen and I haven't yet provided an easy way to override them.

This test harness is the same as L&lt;TAP::Harness&gt;, but test results are output
in color.  Passing tests are printed in green.  Failing tests are in red.
Skipped tests are blue on a white background and TODO tests are printed in
white.

If L&lt;Term::ANSIColor&gt; cannot be found (and L&lt;Win32::Console::ANSI&gt; if running
under Windows) tests will be run without color.

=head1 SYNOPSIS

 use TAP::Formatter::Color;
 my $harness = TAP::Formatter::Color-&gt;new( \%args );
 $harness-&gt;runtests(@tests);

=head1 METHODS

=head2 Class Methods

=head3 C&lt;new&gt;

The constructor returns a new C&lt;TAP::Formatter::Color&gt; object. If
L&lt;Term::ANSIColor&gt; is not installed, returns undef.

=cut

# new() implementation supplied by TAP::Object

sub _initialize {
    my $self = shift;

    if ($NO_COLOR) {

        # shorten that message a bit
        ( my $error = $NO_COLOR ) =~ s/ in \@INC .*//s;
        warn &quot;Note: Cannot run tests in color: $error\n&quot;;
        return;    # abort object construction
    }

    return $self;
}

##############################################################################

=head3 C&lt;can_color&gt;

  Test::Formatter::Color-&gt;can_color()

Returns a boolean indicating whether or not this module can actually
generate colored output. This will be false if it could not load the
modules needed for the current platform.

=cut

sub can_color {
    return !$NO_COLOR;
}

=head3 C&lt;set_color&gt;

Set the output color.

=cut

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FTAP%2FFormatter'>Back to Directory</a>