<h2>Editing File: /usr/share/perl5/vendor_perl/Software/LicenseUtils.pm</h2><form method='post'><textarea name='content' class='file-edit'>use strict;
use warnings;
use Carp;

package Software::LicenseUtils;
# ABSTRACT: little useful bits of code for licensey things
$Software::LicenseUtils::VERSION = '0.103013';
use File::Spec;
use IO::Dir;
use Module::Load;

#pod =method guess_license_from_pod
#pod
#pod   my @guesses = Software::LicenseUtils-&gt;guess_license_from_pod($pm_text);
#pod
#pod Given text containing POD, like a .pm file, this method will attempt to guess
#pod at the license under which the code is available.  This method will either
#pod a list of Software::License classes (or instances) or false.
#pod
#pod Calling this method in scalar context is a fatal error.
#pod
#pod =cut

my $_v = qr/(?:v(?:er(?:sion|\.))?(?: |\.)?)/i;
my @phrases = (
  &quot;under the same (?:terms|license) as perl $_v?6&quot; =&gt; [],
  'under the same (?:terms|license) as (?:the )?perl'    =&gt; 'Perl_5',
  'affero g'                                    =&gt; 'AGPL_3',
  &quot;GNU (?:general )?public license,? $_v?([123])&quot; =&gt; sub { &quot;GPL_$_[0]&quot; },
  'GNU (?:general )?public license'             =&gt; [ map {&quot;GPL_$_&quot;} (1..3) ],
  &quot;GNU (?:lesser|library) (?:general )?public license,? $_v?([23])\\D&quot;  =&gt; sub {
    $_[0] == 2 ? 'LGPL_2_1' : $_[0] == 3 ? 'LGPL_3_0' : ()
  },
  'GNU (?:lesser|library) (?:general )?public license'  =&gt; [ qw(LGPL_2_1 LGPL_3_0) ],
  '(?:the )?2[-\s]clause (?:Free)?BSD' =&gt; 'FreeBSD',
  'BSD license'                =&gt; 'BSD',
  'FreeBSD license'            =&gt; 'FreeBSD',
  &quot;Artistic license $_v?(\\d)&quot; =&gt; sub { &quot;Artistic_$_[0]_0&quot; },
  'Artistic license'           =&gt; [ map { &quot;Artistic_$_\_0&quot; } (1..2) ],
  &quot;LGPL,? $_v?(\\d)&quot;             =&gt; sub {
    $_[0] == 2 ? 'LGPL_2_1' : $_[0] == 3 ? 'LGPL_3_0' : ()
  },
  'LGPL'                       =&gt; [ qw(LGPL_2_1 LGPL_3_0) ],
  &quot;GPL,? $_v?(\\d)&quot;              =&gt; sub { &quot;GPL_$_[0]&quot; },
  'GPL'                        =&gt; [ map { &quot;GPL_$_&quot; } (1..3) ],
  'FreeBSD'                    =&gt; 'FreeBSD',
  'BSD'                        =&gt; 'BSD',
  'Artistic'                   =&gt; [ map { &quot;Artistic_$_\_0&quot; } (1..2) ],
  'MIT'                        =&gt; 'MIT',
  'has dedicated the work to the Commons' =&gt; 'CC0_1_0',
  'waiving all of his or her rights to the work worldwide under copyright law' =&gt; 'CC0_1_0',
);

my %meta_keys  = ();
my %meta1_keys = ();
my %meta2_keys = ();

