<h2>Editing File: /usr/share/perl5/vendor_perl/Math/BigRat.pm</h2><form method='post'><textarea name='content' class='file-edit'>#
# &quot;Tax the rat farms.&quot; - Lord Vetinari
#

# The following hash values are used:
#   sign : +,-,NaN,+inf,-inf
#   _d   : denominator
#   _n   : numerator (value = _n/_d)
#   _a   : accuracy
#   _p   : precision
# You should not look at the innards of a BigRat - use the methods for this.

package Math::BigRat;

use 5.006;
use strict;
use warnings;

use Carp qw&lt; carp croak &gt;;

use Math::BigFloat 1.999718;

our $VERSION = '0.2614';

our @ISA = qw(Math::BigFloat);

our ($accuracy, $precision, $round_mode, $div_scale,
     $upgrade, $downgrade, $_trap_nan, $_trap_inf);

use overload

  # overload key: with_assign

  '+'     =&gt;      sub { $_[0] -&gt; copy() -&gt; badd($_[1]); },

  '-'     =&gt;      sub { my $c = $_[0] -&gt; copy;
                        $_[2] ? $c -&gt; bneg() -&gt; badd( $_[1])
                              : $c -&gt; bsub($_[1]); },

  '*'     =&gt;      sub { $_[0] -&gt; copy() -&gt; bmul($_[1]); },

  '/'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bdiv($_[0])
                              : $_[0] -&gt; copy() -&gt; bdiv($_[1]); },

  '%'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bmod($_[0])
                              : $_[0] -&gt; copy() -&gt; bmod($_[1]); },

  '**'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bpow($_[0])
                              : $_[0] -&gt; copy() -&gt; bpow($_[1]); },

  '&lt;&lt;'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; blsft($_[0])
                              : $_[0] -&gt; copy() -&gt; blsft($_[1]); },

  '&gt;&gt;'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; brsft($_[0])
                              : $_[0] -&gt; copy() -&gt; brsft($_[1]); },

  # overload key: assign

  '+='    =&gt;      sub { $_[0]-&gt;badd($_[1]); },

  '-='    =&gt;      sub { $_[0]-&gt;bsub($_[1]); },

  '*='    =&gt;      sub { $_[0]-&gt;bmul($_[1]); },

  '/='    =&gt;      sub { scalar $_[0]-&gt;bdiv($_[1]); },

  '%='    =&gt;      sub { $_[0]-&gt;bmod($_[1]); },

  '**='   =&gt;      sub { $_[0]-&gt;bpow($_[1]); },

  '&lt;&lt;='   =&gt;      sub { $_[0]-&gt;blsft($_[1]); },

  '&gt;&gt;='   =&gt;      sub { $_[0]-&gt;brsft($_[1]); },

#  'x='    =&gt;      sub { },

#  '.='    =&gt;      sub { },

  # overload key: num_comparison

  '&lt;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; blt($_[0])
                              : $_[0] -&gt; blt($_[1]); },

  '&lt;='    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; ble($_[0])
                              : $_[0] -&gt; ble($_[1]); },

  '&gt;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bgt($_[0])
                              : $_[0] -&gt; bgt($_[1]); },

  '&gt;='    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bge($_[0])
                              : $_[0] -&gt; bge($_[1]); },

  '=='    =&gt;      sub { $_[0] -&gt; beq($_[1]); },

  '!='    =&gt;      sub { $_[0] -&gt; bne($_[1]); },

  # overload key: 3way_comparison

  '&lt;=&gt;'   =&gt;      sub { my $cmp = $_[0] -&gt; bcmp($_[1]);
                        defined($cmp) &amp;&amp; $_[2] ? -$cmp : $cmp; },

  'cmp'   =&gt;      sub { $_[2] ? &quot;$_[1]&quot; cmp $_[0] -&gt; bstr()
                              : $_[0] -&gt; bstr() cmp &quot;$_[1]&quot;; },

  # overload key: str_comparison

#  'lt'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrlt($_[0])
#                              : $_[0] -&gt; bstrlt($_[1]); },
#
#  'le'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrle($_[0])
#                              : $_[0] -&gt; bstrle($_[1]); },
#
#  'gt'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrgt($_[0])
#                              : $_[0] -&gt; bstrgt($_[1]); },
#
#  'ge'    =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bstrge($_[0])
#                              : $_[0] -&gt; bstrge($_[1]); },
#
#  'eq'    =&gt;      sub { $_[0] -&gt; bstreq($_[1]); },
#
#  'ne'    =&gt;      sub { $_[0] -&gt; bstrne($_[1]); },

  # overload key: binary

  '&amp;'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; band($_[0])
                              : $_[0] -&gt; copy() -&gt; band($_[1]); },

  '&amp;='    =&gt;      sub { $_[0] -&gt; band($_[1]); },

  '|'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bior($_[0])
                              : $_[0] -&gt; copy() -&gt; bior($_[1]); },

  '|='    =&gt;      sub { $_[0] -&gt; bior($_[1]); },

  '^'     =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; bxor($_[0])
                              : $_[0] -&gt; copy() -&gt; bxor($_[1]); },

  '^='    =&gt;      sub { $_[0] -&gt; bxor($_[1]); },

#  '&amp;.'    =&gt;      sub { },

#  '&amp;.='   =&gt;      sub { },

#  '|.'    =&gt;      sub { },

#  '|.='   =&gt;      sub { },

#  '^.'    =&gt;      sub { },

#  '^.='   =&gt;      sub { },

  # overload key: unary

  'neg'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bneg(); },

#  '!'     =&gt;      sub { },

  '~'     =&gt;      sub { $_[0] -&gt; copy() -&gt; bnot(); },

#  '~.'    =&gt;      sub { },

  # overload key: mutators

  '++'    =&gt;      sub { $_[0] -&gt; binc() },

  '--'    =&gt;      sub { $_[0] -&gt; bdec() },

  # overload key: func

  'atan2' =&gt;      sub { $_[2] ? ref($_[0]) -&gt; new($_[1]) -&gt; batan2($_[0])
                              : $_[0] -&gt; copy() -&gt; batan2($_[1]); },

  'cos'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bcos(); },

  'sin'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bsin(); },

  'exp'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bexp($_[1]); },

  'abs'   =&gt;      sub { $_[0] -&gt; copy() -&gt; babs(); },

  'log'   =&gt;      sub { $_[0] -&gt; copy() -&gt; blog(); },

  'sqrt'  =&gt;      sub { $_[0] -&gt; copy() -&gt; bsqrt(); },

  'int'   =&gt;      sub { $_[0] -&gt; copy() -&gt; bint(); },

  # overload key: conversion

  'bool'  =&gt;      sub { $_[0] -&gt; is_zero() ? '' : 1; },

  '&quot;&quot;'    =&gt;      sub { $_[0] -&gt; bstr(); },

  '0+'    =&gt;      sub { $_[0] -&gt; numify(); },

  '='     =&gt;      sub { $_[0]-&gt;copy(); },

  ;

BEGIN {
    *objectify = \&amp;Math::BigInt::objectify;  # inherit this from BigInt
    *AUTOLOAD  = \&amp;Math::BigFloat::AUTOLOAD; # can't inherit AUTOLOAD
    # We inherit these from BigFloat because currently it is not possible that
    # Math::BigFloat has a different $LIB variable than we, because
    # Math::BigFloat also uses Math::BigInt::config-&gt;('lib') (there is always
    # only one library loaded)
    *_e_add = \&amp;Math::BigFloat::_e_add;
    *_e_sub = \&amp;Math::BigFloat::_e_sub;
    *as_number = \&amp;as_int;
    *is_pos = \&amp;is_positive;
    *is_neg = \&amp;is_negative;
}

##############################################################################
# Global constants and flags. Access these only via the accessor methods!

$accuracy   = $precision = undef;
$round_mode = 'even';
$div_scale  = 40;
$upgrade    = undef;
$downgrade  = undef;

# These are internally, and not to be used from the outside at all!

$_trap_nan = 0;                         # are NaNs ok? set w/ config()
$_trap_inf = 0;                         # are infs ok? set w/ config()

# the math backend library

my $LIB = 'Math::BigInt::Calc';

my $nan   = 'NaN';
#my $class = 'Math::BigRat';

sub isa {
    return 0 if $_[1] =~ /^Math::Big(Int|Float)/;       # we aren't
    UNIVERSAL::isa(@_);
}

##############################################################################

