<h2>Editing File: /usr/share/perl5/vendor_perl/MRO/Compat.pm</h2><form method='post'><textarea name='content' class='file-edit'>package MRO::Compat;
use strict;
use warnings;
require 5.006_000;

# Keep this &lt; 1.00, so people can tell the fake
#  mro.pm from the real one
our $VERSION = '0.13';

BEGIN {
    # Alias our private functions over to
    # the mro:: namespace and load
    # Class::C3 if Perl &lt; 5.9.5
    if($] &lt; 5.009_005) {
        $mro::VERSION # to fool Module::Install when generating META.yml
            = $VERSION;
        $INC{'mro.pm'} = __FILE__;
        *mro::import            = \&amp;__import;
        *mro::get_linear_isa    = \&amp;__get_linear_isa;
        *mro::set_mro           = \&amp;__set_mro;
        *mro::get_mro           = \&amp;__get_mro;
        *mro::get_isarev        = \&amp;__get_isarev;
        *mro::is_universal      = \&amp;__is_universal;
        *mro::method_changed_in = \&amp;__method_changed_in;
        *mro::invalidate_all_method_caches
                                = \&amp;__invalidate_all_method_caches;
        require Class::C3;
        if($Class::C3::XS::VERSION &amp;&amp; $Class::C3::XS::VERSION &gt; 0.03) {
            *mro::get_pkg_gen   = \&amp;__get_pkg_gen_c3xs;
        }
        else {
            *mro::get_pkg_gen   = \&amp;__get_pkg_gen_pp;
        }
    }

    # Load mro.pm and provide no-op Class::C3::.*initialize() funcs for 5.9.5+
    else {
        require mro;
        no warnings 'redefine';
        *Class::C3::initialize = sub { 1 };
        *Class::C3::reinitialize = sub { 1 };
        *Class::C3::uninitialize = sub { 1 };
    }
}

=head1 NAME

MRO::Compat - mro::* interface compatibility for Perls &lt; 5.9.5

=head1 SYNOPSIS

   package PPP;      use base qw/Exporter/;
   package X;        use base qw/PPP/;
   package Y;        use base qw/PPP/;
   package Z;        use base qw/PPP/;

   package FooClass; use base qw/X Y Z/;

   package main;
   use MRO::Compat;
   my $linear = mro::get_linear_isa('FooClass');
   print join(q{, }, @$linear);

   # Prints: FooClass, X, PPP, Exporter, Y, Z

=head1 DESCRIPTION

The &quot;mro&quot; namespace provides several utilities for dealing
with method resolution order and method caching in general
in Perl 5.9.5 and higher.

This module provides those interfaces for
earlier versions of Perl (back to 5.6.0 anyways).

It is a harmless no-op to use this module on 5.9.5+.  That
is to say, code which properly uses L&lt;MRO::Compat&gt; will work
unmodified on both older Perls and 5.9.5+.

If you're writing a piece of software that would like to use
the parts of 5.9.5+'s mro:: interfaces that are supported
here, and you want compatibility with older Perls, this
is the module for you.

Some parts of this code will work better and/or faster with
L&lt;Class::C3::XS&gt; installed (which is an optional prereq
of L&lt;Class::C3&gt;, which is in turn a prereq of this
package), but it's not a requirement.

This module never exports any functions.  All calls must
be fully qualified with the C&lt;mro::&gt; prefix.

The interface documentation here serves only as a quick
reference of what the function basically does, and what
differences between L&lt;MRO::Compat&gt; and 5.9.5+ one should
look out for.  The main docs in 5.9.5's L&lt;mro&gt; are the real
interface docs, and contain a lot of other useful information.

=head1 Functions

=head2 mro::get_linear_isa($classname[, $type])

Returns an arrayref which is the linearized &quot;ISA&quot; of the given class.
Uses whichever MRO is currently in effect for that class by default,
or the given MRO (either C&lt;c3&gt; or C&lt;dfs&gt; if specified as C&lt;$type&gt;).

The linearized ISA of a class is a single ordered list of all of the
classes that would be visited in the process of resolving a method
on the given class, starting with itself.  It does not include any
duplicate entries.