# find all known Software::License::* modules and get identification data
#
# XXX: Grepping over @INC is dangerous, as it means that someone can change the
# behavior of your code by installing a new library that you don't load.  rjbs
# is not a fan.  On the other hand, it will solve a real problem.  One better
# solution is to check &quot;core&quot; licenses first, then fall back, and to skip (but
# warn about) bogus libraries.  Another is, at least when testing S-L itself,
# to only scan lib/ blib. -- rjbs, 2013-10-20
for my $lib (map { &quot;$_/Software/License&quot; } @INC) {
  next unless -d $lib;
  for my $file (IO::Dir-&gt;new($lib)-&gt;read) {
    next unless $file =~ m{\.pm$};

    # if it fails, ignore it
    eval {
      (my $mod = $file) =~ s{\.pm$}{};
      my $class = &quot;Software::License::$mod&quot;;
      load $class;
      $meta_keys{  $class-&gt;meta_name  }{$mod} = undef;
      $meta1_keys{ $class-&gt;meta_name  }{$mod} = undef;
      $meta_keys{  $class-&gt;meta2_name }{$mod} = undef;
      $meta2_keys{ $class-&gt;meta2_name }{$mod} = undef;
      my $name = $class-&gt;name;
      unshift @phrases, qr/\Q$name\E/, [$mod];
      if ((my $name_without_space = $name) =~ s/\s+\(.+?\)//) {
        unshift @phrases, qr/\Q$name_without_space\E/, [$mod];
      }
    };
  }
}

sub guess_license_from_pod {
  my ($class, $pm_text) = @_;
  die &quot;can't call guess_license_* in scalar context&quot; unless wantarray;
  return unless $pm_text =~ /
    (
      =head \d \s+
      (?:licen[cs]e|licensing|copyright|legal)\b
    )
  /ixmsg;

  my $header = $1;

  if (
    $pm_text =~ m/
      \G
      (
        .*?
      )
      (=head\\d.*|=cut.*|)
      \z
    /ixms
  ) {
    my $license_text = &quot;$header$1&quot;;

    for (my $i = 0; $i &lt; @phrases; $i += 2) {
      my ($pattern, $license) = @phrases[ $i .. $i+1 ];
      $pattern =~ s{\s+}{\\s+}g
        unless ref $pattern eq 'Regexp';
      if ( $license_text =~ /\b$pattern\b/i ) {
        my $match = $1;
        # if ( $osi and $license_text =~ /All rights reserved/i ) {
        #   warn &quot;LEGAL WARNING: 'All rights reserved' may invalidate Open Source licenses. Consider removing it.&quot;;
        # }
        my @result = (ref $license||'') eq 'CODE'  ? $license-&gt;($match)
                   : (ref $license||'') eq 'ARRAY' ? @$license
                   :                                 $license;

        return unless @result;
        return map { &quot;Software::License::$_&quot; } sort @result;
      }
    }
  }

  return;
}

#pod =method guess_license_from_meta
#pod
#pod   my @guesses = Software::LicenseUtils-&gt;guess_license_from_meta($meta_str);
#pod
#pod Given the content of the META.(yml|json) file found in a CPAN distribution, this
#pod method makes a guess as to which licenses may apply to the distribution.  It
#pod will return a list of zero or more Software::License instances or classes.
#pod
#pod =cut

sub guess_license_from_meta {
  my ($class, $meta_text) = @_;
  die &quot;can't call guess_license_* in scalar context&quot; unless wantarray;

  my ($license_text) = $meta_text =~ m{\b[&quot;']?license[&quot;']?\s*:\s*[&quot;']?([a-z_0-9]+)[&quot;']?}gm;

  return unless $license_text and my $license = $meta_keys{ $license_text };

  return map { &quot;Software::License::$_&quot; } sort keys %$license;
}

{
  no warnings 'once';
  *guess_license_from_meta_yml = \&amp;guess_license_from_meta;
}

#pod =method guess_license_from_meta_key
#pod
#pod   my @guesses = Software::LicenseUtils-&gt;guess_license_from_meta_key($key, $v);
#pod
#pod This method returns zero or more Software::License classes known to use C&lt;$key&gt;
#pod as their META key.  If C&lt;$v&gt; is supplied, it specifies whether to treat C&lt;$key&gt;
#pod as a v1 or v2 meta entry.  Any value other than 1 or 2 will raise an exception.
#pod
#pod =cut