sub new {
    my $proto    = shift;
    my $protoref = ref $proto;
    my $class    = $protoref || $proto;

    # Check the way we are called.

    if ($protoref) {
        croak(&quot;new() is a class method, not an instance method&quot;);
    }

    if (@_ &lt; 1) {
        #carp(&quot;Using new() with no argument is deprecated;&quot;,
        #           &quot; use bzero() or new(0) instead&quot;);
        return $class -&gt; bzero();
    }

    if (@_ &gt; 2) {
        carp(&quot;Superfluous arguments to new() ignored.&quot;);
    }

    # Get numerator and denominator. If any of the arguments is undefined,
    # return zero.

    my ($n, $d) = @_;

    if (@_ == 1 &amp;&amp; !defined $n ||
        @_ == 2 &amp;&amp; (!defined $n || !defined $d))
    {
        #carp(&quot;Use of uninitialized value in new()&quot;);
        return $class -&gt; bzero();
    }

    # Initialize a new object.

    my $self = bless {}, $class;

    # One or two input arguments may be given. First handle the numerator $n.

    if (ref($n)) {
        $n = Math::BigFloat -&gt; new($n, undef, undef)
          unless ($n -&gt; isa('Math::BigRat') ||
                  $n -&gt; isa('Math::BigInt') ||
                  $n -&gt; isa('Math::BigFloat'));
    } else {
        if (defined $d) {
            # If the denominator is defined, the numerator is not a string
            # fraction, e.g., &quot;355/113&quot;.
            $n = Math::BigFloat -&gt; new($n, undef, undef);
        } else {
            # If the denominator is undefined, the numerator might be a string
            # fraction, e.g., &quot;355/113&quot;.
            if ($n =~ m| ^ \s* (\S+) \s* / \s* (\S+) \s* $ |x) {
                $n = Math::BigFloat -&gt; new($1, undef, undef);
                $d = Math::BigFloat -&gt; new($2, undef, undef);
            } else {
                $n = Math::BigFloat -&gt; new($n, undef, undef);
            }
        }
    }

    # At this point $n is an object and $d is either an object or undefined. An
    # undefined $d means that $d was not specified by the caller (not that $d
    # was specified as an undefined value).

    unless (defined $d) {
        #return $n -&gt; copy($n)               if $n -&gt; isa('Math::BigRat');
        return $class -&gt; copy($n)           if $n -&gt; isa('Math::BigRat');
        return $class -&gt; bnan()             if $n -&gt; is_nan();
        return $class -&gt; binf($n -&gt; sign()) if $n -&gt; is_inf();

        if ($n -&gt; isa('Math::BigInt')) {
            $self -&gt; {_n}   = $LIB -&gt; _new($n -&gt; copy() -&gt; babs() -&gt; bstr());
            $self -&gt; {_d}   = $LIB -&gt; _one();
            $self -&gt; {sign} = $n -&gt; sign();
            return $self;
        }

        if ($n -&gt; isa('Math::BigFloat')) {
            my $m = $n -&gt; mantissa() -&gt; babs();
            my $e = $n -&gt; exponent();
            $self -&gt; {_n} = $LIB -&gt; _new($m -&gt; bstr());
            $self -&gt; {_d} = $LIB -&gt; _one();

            if ($e &gt; 0) {
                $self -&gt; {_n} = $LIB -&gt; _lsft($self -&gt; {_n},
                                              $LIB -&gt; _new($e -&gt; bstr()), 10);
            } elsif ($e &lt; 0) {
                $self -&gt; {_d} = $LIB -&gt; _lsft($self -&gt; {_d},
                                              $LIB -&gt; _new(-$e -&gt; bstr()), 10);

                my $gcd = $LIB -&gt; _gcd($LIB -&gt; _copy($self -&gt; {_n}), $self -&gt; {_d});
                if (!$LIB -&gt; _is_one($gcd)) {
                    $self -&gt; {_n} = $LIB -&gt; _div($self-&gt;{_n}, $gcd);
                    $self -&gt; {_d} = $LIB -&gt; _div($self-&gt;{_d}, $gcd);
                }
            }

            $self -&gt; {sign} = $n -&gt; sign();
            return $self;
        }

        die &quot;I don't know how to handle this&quot;;  # should never get here
    }

    # At the point we know that both $n and $d are defined. We know that $n is
    # an object, but $d might still be a scalar. Now handle $d.

    $d = Math::BigFloat -&gt; new($d, undef, undef)
      unless ref($d) &amp;&amp; ($d -&gt; isa('Math::BigRat') ||
                         $d -&gt; isa('Math::BigInt') ||
                         $d -&gt; isa('Math::BigFloat'));

    # At this point both $n and $d are objects.

    return $class -&gt; bnan() if $n -&gt; is_nan() || $d -&gt; is_nan();

    # At this point neither $n nor $d is a NaN.

    if ($n -&gt; is_zero()) {
        return $class -&gt; bnan() if $d -&gt; is_zero();     # 0/0 = NaN
        return $class -&gt; bzero();
    }

    return $class -&gt; binf($d -&gt; sign()) if $d -&gt; is_zero();

    # At this point, neither $n nor $d is a NaN or a zero.

    if ($d &lt; 0) {               # make sure denominator is positive
        $n -&gt; bneg();
        $d -&gt; bneg();
    }

    if ($n -&gt; is_inf()) {
        return $class -&gt; bnan() if $d -&gt; is_inf();      # Inf/Inf = NaN
        return $class -&gt; binf($n -&gt; sign());
    }

    # At this point $n is finite.

    return $class -&gt; bzero()            if $d -&gt; is_inf();
    return $class -&gt; binf($d -&gt; sign()) if $d -&gt; is_zero();

    # At this point both $n and $d are finite and non-zero.

    if ($n &lt; 0) {
        $n -&gt; bneg();
        $self -&gt; {sign} = '-';
    } else {
        $self -&gt; {sign} = '+';
    }

    if ($n -&gt; isa('Math::BigRat')) {

        if ($d -&gt; isa('Math::BigRat')) {

            # At this point both $n and $d is a Math::BigRat.

            # p   r    p * s    (p / gcd(p, r)) * (s / gcd(s, q))
            # - / -  = ----- =  ---------------------------------
            # q   s    q * r    (q / gcd(s, q)) * (r / gcd(p, r))

            my $p = $n -&gt; {_n};
            my $q = $n -&gt; {_d};
            my $r = $d -&gt; {_n};
            my $s = $d -&gt; {_d};
            my $gcd_pr = $LIB -&gt; _gcd($LIB -&gt; _copy($p), $r);
            my $gcd_sq = $LIB -&gt; _gcd($LIB -&gt; _copy($s), $q);
            $self -&gt; {_n} = $LIB -&gt; _mul($LIB -&gt; _div($LIB -&gt; _copy($p), $gcd_pr),
                                         $LIB -&gt; _div($LIB -&gt; _copy($s), $gcd_sq));
            $self -&gt; {_d} = $LIB -&gt; _mul($LIB -&gt; _div($LIB -&gt; _copy($q), $gcd_sq),
                                         $LIB -&gt; _div($LIB -&gt; _copy($r), $gcd_pr));

            return $self;       # no need for $self -&gt; bnorm() here
        }

        # At this point, $n is a Math::BigRat and $d is a Math::Big(Int|Float).

        my $p = $n -&gt; {_n};
        my $q = $n -&gt; {_d};
        my $m = $d -&gt; mantissa();
        my $e = $d -&gt; exponent();

        #                   /      p
        #                  |  ------------  if e &gt; 0
        #                  |  q * m * 10^e
        #                  |
        # p                |    p
        # - / (m * 10^e) = |  -----         if e == 0
        # q                |  q * m
        #                  |
        #                  |  p * 10^-e
        #                  |  --------      if e &lt; 0
        #                   \  q * m

        $self -&gt; {_n} = $LIB -&gt; _copy($p);
        $self -&gt; {_d} = $LIB -&gt; _mul($LIB -&gt; _copy($q), $m);
        if ($e &gt; 0) {
            $self -&gt; {_d} = $LIB -&gt; _lsft($self -&gt; {_d}, $e, 10);
        } elsif ($e &lt; 0) {
            $self -&gt; {_n} = $LIB -&gt; _lsft($self -&gt; {_n}, -$e, 10);
        }

        return $self -&gt; bnorm();

    } else {

        if ($d -&gt; isa('Math::BigRat')) {

            # At this point $n is a Math::Big(Int|Float) and $d is a
            # Math::BigRat.

            my $m = $n -&gt; mantissa();
            my $e = $n -&gt; exponent();
            my $p = $d -&gt; {_n};
            my $q = $d -&gt; {_d};

            #                   /  q * m * 10^e
            #                  |   ------------  if e &gt; 0
            #                  |        p
            #                  |
            #              p   |   m * q
            # (m * 10^e) / - = |   -----         if e == 0
            #              q   |     p
            #                  |
            #                  |     q * m
            #                  |   ---------     if e &lt; 0
            #                   \  p * 10^-e

            $self -&gt; {_n} = $LIB -&gt; _mul($LIB -&gt; _copy($q), $m);
            $self -&gt; {_d} = $LIB -&gt; _copy($p);
            if ($e &gt; 0) {
                $self -&gt; {_n} = $LIB -&gt; _lsft($self -&gt; {_n}, $e, 10);
            } elsif ($e &lt; 0) {
                $self -&gt; {_d} = $LIB -&gt; _lsft($self -&gt; {_d}, -$e, 10);
            }
            return $self -&gt; bnorm();

        } else {

            # At this point $n and $d are both a Math::Big(Int|Float)

            my $m1 = $n -&gt; mantissa();
            my $e1 = $n -&gt; exponent();
            my $m2 = $d -&gt; mantissa();
            my $e2 = $d -&gt; exponent();

            #               /
            #              |  m1 * 10^(e1 - e2)
            #              |  -----------------  if e1 &gt; e2
            #              |         m2
            #              |
            # m1 * 10^e1   |  m1
            # ---------- = |  --                 if e1 = e2
            # m2 * 10^e2   |  m2
            #              |
            #              |         m1
            #              |  -----------------  if e1 &lt; e2
            #              |  m2 * 10^(e2 - e1)
            #               \

            $self -&gt; {_n} = $LIB -&gt; _new($m1 -&gt; bstr());
            $self -&gt; {_d} = $LIB -&gt; _new($m2 -&gt; bstr());
            my $ediff = $e1 - $e2;
            if ($ediff &gt; 0) {
                $self -&gt; {_n} = $LIB -&gt; _lsft($self -&gt; {_n},
                                              $LIB -&gt; _new($ediff -&gt; bstr()),
                                              10);
            } elsif ($ediff &lt; 0) {
                $self -&gt; {_d} = $LIB -&gt; _lsft($self -&gt; {_d},
                                              $LIB -&gt; _new(-$ediff -&gt; bstr()),
                                              10);
            }

            return $self -&gt; bnorm();
        }
    }

    return $self;
}

sub copy {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    # If called as a class method, the object to copy is the next argument.

    $self = shift() unless $selfref;

    my $copy = bless {}, $class;

    $copy-&gt;{sign} = $self-&gt;{sign};
    $copy-&gt;{_d} = $LIB-&gt;_copy($self-&gt;{_d});
    $copy-&gt;{_n} = $LIB-&gt;_copy($self-&gt;{_n});
    $copy-&gt;{_a} = $self-&gt;{_a} if defined $self-&gt;{_a};
    $copy-&gt;{_p} = $self-&gt;{_p} if defined $self-&gt;{_p};

    #($copy, $copy-&gt;{_a}, $copy-&gt;{_p})
    #  = $copy-&gt;_find_round_parameters(@_);

    return $copy;
}

sub bnan {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    $self = bless {}, $class unless $selfref;

    if ($_trap_nan) {
        croak (&quot;Tried to set a variable to NaN in $class-&gt;bnan()&quot;);
    }

    $self -&gt; {sign} = $nan;
    $self -&gt; {_n}   = $LIB -&gt; _zero();
    $self -&gt; {_d}   = $LIB -&gt; _one();

    ($self, $self-&gt;{_a}, $self-&gt;{_p})
      = $self-&gt;_find_round_parameters(@_);

    return $self;
}

sub binf {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    $self = bless {}, $class unless $selfref;

    my $sign = shift();
    $sign = defined($sign) &amp;&amp; substr($sign, 0, 1) eq '-' ? '-inf' : '+inf';

    if ($_trap_inf) {
        croak (&quot;Tried to set a variable to +-inf in $class-&gt;binf()&quot;);
    }

    $self -&gt; {sign} = $sign;
    $self -&gt; {_n}   = $LIB -&gt; _zero();
    $self -&gt; {_d}   = $LIB -&gt; _one();

    ($self, $self-&gt;{_a}, $self-&gt;{_p})
      = $self-&gt;_find_round_parameters(@_);

    return $self;
}

sub bone {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    $self = bless {}, $class unless $selfref;

    my $sign = shift();
    $sign = '+' unless defined($sign) &amp;&amp; $sign eq '-';

    $self -&gt; {sign} = $sign;
    $self -&gt; {_n}   = $LIB -&gt; _one();
    $self -&gt; {_d}   = $LIB -&gt; _one();

    ($self, $self-&gt;{_a}, $self-&gt;{_p})
      = $self-&gt;_find_round_parameters(@_);

    return $self;
}

sub bzero {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    $self = bless {}, $class unless $selfref;

    $self -&gt; {sign} = '+';
    $self -&gt; {_n}   = $LIB -&gt; _zero();
    $self -&gt; {_d}   = $LIB -&gt; _one();

    ($self, $self-&gt;{_a}, $self-&gt;{_p})
      = $self-&gt;_find_round_parameters(@_);

    return $self;
}

##############################################################################

sub config {
    # return (later set?) configuration data as hash ref
    my $class = shift() || 'Math::BigRat';

    if (@_ == 1 &amp;&amp; ref($_[0]) ne 'HASH') {
        my $cfg = $class-&gt;SUPER::config();
        return $cfg-&gt;{$_[0]};
    }

    my $cfg = $class-&gt;SUPER::config(@_);

    # now we need only to override the ones that are different from our parent
    $cfg-&gt;{class} = $class;
    $cfg-&gt;{with}  = $LIB;

    $cfg;
}

##############################################################################

sub bstr {
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    if ($x-&gt;{sign} !~ /^[+-]$/) {               # inf, NaN etc
        my $s = $x-&gt;{sign};
        $s =~ s/^\+//;                          # +inf =&gt; inf
        return $s;
    }

    my $s = '';
    $s = $x-&gt;{sign} if $x-&gt;{sign} ne '+';       # '+3/2' =&gt; '3/2'

    return $s . $LIB-&gt;_str($x-&gt;{_n}) if $LIB-&gt;_is_one($x-&gt;{_d});
    $s . $LIB-&gt;_str($x-&gt;{_n}) . '/' . $LIB-&gt;_str($x-&gt;{_d});
}

sub bsstr {
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    if ($x-&gt;{sign} !~ /^[+-]$/) {               # inf, NaN etc
        my $s = $x-&gt;{sign};
        $s =~ s/^\+//;                          # +inf =&gt; inf
        return $s;
    }

    my $s = '';
    $s = $x-&gt;{sign} if $x-&gt;{sign} ne '+';       # +3 vs 3
    $s . $LIB-&gt;_str($x-&gt;{_n}) . '/' . $LIB-&gt;_str($x-&gt;{_d});
}

