<h2>Editing File: /usr/share/perl5/vendor_perl/IO/Socket/SSL/Intercept.pm</h2><form method='post'><textarea name='content' class='file-edit'>
package IO::Socket::SSL::Intercept;
use strict;
use warnings;
use Carp 'croak';
use IO::Socket::SSL::Utils;
use Net::SSLeay;

our $VERSION = '2.056';


sub new {
    my ($class,%args) = @_;

    my $cacert = delete $args{proxy_cert};
    if ( ! $cacert ) {
	if ( my $f = delete $args{proxy_cert_file} ) {
	    $cacert = PEM_file2cert($f);
	} else {
	    croak &quot;no proxy_cert or proxy_cert_file given&quot;;
	}
    }

    my $cakey  = delete $args{proxy_key};
    if ( ! $cakey ) {
	if ( my $f = delete $args{proxy_key_file} ) {
	    $cakey = PEM_file2key($f);
	} else {
	    croak &quot;no proxy_cert or proxy_cert_file given&quot;;
	}
    }

    my $certkey = delete $args{cert_key};
    if ( ! $certkey ) {
	if ( my $f = delete $args{cert_key_file} ) {
	    $certkey = PEM_file2key($f);
	}
    }

    my $cache = delete $args{cache} || {};
    if (ref($cache) eq 'CODE') {
	# check cache type
	my $type = $cache-&gt;('type');
	if (!$type) {
	    # old cache interface - change into new interface
	    # get: $cache-&gt;(fp)
	    # set: $cache-&gt;(fp,cert,key)
	    my $oc = $cache;
	    $cache = sub {
		my ($fp,$create_cb) = @_;
		my @ck = $oc-&gt;($fp);
		$oc-&gt;($fp, @ck = &amp;$create_cb) if !@ck;
		return @ck;
	    };
	} elsif ($type == 1) {
	    # current interface:
	    # get/set: $cache-&gt;(fp,cb_create)
	} else {
	    die &quot;invalid type of cache: $type&quot;;
	}
    }

    my $self = bless {
	cacert =&gt; $cacert,
	cakey =&gt; $cakey,
	certkey =&gt; $certkey,
	cache =&gt; $cache,
	serial =&gt; delete $args{serial},
    };
    return $self;
}

sub DESTROY {
    # call various ssl _free routines
    my $self = shift or return;
    for ( \$self-&gt;{cacert}, 
	map { \$_-&gt;{cert} } ref($self-&gt;{cache}) ne 'CODE' ? values %{$self-&gt;{cache}} :()) {
	$$_ or next;
	CERT_free($$_);
	$$_ = undef;
    }
    for ( \$self-&gt;{cakey}, \$self-&gt;{pubkey} ) {
	$$_ or next;
	KEY_free($$_);
	$$_ = undef;
    }
}

sub clone_cert {
    my ($self,$old_cert,$clone_key) = @_;

    my $hash = CERT_asHash($old_cert);
    my $create_cb = sub {
	# if not in cache create new certificate based on original
	# copy most but not all extensions
	if (my $ext = $hash-&gt;{ext}) {
	    @$ext = grep {
		defined($_-&gt;{sn}) &amp;&amp; $_-&gt;{sn} !~m{^(?:
		    authorityInfoAccess    |
		    subjectKeyIdentifier   |
		    authorityKeyIdentifier |
		    certificatePolicies    |
		    crlDistributionPoints
		)$}x
	    } @$ext;
	}
	my ($clone,$key) = CERT_create(
	    %$hash,
	    issuer_cert =&gt; $self-&gt;{cacert},
	    issuer_key =&gt; $self-&gt;{cakey},
	    key =&gt; $self-&gt;{certkey},
	    serial =&gt;
		! defined($self-&gt;{serial}) ? (unpack('L',$hash-&gt;{x509_digest_sha256}))[0] :
		ref($self-&gt;{serial}) eq 'CODE' ? $self-&gt;{serial}($old_cert,$hash) :
		++$self-&gt;{serial},
	);
	return ($clone,$key);
    };

    $clone_key ||= substr(unpack(&quot;H*&quot;, $hash-&gt;{x509_digest_sha256}),0,32);
    my $c = $self-&gt;{cache};
    return $c-&gt;($clone_key,$create_cb) if ref($c) eq 'CODE';

    my $e = $c-&gt;{$clone_key} ||= do {
	my ($cert,$key) = &amp;$create_cb;
	{ cert =&gt; $cert, key =&gt; $key };
    };
    $e-&gt;{atime} = time();
    return ($e-&gt;{cert},$e-&gt;{key});
}


sub STORABLE_freeze { my $self = shift; $self-&gt;serialize() }
sub STORABLE_thaw   { my ($class,undef,$data) = @_; $class-&gt;unserialize($data) }