Note that C&lt;UNIVERSAL&gt; (and any members of C&lt;UNIVERSAL&gt;'s MRO) are not
part of the MRO of a class, even though all classes implicitly inherit
methods from C&lt;UNIVERSAL&gt; and its parents.

=cut

sub __get_linear_isa_dfs {
    no strict 'refs';

    my $classname = shift;

    my @lin = ($classname);
    my %stored;
    foreach my $parent (@{&quot;$classname\::ISA&quot;}) {
        my $plin = __get_linear_isa_dfs($parent);
        foreach (@$plin) {
            next if exists $stored{$_};
            push(@lin, $_);
            $stored{$_} = 1;
        }
    }
    return \@lin;
}

sub __get_linear_isa {
    my ($classname, $type) = @_;
    die &quot;mro::get_mro requires a classname&quot; if !defined $classname;

    $type ||= __get_mro($classname);
    if($type eq 'dfs') {
        return __get_linear_isa_dfs($classname);
    }
    elsif($type eq 'c3') {
        return [Class::C3::calculateMRO($classname)];
    }
    die &quot;type argument must be 'dfs' or 'c3'&quot;;
}

=head2 mro::import

This allows the C&lt;use mro 'dfs'&gt; and
C&lt;use mro 'c3'&gt; syntaxes, providing you
L&lt;use MRO::Compat&gt; first.  Please see the
L&lt;/USING C3&gt; section for additional details.

=cut

sub __import {
    if($_[1]) {
        goto &amp;Class::C3::import if $_[1] eq 'c3';
        __set_mro(scalar(caller), $_[1]);
    }
}

=head2 mro::set_mro($classname, $type)

Sets the mro of C&lt;$classname&gt; to one of the types
C&lt;dfs&gt; or C&lt;c3&gt;.  Please see the L&lt;/USING C3&gt;
section for additional details.

=cut

sub __set_mro {
    my ($classname, $type) = @_;

    if(!defined $classname || !$type) {
        die q{Usage: mro::set_mro($classname, $type)};
    }

    if($type eq 'c3') {
        eval &quot;package $classname; use Class::C3&quot;;
        die $@ if $@;
    }
    elsif($type eq 'dfs') {
        # In the dfs case, check whether we need to undo C3
        if(defined $Class::C3::MRO{$classname}) {
            Class::C3::_remove_method_dispatch_table($classname);
        }
        delete $Class::C3::MRO{$classname};
    }
    else {
        die qq{Invalid mro type &quot;$type&quot;};
    }

    return;
}

=head2 mro::get_mro($classname)

Returns the MRO of the given class (either C&lt;c3&gt; or C&lt;dfs&gt;).

It considers any Class::C3-using class to have C3 MRO
even before L&lt;Class::C3::initialize()&gt; is called.

=cut

sub __get_mro {
    my $classname = shift;
    die &quot;mro::get_mro requires a classname&quot; if !defined $classname;
    return 'c3' if exists $Class::C3::MRO{$classname};
    return 'dfs';
}

=head2 mro::get_isarev($classname)

Returns an arrayref of classes who are subclasses of the
given classname.  In other words, classes in whose @ISA
hierarchy we appear, no matter how indirectly.

This is much slower on pre-5.9.5 Perls with MRO::Compat
than it is on 5.9.5+, as it has to search the entire
package namespace.

=cut

sub __get_all_pkgs_with_isas {
    no strict 'refs';
    no warnings 'recursion';

    my @retval;

    my $search = shift;
    my $pfx;
    my $isa;
    if(defined $search) {
        $isa = \@{&quot;$search\::ISA&quot;};
        $pfx = &quot;$search\::&quot;;
    }
    else {
        $search = 'main';
        $isa = \@main::ISA;
        $pfx = '';
    }

    push(@retval, $search) if scalar(@$isa);

    foreach my $cand (keys %{&quot;$search\::&quot;}) {
        if($cand =~ s/::$//) {
            next if $cand eq $search; # skip self-reference (main?)
            push(@retval, @{__get_all_pkgs_with_isas($pfx . $cand)});
        }
    }

    return \@retval;
}

sub __get_isarev_recurse {
    no strict 'refs';

    my ($class, $all_isas, $level) = @_;

    die &quot;Recursive inheritance detected&quot; if $level &gt; 100;

    my %retval;

    foreach my $cand (@$all_isas) {
        my $found_me;
        foreach (@{&quot;$cand\::ISA&quot;}) {
            if($_ eq $class) {
                $found_me = 1;
                last;
            }
        }
        if($found_me) {
            $retval{$cand} = 1;
            map { $retval{$_} = 1 }
                @{__get_isarev_recurse($cand, $all_isas, $level+1)};
        }
    }
    return [keys %retval];
}

sub __get_isarev {
    my $classname = shift;
    die &quot;mro::get_isarev requires a classname&quot; if !defined $classname;

    __get_isarev_recurse($classname, __get_all_pkgs_with_isas(), 0);
}

=head2 mro::is_universal($classname)

Returns a boolean status indicating whether or not
the given classname is either C&lt;UNIVERSAL&gt; itself,
or one of C&lt;UNIVERSAL&gt;'s parents by C&lt;@ISA&gt; inheritance.

Any class for which this function returns true is
&quot;universal&quot; in the sense that all classes potentially
inherit methods from it.

=cut

sub __is_universal {
    my $classname = shift;
    die &quot;mro::is_universal requires a classname&quot; if !defined $classname;

    my $lin = __get_linear_isa('UNIVERSAL');
    foreach (@$lin) {
        return 1 if $classname eq $_;
    }

    return 0;
}

=head2 mro::invalidate_all_method_caches

Increments C&lt;PL_sub_generation&gt;, which invalidates method
caching in all packages.

Please note that this is rarely necessary, unless you are
dealing with a situation which is known to confuse Perl's
method caching.

=cut

sub __invalidate_all_method_caches {
    # Super secret mystery code :)
    @f845a9c1ac41be33::ISA = @f845a9c1ac41be33::ISA;
    return;
}

=head2 mro::method_changed_in($classname)

Invalidates the method cache of any classes dependent on the
given class.  In L&lt;MRO::Compat&gt; on pre-5.9.5 Perls, this is
an alias for C&lt;mro::invalidate_all_method_caches&gt; above, as
pre-5.9.5 Perls have no other way to do this.  It will still
enforce the requirement that you pass it a classname, for
compatibility.

Please note that this is rarely necessary, unless you are
dealing with a situation which is known to confuse Perl's
method caching.

=cut

sub __method_changed_in {
    my $classname = shift;
    die &quot;mro::method_changed_in requires a classname&quot; if !defined $classname;

    __invalidate_all_method_caches();
}

=head2 mro::get_pkg_gen($classname)

Returns an integer which is incremented every time a local
method of or the C&lt;@ISA&gt; of the given package changes on
Perl 5.9.5+.  On earlier Perls with this L&lt;MRO::Compat&gt; module,
it will probably increment a lot more often than necessary.

=cut

{
    my $__pkg_gen = 2;
    sub __get_pkg_gen_pp {
        my $classname = shift;
        die &quot;mro::get_pkg_gen requires a classname&quot; if !defined $classname;
        return $__pkg_gen++;
    }
}

sub __get_pkg_gen_c3xs {
    my $classname = shift;
    die &quot;mro::get_pkg_gen requires a classname&quot; if !defined $classname;

    return Class::C3::XS::_plsubgen();
}

=head1 USING C3

While this module makes the 5.9.5+ syntaxes
C&lt;use mro 'c3'&gt; and C&lt;mro::set_mro(&quot;Foo&quot;, 'c3')&gt; available
on older Perls, it does so merely by passing off the work
to L&lt;Class::C3&gt;.

It does not remove the need for you to call
C&lt;Class::C3::initialize()&gt;, C&lt;Class::C3::reinitialize()&gt;, and/or
C&lt;Class::C3::uninitialize()&gt; at the appropriate times
as documented in the L&lt;Class::C3&gt; docs.  These three functions
are always provided by L&lt;MRO::Compat&gt;, either via L&lt;Class::C3&gt;
itself on older Perls, or directly as no-ops on 5.9.5+.

=head1 SEE ALSO

L&lt;Class::C3&gt;

L&lt;mro&gt;

=head1 AUTHOR

Brandon L. Black, E&lt;lt&gt;blblack@gmail.comE&lt;gt&gt;

=head1 COPYRIGHT AND LICENSE

Copyright 2007-2008 Brandon L. Black E&lt;lt&gt;blblack@gmail.comE&lt;gt&gt;

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself. 

=cut

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FMRO'>Back to Directory</a>