sub bnorm {
    # reduce the number to the shortest form
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    # Both parts must be objects of whatever we are using today.
    if (my $c = $LIB-&gt;_check($x-&gt;{_n})) {
        croak(&quot;n did not pass the self-check ($c) in bnorm()&quot;);
    }
    if (my $c = $LIB-&gt;_check($x-&gt;{_d})) {
        croak(&quot;d did not pass the self-check ($c) in bnorm()&quot;);
    }

    # no normalize for NaN, inf etc.
    return $x if $x-&gt;{sign} !~ /^[+-]$/;

    # normalize zeros to 0/1
    if ($LIB-&gt;_is_zero($x-&gt;{_n})) {
        $x-&gt;{sign} = '+';                               # never leave a -0
        $x-&gt;{_d} = $LIB-&gt;_one() unless $LIB-&gt;_is_one($x-&gt;{_d});
        return $x;
    }

    return $x if $LIB-&gt;_is_one($x-&gt;{_d});               # no need to reduce

    # Compute the GCD.
    my $gcd = $LIB-&gt;_gcd($LIB-&gt;_copy($x-&gt;{_n}), $x-&gt;{_d});
    if (!$LIB-&gt;_is_one($gcd)) {
        $x-&gt;{_n} = $LIB-&gt;_div($x-&gt;{_n}, $gcd);
        $x-&gt;{_d} = $LIB-&gt;_div($x-&gt;{_d}, $gcd);
    }

    $x;
}

##############################################################################
# sign manipulation

sub bneg {
    # (BRAT or num_str) return BRAT
    # negate number or make a negated number from string
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return $x if $x-&gt;modify('bneg');

    # for +0 do not negate (to have always normalized +0). Does nothing for 'NaN'
    $x-&gt;{sign} =~ tr/+-/-+/
      unless ($x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_n}));
    $x;
}

##############################################################################
# special values

sub _bnan {
    # used by parent class bnan() to initialize number to NaN
    my $self = shift;

    if ($_trap_nan) {
        my $class = ref($self);
        # &quot;$self&quot; below will stringify the object, this blows up if $self is a
        # partial object (happens under trap_nan), so fix it beforehand
        $self-&gt;{_d} = $LIB-&gt;_zero() unless defined $self-&gt;{_d};
        $self-&gt;{_n} = $LIB-&gt;_zero() unless defined $self-&gt;{_n};
        croak (&quot;Tried to set $self to NaN in $class\::_bnan()&quot;);
    }
    $self-&gt;{_n} = $LIB-&gt;_zero();
    $self-&gt;{_d} = $LIB-&gt;_zero();
}

sub _binf {
    # used by parent class bone() to initialize number to +inf/-inf
    my $self = shift;

    if ($_trap_inf) {
        my $class = ref($self);
        # &quot;$self&quot; below will stringify the object, this blows up if $self is a
        # partial object (happens under trap_nan), so fix it beforehand
        $self-&gt;{_d} = $LIB-&gt;_zero() unless defined $self-&gt;{_d};
        $self-&gt;{_n} = $LIB-&gt;_zero() unless defined $self-&gt;{_n};
        croak (&quot;Tried to set $self to inf in $class\::_binf()&quot;);
    }
    $self-&gt;{_n} = $LIB-&gt;_zero();
    $self-&gt;{_d} = $LIB-&gt;_zero();
}

sub _bone {
    # used by parent class bone() to initialize number to +1/-1
    my $self = shift;
    $self-&gt;{_n} = $LIB-&gt;_one();
    $self-&gt;{_d} = $LIB-&gt;_one();
}

sub _bzero {
    # used by parent class bzero() to initialize number to 0
    my $self = shift;
    $self-&gt;{_n} = $LIB-&gt;_zero();
    $self-&gt;{_d} = $LIB-&gt;_one();
}

##############################################################################
# mul/add/div etc

sub badd {
    # add two rational numbers

    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    # +inf + +inf =&gt; +inf, -inf + -inf =&gt; -inf
    return $x-&gt;binf(substr($x-&gt;{sign}, 0, 1))
      if $x-&gt;{sign} eq $y-&gt;{sign} &amp;&amp; $x-&gt;{sign} =~ /^[+-]inf$/;

    # +inf + -inf or -inf + +inf =&gt; NaN
    return $x-&gt;bnan() if ($x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/);

    #  1   1    gcd(3, 4) = 1    1*3 + 1*4    7
    #  - + -                  = --------- = --
    #  4   3                      4*3       12

    # we do not compute the gcd() here, but simple do:
    #  5   7    5*3 + 7*4   43
    #  - + -  = --------- = --
    #  4   3       4*3      12

    # and bnorm() will then take care of the rest

    # 5 * 3
    $x-&gt;{_n} = $LIB-&gt;_mul($x-&gt;{_n}, $y-&gt;{_d});

    # 7 * 4
    my $m = $LIB-&gt;_mul($LIB-&gt;_copy($y-&gt;{_n}), $x-&gt;{_d});

    # 5 * 3 + 7 * 4
    ($x-&gt;{_n}, $x-&gt;{sign}) = _e_add($x-&gt;{_n}, $m, $x-&gt;{sign}, $y-&gt;{sign});

    # 4 * 3
    $x-&gt;{_d} = $LIB-&gt;_mul($x-&gt;{_d}, $y-&gt;{_d});

    # normalize result, and possible round
    $x-&gt;bnorm()-&gt;round(@r);
}

sub bsub {
    # subtract two rational numbers

    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    # flip sign of $x, call badd(), then flip sign of result
    $x-&gt;{sign} =~ tr/+-/-+/
      unless $x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_n}); # not -0
    $x-&gt;badd($y, @r);           # does norm and round
    $x-&gt;{sign} =~ tr/+-/-+/
      unless $x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_n}); # not -0

    $x;
}

sub bmul {
    # multiply two rational numbers

    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    return $x-&gt;bnan() if $x-&gt;{sign} eq 'NaN' || $y-&gt;{sign} eq 'NaN';

    # inf handling
    if ($x-&gt;{sign} =~ /^[+-]inf$/ || $y-&gt;{sign} =~ /^[+-]inf$/) {
        return $x-&gt;bnan() if $x-&gt;is_zero() || $y-&gt;is_zero();
        # result will always be +-inf:
        # +inf * +/+inf =&gt; +inf, -inf * -/-inf =&gt; +inf
        # +inf * -/-inf =&gt; -inf, -inf * +/+inf =&gt; -inf
        return $x-&gt;binf() if ($x-&gt;{sign} =~ /^\+/ &amp;&amp; $y-&gt;{sign} =~ /^\+/);
        return $x-&gt;binf() if ($x-&gt;{sign} =~ /^-/ &amp;&amp; $y-&gt;{sign} =~ /^-/);
        return $x-&gt;binf('-');
    }

    # x == 0  # also: or y == 1 or y == -1
    return wantarray ? ($x, $class-&gt;bzero()) : $x if $x -&gt; is_zero();

    if ($y -&gt; is_zero()) {
        $x -&gt; bzero();
        return wantarray ? ($x, $class-&gt;bzero()) : $x;
    }

    # According to Knuth, this can be optimized by doing gcd twice (for d
    # and n) and reducing in one step. This saves us a bnorm() at the end.
    #
    # p   s    p * s    (p / gcd(p, r)) * (s / gcd(s, q))
    # - * -  = ----- =  ---------------------------------
    # q   r    q * r    (q / gcd(s, q)) * (r / gcd(p, r))

    my $gcd_pr = $LIB -&gt; _gcd($LIB -&gt; _copy($x-&gt;{_n}), $y-&gt;{_d});
    my $gcd_sq = $LIB -&gt; _gcd($LIB -&gt; _copy($y-&gt;{_n}), $x-&gt;{_d});

    $x-&gt;{_n} = $LIB -&gt; _mul(scalar $LIB -&gt; _div($x-&gt;{_n}, $gcd_pr),
                            scalar $LIB -&gt; _div($LIB -&gt; _copy($y-&gt;{_n}),
                                                $gcd_sq));
    $x-&gt;{_d} = $LIB -&gt; _mul(scalar $LIB -&gt; _div($x-&gt;{_d}, $gcd_sq),
                            scalar $LIB -&gt; _div($LIB -&gt; _copy($y-&gt;{_d}),
                                                $gcd_pr));

    # compute new sign
    $x-&gt;{sign} = $x-&gt;{sign} eq $y-&gt;{sign} ? '+' : '-';

    $x-&gt;round(@r);
}

sub bdiv {
    # (dividend: BRAT or num_str, divisor: BRAT or num_str) return
    # (BRAT, BRAT) (quo, rem) or BRAT (only rem)

    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    return $x if $x-&gt;modify('bdiv');

    my $wantarray = wantarray;  # call only once

    # At least one argument is NaN. This is handled the same way as in
    # Math::BigInt -&gt; bdiv(). See the comments in the code implementing that
    # method.

    if ($x -&gt; is_nan() || $y -&gt; is_nan()) {
        return $wantarray ? ($x -&gt; bnan(), $class -&gt; bnan()) : $x -&gt; bnan();
    }

    # Divide by zero and modulo zero. This is handled the same way as in
    # Math::BigInt -&gt; bdiv(). See the comments in the code implementing that
    # method.

    if ($y -&gt; is_zero()) {
        my ($quo, $rem);
        if ($wantarray) {
            $rem = $x -&gt; copy();
        }
        if ($x -&gt; is_zero()) {
            $quo = $x -&gt; bnan();
        } else {
            $quo = $x -&gt; binf($x -&gt; {sign});
        }
        return $wantarray ? ($quo, $rem) : $quo;
    }

    # Numerator (dividend) is +/-inf. This is handled the same way as in
    # Math::BigInt -&gt; bdiv(). See the comments in the code implementing that
    # method.

    if ($x -&gt; is_inf()) {
        my ($quo, $rem);
        $rem = $class -&gt; bnan() if $wantarray;
        if ($y -&gt; is_inf()) {
            $quo = $x -&gt; bnan();
        } else {
            my $sign = $x -&gt; bcmp(0) == $y -&gt; bcmp(0) ? '+' : '-';
            $quo = $x -&gt; binf($sign);
        }
        return $wantarray ? ($quo, $rem) : $quo;
    }

    # Denominator (divisor) is +/-inf. This is handled the same way as in
    # Math::BigFloat -&gt; bdiv(). See the comments in the code implementing that
    # method.

    if ($y -&gt; is_inf()) {
        my ($quo, $rem);
        if ($wantarray) {
            if ($x -&gt; is_zero() || $x -&gt; bcmp(0) == $y -&gt; bcmp(0)) {
                $rem = $x -&gt; copy();
                $quo = $x -&gt; bzero();
            } else {
                $rem = $class -&gt; binf($y -&gt; {sign});
                $quo = $x -&gt; bone('-');
            }
            return ($quo, $rem);
        } else {
            if ($y -&gt; is_inf()) {
                if ($x -&gt; is_nan() || $x -&gt; is_inf()) {
                    return $x -&gt; bnan();
                } else {
                    return $x -&gt; bzero();
                }
            }
        }
    }

    # At this point, both the numerator and denominator are finite numbers, and
    # the denominator (divisor) is non-zero.

    # x == 0?
    return wantarray ? ($x, $class-&gt;bzero()) : $x if $x-&gt;is_zero();

    # XXX TODO: list context, upgrade
    # According to Knuth, this can be optimized by doing gcd twice (for d and n)
    # and reducing in one step. This would save us the bnorm() at the end.
    #
    # p   r    p * s    (p / gcd(p, r)) * (s / gcd(s, q))
    # - / -  = ----- =  ---------------------------------
    # q   s    q * r    (q / gcd(s, q)) * (r / gcd(p, r))

    $x-&gt;{_n} = $LIB-&gt;_mul($x-&gt;{_n}, $y-&gt;{_d});
    $x-&gt;{_d} = $LIB-&gt;_mul($x-&gt;{_d}, $y-&gt;{_n});

    # compute new sign
    $x-&gt;{sign} = $x-&gt;{sign} eq $y-&gt;{sign} ? '+' : '-';

    $x -&gt; bnorm();
    if (wantarray) {
        my $rem = $x -&gt; copy();
        $x -&gt; bfloor();
        $x -&gt; round(@r);
        $rem -&gt; bsub($x -&gt; copy()) -&gt; bmul($y);
        return $x, $rem;
    } else {
        $x -&gt; round(@r);
        return $x;
    }
}