sub serialize {
    my $self = shift;
    my $data = pack(&quot;N&quot;,2); # version
    $data .= pack(&quot;N/a&quot;, PEM_cert2string($self-&gt;{cacert}));
    $data .= pack(&quot;N/a&quot;, PEM_key2string($self-&gt;{cakey}));
    if ( $self-&gt;{certkey} ) {
	$data .= pack(&quot;N/a&quot;, PEM_key2string($self-&gt;{certkey}));
    } else {
	$data .= pack(&quot;N/a&quot;, '');
    }
    $data .= pack(&quot;N&quot;,$self-&gt;{serial});
    if ( ref($self-&gt;{cache}) eq 'HASH' ) {
	while ( my($k,$v) = each %{ $self-&gt;{cache}} ) {
	    $data .= pack(&quot;N/aN/aN/aN&quot;, $k,
		PEM_cert2string($k-&gt;{cert}),
		$k-&gt;{key} ? PEM_key2string($k-&gt;{key}) : '',
		$k-&gt;{atime});
	}
    }
    return $data;
}

sub unserialize {
    my ($class,$data) = @_;
    unpack(&quot;N&quot;,substr($data,0,4,'')) == 2 or 
	croak(&quot;serialized with wrong version&quot;);
    ( my $cacert,my $cakey,my $certkey,my $serial,$data) 
	= unpack(&quot;N/aN/aN/aNa*&quot;,$data);
    my $self = bless {
	serial =&gt; $serial,
	cacert =&gt; PEM_string2cert($cacert),
	cakey =&gt; PEM_string2key($cakey),
	$certkey ? ( certkey =&gt; PEM_string2key($certkey)):(),
    }, ref($class)||$class;

    $self-&gt;{cache} = {} if $data ne '';
    while ( $data ne '' ) {
	(my $key,my $cert,my $certkey, my $atime,$data) = unpack(&quot;N/aN/aNa*&quot;,$data);
	$self-&gt;{cache}{$key} = { 
	    cert =&gt; PEM_string2cert($cert), 
	    $key ? ( key =&gt; PEM_string2key($certkey)):(),
	    atime =&gt; $atime 
	};
    }
    return $self;
}

1;

__END__

=head1 NAME

IO::Socket::SSL::Intercept -- SSL interception (man in the middle)

=head1 SYNOPSIS

    use IO::Socket::SSL::Intercept;
    # create interceptor with proxy certificates
    my $mitm = IO::Socket::SSL::Intercept-&gt;new(
	proxy_cert_file =&gt; 'proxy_cert.pem',
	proxy_key_file  =&gt; 'proxy_key.pem',
	...
    );
    my $listen = IO::Socket::INET-&gt;new( LocalAddr =&gt; .., Listen =&gt; .. );
    while (1) {
	# TCP accept new client
	my $client = $listen-&gt;accept or next;
	# SSL connect to server
	my $server = IO::Socket::SSL-&gt;new(
	    PeerAddr =&gt; ..,
	    SSL_verify_mode =&gt; ...,
	    ...
	) or die &quot;ssl connect failed: $!,$SSL_ERROR&quot;;
	# clone server certificate
	my ($cert,$key) = $mitm-&gt;clone_cert( $server-&gt;peer_certificate );
	# and upgrade client side to SSL with cloned certificate
	IO::Socket::SSL-&gt;start_SSL($client,
	    SSL_server =&gt; 1,
	    SSL_cert =&gt; $cert,
	    SSL_key =&gt; $key
	) or die &quot;upgrade failed: $SSL_ERROR&quot;;
	# now transfer data between $client and $server and analyze
	# the unencrypted data
	...
    }


=head1 DESCRIPTION

This module provides functionality to clone certificates and sign them with a
proxy certificate, thus making it easy to intercept SSL connections (man in the
middle). It also manages a cache of the generated certificates.

=head1 How Intercepting SSL Works

Intercepting SSL connections is useful for analyzing encrypted traffic for
security reasons or for testing. It does not break the end-to-end security of
SSL, e.g. a properly written client will notice the interception unless you
explicitly configure the client to trust your interceptor.
Intercepting SSL works the following way:

=over 4

=item *

Create a new CA certificate, which will be used to sign the cloned certificates.
This proxy CA certificate should be trusted by the client, or (a properly
written client) will throw error messages or deny the connections because it
detected a man in the middle attack.
Due to the way the interception works there no support for client side
certificates is possible.

Using openssl such a proxy CA certificate and private key can be created with:

  openssl genrsa -out proxy_key.pem 1024
  openssl req -new -x509 -extensions v3_ca -key proxy_key.pem -out proxy_cert.pem
  # export as PKCS12 for import into browser
  openssl pkcs12 -export -in proxy_cert.pem -inkey proxy_key.pem -out proxy_cert.p12