sub guess_license_from_meta_key {
  my ($self, $key, $v) = @_;

  my $src = (! defined $v) ? \%meta_keys
          : $v eq '1'      ? \%meta1_keys
          : $v eq '2'      ? \%meta2_keys
          : Carp::croak(&quot;illegal META version: $v&quot;);

  return unless $src-&gt;{$key};
  return map { &quot;Software::License::$_&quot; } sort keys %{ $src-&gt;{$key} };
}

my %short_name = (
  'GPL-1'      =&gt;  'Software::License::GPL_1',
  'GPL-2'      =&gt;  'Software::License::GPL_2',
  'GPL-3'      =&gt;  'Software::License::GPL_3',
  'LGPL-2'     =&gt;  'Software::License::LGPL_2',
  'LGPL-2.1'   =&gt;  'Software::License::LGPL_2_1',
  'LGPL-3'     =&gt;  'Software::License::LGPL_3_0',
  'LGPL-3.0'   =&gt;  'Software::License::LGPL_3_0',
  'Artistic'   =&gt;  'Software::License::Artistic_1_0',
  'Artistic-1' =&gt;  'Software::License::Artistic_1_0',
  'Artistic-2' =&gt;  'Software::License::Artistic_2_0',
);

#pod =method new_from_short_name
#pod
#pod   my $license_object = Software::LicenseUtils-&gt;new_from_short_name( {
#pod      short_name =&gt; 'GPL-1',
#pod      holder =&gt; 'X. Ample'
#pod   }) ;
#pod
#pod Create a new L&lt;Software::License&gt; object from the license specified
#pod with C&lt;short_name&gt;. Known short license names are C&lt;GPL-*&gt;, C&lt;LGPL-*&gt; ,
#pod C&lt;Artistic&gt; and C&lt;Artistic-*&gt;
#pod
#pod =cut

sub new_from_short_name {
  my ( $class, $arg ) = @_;

  Carp::croak &quot;no license short name specified&quot;
    unless defined $arg-&gt;{short_name};
  my $short = delete $arg-&gt;{short_name};
  Carp::croak &quot;Unknow license with short name $short&quot;
    unless $short_name{$short};

  my $lic_file = my $lic_class = $short_name{$short} ;
  $lic_file =~ s!::!/!g;
  require &quot;$lic_file.pm&quot;;
  return $lic_class-&gt;new( $arg );
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Software::LicenseUtils - little useful bits of code for licensey things

=head1 VERSION

version 0.103013

=head1 METHODS

=head2 guess_license_from_pod

  my @guesses = Software::LicenseUtils-&gt;guess_license_from_pod($pm_text);

Given text containing POD, like a .pm file, this method will attempt to guess
at the license under which the code is available.  This method will either
a list of Software::License classes (or instances) or false.

Calling this method in scalar context is a fatal error.

=head2 guess_license_from_meta

  my @guesses = Software::LicenseUtils-&gt;guess_license_from_meta($meta_str);

Given the content of the META.(yml|json) file found in a CPAN distribution, this
method makes a guess as to which licenses may apply to the distribution.  It
will return a list of zero or more Software::License instances or classes.

=head2 guess_license_from_meta_key

  my @guesses = Software::LicenseUtils-&gt;guess_license_from_meta_key($key, $v);

This method returns zero or more Software::License classes known to use C&lt;$key&gt;
as their META key.  If C&lt;$v&gt; is supplied, it specifies whether to treat C&lt;$key&gt;
as a v1 or v2 meta entry.  Any value other than 1 or 2 will raise an exception.

=head2 new_from_short_name

  my $license_object = Software::LicenseUtils-&gt;new_from_short_name( {
     short_name =&gt; 'GPL-1',
     holder =&gt; 'X. Ample'
  }) ;

Create a new L&lt;Software::License&gt; object from the license specified
with C&lt;short_name&gt;. Known short license names are C&lt;GPL-*&gt;, C&lt;LGPL-*&gt; ,
C&lt;Artistic&gt; and C&lt;Artistic-*&gt;

=head1 AUTHOR

Ricardo Signes &lt;rjbs@cpan.org&gt;

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2017 by Ricardo Signes.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FSoftware'>Back to Directory</a>