sub bmod {
    # compute &quot;remainder&quot; (in Perl way) of $x / $y

    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    return $x if $x-&gt;modify('bmod');

    # At least one argument is NaN. This is handled the same way as in
    # Math::BigInt -&gt; bmod().

    if ($x -&gt; is_nan() || $y -&gt; is_nan()) {
        return $x -&gt; bnan();
    }

    # Modulo zero. This is handled the same way as in Math::BigInt -&gt; bmod().

    if ($y -&gt; is_zero()) {
        return $x;
    }

    # Numerator (dividend) is +/-inf. This is handled the same way as in
    # Math::BigInt -&gt; bmod().

    if ($x -&gt; is_inf()) {
        return $x -&gt; bnan();
    }

    # Denominator (divisor) is +/-inf. This is handled the same way as in
    # Math::BigInt -&gt; bmod().

    if ($y -&gt; is_inf()) {
        if ($x -&gt; is_zero() || $x -&gt; bcmp(0) == $y -&gt; bcmp(0)) {
            return $x;
        } else {
            return $x -&gt; binf($y -&gt; sign());
        }
    }

    # At this point, both the numerator and denominator are finite numbers, and
    # the denominator (divisor) is non-zero.

    return $x if $x-&gt;is_zero(); # 0 / 7 = 0, mod 0

    # Compute $x - $y * floor($x/$y). This can probably be optimized by working
    # on a lower level.

    $x -&gt; bsub($x -&gt; copy() -&gt; bdiv($y) -&gt; bfloor() -&gt; bmul($y));
    return $x -&gt; round(@r);
}

##############################################################################
# bdec/binc

sub bdec {
    # decrement value (subtract 1)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;{sign} !~ /^[+-]$/; # NaN, inf, -inf

    if ($x-&gt;{sign} eq '-') {
        $x-&gt;{_n} = $LIB-&gt;_add($x-&gt;{_n}, $x-&gt;{_d}); # -5/2 =&gt; -7/2
    } else {
        if ($LIB-&gt;_acmp($x-&gt;{_n}, $x-&gt;{_d}) &lt; 0) # n &lt; d?
        {
            # 1/3 -- =&gt; -2/3
            $x-&gt;{_n} = $LIB-&gt;_sub($LIB-&gt;_copy($x-&gt;{_d}), $x-&gt;{_n});
            $x-&gt;{sign} = '-';
        } else {
            $x-&gt;{_n} = $LIB-&gt;_sub($x-&gt;{_n}, $x-&gt;{_d}); # 5/2 =&gt; 3/2
        }
    }
    $x-&gt;bnorm()-&gt;round(@r);
}

sub binc {
    # increment value (add 1)
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x if $x-&gt;{sign} !~ /^[+-]$/; # NaN, inf, -inf

    if ($x-&gt;{sign} eq '-') {
        if ($LIB-&gt;_acmp($x-&gt;{_n}, $x-&gt;{_d}) &lt; 0) {
            # -1/3 ++ =&gt; 2/3 (overflow at 0)
            $x-&gt;{_n} = $LIB-&gt;_sub($LIB-&gt;_copy($x-&gt;{_d}), $x-&gt;{_n});
            $x-&gt;{sign} = '+';
        } else {
            $x-&gt;{_n} = $LIB-&gt;_sub($x-&gt;{_n}, $x-&gt;{_d}); # -5/2 =&gt; -3/2
        }
    } else {
        $x-&gt;{_n} = $LIB-&gt;_add($x-&gt;{_n}, $x-&gt;{_d}); # 5/2 =&gt; 7/2
    }
    $x-&gt;bnorm()-&gt;round(@r);
}

##############################################################################
# is_foo methods (the rest is inherited)

sub is_int {
    # return true if arg (BRAT or num_str) is an integer
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return 1 if ($x-&gt;{sign} =~ /^[+-]$/) &amp;&amp; # NaN and +-inf aren't
      $LIB-&gt;_is_one($x-&gt;{_d});              # x/y &amp;&amp; y != 1 =&gt; no integer
    0;
}

sub is_zero {
    # return true if arg (BRAT or num_str) is zero
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return 1 if $x-&gt;{sign} eq '+' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_n});
    0;
}

sub is_one {
    # return true if arg (BRAT or num_str) is +1 or -1 if signis given
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    croak &quot;too many arguments for is_one()&quot; if @_ &gt; 2;
    my $sign = $_[1] || '';
    $sign = '+' if $sign ne '-';
    return 1 if ($x-&gt;{sign} eq $sign &amp;&amp;
                 $LIB-&gt;_is_one($x-&gt;{_n}) &amp;&amp; $LIB-&gt;_is_one($x-&gt;{_d}));
    0;
}

sub is_odd {
    # return true if arg (BFLOAT or num_str) is odd or false if even
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return 1 if ($x-&gt;{sign} =~ /^[+-]$/) &amp;&amp;               # NaN &amp; +-inf aren't
      ($LIB-&gt;_is_one($x-&gt;{_d}) &amp;&amp; $LIB-&gt;_is_odd($x-&gt;{_n})); # x/2 is not, but 3/1
    0;
}

sub is_even {
    # return true if arg (BINT or num_str) is even or false if odd
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return 0 if $x-&gt;{sign} !~ /^[+-]$/; # NaN &amp; +-inf aren't
    return 1 if ($LIB-&gt;_is_one($x-&gt;{_d}) # x/3 is never
                 &amp;&amp; $LIB-&gt;_is_even($x-&gt;{_n})); # but 4/1 is
    0;
}

##############################################################################
# parts() and friends

sub numerator {
    my ($class, $x) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    # NaN, inf, -inf
    return Math::BigInt-&gt;new($x-&gt;{sign}) if ($x-&gt;{sign} !~ /^[+-]$/);

    my $n = Math::BigInt-&gt;new($LIB-&gt;_str($x-&gt;{_n}));
    $n-&gt;{sign} = $x-&gt;{sign};
    $n;
}

sub denominator {
    my ($class, $x) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    # NaN
    return Math::BigInt-&gt;new($x-&gt;{sign}) if $x-&gt;{sign} eq 'NaN';
    # inf, -inf
    return Math::BigInt-&gt;bone() if $x-&gt;{sign} !~ /^[+-]$/;

    Math::BigInt-&gt;new($LIB-&gt;_str($x-&gt;{_d}));
}

sub parts {
    my ($class, $x) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    my $c = 'Math::BigInt';

    return ($c-&gt;bnan(), $c-&gt;bnan()) if $x-&gt;{sign} eq 'NaN';
    return ($c-&gt;binf(), $c-&gt;binf()) if $x-&gt;{sign} eq '+inf';
    return ($c-&gt;binf('-'), $c-&gt;binf()) if $x-&gt;{sign} eq '-inf';

    my $n = $c-&gt;new($LIB-&gt;_str($x-&gt;{_n}));
    $n-&gt;{sign} = $x-&gt;{sign};
    my $d = $c-&gt;new($LIB-&gt;_str($x-&gt;{_d}));
    ($n, $d);
}

sub length {
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return $nan unless $x-&gt;is_int();
    $LIB-&gt;_len($x-&gt;{_n});       # length(-123/1) =&gt; length(123)
}

sub digit {
    my ($class, $x, $n) = ref($_[0]) ? (undef, $_[0], $_[1]) : objectify(1, @_);

    return $nan unless $x-&gt;is_int();
    $LIB-&gt;_digit($x-&gt;{_n}, $n || 0); # digit(-123/1, 2) =&gt; digit(123, 2)
}

##############################################################################
# special calc routines

sub bceil {
    my ($class, $x) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    return $x if ($x-&gt;{sign} !~ /^[+-]$/ ||     # not for NaN, inf
                  $LIB-&gt;_is_one($x-&gt;{_d}));     # 22/1 =&gt; 22, 0/1 =&gt; 0

    $x-&gt;{_n} = $LIB-&gt;_div($x-&gt;{_n}, $x-&gt;{_d});  # 22/7 =&gt; 3/1 w/ truncate
    $x-&gt;{_d} = $LIB-&gt;_one();                    # d =&gt; 1
    $x-&gt;{_n} = $LIB-&gt;_inc($x-&gt;{_n}) if $x-&gt;{sign} eq '+';   # +22/7 =&gt; 4/1
    $x-&gt;{sign} = '+' if $x-&gt;{sign} eq '-' &amp;&amp; $LIB-&gt;_is_zero($x-&gt;{_n}); # -0 =&gt; 0
    $x;
}

sub bfloor {
    my ($class, $x) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    return $x if ($x-&gt;{sign} !~ /^[+-]$/ ||     # not for NaN, inf
                  $LIB-&gt;_is_one($x-&gt;{_d}));     # 22/1 =&gt; 22, 0/1 =&gt; 0

    $x-&gt;{_n} = $LIB-&gt;_div($x-&gt;{_n}, $x-&gt;{_d});  # 22/7 =&gt; 3/1 w/ truncate
    $x-&gt;{_d} = $LIB-&gt;_one();                    # d =&gt; 1
    $x-&gt;{_n} = $LIB-&gt;_inc($x-&gt;{_n}) if $x-&gt;{sign} eq '-';   # -22/7 =&gt; -4/1
    $x;
}

sub bint {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), $_[0]) : objectify(1, @_);

    return $x if ($x-&gt;{sign} !~ /^[+-]$/ ||     # +/-inf or NaN
                  $LIB -&gt; _is_one($x-&gt;{_d}));   # already an integer

    $x-&gt;{_n} = $LIB-&gt;_div($x-&gt;{_n}, $x-&gt;{_d});  # 22/7 =&gt; 3/1 w/ truncate
    $x-&gt;{_d} = $LIB-&gt;_one();                    # d =&gt; 1
    $x-&gt;{sign} = '+' if $x-&gt;{sign} eq '-' &amp;&amp; $LIB -&gt; _is_zero($x-&gt;{_n});
    return $x;
}

sub bfac {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    # if $x is not an integer
    if (($x-&gt;{sign} ne '+') || (!$LIB-&gt;_is_one($x-&gt;{_d}))) {
        return $x-&gt;bnan();
    }

    $x-&gt;{_n} = $LIB-&gt;_fac($x-&gt;{_n});
    # since _d is 1, we don't need to reduce/norm the result
    $x-&gt;round(@r);
}