=item * 

Configure client to connect to use intercepting proxy or somehow redirect
connections from client to the proxy (e.g. packet filter redirects, ARP or DNS
spoofing etc).

=item *

Accept the TCP connection from the client, e.g. don't do any SSL handshakes with
the client yet.

=item *

Establish the SSL connection to the server and verify the servers certificate as
usually. Then create a new certificate based on the original servers
certificate, but signed by your proxy CA.
This is the step where IO::Socket::SSL::Intercept helps.

=item *

Upgrade the TCP connection to the client to SSL using the cloned certificate
from the server. If the client trusts your proxy CA it will accept the upgrade
to SSL.

=item *

Transfer data between client and server. While the connections to client and
server are both encrypted with SSL you will read/write the unencrypted data in
your proxy application.

=back

=head1 METHODS 

IO::Socket::SSL::Intercept helps creating the cloned certificate with the
following methods:

=over 4

=item B&lt;&lt; $mitm = IO::Socket::SSL::Intercept-&gt;new(%args) &gt;&gt;

This creates a new interceptor object. C&lt;%args&gt; should be

=over 8

=item proxy_cert X509 | proxy_cert_file filename

This is the proxy certificate.
It can be either given by an X509 object from L&lt;Net::SSLeay&gt;s internal
representation, or using a file in PEM format.

=item proxy_key EVP_PKEY | proxy_key_file filename

This is the key for the proxy certificate.
It can be either given by an EVP_PKEY object from L&lt;Net::SSLeay&gt;s internal
representation, or using a file in PEM format.
The key should not have a passphrase.

=item pubkey EVP_PKEY | pubkey_file filename

This optional argument specifies the public key used for the cloned certificate.
It can be either given by an EVP_PKEY object from L&lt;Net::SSLeay&gt;s internal
representation, or using a file in PEM format.
If not given it will create a new public key on each call of C&lt;new&gt;.

=item serial INTEGER|CODE

This optional argument gives the starting point for the serial numbers of the
newly created certificates. If not set the serial number will be created based
on the digest of the original certificate. If the value is code it will be
called with C&lt;&lt; serial(original_cert,CERT_asHash(original_cert)) &gt;&gt; and should
return the new serial number.

=item cache HASH | SUBROUTINE

This optional argument gives a way to cache created certificates, so that they
don't get recreated on future accesses to the same host.
If the argument ist not given an internal HASH ist used.

If the argument is a hash it will store for each generated certificate a hash
reference with C&lt;cert&gt; and C&lt;atime&gt; in the hash, where C&lt;atime&gt; is the time of
last access (to expire unused entries) and C&lt;cert&gt; is the certificate. Please
note, that the certificate is in L&lt;Net::SSLeay&gt;s internal X509 format and can
thus not be simply dumped and restored.
The key for the hash is an C&lt;ident&gt; either given to C&lt;clone_cert&gt; or generated
from the original certificate.

If the argument is a subroutine it will be called as C&lt;&lt; $cache-&gt;(ident,sub) &gt;&gt;.
This call should return either an existing (cached) C&lt;&lt; (cert,key) &gt;&gt; or
call C&lt;sub&gt; without arguments to create a new C&lt;&lt; (cert,key) &gt;&gt;, store it
and return it.
If called with C&lt;&lt; $cache-&gt;('type') &gt;&gt; the function should just return 1 to
signal that it supports the current type of cache. If it reutrns nothing
instead the older cache interface is assumed for compatibility reasons.

=back

=item B&lt;&lt; ($clone_cert,$key) = $mitm-&gt;clone_cert($original_cert,[ $ident ]) &gt;&gt;

This clones the given certificate.
An ident as the key into the cache can be given (like C&lt;host:port&gt;), if not it
will be created from the properties of the original certificate.
It returns the cloned certificate and its key (which is the same for alle
created certificates).

=item B&lt;&lt; $string = $mitm-&gt;serialize &gt;&gt;

This creates a serialized version of the object (e.g. a string) which can then
be used to persistantly store created certificates over restarts of the
application. The cache will only be serialized if it is a HASH.
To work together with L&lt;Storable&gt; the C&lt;STORABLE_freeze&gt; function is defined to
call C&lt;serialize&gt;.

=item B&lt;&lt; $mitm = IO::Socket::SSL::Intercept-&gt;unserialize($string) &gt;&gt;

This restores an Intercept object from a serialized string.
To work together with L&lt;Storable&gt; the C&lt;STORABLE_thaw&gt; function is defined to
call C&lt;unserialize&gt;.

=back

=head1 AUTHOR

Steffen Ullrich
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FIO%2FSocket%2FSSL'>Back to Directory</a>