sub bpow {
    # power ($x ** $y)

    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);

    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    # $x and/or $y is a NaN
    return $x-&gt;bnan() if $x-&gt;is_nan() || $y-&gt;is_nan();

    # $x and/or $y is a +/-Inf
    if ($x-&gt;is_inf(&quot;-&quot;)) {
        return $x-&gt;bzero()   if $y-&gt;is_negative();
        return $x-&gt;bnan()    if $y-&gt;is_zero();
        return $x            if $y-&gt;is_odd();
        return $x-&gt;bneg();
    } elsif ($x-&gt;is_inf(&quot;+&quot;)) {
        return $x-&gt;bzero()   if $y-&gt;is_negative();
        return $x-&gt;bnan()    if $y-&gt;is_zero();
        return $x;
    } elsif ($y-&gt;is_inf(&quot;-&quot;)) {
        return $x-&gt;bnan()    if $x -&gt; is_one(&quot;-&quot;);
        return $x-&gt;binf(&quot;+&quot;) if $x &gt; -1 &amp;&amp; $x &lt; 1;
        return $x-&gt;bone()    if $x -&gt; is_one(&quot;+&quot;);
        return $x-&gt;bzero();
    } elsif ($y-&gt;is_inf(&quot;+&quot;)) {
        return $x-&gt;bnan()    if $x -&gt; is_one(&quot;-&quot;);
        return $x-&gt;bzero()   if $x &gt; -1 &amp;&amp; $x &lt; 1;
        return $x-&gt;bone()    if $x -&gt; is_one(&quot;+&quot;);
        return $x-&gt;binf(&quot;+&quot;);
    }

    if ($x-&gt;is_zero()) {
        return $x-&gt;binf()    if $y-&gt;is_negative();
        return $x-&gt;bone(&quot;+&quot;) if $y-&gt;is_zero();
        return $x;
    } elsif ($x-&gt;is_one()) {
        return $x-&gt;round(@r) if $y-&gt;is_odd();   # x is -1, y is odd =&gt; -1
        return $x-&gt;babs()-&gt;round(@r);           # x is -1, y is even =&gt; 1
    } elsif ($y-&gt;is_zero()) {
        return $x-&gt;bone(@r);                    # x^0 and x != 0 =&gt; 1
    } elsif ($y-&gt;is_one()) {
        return $x-&gt;round(@r);                   # x^1 =&gt; x
    }

    # we don't support complex numbers, so return NaN
    return $x-&gt;bnan() if $x-&gt;is_negative() &amp;&amp; !$y-&gt;is_int();

    # (a/b)^-(c/d) = (b/a)^(c/d)
    ($x-&gt;{_n}, $x-&gt;{_d}) = ($x-&gt;{_d}, $x-&gt;{_n}) if $y-&gt;is_negative();

    unless ($LIB-&gt;_is_one($y-&gt;{_n})) {
        $x-&gt;{_n} = $LIB-&gt;_pow($x-&gt;{_n}, $y-&gt;{_n});
        $x-&gt;{_d} = $LIB-&gt;_pow($x-&gt;{_d}, $y-&gt;{_n});
        $x-&gt;{sign} = '+' if $x-&gt;{sign} eq '-' &amp;&amp; $LIB-&gt;_is_even($y-&gt;{_n});
    }

    unless ($LIB-&gt;_is_one($y-&gt;{_d})) {
        return $x-&gt;bsqrt(@r) if $LIB-&gt;_is_two($y-&gt;{_d}); # 1/2 =&gt; sqrt
        return $x-&gt;broot($LIB-&gt;_str($y-&gt;{_d}), @r);      # 1/N =&gt; root(N)
    }

    return $x-&gt;round(@r);
}

sub blog {
    # Return the logarithm of the operand. If a second operand is defined, that
    # value is used as the base, otherwise the base is assumed to be Euler's
    # constant.

    my ($class, $x, $base, @r);

    # Don't objectify the base, since an undefined base, as in $x-&gt;blog() or
    # $x-&gt;blog(undef) signals that the base is Euler's number.

    if (!ref($_[0]) &amp;&amp; $_[0] =~ /^[A-Za-z]|::/) {
        # E.g., Math::BigFloat-&gt;blog(256, 2)
        ($class, $x, $base, @r) =
          defined $_[2] ? objectify(2, @_) : objectify(1, @_);
    } else {
        # E.g., Math::BigFloat::blog(256, 2) or $x-&gt;blog(2)
        ($class, $x, $base, @r) =
          defined $_[1] ? objectify(2, @_) : objectify(1, @_);
    }

    return $x if $x-&gt;modify('blog');

    # Handle all exception cases and all trivial cases. I have used Wolfram Alpha
    # (http://www.wolframalpha.com) as the reference for these cases.

    return $x -&gt; bnan() if $x -&gt; is_nan();

    if (defined $base) {
        $base = $class -&gt; new($base) unless ref $base;
        if ($base -&gt; is_nan() || $base -&gt; is_one()) {
            return $x -&gt; bnan();
        } elsif ($base -&gt; is_inf() || $base -&gt; is_zero()) {
            return $x -&gt; bnan() if $x -&gt; is_inf() || $x -&gt; is_zero();
            return $x -&gt; bzero();
        } elsif ($base -&gt; is_negative()) {        # -inf &lt; base &lt; 0
            return $x -&gt; bzero() if $x -&gt; is_one(); #     x = 1
            return $x -&gt; bone()  if $x == $base;    #     x = base
            return $x -&gt; bnan();                    #     otherwise
        }
        return $x -&gt; bone() if $x == $base; # 0 &lt; base &amp;&amp; 0 &lt; x &lt; inf
    }

    # We now know that the base is either undefined or positive and finite.

    if ($x -&gt; is_inf()) {       # x = +/-inf
        my $sign = defined $base &amp;&amp; $base &lt; 1 ? '-' : '+';
        return $x -&gt; binf($sign);
    } elsif ($x -&gt; is_neg()) {  # -inf &lt; x &lt; 0
        return $x -&gt; bnan();
    } elsif ($x -&gt; is_one()) {  # x = 1
        return $x -&gt; bzero();
    } elsif ($x -&gt; is_zero()) { # x = 0
        my $sign = defined $base &amp;&amp; $base &lt; 1 ? '+' : '-';
        return $x -&gt; binf($sign);
    }

    # At this point we are done handling all exception cases and trivial cases.

    $base = Math::BigFloat -&gt; new($base) if defined $base;

    my $xn = Math::BigFloat -&gt; new($LIB -&gt; _str($x-&gt;{_n}));
    my $xd = Math::BigFloat -&gt; new($LIB -&gt; _str($x-&gt;{_d}));

    my $xtmp = Math::BigRat -&gt; new($xn -&gt; bdiv($xd) -&gt; blog($base, @r) -&gt; bsstr());

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};

    return $x;
}

sub bexp {
    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);

    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(1, @_);
    }

    return $x-&gt;binf(@r)  if $x-&gt;{sign} eq '+inf';
    return $x-&gt;bzero(@r) if $x-&gt;{sign} eq '-inf';

    # we need to limit the accuracy to protect against overflow
    my $fallback = 0;
    my ($scale, @params);
    ($x, @params) = $x-&gt;_find_round_parameters(@r);

    # also takes care of the &quot;error in _find_round_parameters?&quot; case
    return $x if $x-&gt;{sign} eq 'NaN';

    # no rounding at all, so must use fallback
    if (scalar @params == 0) {
        # simulate old behaviour
        $params[0] = $class-&gt;div_scale(); # and round to it as accuracy
        $params[1] = undef;              # P = undef
        $scale = $params[0]+4;           # at least four more for proper round
        $params[2] = $r[2];              # round mode by caller or undef
        $fallback = 1;                   # to clear a/p afterwards
    } else {
        # the 4 below is empirical, and there might be cases where it's not enough...
        $scale = abs($params[0] || $params[1]) + 4; # take whatever is defined
    }

    return $x-&gt;bone(@params) if $x-&gt;is_zero();

    # See the comments in Math::BigFloat on how this algorithm works.
    # Basically we calculate A and B (where B is faculty(N)) so that A/B = e

    my $x_org = $x-&gt;copy();
    if ($scale &lt;= 75) {
        # set $x directly from a cached string form
        $x-&gt;{_n} =
          $LIB-&gt;_new(&quot;90933395208605785401971970164779391644753259799242&quot;);
        $x-&gt;{_d} =
          $LIB-&gt;_new(&quot;33452526613163807108170062053440751665152000000000&quot;);
        $x-&gt;{sign} = '+';
    } else {
        # compute A and B so that e = A / B.

        # After some terms we end up with this, so we use it as a starting point:
        my $A = $LIB-&gt;_new(&quot;90933395208605785401971970164779391644753259799242&quot;);
        my $F = $LIB-&gt;_new(42); my $step = 42;

        # Compute how many steps we need to take to get $A and $B sufficiently big
        my $steps = Math::BigFloat::_len_to_steps($scale - 4);
        #    print STDERR &quot;# Doing $steps steps for &quot;, $scale-4, &quot; digits\n&quot;;
        while ($step++ &lt;= $steps) {
            # calculate $a * $f + 1
            $A = $LIB-&gt;_mul($A, $F);
            $A = $LIB-&gt;_inc($A);
            # increment f
            $F = $LIB-&gt;_inc($F);
        }
        # compute $B as factorial of $steps (this is faster than doing it manually)
        my $B = $LIB-&gt;_fac($LIB-&gt;_new($steps));

        #  print &quot;A &quot;, $LIB-&gt;_str($A), &quot;\nB &quot;, $LIB-&gt;_str($B), &quot;\n&quot;;

        $x-&gt;{_n} = $A;
        $x-&gt;{_d} = $B;
        $x-&gt;{sign} = '+';
    }

    # $x contains now an estimate of e, with some surplus digits, so we can round
    if (!$x_org-&gt;is_one()) {
        # raise $x to the wanted power and round it in one step:
        $x-&gt;bpow($x_org, @params);
    } else {
        # else just round the already computed result
        delete $x-&gt;{_a}; delete $x-&gt;{_p};
        # shortcut to not run through _find_round_parameters again
        if (defined $params[0]) {
            $x-&gt;bround($params[0], $params[2]); # then round accordingly
        } else {
            $x-&gt;bfround($params[1], $params[2]); # then round accordingly
        }
    }
    if ($fallback) {
        # clear a/p after round, since user did not request it
        delete $x-&gt;{_a}; delete $x-&gt;{_p};
    }

    $x;
}

sub bnok {
    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);

    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    my $xint = Math::BigInt -&gt; new($x -&gt; bint() -&gt; bsstr());
    my $yint = Math::BigInt -&gt; new($y -&gt; bint() -&gt; bsstr());
    $xint -&gt; bnok($yint);

    $x -&gt; {sign} = $xint -&gt; {sign};
    $x -&gt; {_n}   = $xint -&gt; {_n};
    $x -&gt; {_d}   = $xint -&gt; {_d};

    return $x;
}

sub broot {
    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    # Convert $x into a Math::BigFloat.

    my $xd   = Math::BigFloat -&gt; new($LIB -&gt; _str($x-&gt;{_d}));
    my $xflt = Math::BigFloat -&gt; new($LIB -&gt; _str($x-&gt;{_n})) -&gt; bdiv($xd);
    $xflt -&gt; {sign} = $x -&gt; {sign};

    # Convert $y into a Math::BigFloat.

    my $yd   = Math::BigFloat -&gt; new($LIB -&gt; _str($y-&gt;{_d}));
    my $yflt = Math::BigFloat -&gt; new($LIB -&gt; _str($y-&gt;{_n})) -&gt; bdiv($yd);
    $yflt -&gt; {sign} = $y -&gt; {sign};

    # Compute the root and convert back to a Math::BigRat.

    $xflt -&gt; broot($yflt, @r);
    my $xtmp = Math::BigRat -&gt; new($xflt -&gt; bsstr());

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};

    return $x;
}

sub bmodpow {
    # set up parameters
    my ($class, $x, $y, $m, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, $m, @r) = objectify(3, @_);
    }

    # Convert $x, $y, and $m into Math::BigInt objects.

    my $xint = Math::BigInt -&gt; new($x -&gt; copy() -&gt; bint());
    my $yint = Math::BigInt -&gt; new($y -&gt; copy() -&gt; bint());
    my $mint = Math::BigInt -&gt; new($m -&gt; copy() -&gt; bint());

    $xint -&gt; bmodpow($y, $m, @r);
    my $xtmp = Math::BigRat -&gt; new($xint -&gt; bsstr());

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};
    return $x;
}

sub bmodinv {
    # set up parameters
    my ($class, $x, $y, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y, @r) = objectify(2, @_);
    }

    # Convert $x and $y into Math::BigInt objects.

    my $xint = Math::BigInt -&gt; new($x -&gt; copy() -&gt; bint());
    my $yint = Math::BigInt -&gt; new($y -&gt; copy() -&gt; bint());

    $xint -&gt; bmodinv($y, @r);
    my $xtmp = Math::BigRat -&gt; new($xint -&gt; bsstr());

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};
    return $x;
}

sub bsqrt {
    my ($class, $x, @r) = ref($_[0]) ? (ref($_[0]), @_) : objectify(1, @_);

    return $x-&gt;bnan() if $x-&gt;{sign} !~ /^[+]/; # NaN, -inf or &lt; 0
    return $x if $x-&gt;{sign} eq '+inf';         # sqrt(inf) == inf
    return $x-&gt;round(@r) if $x-&gt;is_zero() || $x-&gt;is_one();

    my $n = $x -&gt; {_n};
    my $d = $x -&gt; {_d};

    # Look for an exact solution. For the numerator and the denominator, take
    # the square root and square it and see if we got the original value. If we
    # did, for both the numerator and the denominator, we have an exact
    # solution.

    {
        my $nsqrt = $LIB -&gt; _sqrt($LIB -&gt; _copy($n));
        my $n2    = $LIB -&gt; _mul($LIB -&gt; _copy($nsqrt), $nsqrt);
        if ($LIB -&gt; _acmp($n, $n2) == 0) {
            my $dsqrt = $LIB -&gt; _sqrt($LIB -&gt; _copy($d));
            my $d2    = $LIB -&gt; _mul($LIB -&gt; _copy($dsqrt), $dsqrt);
            if ($LIB -&gt; _acmp($d, $d2) == 0) {
                $x -&gt; {_n} = $nsqrt;
                $x -&gt; {_d} = $dsqrt;
                return $x-&gt;round(@r);
            }
        }
    }

    local $Math::BigFloat::upgrade   = undef;
    local $Math::BigFloat::downgrade = undef;
    local $Math::BigFloat::precision = undef;
    local $Math::BigFloat::accuracy  = undef;
    local $Math::BigInt::upgrade     = undef;
    local $Math::BigInt::precision   = undef;
    local $Math::BigInt::accuracy    = undef;

    my $xn = Math::BigFloat -&gt; new($LIB -&gt; _str($n));
    my $xd = Math::BigFloat -&gt; new($LIB -&gt; _str($d));

    my $xtmp = Math::BigRat -&gt; new($xn -&gt; bdiv($xd) -&gt; bsqrt() -&gt; bsstr());

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};

    $x-&gt;round(@r);
}

sub blsft {
    my ($class, $x, $y, $b, @r) = objectify(2, @_);

    $b = 2 if !defined $b;
    $b = $class -&gt; new($b) unless ref($b) &amp;&amp; $b -&gt; isa($class);

    return $x -&gt; bnan() if $x -&gt; is_nan() || $y -&gt; is_nan() || $b -&gt; is_nan();

    # shift by a negative amount?
    return $x -&gt; brsft($y -&gt; copy() -&gt; babs(), $b) if $y -&gt; {sign} =~ /^-/;

    $x -&gt; bmul($b -&gt; bpow($y));
}

sub brsft {
    my ($class, $x, $y, $b, @r) = objectify(2, @_);

    $b = 2 if !defined $b;
    $b = $class -&gt; new($b) unless ref($b) &amp;&amp; $b -&gt; isa($class);

    return $x -&gt; bnan() if $x -&gt; is_nan() || $y -&gt; is_nan() || $b -&gt; is_nan();

    # shift by a negative amount?
    return $x -&gt; blsft($y -&gt; copy() -&gt; babs(), $b) if $y -&gt; {sign} =~ /^-/;

    # the following call to bdiv() will return either quotient (scalar context)
    # or quotient and remainder (list context).
    $x -&gt; bdiv($b -&gt; bpow($y));
}

sub band {
    my $x     = shift;
    my $xref  = ref($x);
    my $class = $xref || $x;

    croak 'band() is an instance method, not a class method' unless $xref;
    croak 'Not enough arguments for band()' if @_ &lt; 1;

    my $y = shift;
    $y = $class -&gt; new($y) unless ref($y);

    my @r = @_;

    my $xtmp = Math::BigInt -&gt; new($x -&gt; bint());   # to Math::BigInt
    $xtmp -&gt; band($y);
    $xtmp = $class -&gt; new($xtmp);                   # back to Math::BigRat

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};

    return $x -&gt; round(@r);
}

sub bior {
    my $x     = shift;
    my $xref  = ref($x);
    my $class = $xref || $x;

    croak 'bior() is an instance method, not a class method' unless $xref;
    croak 'Not enough arguments for bior()' if @_ &lt; 1;

    my $y = shift;
    $y = $class -&gt; new($y) unless ref($y);

    my @r = @_;

    my $xtmp = Math::BigInt -&gt; new($x -&gt; bint());   # to Math::BigInt
    $xtmp -&gt; bior($y);
    $xtmp = $class -&gt; new($xtmp);                   # back to Math::BigRat

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};

    return $x -&gt; round(@r);
}

sub bxor {
    my $x     = shift;
    my $xref  = ref($x);
    my $class = $xref || $x;

    croak 'bxor() is an instance method, not a class method' unless $xref;
    croak 'Not enough arguments for bxor()' if @_ &lt; 1;

    my $y = shift;
    $y = $class -&gt; new($y) unless ref($y);

    my @r = @_;

    my $xtmp = Math::BigInt -&gt; new($x -&gt; bint());   # to Math::BigInt
    $xtmp -&gt; bxor($y);
    $xtmp = $class -&gt; new($xtmp);                   # back to Math::BigRat

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};

    return $x -&gt; round(@r);
}

sub bnot {
    my $x     = shift;
    my $xref  = ref($x);
    my $class = $xref || $x;

    croak 'bnot() is an instance method, not a class method' unless $xref;

    my @r = @_;

    my $xtmp = Math::BigInt -&gt; new($x -&gt; bint());   # to Math::BigInt
    $xtmp -&gt; bnot();
    $xtmp = $class -&gt; new($xtmp);                   # back to Math::BigRat

    $x -&gt; {sign} = $xtmp -&gt; {sign};
    $x -&gt; {_n}   = $xtmp -&gt; {_n};
    $x -&gt; {_d}   = $xtmp -&gt; {_d};

    return $x -&gt; round(@r);
}

##############################################################################
# round

sub round {
    $_[0];
}

sub bround {
    $_[0];
}

sub bfround {
    $_[0];
}

##############################################################################
# comparing

sub bcmp {
    # compare two signed numbers

    # set up parameters
    my ($class, $x, $y) = (ref($_[0]), @_);

    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y) = objectify(2, @_);
    }

    if ($x-&gt;{sign} !~ /^[+-]$/ || $y-&gt;{sign} !~ /^[+-]$/) {
        # $x is NaN and/or $y is NaN
        return undef if $x-&gt;{sign} eq $nan || $y-&gt;{sign} eq $nan;
        # $x and $y are both either +inf or -inf
        return 0     if $x-&gt;{sign} eq $y-&gt;{sign} &amp;&amp; $x-&gt;{sign} =~ /^[+-]inf$/;
        # $x = +inf and $y &lt; +inf
        return +1    if $x-&gt;{sign} eq '+inf';
        # $x = -inf and $y &gt; -inf
        return -1    if $x-&gt;{sign} eq '-inf';
        # $x &lt; +inf and $y = +inf
        return -1    if $y-&gt;{sign} eq '+inf';
        # $x &gt; -inf and $y = -inf
        return +1;
    }

    # $x &gt;= 0 and $y &lt; 0
    return  1 if $x-&gt;{sign} eq '+' &amp;&amp; $y-&gt;{sign} eq '-';
    # $x &lt; 0 and $y &gt;= 0
    return -1 if $x-&gt;{sign} eq '-' &amp;&amp; $y-&gt;{sign} eq '+';

    # At this point, we know that $x and $y have the same sign.

    # shortcut
    my $xz = $LIB-&gt;_is_zero($x-&gt;{_n});
    my $yz = $LIB-&gt;_is_zero($y-&gt;{_n});
    return  0 if $xz &amp;&amp; $yz;               # 0 &lt;=&gt; 0
    return -1 if $xz &amp;&amp; $y-&gt;{sign} eq '+'; # 0 &lt;=&gt; +y
    return  1 if $yz &amp;&amp; $x-&gt;{sign} eq '+'; # +x &lt;=&gt; 0

    my $t = $LIB-&gt;_mul($LIB-&gt;_copy($x-&gt;{_n}), $y-&gt;{_d});
    my $u = $LIB-&gt;_mul($LIB-&gt;_copy($y-&gt;{_n}), $x-&gt;{_d});

    my $cmp = $LIB-&gt;_acmp($t, $u);     # signs are equal
    $cmp = -$cmp if $x-&gt;{sign} eq '-'; # both are '-' =&gt; reverse
    $cmp;
}

sub bacmp {
    # compare two numbers (as unsigned)

    # set up parameters
    my ($class, $x, $y) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1]))) {
        ($class, $x, $y) = objectify(2, @_);
    }

    if (($x-&gt;{sign} !~ /^[+-]$/) || ($y-&gt;{sign} !~ /^[+-]$/)) {
        # handle +-inf and NaN
        return undef if (($x-&gt;{sign} eq $nan) || ($y-&gt;{sign} eq $nan));
        return 0 if $x-&gt;{sign} =~ /^[+-]inf$/ &amp;&amp; $y-&gt;{sign} =~ /^[+-]inf$/;
        return 1 if $x-&gt;{sign} =~ /^[+-]inf$/ &amp;&amp; $y-&gt;{sign} !~ /^[+-]inf$/;
        return -1;
    }

    my $t = $LIB-&gt;_mul($LIB-&gt;_copy($x-&gt;{_n}), $y-&gt;{_d});
    my $u = $LIB-&gt;_mul($LIB-&gt;_copy($y-&gt;{_n}), $x-&gt;{_d});
    $LIB-&gt;_acmp($t, $u);        # ignore signs
}

sub beq {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    croak 'beq() is an instance method, not a class method' unless $selfref;
    croak 'Wrong number of arguments for beq()' unless @_ == 1;

    my $cmp = $self -&gt; bcmp(shift);
    return defined($cmp) &amp;&amp; ! $cmp;
}

sub bne {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    croak 'bne() is an instance method, not a class method' unless $selfref;
    croak 'Wrong number of arguments for bne()' unless @_ == 1;

    my $cmp = $self -&gt; bcmp(shift);
    return defined($cmp) &amp;&amp; ! $cmp ? '' : 1;
}

sub blt {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    croak 'blt() is an instance method, not a class method' unless $selfref;
    croak 'Wrong number of arguments for blt()' unless @_ == 1;

    my $cmp = $self -&gt; bcmp(shift);
    return defined($cmp) &amp;&amp; $cmp &lt; 0;
}

sub ble {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    croak 'ble() is an instance method, not a class method' unless $selfref;
    croak 'Wrong number of arguments for ble()' unless @_ == 1;

    my $cmp = $self -&gt; bcmp(shift);
    return defined($cmp) &amp;&amp; $cmp &lt;= 0;
}

sub bgt {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    croak 'bgt() is an instance method, not a class method' unless $selfref;
    croak 'Wrong number of arguments for bgt()' unless @_ == 1;

    my $cmp = $self -&gt; bcmp(shift);
    return defined($cmp) &amp;&amp; $cmp &gt; 0;
}

sub bge {
    my $self    = shift;
    my $selfref = ref $self;
    my $class   = $selfref || $self;

    croak 'bge() is an instance method, not a class method'
        unless $selfref;
    croak 'Wrong number of arguments for bge()' unless @_ == 1;

    my $cmp = $self -&gt; bcmp(shift);
    return defined($cmp) &amp;&amp; $cmp &gt;= 0;
}

##############################################################################
# output conversion

sub numify {
    # convert 17/8 =&gt; float (aka 2.125)
    my ($self, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    # Non-finite number.

    return $x-&gt;bstr() if $x-&gt;{sign} !~ /^[+-]$/;

    # Finite number.

    my $abs = $LIB-&gt;_is_one($x-&gt;{_d})
            ? $LIB-&gt;_num($x-&gt;{_n})
            : Math::BigFloat -&gt; new($LIB-&gt;_str($x-&gt;{_n}))
                             -&gt; bdiv($LIB-&gt;_str($x-&gt;{_d}))
                             -&gt; bstr();
    return $x-&gt;{sign} eq '-' ? 0 - $abs : 0 + $abs;
}

sub as_int {
    my ($self, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    # NaN, inf etc
    return Math::BigInt-&gt;new($x-&gt;{sign}) if $x-&gt;{sign} !~ /^[+-]$/;

    my $u = Math::BigInt-&gt;bzero();
    $u-&gt;{value} = $LIB-&gt;_div($LIB-&gt;_copy($x-&gt;{_n}), $x-&gt;{_d}); # 22/7 =&gt; 3
    $u-&gt;bneg if $x-&gt;{sign} eq '-'; # no negative zero
    $u;
}

sub as_float {
    # return N/D as Math::BigFloat

    # set up parameters
    my ($class, $x, @r) = (ref($_[0]), @_);
    # objectify is costly, so avoid it
    ($class, $x, @r) = objectify(1, @_) unless ref $_[0];

    # NaN, inf etc
    return Math::BigFloat-&gt;new($x-&gt;{sign}) if $x-&gt;{sign} !~ /^[+-]$/;

    my $xd   = Math::BigFloat -&gt; new($LIB -&gt; _str($x-&gt;{_d}));
    my $xflt = Math::BigFloat -&gt; new($LIB -&gt; _str($x-&gt;{_n}));
    $xflt -&gt; {sign} = $x -&gt; {sign};
    $xflt -&gt; bdiv($xd, @r);

    return $xflt;
}

sub as_bin {
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return $x unless $x-&gt;is_int();

    my $s = $x-&gt;{sign};
    $s = '' if $s eq '+';
    $s . $LIB-&gt;_as_bin($x-&gt;{_n});
}

sub as_hex {
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return $x unless $x-&gt;is_int();

    my $s = $x-&gt;{sign}; $s = '' if $s eq '+';
    $s . $LIB-&gt;_as_hex($x-&gt;{_n});
}

sub as_oct {
    my ($class, $x) = ref($_[0]) ? (undef, $_[0]) : objectify(1, @_);

    return $x unless $x-&gt;is_int();

    my $s = $x-&gt;{sign}; $s = '' if $s eq '+';
    $s . $LIB-&gt;_as_oct($x-&gt;{_n});
}

##############################################################################

sub from_hex {
    my $class = shift;

    $class-&gt;new(@_);
}

sub from_bin {
    my $class = shift;

    $class-&gt;new(@_);
}

sub from_oct {
    my $class = shift;

    my @parts;
    for my $c (@_) {
        push @parts, Math::BigInt-&gt;from_oct($c);
    }
    $class-&gt;new (@parts);
}

##############################################################################
# import

sub import {
    my $class = shift;
    my $l = scalar @_;
    my $lib = ''; my @a;
    my $try = 'try';

    for (my $i = 0; $i &lt; $l ; $i++) {
        if ($_[$i] eq ':constant') {
            # this rest causes overlord er load to step in
            overload::constant float =&gt; sub { $class-&gt;new(shift); };
        }
        #    elsif ($_[$i] eq 'upgrade')
        #      {
        #     # this causes upgrading
        #      $upgrade = $_[$i+1];             # or undef to disable
        #      $i++;
        #      }
        elsif ($_[$i] eq 'downgrade') {
            # this causes downgrading
            $downgrade = $_[$i+1]; # or undef to disable
            $i++;
        } elsif ($_[$i] =~ /^(lib|try|only)\z/) {
            $lib = $_[$i+1] || ''; # default Calc
            $try = $1;             # lib, try or only
            $i++;
        } elsif ($_[$i] eq 'with') {
            # this argument is no longer used
            #$LIB = $_[$i+1] || 'Math::BigInt::Calc'; # default Math::BigInt::Calc
            $i++;
        } else {
            push @a, $_[$i];
        }
    }
    require Math::BigInt;

    # let use Math::BigInt lib =&gt; 'GMP'; use Math::BigRat; still have GMP
    if ($lib ne '') {
        my @c = split /\s*,\s*/, $lib;
        foreach (@c) {
            $_ =~ tr/a-zA-Z0-9://cd; # limit to sane characters
        }
        $lib = join(&quot;,&quot;, @c);
    }
    my @import = ('objectify');
    push @import, $try =&gt; $lib if $lib ne '';

    # LIB already loaded, so feed it our lib arguments
    Math::BigInt-&gt;import(@import);

    $LIB = Math::BigFloat-&gt;config(&quot;lib&quot;);

    # register us with LIB to get notified of future lib changes
    Math::BigInt::_register_callback($class, sub { $LIB = $_[0]; });

    # any non :constant stuff is handled by Exporter (loaded by parent class)
    # even if @_ is empty, to give it a chance
    $class-&gt;SUPER::import(@a);           # for subclasses
    $class-&gt;export_to_level(1, $class, @a); # need this, too
}

1;

__END__

=pod

=head1 NAME

Math::BigRat - Arbitrary big rational numbers

=head1 SYNOPSIS

    use Math::BigRat;

    my $x = Math::BigRat-&gt;new('3/7'); $x += '5/9';

    print $x-&gt;bstr(), &quot;\n&quot;;
    print $x ** 2, &quot;\n&quot;;

    my $y = Math::BigRat-&gt;new('inf');
    print &quot;$y &quot;, ($y-&gt;is_inf ? 'is' : 'is not'), &quot; infinity\n&quot;;

    my $z = Math::BigRat-&gt;new(144); $z-&gt;bsqrt();

=head1 DESCRIPTION

Math::BigRat complements Math::BigInt and Math::BigFloat by providing support
for arbitrary big rational numbers.

=head2 MATH LIBRARY

You can change the underlying module that does the low-level
math operations by using:

    use Math::BigRat try =&gt; 'GMP';

Note: This needs Math::BigInt::GMP installed.

The following would first try to find Math::BigInt::Foo, then
Math::BigInt::Bar, and when this also fails, revert to Math::BigInt::Calc:

    use Math::BigRat try =&gt; 'Foo,Math::BigInt::Bar';

If you want to get warned when the fallback occurs, replace &quot;try&quot; with &quot;lib&quot;:

    use Math::BigRat lib =&gt; 'Foo,Math::BigInt::Bar';

If you want the code to die instead, replace &quot;try&quot; with &quot;only&quot;:

    use Math::BigRat only =&gt; 'Foo,Math::BigInt::Bar';

=head1 METHODS

Any methods not listed here are derived from Math::BigFloat (or
Math::BigInt), so make sure you check these two modules for further
information.

=over

=item new()

    $x = Math::BigRat-&gt;new('1/3');

Create a new Math::BigRat object. Input can come in various forms:

    $x = Math::BigRat-&gt;new(123);                            # scalars
    $x = Math::BigRat-&gt;new('inf');                          # infinity
    $x = Math::BigRat-&gt;new('123.3');                        # float
    $x = Math::BigRat-&gt;new('1/3');                          # simple string
    $x = Math::BigRat-&gt;new('1 / 3');                        # spaced
    $x = Math::BigRat-&gt;new('1 / 0.1');                      # w/ floats
    $x = Math::BigRat-&gt;new(Math::BigInt-&gt;new(3));           # BigInt
    $x = Math::BigRat-&gt;new(Math::BigFloat-&gt;new('3.1'));     # BigFloat
    $x = Math::BigRat-&gt;new(Math::BigInt::Lite-&gt;new('2'));   # BigLite

    # You can also give D and N as different objects:
    $x = Math::BigRat-&gt;new(
            Math::BigInt-&gt;new(-123),
            Math::BigInt-&gt;new(7),
         );                      # =&gt; -123/7

=item numerator()

    $n = $x-&gt;numerator();

Returns a copy of the numerator (the part above the line) as signed BigInt.

=item denominator()

    $d = $x-&gt;denominator();

Returns a copy of the denominator (the part under the line) as positive BigInt.

=item parts()

    ($n, $d) = $x-&gt;parts();

Return a list consisting of (signed) numerator and (unsigned) denominator as
BigInts.

=item numify()

    my $y = $x-&gt;numify();

Returns the object as a scalar. This will lose some data if the object
cannot be represented by a normal Perl scalar (integer or float), so
use L&lt;/as_int()&gt; or L&lt;/as_float()&gt; instead.

This routine is automatically used whenever a scalar is required:

    my $x = Math::BigRat-&gt;new('3/1');
    @array = (0, 1, 2, 3);
    $y = $array[$x];                # set $y to 3

=item as_int()

=item as_number()

    $x = Math::BigRat-&gt;new('13/7');
    print $x-&gt;as_int(), &quot;\n&quot;;               # '1'

Returns a copy of the object as BigInt, truncated to an integer.

C&lt;as_number()&gt; is an alias for C&lt;as_int()&gt;.

=item as_float()

    $x = Math::BigRat-&gt;new('13/7');
    print $x-&gt;as_float(), &quot;\n&quot;;             # '1'

    $x = Math::BigRat-&gt;new('2/3');
    print $x-&gt;as_float(5), &quot;\n&quot;;            # '0.66667'

Returns a copy of the object as BigFloat, preserving the
accuracy as wanted, or the default of 40 digits.

This method was added in v0.22 of Math::BigRat (April 2008).

=item as_hex()

    $x = Math::BigRat-&gt;new('13');
    print $x-&gt;as_hex(), &quot;\n&quot;;               # '0xd'

Returns the BigRat as hexadecimal string. Works only for integers.

=item as_bin()

    $x = Math::BigRat-&gt;new('13');
    print $x-&gt;as_bin(), &quot;\n&quot;;               # '0x1101'

Returns the BigRat as binary string. Works only for integers.

=item as_oct()

    $x = Math::BigRat-&gt;new('13');
    print $x-&gt;as_oct(), &quot;\n&quot;;               # '015'

Returns the BigRat as octal string. Works only for integers.

=item from_hex()

    my $h = Math::BigRat-&gt;from_hex('0x10');

Create a BigRat from a hexadecimal number in string form.

=item from_oct()

    my $o = Math::BigRat-&gt;from_oct('020');

Create a BigRat from an octal number in string form.

=item from_bin()

    my $b = Math::BigRat-&gt;from_bin('0b10000000');

Create a BigRat from an binary number in string form.

=item bnan()

    $x = Math::BigRat-&gt;bnan();

Creates a new BigRat object representing NaN (Not A Number).
If used on an object, it will set it to NaN:

    $x-&gt;bnan();

=item bzero()

    $x = Math::BigRat-&gt;bzero();

Creates a new BigRat object representing zero.
If used on an object, it will set it to zero:

    $x-&gt;bzero();

=item binf()

    $x = Math::BigRat-&gt;binf($sign);

Creates a new BigRat object representing infinity. The optional argument is
either '-' or '+', indicating whether you want infinity or minus infinity.
If used on an object, it will set it to infinity:

    $x-&gt;binf();
    $x-&gt;binf('-');

=item bone()

    $x = Math::BigRat-&gt;bone($sign);

Creates a new BigRat object representing one. The optional argument is
either '-' or '+', indicating whether you want one or minus one.
If used on an object, it will set it to one:

    $x-&gt;bone();                 # +1
    $x-&gt;bone('-');              # -1

=item length()

    $len = $x-&gt;length();

Return the length of $x in digits for integer values.

=item digit()

    print Math::BigRat-&gt;new('123/1')-&gt;digit(1);     # 1
    print Math::BigRat-&gt;new('123/1')-&gt;digit(-1);    # 3

Return the N'ths digit from X when X is an integer value.

=item bnorm()

    $x-&gt;bnorm();

Reduce the number to the shortest form. This routine is called
automatically whenever it is needed.

=item bfac()

    $x-&gt;bfac();

Calculates the factorial of $x. For instance:

    print Math::BigRat-&gt;new('3/1')-&gt;bfac(), &quot;\n&quot;;   # 1*2*3
    print Math::BigRat-&gt;new('5/1')-&gt;bfac(), &quot;\n&quot;;   # 1*2*3*4*5

Works currently only for integers.

=item bround()/round()/bfround()

Are not yet implemented.

=item bmod()

    $x-&gt;bmod($y);

Returns $x modulo $y. When $x is finite, and $y is finite and non-zero, the
result is identical to the remainder after floored division (F-division). If,
in addition, both $x and $y are integers, the result is identical to the result
from Perl's % operator.

=item bmodinv()

    $x-&gt;bmodinv($mod);          # modular multiplicative inverse

Returns the multiplicative inverse of C&lt;$x&gt; modulo C&lt;$mod&gt;. If

    $y = $x -&gt; copy() -&gt; bmodinv($mod)

then C&lt;$y&gt; is the number closest to zero, and with the same sign as C&lt;$mod&gt;,
satisfying

    ($x * $y) % $mod = 1 % $mod

If C&lt;$x&gt; and C&lt;$y&gt; are non-zero, they must be relative primes, i.e.,
C&lt;bgcd($y, $mod)==1&gt;. 'C&lt;NaN&gt;' is returned when no modular multiplicative
inverse exists.

=item bmodpow()

    $num-&gt;bmodpow($exp,$mod);           # modular exponentiation
                                        # ($num**$exp % $mod)

Returns the value of C&lt;$num&gt; taken to the power C&lt;$exp&gt; in the modulus
C&lt;$mod&gt; using binary exponentiation.  C&lt;bmodpow&gt; is far superior to
writing

    $num ** $exp % $mod

because it is much faster - it reduces internal variables into
the modulus whenever possible, so it operates on smaller numbers.

C&lt;bmodpow&gt; also supports negative exponents.

    bmodpow($num, -1, $mod)

is exactly equivalent to

    bmodinv($num, $mod)

=item bneg()

    $x-&gt;bneg();

Used to negate the object in-place.

=item is_one()

    print &quot;$x is 1\n&quot; if $x-&gt;is_one();

Return true if $x is exactly one, otherwise false.

=item is_zero()

    print &quot;$x is 0\n&quot; if $x-&gt;is_zero();

Return true if $x is exactly zero, otherwise false.

=item is_pos()/is_positive()

    print &quot;$x is &gt;= 0\n&quot; if $x-&gt;is_positive();

Return true if $x is positive (greater than or equal to zero), otherwise
false. Please note that '+inf' is also positive, while 'NaN' and '-inf' aren't.

C&lt;is_positive()&gt; is an alias for C&lt;is_pos()&gt;.

=item is_neg()/is_negative()

    print &quot;$x is &lt; 0\n&quot; if $x-&gt;is_negative();

Return true if $x is negative (smaller than zero), otherwise false. Please
note that '-inf' is also negative, while 'NaN' and '+inf' aren't.

C&lt;is_negative()&gt; is an alias for C&lt;is_neg()&gt;.

=item is_int()

    print &quot;$x is an integer\n&quot; if $x-&gt;is_int();

Return true if $x has a denominator of 1 (e.g. no fraction parts), otherwise
false. Please note that '-inf', 'inf' and 'NaN' aren't integer.

=item is_odd()

    print &quot;$x is odd\n&quot; if $x-&gt;is_odd();

Return true if $x is odd, otherwise false.

=item is_even()

    print &quot;$x is even\n&quot; if $x-&gt;is_even();

Return true if $x is even, otherwise false.

=item bceil()

    $x-&gt;bceil();

Set $x to the next bigger integer value (e.g. truncate the number to integer
and then increment it by one).

=item bfloor()

    $x-&gt;bfloor();

Truncate $x to an integer value.

=item bint()

    $x-&gt;bint();

Round $x towards zero.

=item bsqrt()

    $x-&gt;bsqrt();

Calculate the square root of $x.

=item broot()

    $x-&gt;broot($n);

Calculate the N'th root of $x.

=item badd()

    $x-&gt;badd($y);

Adds $y to $x and returns the result.

=item bmul()

    $x-&gt;bmul($y);

Multiplies $y to $x and returns the result.

=item bsub()

    $x-&gt;bsub($y);

Subtracts $y from $x and returns the result.

=item bdiv()

    $q = $x-&gt;bdiv($y);
    ($q, $r) = $x-&gt;bdiv($y);

In scalar context, divides $x by $y and returns the result. In list context,
does floored division (F-division), returning an integer $q and a remainder $r
so that $x = $q * $y + $r. The remainer (modulo) is equal to what is returned
by C&lt;$x-&gt;bmod($y)&gt;.

=item bdec()

    $x-&gt;bdec();

Decrements $x by 1 and returns the result.

=item binc()

    $x-&gt;binc();

Increments $x by 1 and returns the result.

=item copy()

    my $z = $x-&gt;copy();

Makes a deep copy of the object.

Please see the documentation in L&lt;Math::BigInt&gt; for further details.

=item bstr()/bsstr()

    my $x = Math::BigRat-&gt;new('8/4');
    print $x-&gt;bstr(), &quot;\n&quot;;             # prints 1/2
    print $x-&gt;bsstr(), &quot;\n&quot;;            # prints 1/2

Return a string representing this object.

=item bcmp()

    $x-&gt;bcmp($y);

Compares $x with $y and takes the sign into account.
Returns -1, 0, 1 or undef.

=item bacmp()

    $x-&gt;bacmp($y);

Compares $x with $y while ignoring their sign. Returns -1, 0, 1 or undef.

=item beq()

    $x -&gt; beq($y);

Returns true if and only if $x is equal to $y, and false otherwise.

=item bne()

    $x -&gt; bne($y);

Returns true if and only if $x is not equal to $y, and false otherwise.

=item blt()

    $x -&gt; blt($y);

Returns true if and only if $x is equal to $y, and false otherwise.

=item ble()

    $x -&gt; ble($y);

Returns true if and only if $x is less than or equal to $y, and false
otherwise.

=item bgt()

    $x -&gt; bgt($y);

Returns true if and only if $x is greater than $y, and false otherwise.

=item bge()

    $x -&gt; bge($y);

Returns true if and only if $x is greater than or equal to $y, and false
otherwise.

=item blsft()/brsft()

Used to shift numbers left/right.

Please see the documentation in L&lt;Math::BigInt&gt; for further details.

=item band()

    $x-&gt;band($y);               # bitwise and

=item bior()

    $x-&gt;bior($y);               # bitwise inclusive or

=item bxor()

    $x-&gt;bxor($y);               # bitwise exclusive or

=item bnot()

    $x-&gt;bnot();                 # bitwise not (two's complement)

=item bpow()

    $x-&gt;bpow($y);

Compute $x ** $y.

Please see the documentation in L&lt;Math::BigInt&gt; for further details.

=item blog()

    $x-&gt;blog($base, $accuracy);         # logarithm of x to the base $base

If C&lt;$base&gt; is not defined, Euler's number (e) is used:

    print $x-&gt;blog(undef, 100);         # log(x) to 100 digits

=item bexp()

    $x-&gt;bexp($accuracy);        # calculate e ** X

Calculates two integers A and B so that A/B is equal to C&lt;e ** $x&gt;, where C&lt;e&gt; is
Euler's number.

This method was added in v0.20 of Math::BigRat (May 2007).

See also C&lt;blog()&gt;.

=item bnok()

    $x-&gt;bnok($y);               # x over y (binomial coefficient n over k)

Calculates the binomial coefficient n over k, also called the &quot;choose&quot;
function. The result is equivalent to:

    ( n )      n!
    | - |  = -------
    ( k )    k!(n-k)!

This method was added in v0.20 of Math::BigRat (May 2007).

=item config()

    Math::BigRat-&gt;config(&quot;trap_nan&quot; =&gt; 1);      # set
    $accu = Math::BigRat-&gt;config(&quot;accuracy&quot;);   # get

Set or get configuration parameter values. Read-only parameters are marked as
RO. Read-write parameters are marked as RW. The following parameters are
supported.

    Parameter       RO/RW   Description
                            Example
    ============================================================
    lib             RO      Name of the math backend library
                            Math::BigInt::Calc
    lib_version     RO      Version of the math backend library
                            0.30
    class           RO      The class of config you just called
                            Math::BigRat
    version         RO      version number of the class you used
                            0.10
    upgrade         RW      To which class numbers are upgraded
                            undef
    downgrade       RW      To which class numbers are downgraded
                            undef
    precision       RW      Global precision
                            undef
    accuracy        RW      Global accuracy
                            undef
    round_mode      RW      Global round mode
                            even
    div_scale       RW      Fallback accuracy for div, sqrt etc.
                            40
    trap_nan        RW      Trap NaNs
                            undef
    trap_inf        RW      Trap +inf/-inf
                            undef

=back

=head1 BUGS

Please report any bugs or feature requests to
C&lt;bug-math-bigrat at rt.cpan.org&gt;, or through the web interface at
L&lt;https://rt.cpan.org/Ticket/Create.html?Queue=Math-BigRat&gt;
(requires login).
We will be notified, and then you'll automatically be notified of progress on
your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc Math::BigRat

You can also look for information at:

=over 4

=item * RT: CPAN's request tracker

L&lt;https://rt.cpan.org/Public/Dist/Display.html?Name=Math-BigRat&gt;

=item * AnnoCPAN: Annotated CPAN documentation

L&lt;http://annocpan.org/dist/Math-BigRat&gt;

=item * CPAN Ratings

L&lt;http://cpanratings.perl.org/dist/Math-BigRat&gt;

=item * Search CPAN

L&lt;http://search.cpan.org/dist/Math-BigRat/&gt;

=item * CPAN Testers Matrix

L&lt;http://matrix.cpantesters.org/?dist=Math-BigRat&gt;

=item * The Bignum mailing list

=over 4

=item * Post to mailing list

C&lt;bignum at lists.scsys.co.uk&gt;

=item * View mailing list

L&lt;http://lists.scsys.co.uk/pipermail/bignum/&gt;

=item * Subscribe/Unsubscribe

L&lt;http://lists.scsys.co.uk/cgi-bin/mailman/listinfo/bignum&gt;

=back

=back

=head1 LICENSE

This program is free software; you may redistribute it and/or modify it under
the same terms as Perl itself.

=head1 SEE ALSO

L&lt;bigrat&gt;, L&lt;Math::BigFloat&gt; and L&lt;Math::BigInt&gt; as well as the backends
L&lt;Math::BigInt::FastCalc&gt;, L&lt;Math::BigInt::GMP&gt;, and L&lt;Math::BigInt::Pari&gt;.

=head1 AUTHORS

=over 4

=item *

Tels L&lt;http://bloodgate.com/&gt; 2001-2009.

=item *

Maintained by Peter John Acklam &lt;pjacklam@online.no&gt; 2011-

=back

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FMath'>Back to Directory</a>