<h2>Editing File: /usr/share/perl5/vendor_perl/HTTP/Tiny.pm</h2><form method='post'><textarea name='content' class='file-edit'># vim: ts=4 sts=4 sw=4 et:
package HTTP::Tiny;
use strict;
use warnings;
# ABSTRACT: A small, simple, correct HTTP/1.1 client

our $VERSION = '0.074';

sub _croak { require Carp; Carp::croak(@_) }

#pod =method new
#pod
#pod     $http = HTTP::Tiny-&gt;new( %attributes );
#pod
#pod This constructor returns a new HTTP::Tiny object.  Valid attributes include:
#pod
#pod =for :list
#pod * C&lt;agent&gt; — A user-agent string (defaults to 'HTTP-Tiny/$VERSION'). If
#pod   C&lt;agent&gt; — ends in a space character, the default user-agent string is
#pod   appended.
#pod * C&lt;cookie_jar&gt; — An instance of L&lt;HTTP::CookieJar&gt; — or equivalent class
#pod   that supports the C&lt;add&gt; and C&lt;cookie_header&gt; methods
#pod * C&lt;default_headers&gt; — A hashref of default headers to apply to requests
#pod * C&lt;local_address&gt; — The local IP address to bind to
#pod * C&lt;keep_alive&gt; — Whether to reuse the last connection (if for the same
#pod   scheme, host and port) (defaults to 1)
#pod * C&lt;max_redirect&gt; — Maximum number of redirects allowed (defaults to 5)
#pod * C&lt;max_size&gt; — Maximum response size in bytes (only when not using a data
#pod   callback).  If defined, responses larger than this will return an
#pod   exception.
#pod * C&lt;http_proxy&gt; — URL of a proxy server to use for HTTP connections
#pod   (default is C&lt;$ENV{http_proxy}&gt; — if set)
#pod * C&lt;https_proxy&gt; — URL of a proxy server to use for HTTPS connections
#pod   (default is C&lt;$ENV{https_proxy}&gt; — if set)
#pod * C&lt;proxy&gt; — URL of a generic proxy server for both HTTP and HTTPS
#pod   connections (default is C&lt;$ENV{all_proxy}&gt; — if set)
#pod * C&lt;no_proxy&gt; — List of domain suffixes that should not be proxied.  Must
#pod   be a comma-separated string or an array reference. (default is
#pod   C&lt;$ENV{no_proxy}&gt; —)
#pod * C&lt;timeout&gt; — Request timeout in seconds (default is 60) If a socket open,
#pod   read or write takes longer than the timeout, an exception is thrown.
#pod * C&lt;verify_SSL&gt; — A boolean that indicates whether to validate the TLS/SSL
#pod   certificate of an C&lt;https&gt; ? connection (default is true). Changed from false
#pod   to true for CVE-2023-31486.
#pod * C&lt;SSL_options&gt; — A hashref of C&lt;SSL_*&gt; — options to pass through to
#pod   L&lt;IO::Socket::SSL&gt;
#pod * C&lt;$ENV{PERL_HTTP_TINY_SSL_INSECURE_BY_DEFAULT}&gt; - Changes the default
#pod   certificate verification behavior to not check server identity if set to 1.
#pod   Only effective if C&lt;verify_SSL&gt; is not set. Added for CVE-2023-31486.
#pod
#pod Passing an explicit C&lt;undef&gt; for C&lt;proxy&gt;, C&lt;http_proxy&gt; or C&lt;https_proxy&gt; will
#pod prevent getting the corresponding proxies from the environment.
#pod
#pod Exceptions from C&lt;max_size&gt;, C&lt;timeout&gt; or other errors will result in a
#pod pseudo-HTTP status code of 599 and a reason of &quot;Internal Exception&quot;. The
#pod content field in the response will contain the text of the exception.
#pod
#pod The C&lt;keep_alive&gt; parameter enables a persistent connection, but only to a
#pod single destination scheme, host and port.  Also, if any connection-relevant
#pod attributes are modified, or if the process ID or thread ID change, the
#pod persistent connection will be dropped.  If you want persistent connections
#pod across multiple destinations, use multiple HTTP::Tiny objects.
#pod
#pod See L&lt;/SSL SUPPORT&gt; for more on the C&lt;verify_SSL&gt; and C&lt;SSL_options&gt; attributes.
#pod
#pod =cut

my @attributes;
BEGIN {
    @attributes = qw(
        cookie_jar default_headers http_proxy https_proxy keep_alive
        local_address max_redirect max_size proxy no_proxy
        SSL_options verify_SSL
    );
    my %persist_ok = map {; $_ =&gt; 1 } qw(
        cookie_jar default_headers max_redirect max_size
    );
    no strict 'refs';
    no warnings 'uninitialized';
    for my $accessor ( @attributes ) {
        *{$accessor} = sub {
            @_ &gt; 1
                ? do {
                    delete $_[0]-&gt;{handle} if !$persist_ok{$accessor} &amp;&amp; $_[1] ne $_[0]-&gt;{$accessor};
                    $_[0]-&gt;{$accessor} = $_[1]
                }
                : $_[0]-&gt;{$accessor};
        };
    }
}

sub agent {
    my($self, $agent) = @_;
    if( @_ &gt; 1 ){
        $self-&gt;{agent} =
            (defined $agent &amp;&amp; $agent =~ / $/) ? $agent . $self-&gt;_agent : $agent;
    }
    return $self-&gt;{agent};
}

sub timeout {
    my ($self, $timeout) = @_;
    if ( @_ &gt; 1 ) {
        $self-&gt;{timeout} = $timeout;
        if ($self-&gt;{handle}) {
            $self-&gt;{handle}-&gt;timeout($timeout);
        }
    }
    return $self-&gt;{timeout};
}

sub new {
    my($class, %args) = @_;

    # Support lower case verify_ssl argument, but only if verify_SSL is not
    # true.
    if ( exists $args{verify_ssl} ) {
        $args{verify_SSL}  ||= $args{verify_ssl};
    }

    my $self = {
        max_redirect =&gt; 5,
        timeout      =&gt; defined $args{timeout} ? $args{timeout} : 60,
        keep_alive   =&gt; 1,
        verify_SSL   =&gt; defined $args{verify_SSL} ? $args{verify_SSL} : _verify_SSL_default(),
        no_proxy     =&gt; $ENV{no_proxy},
    };

    bless $self, $class;

    $class-&gt;_validate_cookie_jar( $args{cookie_jar} ) if $args{cookie_jar};

    for my $key ( @attributes ) {
        $self-&gt;{$key} = $args{$key} if exists $args{$key}
    }

    $self-&gt;agent( exists $args{agent} ? $args{agent} : $class-&gt;_agent );

    $self-&gt;_set_proxies;

    return $self;
}

sub _verify_SSL_default {
    my ($self) = @_;
    # Check if insecure default certificate verification behaviour has been
    # changed by the user by setting PERL_HTTP_TINY_SSL_INSECURE_BY_DEFAULT=1
    return (($ENV{PERL_HTTP_TINY_SSL_INSECURE_BY_DEFAULT} || '') eq '1') ? 0 : 1;
}

sub _set_proxies {
    my ($self) = @_;

    # get proxies from %ENV only if not provided; explicit undef will disable
    # getting proxies from the environment

    # generic proxy
    if (! exists $self-&gt;{proxy} ) {
        $self-&gt;{proxy} = $ENV{all_proxy} || $ENV{ALL_PROXY};
    }

    if ( defined $self-&gt;{proxy} ) {
        $self-&gt;_split_proxy( 'generic proxy' =&gt; $self-&gt;{proxy} ); # validate
    }
    else {
        delete $self-&gt;{proxy};
    }

    # http proxy
    if (! exists $self-&gt;{http_proxy} ) {
        # under CGI, bypass HTTP_PROXY as request sets it from Proxy header
        local $ENV{HTTP_PROXY} if $ENV{REQUEST_METHOD};
        $self-&gt;{http_proxy} = $ENV{http_proxy} || $ENV{HTTP_PROXY} || $self-&gt;{proxy};
    }

    if ( defined $self-&gt;{http_proxy} ) {
        $self-&gt;_split_proxy( http_proxy =&gt; $self-&gt;{http_proxy} ); # validate
        $self-&gt;{_has_proxy}{http} = 1;
    }
    else {
        delete $self-&gt;{http_proxy};
    }

    # https proxy
    if (! exists $self-&gt;{https_proxy} ) {
        $self-&gt;{https_proxy} = $ENV{https_proxy} || $ENV{HTTPS_PROXY} || $self-&gt;{proxy};
    }

    if ( $self-&gt;{https_proxy} ) {
        $self-&gt;_split_proxy( https_proxy =&gt; $self-&gt;{https_proxy} ); # validate
        $self-&gt;{_has_proxy}{https} = 1;
    }
    else {
        delete $self-&gt;{https_proxy};
    }

    # Split no_proxy to array reference if not provided as such
    unless ( ref $self-&gt;{no_proxy} eq 'ARRAY' ) {
        $self-&gt;{no_proxy} =
            (defined $self-&gt;{no_proxy}) ? [ split /\s*,\s*/, $self-&gt;{no_proxy} ] : [];
    }

    return;
}

#pod =method get|head|put|post|delete
#pod
#pod     $response = $http-&gt;get($url);
#pod     $response = $http-&gt;get($url, \%options);
#pod     $response = $http-&gt;head($url);
#pod
#pod These methods are shorthand for calling C&lt;request()&gt; for the given method.  The
#pod URL must have unsafe characters escaped and international domain names encoded.
#pod See C&lt;request()&gt; for valid options and a description of the response.
#pod
#pod The C&lt;success&gt; field of the response will be true if the status code is 2XX.
#pod
#pod =cut

for my $sub_name ( qw/get head put post delete/ ) {
    my $req_method = uc $sub_name;
    no strict 'refs';
    eval &lt;&lt;&quot;HERE&quot;; ## no critic
    sub $sub_name {
        my (\$self, \$url, \$args) = \@_;
        \@_ == 2 || (\@_ == 3 &amp;&amp; ref \$args eq 'HASH')
        or _croak(q/Usage: \$http-&gt;$sub_name(URL, [HASHREF])/ . &quot;\n&quot;);
        return \$self-&gt;request('$req_method', \$url, \$args || {});
    }
HERE
}

#pod =method post_form
#pod
#pod     $response = $http-&gt;post_form($url, $form_data);
#pod     $response = $http-&gt;post_form($url, $form_data, \%options);
#pod
#pod This method executes a C&lt;POST&gt; request and sends the key/value pairs from a
#pod form data hash or array reference to the given URL with a C&lt;content-type&gt; of
#pod C&lt;application/x-www-form-urlencoded&gt;.  If data is provided as an array
#pod reference, the order is preserved; if provided as a hash reference, the terms
#pod are sorted on key and value for consistency.  See documentation for the
#pod C&lt;www_form_urlencode&gt; method for details on the encoding.
#pod
#pod The URL must have unsafe characters escaped and international domain names
#pod encoded.  See C&lt;request()&gt; for valid options and a description of the response.
#pod Any C&lt;content-type&gt; header or content in the options hashref will be ignored.
#pod
#pod The C&lt;success&gt; field of the response will be true if the status code is 2XX.
#pod
#pod =cut

sub post_form {
    my ($self, $url, $data, $args) = @_;
    (@_ == 3 || @_ == 4 &amp;&amp; ref $args eq 'HASH')
        or _croak(q/Usage: $http-&gt;post_form(URL, DATAREF, [HASHREF])/ . &quot;\n&quot;);

    my $headers = {};
    while ( my ($key, $value) = each %{$args-&gt;{headers} || {}} ) {
        $headers-&gt;{lc $key} = $value;
    }
    delete $args-&gt;{headers};

    return $self-&gt;request('POST', $url, {
            %$args,
            content =&gt; $self-&gt;www_form_urlencode($data),
            headers =&gt; {
                %$headers,
                'content-type' =&gt; 'application/x-www-form-urlencoded'
            },
        }
    );
}

#pod =method mirror
#pod
#pod     $response = $http-&gt;mirror($url, $file, \%options)
#pod     if ( $response-&gt;{success} ) {
#pod         print &quot;$file is up to date\n&quot;;
#pod     }
#pod
#pod Executes a C&lt;GET&gt; request for the URL and saves the response body to the file
#pod name provided.  The URL must have unsafe characters escaped and international
#pod domain names encoded.  If the file already exists, the request will include an
#pod C&lt;If-Modified-Since&gt; header with the modification timestamp of the file.  You
#pod may specify a different C&lt;If-Modified-Since&gt; header yourself in the C&lt;&lt;
#pod $options-&gt;{headers} &gt;&gt; hash.
#pod
#pod The C&lt;success&gt; field of the response will be true if the status code is 2XX
#pod or if the status code is 304 (unmodified).
#pod
#pod If the file was modified and the server response includes a properly
#pod formatted C&lt;Last-Modified&gt; header, the file modification time will
#pod be updated accordingly.
#pod
#pod =cut

sub mirror {
    my ($self, $url, $file, $args) = @_;
    @_ == 3 || (@_ == 4 &amp;&amp; ref $args eq 'HASH')
      or _croak(q/Usage: $http-&gt;mirror(URL, FILE, [HASHREF])/ . &quot;\n&quot;);

    if ( exists $args-&gt;{headers} ) {
        my $headers = {};
        while ( my ($key, $value) = each %{$args-&gt;{headers} || {}} ) {
            $headers-&gt;{lc $key} = $value;
        }
        $args-&gt;{headers} = $headers;
    }

    if ( -e $file and my $mtime = (stat($file))[9] ) {
        $args-&gt;{headers}{'if-modified-since'} ||= $self-&gt;_http_date($mtime);
    }
    my $tempfile = $file . int(rand(2**31));

    require Fcntl;
    sysopen my $fh, $tempfile, Fcntl::O_CREAT()|Fcntl::O_EXCL()|Fcntl::O_WRONLY()
       or _croak(qq/Error: Could not create temporary file $tempfile for downloading: $!\n/);
    binmode $fh;
    $args-&gt;{data_callback} = sub {
        print {$fh} $_[0]
        or _croak(qq/Error: Could not write into temporary file $tempfile: $!\n/);
    };
    my $response = $self-&gt;request('GET', $url, $args);
    close $fh
        or _croak(qq/Error: Caught error closing temporary file $tempfile: $!\n/);

    if ( $response-&gt;{success} ) {
        rename $tempfile, $file
            or _croak(qq/Error replacing $file with $tempfile: $!\n/);
        my $lm = $response-&gt;{headers}{'last-modified'};
        if ( $lm and my $mtime = $self-&gt;_parse_http_date($lm) ) {
            utime $mtime, $mtime, $file;
        }
    }
    $response-&gt;{success} ||= $response-&gt;{status} eq '304';
    unlink $tempfile;
    return $response;
}

#pod =method request
#pod
#pod     $response = $http-&gt;request($method, $url);
#pod     $response = $http-&gt;request($method, $url, \%options);
#pod
#pod Executes an HTTP request of the given method type ('GET', 'HEAD', 'POST',
#pod 'PUT', etc.) on the given URL.  The URL must have unsafe characters escaped and
#pod international domain names encoded.
#pod
#pod B&lt;NOTE&gt;: Method names are B&lt;case-sensitive&gt; per the HTTP/1.1 specification.
#pod Don't use C&lt;get&gt; when you really want C&lt;GET&gt;.  See L&lt;LIMITATIONS&gt; for
#pod how this applies to redirection.
#pod
#pod If the URL includes a &quot;user:password&quot; stanza, they will be used for Basic-style
#pod authorization headers.  (Authorization headers will not be included in a
#pod redirected request.) For example:
#pod
#pod     $http-&gt;request('GET', 'http://Aladdin:open sesame@example.com/');
#pod
#pod If the &quot;user:password&quot; stanza contains reserved characters, they must
#pod be percent-escaped:
#pod
#pod     $http-&gt;request('GET', 'http://john%40example.com:password@example.com/');
#pod
#pod A hashref of options may be appended to modify the request.
#pod
#pod Valid options are:
#pod
#pod =for :list
#pod * C&lt;headers&gt; —
#pod     A hashref containing headers to include with the request.  If the value for
#pod     a header is an array reference, the header will be output multiple times with
#pod     each value in the array.  These headers over-write any default headers.
#pod * C&lt;content&gt; —
#pod     A scalar to include as the body of the request OR a code reference
#pod     that will be called iteratively to produce the body of the request
#pod * C&lt;trailer_callback&gt; —
#pod     A code reference that will be called if it exists to provide a hashref
#pod     of trailing headers (only used with chunked transfer-encoding)
#pod * C&lt;data_callback&gt; —
#pod     A code reference that will be called for each chunks of the response
#pod     body received.
#pod * C&lt;peer&gt; —
#pod     Override host resolution and force all connections to go only to a
#pod     specific peer address, regardless of the URL of the request.  This will
#pod     include any redirections!  This options should be used with extreme
#pod     caution (e.g. debugging or very special circumstances).
#pod
#pod The C&lt;Host&gt; header is generated from the URL in accordance with RFC 2616.  It
#pod is a fatal error to specify C&lt;Host&gt; in the C&lt;headers&gt; option.  Other headers
#pod may be ignored or overwritten if necessary for transport compliance.
#pod
#pod If the C&lt;content&gt; option is a code reference, it will be called iteratively
#pod to provide the content body of the request.  It should return the empty
#pod string or undef when the iterator is exhausted.
#pod
#pod If the C&lt;content&gt; option is the empty string, no C&lt;content-type&gt; or
#pod C&lt;content-length&gt; headers will be generated.
#pod
#pod If the C&lt;data_callback&gt; option is provided, it will be called iteratively until
#pod the entire response body is received.  The first argument will be a string
#pod containing a chunk of the response body, the second argument will be the
#pod in-progress response hash reference, as described below.  (This allows
#pod customizing the action of the callback based on the C&lt;status&gt; or C&lt;headers&gt;
#pod received prior to the content body.)
#pod
#pod The C&lt;request&gt; method returns a hashref containing the response.  The hashref
#pod will have the following keys:
#pod
#pod =for :list
#pod * C&lt;success&gt; —
#pod     Boolean indicating whether the operation returned a 2XX status code
#pod * C&lt;url&gt; —
#pod     URL that provided the response. This is the URL of the request unless
#pod     there were redirections, in which case it is the last URL queried
#pod     in a redirection chain
#pod * C&lt;status&gt; —
#pod     The HTTP status code of the response
#pod * C&lt;reason&gt; —
#pod     The response phrase returned by the server
#pod * C&lt;content&gt; —
#pod     The body of the response.  If the response does not have any content
#pod     or if a data callback is provided to consume the response body,
#pod     this will be the empty string
#pod * C&lt;headers&gt; —
#pod     A hashref of header fields.  All header field names will be normalized
#pod     to be lower case. If a header is repeated, the value will be an arrayref;
#pod     it will otherwise be a scalar string containing the value
#pod * C&lt;protocol&gt; -
#pod     If this field exists, it is the protocol of the response
#pod     such as HTTP/1.0 or HTTP/1.1
#pod * C&lt;redirects&gt;
#pod     If this field exists, it is an arrayref of response hash references from
#pod     redirects in the same order that redirections occurred.  If it does
#pod     not exist, then no redirections occurred.
#pod
#pod On an exception during the execution of the request, the C&lt;status&gt; field will
#pod contain 599, and the C&lt;content&gt; field will contain the text of the exception.
#pod
#pod =cut

my %idempotent = map { $_ =&gt; 1 } qw/GET HEAD PUT DELETE OPTIONS TRACE/;

sub request {
    my ($self, $method, $url, $args) = @_;
    @_ == 3 || (@_ == 4 &amp;&amp; ref $args eq 'HASH')
      or _croak(q/Usage: $http-&gt;request(METHOD, URL, [HASHREF])/ . &quot;\n&quot;);
    $args ||= {}; # we keep some state in this during _request

    # RFC 2616 Section 8.1.4 mandates a single retry on broken socket
    my $response;
    for ( 0 .. 1 ) {
        $response = eval { $self-&gt;_request($method, $url, $args) };
        last unless $@ &amp;&amp; $idempotent{$method}
            &amp;&amp; $@ =~ m{^(?:Socket closed|Unexpected end)};
    }

    if (my $e = $@) {
        # maybe we got a response hash thrown from somewhere deep
        if ( ref $e eq 'HASH' &amp;&amp; exists $e-&gt;{status} ) {
            $e-&gt;{redirects} = delete $args-&gt;{_redirects} if @{ $args-&gt;{_redirects} || []};
            return $e;
        }

        # otherwise, stringify it
        $e = &quot;$e&quot;;
        $response = {
            url     =&gt; $url,
            success =&gt; q{},
            status  =&gt; 599,
            reason  =&gt; 'Internal Exception',
            content =&gt; $e,
            headers =&gt; {
                'content-type'   =&gt; 'text/plain',
                'content-length' =&gt; length $e,
            },
            ( @{$args-&gt;{_redirects} || []} ? (redirects =&gt; delete $args-&gt;{_redirects}) : () ),
        };
    }
    return $response;
}

#pod =method www_form_urlencode
#pod
#pod     $params = $http-&gt;www_form_urlencode( $data );
#pod     $response = $http-&gt;get(&quot;http://example.com/query?$params&quot;);
#pod
#pod This method converts the key/value pairs from a data hash or array reference
#pod into a C&lt;x-www-form-urlencoded&gt; string.  The keys and values from the data
#pod reference will be UTF-8 encoded and escaped per RFC 3986.  If a value is an
#pod array reference, the key will be repeated with each of the values of the array
#pod reference.  If data is provided as a hash reference, the key/value pairs in the
#pod resulting string will be sorted by key and value for consistent ordering.
#pod
#pod =cut

sub www_form_urlencode {
    my ($self, $data) = @_;
    (@_ == 2 &amp;&amp; ref $data)
        or _croak(q/Usage: $http-&gt;www_form_urlencode(DATAREF)/ . &quot;\n&quot;);
    (ref $data eq 'HASH' || ref $data eq 'ARRAY')
        or _croak(&quot;form data must be a hash or array reference\n&quot;);

    my @params = ref $data eq 'HASH' ? %$data : @$data;
    @params % 2 == 0
        or _croak(&quot;form data reference must have an even number of terms\n&quot;);

    my @terms;
    while( @params ) {
        my ($key, $value) = splice(@params, 0, 2);
        if ( ref $value eq 'ARRAY' ) {
            unshift @params, map { $key =&gt; $_ } @$value;
        }
        else {
            push @terms, join(&quot;=&quot;, map { $self-&gt;_uri_escape($_) } $key, $value);
        }
    }

    return join(&quot;&amp;&quot;, (ref $data eq 'ARRAY') ? (@terms) : (sort @terms) );
}

#pod =method can_ssl
#pod
#pod     $ok         = HTTP::Tiny-&gt;can_ssl;
#pod     ($ok, $why) = HTTP::Tiny-&gt;can_ssl;
#pod     ($ok, $why) = $http-&gt;can_ssl;
#pod
#pod Indicates if SSL support is available.  When called as a class object, it
#pod checks for the correct version of L&lt;Net::SSLeay&gt; and L&lt;IO::Socket::SSL&gt;.
#pod When called as an object methods, if C&lt;SSL_verify&gt; is true or if C&lt;SSL_verify_mode&gt;
#pod is set in C&lt;SSL_options&gt;, it checks that a CA file is available.
#pod
#pod In scalar context, returns a boolean indicating if SSL is available.
#pod In list context, returns the boolean and a (possibly multi-line) string of
#pod errors indicating why SSL isn't available.
#pod
#pod =cut

sub can_ssl {
    my ($self) = @_;

    my($ok, $reason) = (1, '');

    # Need IO::Socket::SSL 1.42 for SSL_create_ctx_callback
    local @INC = @INC;
    pop @INC if $INC[-1] eq '.';
    unless (eval {require IO::Socket::SSL; IO::Socket::SSL-&gt;VERSION(1.42)}) {
        $ok = 0;
        $reason .= qq/IO::Socket::SSL 1.42 must be installed for https support\n/;
    }

    # Need Net::SSLeay 1.49 for MODE_AUTO_RETRY
    unless (eval {require Net::SSLeay; Net::SSLeay-&gt;VERSION(1.49)}) {
        $ok = 0;
        $reason .= qq/Net::SSLeay 1.49 must be installed for https support\n/;
    }

    # If an object, check that SSL config lets us get a CA if necessary
    if ( ref($self) &amp;&amp; ( $self-&gt;{verify_SSL} || $self-&gt;{SSL_options}{SSL_verify_mode} ) ) {
        my $handle = HTTP::Tiny::Handle-&gt;new(
            SSL_options =&gt; $self-&gt;{SSL_options},
            verify_SSL  =&gt; $self-&gt;{verify_SSL},
        );
        unless ( eval { $handle-&gt;_find_CA_file; 1 } ) {
            $ok = 0;
            $reason .= &quot;$@&quot;;
        }
    }

    wantarray ? ($ok, $reason) : $ok;
}

#pod =method connected
#pod
#pod     $host = $http-&gt;connected;
#pod     ($host, $port) = $http-&gt;connected;
#pod
#pod Indicates if a connection to a peer is being kept alive, per the C&lt;keep_alive&gt;
#pod option.
#pod
#pod In scalar context, returns the peer host and port, joined with a colon, or
#pod C&lt;undef&gt; (if no peer is connected).
#pod In list context, returns the peer host and port or an empty list (if no peer
#pod is connected).
#pod
#pod B&lt;Note&gt;: This method cannot reliably be used to discover whether the remote
#pod host has closed its end of the socket.
#pod
#pod =cut

sub connected {
    my ($self) = @_;

    # If a socket exists...
    if ($self-&gt;{handle} &amp;&amp; $self-&gt;{handle}{fh}) {
        my $socket = $self-&gt;{handle}{fh};

        # ...and is connected, return the peer host and port.
        if ($socket-&gt;connected) {
            return wantarray
                ? ($socket-&gt;peerhost, $socket-&gt;peerport)
                : join(':', $socket-&gt;peerhost, $socket-&gt;peerport);
        }
    }
    return;
}

#--------------------------------------------------------------------------#
# private methods
#--------------------------------------------------------------------------#

my %DefaultPort = (
    http =&gt; 80,
    https =&gt; 443,
);

sub _agent {
    my $class = ref($_[0]) || $_[0];
    (my $default_agent = $class) =~ s{::}{-}g;
    return $default_agent . &quot;/&quot; . $class-&gt;VERSION;
}

sub _request {
    my ($self, $method, $url, $args) = @_;

    my ($scheme, $host, $port, $path_query, $auth) = $self-&gt;_split_url($url);

    my $request = {
        method    =&gt; $method,
        scheme    =&gt; $scheme,
        host      =&gt; $host,
        port      =&gt; $port,
        host_port =&gt; ($port == $DefaultPort{$scheme} ? $host : &quot;$host:$port&quot;),
        uri       =&gt; $path_query,
        headers   =&gt; {},
    };

    my $peer = $args-&gt;{peer} || $host;

    # We remove the cached handle so it is not reused in the case of redirect.
    # If all is well, it will be recached at the end of _request.  We only
    # reuse for the same scheme, host and port
    my $handle = delete $self-&gt;{handle};
    if ( $handle ) {
        unless ( $handle-&gt;can_reuse( $scheme, $host, $port, $peer ) ) {
            $handle-&gt;close;
            undef $handle;
        }
    }
    $handle ||= $self-&gt;_open_handle( $request, $scheme, $host, $port, $peer );

    $self-&gt;_prepare_headers_and_cb($request, $args, $url, $auth);
    $handle-&gt;write_request($request);

    my $response;
    do { $response = $handle-&gt;read_response_header }
        until (substr($response-&gt;{status},0,1) ne '1');

    $self-&gt;_update_cookie_jar( $url, $response ) if $self-&gt;{cookie_jar};
    my @redir_args = $self-&gt;_maybe_redirect($request, $response, $args);

    my $known_message_length;
    if ($method eq 'HEAD' || $response-&gt;{status} =~ /^[23]04/) {
        # response has no message body
        $known_message_length = 1;
    }
    else {
        # Ignore any data callbacks during redirection.
        my $cb_args = @redir_args ? +{} : $args;
        my $data_cb = $self-&gt;_prepare_data_cb($response, $cb_args);
        $known_message_length = $handle-&gt;read_body($data_cb, $response);
    }

    if ( $self-&gt;{keep_alive}
        &amp;&amp; $known_message_length
        &amp;&amp; $response-&gt;{protocol} eq 'HTTP/1.1'
        &amp;&amp; ($response-&gt;{headers}{connection} || '') ne 'close'
    ) {
        $self-&gt;{handle} = $handle;
    }
    else {
        $handle-&gt;close;
    }

    $response-&gt;{success} = substr( $response-&gt;{status}, 0, 1 ) eq '2';
    $response-&gt;{url} = $url;

    # Push the current response onto the stack of redirects if redirecting.
    if (@redir_args) {
        push @{$args-&gt;{_redirects}}, $response;
        return $self-&gt;_request(@redir_args, $args);
    }

    # Copy the stack of redirects into the response before returning.
    $response-&gt;{redirects} = delete $args-&gt;{_redirects}
      if @{$args-&gt;{_redirects}};
    return $response;
}

sub _open_handle {
    my ($self, $request, $scheme, $host, $port, $peer) = @_;

    my $handle  = HTTP::Tiny::Handle-&gt;new(
        timeout         =&gt; $self-&gt;{timeout},
        SSL_options     =&gt; $self-&gt;{SSL_options},
        verify_SSL      =&gt; $self-&gt;{verify_SSL},
        local_address   =&gt; $self-&gt;{local_address},
        keep_alive      =&gt; $self-&gt;{keep_alive}
    );

    if ($self-&gt;{_has_proxy}{$scheme} &amp;&amp; ! grep { $host =~ /\Q$_\E$/ } @{$self-&gt;{no_proxy}}) {
        return $self-&gt;_proxy_connect( $request, $handle );
    }
    else {
        return $handle-&gt;connect($scheme, $host, $port, $peer);
    }
}

sub _proxy_connect {
    my ($self, $request, $handle) = @_;

    my @proxy_vars;
    if ( $request-&gt;{scheme} eq 'https' ) {
        _croak(qq{No https_proxy defined}) unless $self-&gt;{https_proxy};
        @proxy_vars = $self-&gt;_split_proxy( https_proxy =&gt; $self-&gt;{https_proxy} );
        if ( $proxy_vars[0] eq 'https' ) {
            _croak(qq{Can't proxy https over https: $request-&gt;{uri} via $self-&gt;{https_proxy}});
        }
    }
    else {
        _croak(qq{No http_proxy defined}) unless $self-&gt;{http_proxy};
        @proxy_vars = $self-&gt;_split_proxy( http_proxy =&gt; $self-&gt;{http_proxy} );
    }

    my ($p_scheme, $p_host, $p_port, $p_auth) = @proxy_vars;

    if ( length $p_auth &amp;&amp; ! defined $request-&gt;{headers}{'proxy-authorization'} ) {
        $self-&gt;_add_basic_auth_header( $request, 'proxy-authorization' =&gt; $p_auth );
    }

    $handle-&gt;connect($p_scheme, $p_host, $p_port, $p_host);

    if ($request-&gt;{scheme} eq 'https') {
        $self-&gt;_create_proxy_tunnel( $request, $handle );
    }
    else {
        # non-tunneled proxy requires absolute URI
        $request-&gt;{uri} = &quot;$request-&gt;{scheme}://$request-&gt;{host_port}$request-&gt;{uri}&quot;;
    }

    return $handle;
}

sub _split_proxy {
    my ($self, $type, $proxy) = @_;

    my ($scheme, $host, $port, $path_query, $auth) = eval { $self-&gt;_split_url($proxy) };

    unless(
        defined($scheme) &amp;&amp; length($scheme) &amp;&amp; length($host) &amp;&amp; length($port)
        &amp;&amp; $path_query eq '/'
    ) {
        _croak(qq{$type URL must be in format http[s]://[auth@]&lt;host&gt;:&lt;port&gt;/\n});
    }

    return ($scheme, $host, $port, $auth);
}

sub _create_proxy_tunnel {
    my ($self, $request, $handle) = @_;

    $handle-&gt;_assert_ssl;

    my $agent = exists($request-&gt;{headers}{'user-agent'})
        ? $request-&gt;{headers}{'user-agent'} : $self-&gt;{agent};

    my $connect_request = {
        method    =&gt; 'CONNECT',
        uri       =&gt; &quot;$request-&gt;{host}:$request-&gt;{port}&quot;,
        headers   =&gt; {
            host =&gt; &quot;$request-&gt;{host}:$request-&gt;{port}&quot;,
            'user-agent' =&gt; $agent,
        }
    };

    if ( $request-&gt;{headers}{'proxy-authorization'} ) {
        $connect_request-&gt;{headers}{'proxy-authorization'} =
            delete $request-&gt;{headers}{'proxy-authorization'};
    }

    $handle-&gt;write_request($connect_request);
    my $response;
    do { $response = $handle-&gt;read_response_header }
        until (substr($response-&gt;{status},0,1) ne '1');

    # if CONNECT failed, throw the response so it will be
    # returned from the original request() method;
    unless (substr($response-&gt;{status},0,1) eq '2') {
        die $response;
    }

    # tunnel established, so start SSL handshake
    $handle-&gt;start_ssl( $request-&gt;{host} );

    return;
}

sub _prepare_headers_and_cb {
    my ($self, $request, $args, $url, $auth) = @_;

    for ($self-&gt;{default_headers}, $args-&gt;{headers}) {
        next unless defined;
        while (my ($k, $v) = each %$_) {
            $request-&gt;{headers}{lc $k} = $v;
            $request-&gt;{header_case}{lc $k} = $k;
        }
    }

    if (exists $request-&gt;{headers}{'host'}) {
        die(qq/The 'Host' header must not be provided as header option\n/);
    }

    $request-&gt;{headers}{'host'}         = $request-&gt;{host_port};
    $request-&gt;{headers}{'user-agent'} ||= $self-&gt;{agent};
    $request-&gt;{headers}{'connection'}   = &quot;close&quot;
        unless $self-&gt;{keep_alive};

    if ( defined $args-&gt;{content} ) {
        if (ref $args-&gt;{content} eq 'CODE') {
            $request-&gt;{headers}{'content-type'} ||= &quot;application/octet-stream&quot;;
            $request-&gt;{headers}{'transfer-encoding'} = 'chunked'
              unless $request-&gt;{headers}{'content-length'}
                  || $request-&gt;{headers}{'transfer-encoding'};
            $request-&gt;{cb} = $args-&gt;{content};
        }
        elsif ( length $args-&gt;{content} ) {
            my $content = $args-&gt;{content};
            if ( $] ge '5.008' ) {
                utf8::downgrade($content, 1)
                    or die(qq/Wide character in request message body\n/);
            }
            $request-&gt;{headers}{'content-type'} ||= &quot;application/octet-stream&quot;;
            $request-&gt;{headers}{'content-length'} = length $content
              unless $request-&gt;{headers}{'content-length'}
                  || $request-&gt;{headers}{'transfer-encoding'};
            $request-&gt;{cb} = sub { substr $content, 0, length $content, '' };
        }
        $request-&gt;{trailer_cb} = $args-&gt;{trailer_callback}
            if ref $args-&gt;{trailer_callback} eq 'CODE';
    }

    ### If we have a cookie jar, then maybe add relevant cookies
    if ( $self-&gt;{cookie_jar} ) {
        my $cookies = $self-&gt;cookie_jar-&gt;cookie_header( $url );
        $request-&gt;{headers}{cookie} = $cookies if length $cookies;
    }

    # if we have Basic auth parameters, add them
    if ( length $auth &amp;&amp; ! defined $request-&gt;{headers}{authorization} ) {
        $self-&gt;_add_basic_auth_header( $request, 'authorization' =&gt; $auth );
    }

    return;
}

sub _add_basic_auth_header {
    my ($self, $request, $header, $auth) = @_;
    require MIME::Base64;
    $request-&gt;{headers}{$header} =
        &quot;Basic &quot; . MIME::Base64::encode_base64($auth, &quot;&quot;);
    return;
}

sub _prepare_data_cb {
    my ($self, $response, $args) = @_;
    my $data_cb = $args-&gt;{data_callback};
    $response-&gt;{content} = '';

    if (!$data_cb || $response-&gt;{status} !~ /^2/) {
        if (defined $self-&gt;{max_size}) {
            $data_cb = sub {
                $_[1]-&gt;{content} .= $_[0];
                die(qq/Size of response body exceeds the maximum allowed of $self-&gt;{max_size}\n/)
                  if length $_[1]-&gt;{content} &gt; $self-&gt;{max_size};
            };
        }
        else {
            $data_cb = sub { $_[1]-&gt;{content} .= $_[0] };
        }
    }
    return $data_cb;
}

sub _update_cookie_jar {
    my ($self, $url, $response) = @_;

    my $cookies = $response-&gt;{headers}-&gt;{'set-cookie'};
    return unless defined $cookies;

    my @cookies = ref $cookies ? @$cookies : $cookies;

    $self-&gt;cookie_jar-&gt;add( $url, $_ ) for @cookies;

    return;
}

sub _validate_cookie_jar {
    my ($class, $jar) = @_;

    # duck typing
    for my $method ( qw/add cookie_header/ ) {
        _croak(qq/Cookie jar must provide the '$method' method\n/)
            unless ref($jar) &amp;&amp; ref($jar)-&gt;can($method);
    }

    return;
}

sub _maybe_redirect {
    my ($self, $request, $response, $args) = @_;
    my $headers = $response-&gt;{headers};
    my ($status, $method) = ($response-&gt;{status}, $request-&gt;{method});
    $args-&gt;{_redirects} ||= [];

    if (($status eq '303' or ($status =~ /^30[1278]/ &amp;&amp; $method =~ /^GET|HEAD$/))
        and $headers-&gt;{location}
        and @{$args-&gt;{_redirects}} &lt; $self-&gt;{max_redirect}
    ) {
        my $location = ($headers-&gt;{location} =~ /^\//)
            ? &quot;$request-&gt;{scheme}://$request-&gt;{host_port}$headers-&gt;{location}&quot;
            : $headers-&gt;{location} ;
        return (($status eq '303' ? 'GET' : $method), $location);
    }
    return;
}

sub _split_url {
    my $url = pop;

    # URI regex adapted from the URI module
    my ($scheme, $host, $path_query) = $url =~ m&lt;\A([^:/?#]+)://([^/?#]*)([^#]*)&gt;
      or die(qq/Cannot parse URL: '$url'\n/);

    $scheme     = lc $scheme;
    $path_query = &quot;/$path_query&quot; unless $path_query =~ m&lt;\A/&gt;;

    my $auth = '';
    if ( (my $i = index $host, '@') != -1 ) {
        # user:pass@host
        $auth = substr $host, 0, $i, ''; # take up to the @ for auth
        substr $host, 0, 1, '';          # knock the @ off the host

        # userinfo might be percent escaped, so recover real auth info
        $auth =~ s/%([0-9A-Fa-f]{2})/chr(hex($1))/eg;
    }
    my $port = $host =~ s/:(\d*)\z// &amp;&amp; length $1 ? $1
             : $scheme eq 'http'                  ? 80
             : $scheme eq 'https'                 ? 443
             : undef;

    return ($scheme, (length $host ? lc $host : &quot;localhost&quot;) , $port, $path_query, $auth);
}

# Date conversions adapted from HTTP::Date
my $DoW = &quot;Sun|Mon|Tue|Wed|Thu|Fri|Sat&quot;;
my $MoY = &quot;Jan|Feb|Mar|Apr|May|Jun|Jul|Aug|Sep|Oct|Nov|Dec&quot;;
sub _http_date {
    my ($sec, $min, $hour, $mday, $mon, $year, $wday) = gmtime($_[1]);
    return sprintf(&quot;%s, %02d %s %04d %02d:%02d:%02d GMT&quot;,
        substr($DoW,$wday*4,3),
        $mday, substr($MoY,$mon*4,3), $year+1900,
        $hour, $min, $sec
    );
}

sub _parse_http_date {
    my ($self, $str) = @_;
    require Time::Local;
    my @tl_parts;
    if ($str =~ /^[SMTWF][a-z]+, +(\d{1,2}) ($MoY) +(\d\d\d\d) +(\d\d):(\d\d):(\d\d) +GMT$/) {
        @tl_parts = ($6, $5, $4, $1, (index($MoY,$2)/4), $3);
    }
    elsif ($str =~ /^[SMTWF][a-z]+, +(\d\d)-($MoY)-(\d{2,4}) +(\d\d):(\d\d):(\d\d) +GMT$/ ) {
        @tl_parts = ($6, $5, $4, $1, (index($MoY,$2)/4), $3);
    }
    elsif ($str =~ /^[SMTWF][a-z]+ +($MoY) +(\d{1,2}) +(\d\d):(\d\d):(\d\d) +(?:[^0-9]+ +)?(\d\d\d\d)$/ ) {
        @tl_parts = ($5, $4, $3, $2, (index($MoY,$1)/4), $6);
    }
    return eval {
        my $t = @tl_parts ? Time::Local::timegm(@tl_parts) : -1;
        $t &lt; 0 ? undef : $t;
    };
}

# URI escaping adapted from URI::Escape
# c.f. http://www.w3.org/TR/html4/interact/forms.html#h-17.13.4.1
# perl 5.6 ready UTF-8 encoding adapted from JSON::PP
my %escapes = map { chr($_) =&gt; sprintf(&quot;%%%02X&quot;, $_) } 0..255;
$escapes{' '}=&quot;+&quot;;
my $unsafe_char = qr/[^A-Za-z0-9\-\._~]/;

sub _uri_escape {
    my ($self, $str) = @_;
    if ( $] ge '5.008' ) {
        utf8::encode($str);
    }
    else {
        $str = pack(&quot;U*&quot;, unpack(&quot;C*&quot;, $str)) # UTF-8 encode a byte string
            if ( length $str == do { use bytes; length $str } );
        $str = pack(&quot;C*&quot;, unpack(&quot;C*&quot;, $str)); # clear UTF-8 flag
    }
    $str =~ s/($unsafe_char)/$escapes{$1}/g;
    return $str;
}

package
    HTTP::Tiny::Handle; # hide from PAUSE/indexers
use strict;
use warnings;

use Errno      qw[EINTR EPIPE];
use IO::Socket qw[SOCK_STREAM];
use Socket     qw[SOL_SOCKET SO_KEEPALIVE];

# PERL_HTTP_TINY_IPV4_ONLY is a private environment variable to force old
# behavior if someone is unable to boostrap CPAN from a new perl install; it is
# not intended for general, per-client use and may be removed in the future
my $SOCKET_CLASS =
    $ENV{PERL_HTTP_TINY_IPV4_ONLY} ? 'IO::Socket::INET' :
    eval { require IO::Socket::IP; IO::Socket::IP-&gt;VERSION(0.25) } ? 'IO::Socket::IP' :
    'IO::Socket::INET';

sub BUFSIZE () { 32768 } ## no critic

my $Printable = sub {
    local $_ = shift;
    s/\r/\\r/g;
    s/\n/\\n/g;
    s/\t/\\t/g;
    s/([^\x20-\x7E])/sprintf('\\x%.2X', ord($1))/ge;
    $_;
};

my $Token = qr/[\x21\x23-\x27\x2A\x2B\x2D\x2E\x30-\x39\x41-\x5A\x5E-\x7A\x7C\x7E]/;
my $Field_Content = qr/[[:print:]]+ (?: [\x20\x09]+ [[:print:]]+ )*/x;

sub new {
    my ($class, %args) = @_;
    return bless {
        rbuf             =&gt; '',
        timeout          =&gt; 60,
        max_line_size    =&gt; 16384,
        max_header_lines =&gt; 64,
        verify_SSL       =&gt; HTTP::Tiny::_verify_SSL_default(),
        SSL_options      =&gt; {},
        %args
    }, $class;
}

sub timeout {
    my ($self, $timeout) = @_;
    if ( @_ &gt; 1 ) {
        $self-&gt;{timeout} = $timeout;
        if ( $self-&gt;{fh} &amp;&amp; $self-&gt;{fh}-&gt;can('timeout') ) {
            $self-&gt;{fh}-&gt;timeout($timeout);
        }
    }
    return $self-&gt;{timeout};
}

sub connect {
    @_ == 5 || die(q/Usage: $handle-&gt;connect(scheme, host, port, peer)/ . &quot;\n&quot;);
    my ($self, $scheme, $host, $port, $peer) = @_;

    if ( $scheme eq 'https' ) {
        $self-&gt;_assert_ssl;
    }
    elsif ( $scheme ne 'http' ) {
      die(qq/Unsupported URL scheme '$scheme'\n/);
    }
    $self-&gt;{fh} = $SOCKET_CLASS-&gt;new(
        PeerHost  =&gt; $peer,
        PeerPort  =&gt; $port,
        $self-&gt;{local_address} ?
            ( LocalAddr =&gt; $self-&gt;{local_address} ) : (),
        Proto     =&gt; 'tcp',
        Type      =&gt; SOCK_STREAM,
        Timeout   =&gt; $self-&gt;{timeout},
    ) or die(qq/Could not connect to '$host:$port': $@\n/);

    binmode($self-&gt;{fh})
      or die(qq/Could not binmode() socket: '$!'\n/);

    if ( $self-&gt;{keep_alive} ) {
        unless ( defined( $self-&gt;{fh}-&gt;setsockopt( SOL_SOCKET, SO_KEEPALIVE, 1 ) ) ) {
            CORE::close($self-&gt;{fh});
            die(qq/Could not set SO_KEEPALIVE on socket: '$!'\n/);
        }
    }

    $self-&gt;start_ssl($host) if $scheme eq 'https';

    $self-&gt;{scheme} = $scheme;
    $self-&gt;{host} = $host;
    $self-&gt;{peer} = $peer;
    $self-&gt;{port} = $port;
    $self-&gt;{pid} = $$;
    $self-&gt;{tid} = _get_tid();

    return $self;
}

sub start_ssl {
    my ($self, $host) = @_;

    # As this might be used via CONNECT after an SSL session
    # to a proxy, we shut down any existing SSL before attempting
    # the handshake
    if ( ref($self-&gt;{fh}) eq 'IO::Socket::SSL' ) {
        unless ( $self-&gt;{fh}-&gt;stop_SSL ) {
            my $ssl_err = IO::Socket::SSL-&gt;errstr;
            die(qq/Error halting prior SSL connection: $ssl_err/);
        }
    }

    my $ssl_args = $self-&gt;_ssl_args($host);
    IO::Socket::SSL-&gt;start_SSL(
        $self-&gt;{fh},
        %$ssl_args,
        SSL_create_ctx_callback =&gt; sub {
            my $ctx = shift;
            Net::SSLeay::CTX_set_mode($ctx, Net::SSLeay::MODE_AUTO_RETRY());
        },
    );

    unless ( ref($self-&gt;{fh}) eq 'IO::Socket::SSL' ) {
        my $ssl_err = IO::Socket::SSL-&gt;errstr;
        die(qq/SSL connection failed for $host: $ssl_err\n/);
    }
}

sub close {
    @_ == 1 || die(q/Usage: $handle-&gt;close()/ . &quot;\n&quot;);
    my ($self) = @_;
    CORE::close($self-&gt;{fh})
      or die(qq/Could not close socket: '$!'\n/);
}

sub write {
    @_ == 2 || die(q/Usage: $handle-&gt;write(buf)/ . &quot;\n&quot;);
    my ($self, $buf) = @_;

    if ( $] ge '5.008' ) {
        utf8::downgrade($buf, 1)
            or die(qq/Wide character in write()\n/);
    }

    my $len = length $buf;
    my $off = 0;

    local $SIG{PIPE} = 'IGNORE';

    while () {
        $self-&gt;can_write
          or die(qq/Timed out while waiting for socket to become ready for writing\n/);
        my $r = syswrite($self-&gt;{fh}, $buf, $len, $off);
        if (defined $r) {
            $len -= $r;
            $off += $r;
            last unless $len &gt; 0;
        }
        elsif ($! == EPIPE) {
            die(qq/Socket closed by remote server: $!\n/);
        }
        elsif ($! != EINTR) {
            if ($self-&gt;{fh}-&gt;can('errstr')){
                my $err = $self-&gt;{fh}-&gt;errstr();
                die (qq/Could not write to SSL socket: '$err'\n /);
            }
            else {
                die(qq/Could not write to socket: '$!'\n/);
            }

        }
    }
    return $off;
}

sub read {
    @_ == 2 || @_ == 3 || die(q/Usage: $handle-&gt;read(len [, allow_partial])/ . &quot;\n&quot;);
    my ($self, $len, $allow_partial) = @_;

    my $buf  = '';
    my $got = length $self-&gt;{rbuf};

    if ($got) {
        my $take = ($got &lt; $len) ? $got : $len;
        $buf  = substr($self-&gt;{rbuf}, 0, $take, '');
        $len -= $take;
    }

    while ($len &gt; 0) {
        $self-&gt;can_read
          or die(q/Timed out while waiting for socket to become ready for reading/ . &quot;\n&quot;);
        my $r = sysread($self-&gt;{fh}, $buf, $len, length $buf);
        if (defined $r) {
            last unless $r;
            $len -= $r;
        }
        elsif ($! != EINTR) {
            if ($self-&gt;{fh}-&gt;can('errstr')){
                my $err = $self-&gt;{fh}-&gt;errstr();
                die (qq/Could not read from SSL socket: '$err'\n /);
            }
            else {
                die(qq/Could not read from socket: '$!'\n/);
            }
        }
    }
    if ($len &amp;&amp; !$allow_partial) {
        die(qq/Unexpected end of stream\n/);
    }
    return $buf;
}

sub readline {
    @_ == 1 || die(q/Usage: $handle-&gt;readline()/ . &quot;\n&quot;);
    my ($self) = @_;

    while () {
        if ($self-&gt;{rbuf} =~ s/\A ([^\x0D\x0A]* \x0D?\x0A)//x) {
            return $1;
        }
        if (length $self-&gt;{rbuf} &gt;= $self-&gt;{max_line_size}) {
            die(qq/Line size exceeds the maximum allowed size of $self-&gt;{max_line_size}\n/);
        }
        $self-&gt;can_read
          or die(qq/Timed out while waiting for socket to become ready for reading\n/);
        my $r = sysread($self-&gt;{fh}, $self-&gt;{rbuf}, BUFSIZE, length $self-&gt;{rbuf});
        if (defined $r) {
            last unless $r;
        }
        elsif ($! != EINTR) {
            if ($self-&gt;{fh}-&gt;can('errstr')){
                my $err = $self-&gt;{fh}-&gt;errstr();
                die (qq/Could not read from SSL socket: '$err'\n /);
            }
            else {
                die(qq/Could not read from socket: '$!'\n/);
            }
        }
    }
    die(qq/Unexpected end of stream while looking for line\n/);
}

sub read_header_lines {
    @_ == 1 || @_ == 2 || die(q/Usage: $handle-&gt;read_header_lines([headers])/ . &quot;\n&quot;);
    my ($self, $headers) = @_;
    $headers ||= {};
    my $lines   = 0;
    my $val;

    while () {
         my $line = $self-&gt;readline;

         if (++$lines &gt;= $self-&gt;{max_header_lines}) {
             die(qq/Header lines exceeds maximum number allowed of $self-&gt;{max_header_lines}\n/);
         }
         elsif ($line =~ /\A ([^\x00-\x1F\x7F:]+) : [\x09\x20]* ([^\x0D\x0A]*)/x) {
             my ($field_name) = lc $1;
             if (exists $headers-&gt;{$field_name}) {
                 for ($headers-&gt;{$field_name}) {
                     $_ = [$_] unless ref $_ eq &quot;ARRAY&quot;;
                     push @$_, $2;
                     $val = \$_-&gt;[-1];
                 }
             }
             else {
                 $val = \($headers-&gt;{$field_name} = $2);
             }
         }
         elsif ($line =~ /\A [\x09\x20]+ ([^\x0D\x0A]*)/x) {
             $val
               or die(qq/Unexpected header continuation line\n/);
             next unless length $1;
             $$val .= ' ' if length $$val;
             $$val .= $1;
         }
         elsif ($line =~ /\A \x0D?\x0A \z/x) {
            last;
         }
         else {
            die(q/Malformed header line: / . $Printable-&gt;($line) . &quot;\n&quot;);
         }
    }
    return $headers;
}

sub write_request {
    @_ == 2 || die(q/Usage: $handle-&gt;write_request(request)/ . &quot;\n&quot;);
    my($self, $request) = @_;
    $self-&gt;write_request_header(@{$request}{qw/method uri headers header_case/});
    $self-&gt;write_body($request) if $request-&gt;{cb};
    return;
}

# Standard request header names/case from HTTP/1.1 RFCs
my @rfc_request_headers = qw(
  Accept Accept-Charset Accept-Encoding Accept-Language Authorization
  Cache-Control Connection Content-Length Expect From Host
  If-Match If-Modified-Since If-None-Match If-Range If-Unmodified-Since
  Max-Forwards Pragma Proxy-Authorization Range Referer TE Trailer
  Transfer-Encoding Upgrade User-Agent Via
);

my @other_request_headers = qw(
  Content-Encoding Content-MD5 Content-Type Cookie DNT Date Origin
  X-XSS-Protection
);

my %HeaderCase = map { lc($_) =&gt; $_ } @rfc_request_headers, @other_request_headers;

# to avoid multiple small writes and hence nagle, you can pass the method line or anything else to
# combine writes.
sub write_header_lines {
    (@_ &gt;= 2 &amp;&amp; @_ &lt;= 4 &amp;&amp; ref $_[1] eq 'HASH') || die(q/Usage: $handle-&gt;write_header_lines(headers, [header_case, prefix])/ . &quot;\n&quot;);
    my($self, $headers, $header_case, $prefix_data) = @_;
    $header_case ||= {};

    my $buf = (defined $prefix_data ? $prefix_data : '');

    # Per RFC, control fields should be listed first
    my %seen;
    for my $k ( qw/host cache-control expect max-forwards pragma range te/ ) {
        next unless exists $headers-&gt;{$k};
        $seen{$k}++;
        my $field_name = $HeaderCase{$k};
        my $v = $headers-&gt;{$k};
        for (ref $v eq 'ARRAY' ? @$v : $v) {
            $_ = '' unless defined $_;
            $buf .= &quot;$field_name: $_\x0D\x0A&quot;;
        }
    }

    # Other headers sent in arbitrary order
    while (my ($k, $v) = each %$headers) {
        my $field_name = lc $k;
        next if $seen{$field_name};
        if (exists $HeaderCase{$field_name}) {
            $field_name = $HeaderCase{$field_name};
        }
        else {
            if (exists $header_case-&gt;{$field_name}) {
                $field_name = $header_case-&gt;{$field_name};
            }
            else {
                $field_name =~ s/\b(\w)/\u$1/g;
            }
            $field_name =~ /\A $Token+ \z/xo
              or die(q/Invalid HTTP header field name: / . $Printable-&gt;($field_name) . &quot;\n&quot;);
            $HeaderCase{lc $field_name} = $field_name;
        }
        for (ref $v eq 'ARRAY' ? @$v : $v) {
            # unwrap a field value if pre-wrapped by user
            s/\x0D?\x0A\s+/ /g;
            die(qq/Invalid HTTP header field value ($field_name): / . $Printable-&gt;($_). &quot;\n&quot;)
              unless $_ eq '' || /\A $Field_Content \z/xo;
            $_ = '' unless defined $_;
            $buf .= &quot;$field_name: $_\x0D\x0A&quot;;
        }
    }
    $buf .= &quot;\x0D\x0A&quot;;
    return $self-&gt;write($buf);
}

# return value indicates whether message length was defined; this is generally
# true unless there was no content-length header and we just read until EOF.
# Other message length errors are thrown as exceptions
sub read_body {
    @_ == 3 || die(q/Usage: $handle-&gt;read_body(callback, response)/ . &quot;\n&quot;);
    my ($self, $cb, $response) = @_;
    my $te = $response-&gt;{headers}{'transfer-encoding'} || '';
    my $chunked = grep { /chunked/i } ( ref $te eq 'ARRAY' ? @$te : $te ) ;
    return $chunked
        ? $self-&gt;read_chunked_body($cb, $response)
        : $self-&gt;read_content_body($cb, $response);
}

sub write_body {
    @_ == 2 || die(q/Usage: $handle-&gt;write_body(request)/ . &quot;\n&quot;);
    my ($self, $request) = @_;
    if ($request-&gt;{headers}{'content-length'}) {
        return $self-&gt;write_content_body($request);
    }
    else {
        return $self-&gt;write_chunked_body($request);
    }
}

sub read_content_body {
    @_ == 3 || @_ == 4 || die(q/Usage: $handle-&gt;read_content_body(callback, response, [read_length])/ . &quot;\n&quot;);
    my ($self, $cb, $response, $content_length) = @_;
    $content_length ||= $response-&gt;{headers}{'content-length'};

    if ( defined $content_length ) {
        my $len = $content_length;
        while ($len &gt; 0) {
            my $read = ($len &gt; BUFSIZE) ? BUFSIZE : $len;
            $cb-&gt;($self-&gt;read($read, 0), $response);
            $len -= $read;
        }
        return length($self-&gt;{rbuf}) == 0;
    }

    my $chunk;
    $cb-&gt;($chunk, $response) while length( $chunk = $self-&gt;read(BUFSIZE, 1) );

    return;
}

sub write_content_body {
    @_ == 2 || die(q/Usage: $handle-&gt;write_content_body(request)/ . &quot;\n&quot;);
    my ($self, $request) = @_;

    my ($len, $content_length) = (0, $request-&gt;{headers}{'content-length'});
    while () {
        my $data = $request-&gt;{cb}-&gt;();

        defined $data &amp;&amp; length $data
          or last;

        if ( $] ge '5.008' ) {
            utf8::downgrade($data, 1)
                or die(qq/Wide character in write_content()\n/);
        }

        $len += $self-&gt;write($data);
    }

    $len == $content_length
      or die(qq/Content-Length mismatch (got: $len expected: $content_length)\n/);

    return $len;
}

sub read_chunked_body {
    @_ == 3 || die(q/Usage: $handle-&gt;read_chunked_body(callback, $response)/ . &quot;\n&quot;);
    my ($self, $cb, $response) = @_;

    while () {
        my $head = $self-&gt;readline;

        $head =~ /\A ([A-Fa-f0-9]+)/x
          or die(q/Malformed chunk head: / . $Printable-&gt;($head) . &quot;\n&quot;);

        my $len = hex($1)
          or last;

        $self-&gt;read_content_body($cb, $response, $len);

        $self-&gt;read(2) eq &quot;\x0D\x0A&quot;
          or die(qq/Malformed chunk: missing CRLF after chunk data\n/);
    }
    $self-&gt;read_header_lines($response-&gt;{headers});
    return 1;
}

sub write_chunked_body {
    @_ == 2 || die(q/Usage: $handle-&gt;write_chunked_body(request)/ . &quot;\n&quot;);
    my ($self, $request) = @_;

    my $len = 0;
    while () {
        my $data = $request-&gt;{cb}-&gt;();

        defined $data &amp;&amp; length $data
          or last;

        if ( $] ge '5.008' ) {
            utf8::downgrade($data, 1)
                or die(qq/Wide character in write_chunked_body()\n/);
        }

        $len += length $data;

        my $chunk  = sprintf '%X', length $data;
           $chunk .= &quot;\x0D\x0A&quot;;
           $chunk .= $data;
           $chunk .= &quot;\x0D\x0A&quot;;

        $self-&gt;write($chunk);
    }
    $self-&gt;write(&quot;0\x0D\x0A&quot;);
    if ( ref $request-&gt;{trailer_cb} eq 'CODE' ) {
        $self-&gt;write_header_lines($request-&gt;{trailer_cb}-&gt;())
    }
    else {
        $self-&gt;write(&quot;\x0D\x0A&quot;);
    }
    return $len;
}

sub read_response_header {
    @_ == 1 || die(q/Usage: $handle-&gt;read_response_header()/ . &quot;\n&quot;);
    my ($self) = @_;

    my $line = $self-&gt;readline;

    $line =~ /\A (HTTP\/(0*\d+\.0*\d+)) [\x09\x20]+ ([0-9]{3}) [\x09\x20]+ ([^\x0D\x0A]*) \x0D?\x0A/x
      or die(q/Malformed Status-Line: / . $Printable-&gt;($line). &quot;\n&quot;);

    my ($protocol, $version, $status, $reason) = ($1, $2, $3, $4);

    die (qq/Unsupported HTTP protocol: $protocol\n/)
        unless $version =~ /0*1\.0*[01]/;

    return {
        status       =&gt; $status,
        reason       =&gt; $reason,
        headers      =&gt; $self-&gt;read_header_lines,
        protocol     =&gt; $protocol,
    };
}

sub write_request_header {
    @_ == 5 || die(q/Usage: $handle-&gt;write_request_header(method, request_uri, headers, header_case)/ . &quot;\n&quot;);
    my ($self, $method, $request_uri, $headers, $header_case) = @_;

    return $self-&gt;write_header_lines($headers, $header_case, &quot;$method $request_uri HTTP/1.1\x0D\x0A&quot;);
}

sub _do_timeout {
    my ($self, $type, $timeout) = @_;
    $timeout = $self-&gt;{timeout}
        unless defined $timeout &amp;&amp; $timeout &gt;= 0;

    my $fd = fileno $self-&gt;{fh};
    defined $fd &amp;&amp; $fd &gt;= 0
      or die(qq/select(2): 'Bad file descriptor'\n/);

    my $initial = time;
    my $pending = $timeout;
    my $nfound;

    vec(my $fdset = '', $fd, 1) = 1;

    while () {
        $nfound = ($type eq 'read')
            ? select($fdset, undef, undef, $pending)
            : select(undef, $fdset, undef, $pending) ;
        if ($nfound == -1) {
            $! == EINTR
              or die(qq/select(2): '$!'\n/);
            redo if !$timeout || ($pending = $timeout - (time - $initial)) &gt; 0;
            $nfound = 0;
        }
        last;
    }
    $! = 0;
    return $nfound;
}

sub can_read {
    @_ == 1 || @_ == 2 || die(q/Usage: $handle-&gt;can_read([timeout])/ . &quot;\n&quot;);
    my $self = shift;
    if ( ref($self-&gt;{fh}) eq 'IO::Socket::SSL' ) {
        return 1 if $self-&gt;{fh}-&gt;pending;
    }
    return $self-&gt;_do_timeout('read', @_)
}

sub can_write {
    @_ == 1 || @_ == 2 || die(q/Usage: $handle-&gt;can_write([timeout])/ . &quot;\n&quot;);
    my $self = shift;
    return $self-&gt;_do_timeout('write', @_)
}

sub _assert_ssl {
    my($ok, $reason) = HTTP::Tiny-&gt;can_ssl();
    die $reason unless $ok;
}

sub can_reuse {
    my ($self,$scheme,$host,$port,$peer) = @_;
    return 0 if
        $self-&gt;{pid} != $$
        || $self-&gt;{tid} != _get_tid()
        || length($self-&gt;{rbuf})
        || $scheme ne $self-&gt;{scheme}
        || $host ne $self-&gt;{host}
        || $port ne $self-&gt;{port}
        || $peer ne $self-&gt;{peer}
        || eval { $self-&gt;can_read(0) }
        || $@ ;
        return 1;
}

# Try to find a CA bundle to validate the SSL cert,
# prefer Mozilla::CA or fallback to a system file
sub _find_CA_file {
    my $self = shift();

    my $ca_file =
      defined( $self-&gt;{SSL_options}-&gt;{SSL_ca_file} )
      ? $self-&gt;{SSL_options}-&gt;{SSL_ca_file}
      : $ENV{SSL_CERT_FILE};

    if ( defined $ca_file ) {
        unless ( -r $ca_file ) {
            die qq/SSL_ca_file '$ca_file' not found or not readable\n/;
        }
        return $ca_file;
    }

    local @INC = @INC;
    pop @INC if $INC[-1] eq '.';
    return Mozilla::CA::SSL_ca_file()
        if eval { require Mozilla::CA; 1 };

    # cert list copied from golang src/crypto/x509/root_unix.go
    foreach my $ca_bundle (
        &quot;/etc/ssl/certs/ca-certificates.crt&quot;,     # Debian/Ubuntu/Gentoo etc.
        &quot;/etc/pki/tls/certs/ca-bundle.crt&quot;,       # Fedora/RHEL
        &quot;/etc/ssl/ca-bundle.pem&quot;,                 # OpenSUSE
        &quot;/etc/openssl/certs/ca-certificates.crt&quot;, # NetBSD
        &quot;/etc/ssl/cert.pem&quot;,                      # OpenBSD
        &quot;/usr/local/share/certs/ca-root-nss.crt&quot;, # FreeBSD/DragonFly
        &quot;/etc/pki/tls/cacert.pem&quot;,                # OpenELEC
        &quot;/etc/certs/ca-certificates.crt&quot;,         # Solaris 11.2+
    ) {
        return $ca_bundle if -e $ca_bundle;
    }

    die qq/Couldn't find a CA bundle with which to verify the SSL certificate.\n/
      . qq/Try installing Mozilla::CA from CPAN\n/;
}

# for thread safety, we need to know thread id if threads are loaded
sub _get_tid {
    no warnings 'reserved'; # for 'threads'
    return threads-&gt;can(&quot;tid&quot;) ? threads-&gt;tid : 0;
}

sub _ssl_args {
    my ($self, $host) = @_;

    my %ssl_args;

    # This test reimplements IO::Socket::SSL::can_client_sni(), which wasn't
    # added until IO::Socket::SSL 1.84
    if ( Net::SSLeay::OPENSSL_VERSION_NUMBER() &gt;= 0x01000000 ) {
        $ssl_args{SSL_hostname} = $host,          # Sane SNI support
    }

    if ($self-&gt;{verify_SSL}) {
        $ssl_args{SSL_verifycn_scheme}  = 'http'; # enable CN validation
        $ssl_args{SSL_verifycn_name}    = $host;  # set validation hostname
        $ssl_args{SSL_verify_mode}      = 0x01;   # enable cert validation
        $ssl_args{SSL_ca_file}          = $self-&gt;_find_CA_file;
    }
    else {
        $ssl_args{SSL_verifycn_scheme}  = 'none'; # disable CN validation
        $ssl_args{SSL_verify_mode}      = 0x00;   # disable cert validation
    }

    # user options override settings from verify_SSL
    for my $k ( keys %{$self-&gt;{SSL_options}} ) {
        $ssl_args{$k} = $self-&gt;{SSL_options}{$k} if $k =~ m/^SSL_/;
    }

    return \%ssl_args;
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

HTTP::Tiny - A small, simple, correct HTTP/1.1 client

=head1 VERSION

version 0.074

=head1 SYNOPSIS

    use HTTP::Tiny;

    my $response = HTTP::Tiny-&gt;new-&gt;get('http://example.com/');

    die &quot;Failed!\n&quot; unless $response-&gt;{success};

    print &quot;$response-&gt;{status} $response-&gt;{reason}\n&quot;;

    while (my ($k, $v) = each %{$response-&gt;{headers}}) {
        for (ref $v eq 'ARRAY' ? @$v : $v) {
            print &quot;$k: $_\n&quot;;
        }
    }

    print $response-&gt;{content} if length $response-&gt;{content};

=head1 DESCRIPTION

This is a very simple HTTP/1.1 client, designed for doing simple
requests without the overhead of a large framework like L&lt;LWP::UserAgent&gt;.

It is more correct and more complete than L&lt;HTTP::Lite&gt;.  It supports
proxies and redirection.  It also correctly resumes after EINTR.

If L&lt;IO::Socket::IP&gt; 0.25 or later is installed, HTTP::Tiny will use it instead
of L&lt;IO::Socket::INET&gt; for transparent support for both IPv4 and IPv6.

Cookie support requires L&lt;HTTP::CookieJar&gt; or an equivalent class.

=head1 METHODS

=head2 new

    $http = HTTP::Tiny-&gt;new( %attributes );

This constructor returns a new HTTP::Tiny object.  Valid attributes include:

=over 4

=item *

C&lt;agent&gt; — A user-agent string (defaults to 'HTTP-Tiny/$VERSION'). If C&lt;agent&gt; — ends in a space character, the default user-agent string is appended.

=item *

C&lt;cookie_jar&gt; — An instance of L&lt;HTTP::CookieJar&gt; — or equivalent class that supports the C&lt;add&gt; and C&lt;cookie_header&gt; methods

=item *

C&lt;default_headers&gt; — A hashref of default headers to apply to requests

=item *

C&lt;local_address&gt; — The local IP address to bind to

=item *

C&lt;keep_alive&gt; — Whether to reuse the last connection (if for the same scheme, host and port) (defaults to 1)

=item *

C&lt;max_redirect&gt; — Maximum number of redirects allowed (defaults to 5)

=item *

C&lt;max_size&gt; — Maximum response size in bytes (only when not using a data callback).  If defined, responses larger than this will return an exception.

=item *

C&lt;http_proxy&gt; — URL of a proxy server to use for HTTP connections (default is C&lt;$ENV{http_proxy}&gt; — if set)

=item *

C&lt;https_proxy&gt; — URL of a proxy server to use for HTTPS connections (default is C&lt;$ENV{https_proxy}&gt; — if set)

=item *

C&lt;proxy&gt; — URL of a generic proxy server for both HTTP and HTTPS connections (default is C&lt;$ENV{all_proxy}&gt; — if set)

=item *

C&lt;no_proxy&gt; — List of domain suffixes that should not be proxied.  Must be a comma-separated string or an array reference. (default is C&lt;$ENV{no_proxy}&gt; —)

=item *

C&lt;timeout&gt; — Request timeout in seconds (default is 60) If a socket open, read or write takes longer than the timeout, an exception is thrown.

=item *

C&lt;verify_SSL&gt; — A boolean that indicates whether to validate the SSL certificate of an C&lt;https&gt; — connection (default is true). Changed from false to true for CVE-2023-31486.

=item *

C&lt;SSL_options&gt; — A hashref of C&lt;SSL_*&gt; — options to pass through to L&lt;IO::Socket::SSL&gt;

=item *

C&lt;$ENV{PERL_HTTP_TINY_SSL_INSECURE_BY_DEFAULT}&gt; — Changes the default certificate verification behavior to not check server identity if set to 1. Only effective if C&lt;verify_SSL&gt; is not set. Added for CVE-2023-31486.

=back

Passing an explicit C&lt;undef&gt; for C&lt;proxy&gt;, C&lt;http_proxy&gt; or C&lt;https_proxy&gt; will
prevent getting the corresponding proxies from the environment.

Exceptions from C&lt;max_size&gt;, C&lt;timeout&gt; or other errors will result in a
pseudo-HTTP status code of 599 and a reason of &quot;Internal Exception&quot;. The
content field in the response will contain the text of the exception.

The C&lt;keep_alive&gt; parameter enables a persistent connection, but only to a
single destination scheme, host and port.  Also, if any connection-relevant
attributes are modified, or if the process ID or thread ID change, the
persistent connection will be dropped.  If you want persistent connections
across multiple destinations, use multiple HTTP::Tiny objects.

See L&lt;/SSL SUPPORT&gt; for more on the C&lt;verify_SSL&gt; and C&lt;SSL_options&gt; attributes.

=head2 get|head|put|post|delete

    $response = $http-&gt;get($url);
    $response = $http-&gt;get($url, \%options);
    $response = $http-&gt;head($url);

These methods are shorthand for calling C&lt;request()&gt; for the given method.  The
URL must have unsafe characters escaped and international domain names encoded.
See C&lt;request()&gt; for valid options and a description of the response.

The C&lt;success&gt; field of the response will be true if the status code is 2XX.

=head2 post_form

    $response = $http-&gt;post_form($url, $form_data);
    $response = $http-&gt;post_form($url, $form_data, \%options);

This method executes a C&lt;POST&gt; request and sends the key/value pairs from a
form data hash or array reference to the given URL with a C&lt;content-type&gt; of
C&lt;application/x-www-form-urlencoded&gt;.  If data is provided as an array
reference, the order is preserved; if provided as a hash reference, the terms
are sorted on key and value for consistency.  See documentation for the
C&lt;www_form_urlencode&gt; method for details on the encoding.

The URL must have unsafe characters escaped and international domain names
encoded.  See C&lt;request()&gt; for valid options and a description of the response.
Any C&lt;content-type&gt; header or content in the options hashref will be ignored.

The C&lt;success&gt; field of the response will be true if the status code is 2XX.

=head2 mirror

    $response = $http-&gt;mirror($url, $file, \%options)
    if ( $response-&gt;{success} ) {
        print &quot;$file is up to date\n&quot;;
    }

Executes a C&lt;GET&gt; request for the URL and saves the response body to the file
name provided.  The URL must have unsafe characters escaped and international
domain names encoded.  If the file already exists, the request will include an
C&lt;If-Modified-Since&gt; header with the modification timestamp of the file.  You
may specify a different C&lt;If-Modified-Since&gt; header yourself in the C&lt;&lt;
$options-&gt;{headers} &gt;&gt; hash.

The C&lt;success&gt; field of the response will be true if the status code is 2XX
or if the status code is 304 (unmodified).

If the file was modified and the server response includes a properly
formatted C&lt;Last-Modified&gt; header, the file modification time will
be updated accordingly.

=head2 request

    $response = $http-&gt;request($method, $url);
    $response = $http-&gt;request($method, $url, \%options);

Executes an HTTP request of the given method type ('GET', 'HEAD', 'POST',
'PUT', etc.) on the given URL.  The URL must have unsafe characters escaped and
international domain names encoded.

B&lt;NOTE&gt;: Method names are B&lt;case-sensitive&gt; per the HTTP/1.1 specification.
Don't use C&lt;get&gt; when you really want C&lt;GET&gt;.  See L&lt;LIMITATIONS&gt; for
how this applies to redirection.

If the URL includes a &quot;user:password&quot; stanza, they will be used for Basic-style
authorization headers.  (Authorization headers will not be included in a
redirected request.) For example:

    $http-&gt;request('GET', 'http://Aladdin:open sesame@example.com/');

If the &quot;user:password&quot; stanza contains reserved characters, they must
be percent-escaped:

    $http-&gt;request('GET', 'http://john%40example.com:password@example.com/');

A hashref of options may be appended to modify the request.

Valid options are:

=over 4

=item *

C&lt;headers&gt; — A hashref containing headers to include with the request.  If the value for a header is an array reference, the header will be output multiple times with each value in the array.  These headers over-write any default headers.

=item *

C&lt;content&gt; — A scalar to include as the body of the request OR a code reference that will be called iteratively to produce the body of the request

=item *

C&lt;trailer_callback&gt; — A code reference that will be called if it exists to provide a hashref of trailing headers (only used with chunked transfer-encoding)

=item *

C&lt;data_callback&gt; — A code reference that will be called for each chunks of the response body received.

=item *

C&lt;peer&gt; — Override host resolution and force all connections to go only to a specific peer address, regardless of the URL of the request.  This will include any redirections!  This options should be used with extreme caution (e.g. debugging or very special circumstances).

=back

The C&lt;Host&gt; header is generated from the URL in accordance with RFC 2616.  It
is a fatal error to specify C&lt;Host&gt; in the C&lt;headers&gt; option.  Other headers
may be ignored or overwritten if necessary for transport compliance.

If the C&lt;content&gt; option is a code reference, it will be called iteratively
to provide the content body of the request.  It should return the empty
string or undef when the iterator is exhausted.

If the C&lt;content&gt; option is the empty string, no C&lt;content-type&gt; or
C&lt;content-length&gt; headers will be generated.

If the C&lt;data_callback&gt; option is provided, it will be called iteratively until
the entire response body is received.  The first argument will be a string
containing a chunk of the response body, the second argument will be the
in-progress response hash reference, as described below.  (This allows
customizing the action of the callback based on the C&lt;status&gt; or C&lt;headers&gt;
received prior to the content body.)

The C&lt;request&gt; method returns a hashref containing the response.  The hashref
will have the following keys:

=over 4

=item *

C&lt;success&gt; — Boolean indicating whether the operation returned a 2XX status code

=item *

C&lt;url&gt; — URL that provided the response. This is the URL of the request unless there were redirections, in which case it is the last URL queried in a redirection chain

=item *

C&lt;status&gt; — The HTTP status code of the response

=item *

C&lt;reason&gt; — The response phrase returned by the server

=item *

C&lt;content&gt; — The body of the response.  If the response does not have any content or if a data callback is provided to consume the response body, this will be the empty string

=item *

C&lt;headers&gt; — A hashref of header fields.  All header field names will be normalized to be lower case. If a header is repeated, the value will be an arrayref; it will otherwise be a scalar string containing the value

=item *

C&lt;protocol&gt; - If this field exists, it is the protocol of the response such as HTTP/1.0 or HTTP/1.1

=item *

C&lt;redirects&gt; If this field exists, it is an arrayref of response hash references from redirects in the same order that redirections occurred.  If it does not exist, then no redirections occurred.

=back

On an exception during the execution of the request, the C&lt;status&gt; field will
contain 599, and the C&lt;content&gt; field will contain the text of the exception.

=head2 www_form_urlencode

    $params = $http-&gt;www_form_urlencode( $data );
    $response = $http-&gt;get(&quot;http://example.com/query?$params&quot;);

This method converts the key/value pairs from a data hash or array reference
into a C&lt;x-www-form-urlencoded&gt; string.  The keys and values from the data
reference will be UTF-8 encoded and escaped per RFC 3986.  If a value is an
array reference, the key will be repeated with each of the values of the array
reference.  If data is provided as a hash reference, the key/value pairs in the
resulting string will be sorted by key and value for consistent ordering.

=head2 can_ssl

    $ok         = HTTP::Tiny-&gt;can_ssl;
    ($ok, $why) = HTTP::Tiny-&gt;can_ssl;
    ($ok, $why) = $http-&gt;can_ssl;

Indicates if SSL support is available.  When called as a class object, it
checks for the correct version of L&lt;Net::SSLeay&gt; and L&lt;IO::Socket::SSL&gt;.
When called as an object methods, if C&lt;SSL_verify&gt; is true or if C&lt;SSL_verify_mode&gt;
is set in C&lt;SSL_options&gt;, it checks that a CA file is available.

In scalar context, returns a boolean indicating if SSL is available.
In list context, returns the boolean and a (possibly multi-line) string of
errors indicating why SSL isn't available.

=head2 connected

    $host = $http-&gt;connected;
    ($host, $port) = $http-&gt;connected;

Indicates if a connection to a peer is being kept alive, per the C&lt;keep_alive&gt;
option.

In scalar context, returns the peer host and port, joined with a colon, or
C&lt;undef&gt; (if no peer is connected).
In list context, returns the peer host and port or an empty list (if no peer
is connected).

B&lt;Note&gt;: This method cannot reliably be used to discover whether the remote
host has closed its end of the socket.

=for Pod::Coverage SSL_options
agent
cookie_jar
default_headers
http_proxy
https_proxy
keep_alive
local_address
max_redirect
max_size
no_proxy
proxy
timeout
verify_SSL

=head1 TLS/SSL SUPPORT

Direct C&lt;https&gt; connections are supported only if L&lt;IO::Socket::SSL&gt; 1.56 or
greater and L&lt;Net::SSLeay&gt; 1.49 or greater are installed. An exception will be
thrown if new enough versions of these modules are not installed or if the TLS
encryption fails. You can also use C&lt;HTTP::Tiny::can_ssl()&gt; utility function
that returns boolean to see if the required modules are installed.

An C&lt;https&gt; connection may be made via an C&lt;http&gt; proxy that supports the CONNECT
command (i.e. RFC 2817).  You may not proxy C&lt;https&gt; via a proxy that itself
requires C&lt;https&gt; to communicate.

TLS/SSL provides two distinct capabilities:

=over 4

=item *

Encrypted communication channel

=item *

Verification of server identity

=back

B&lt;By default, HTTP::Tiny verifies server identity&gt;.

This was changed for CVE-2023-31486 due to security concerns. The previous default
behavior can be enabled by setting C&lt;$ENV{PERL_HTTP_TINY_SSL_INSECURE_BY_DEFAULT}&gt;
to 1.

Verification is done by checking that that the TLS/SSL connection has a valid
certificate corresponding to the host name of the connection and that the
certificate has been verified by a CA. Assuming you trust the CA, this will
protect against L&lt;machine-in-the-middle
attacks|http://en.wikipedia.org/wiki/Machine-in-the-middle_attack&gt;.

Certificate verification requires a file containing trusted CA certificates.

If the environment variable C&lt;SSL_CERT_FILE&gt; is present, HTTP::Tiny
will try to find a CA certificate file in that location.

If the L&lt;Mozilla::CA&gt; module is installed, HTTP::Tiny will use the CA file
included with it as a source of trusted CA's.

If that module is not available, then HTTP::Tiny will search several
system-specific default locations for a CA certificate file:

=over 4

=item *

/etc/ssl/certs/ca-certificates.crt

=item *

/etc/pki/tls/certs/ca-bundle.crt

=item *

/etc/ssl/ca-bundle.pem

=item *

/etc/openssl/certs/ca-certificates.crt

=item *

/etc/ssl/cert.pem

=item *

/usr/local/share/certs/ca-root-nss.crt

=item *

/etc/pki/tls/cacert.pem

=item *

/etc/certs/ca-certificates.crt

=back

An exception will be raised if C&lt;verify_SSL&gt; is true and no CA certificate file
is available.

If you desire complete control over TLS/SSL connections, the C&lt;SSL_options&gt;
attribute lets you provide a hash reference that will be passed through to
C&lt;IO::Socket::SSL::start_SSL()&gt;, overriding any options set by HTTP::Tiny. For
example, to provide your own trusted CA file:

    SSL_options =&gt; {
        SSL_ca_file =&gt; $file_path,
    }

The C&lt;SSL_options&gt; attribute could also be used for such things as providing a
client certificate for authentication to a server or controlling the choice of
cipher used for the TLS/SSL connection. See L&lt;IO::Socket::SSL&gt; documentation for
details.

=head1 PROXY SUPPORT

HTTP::Tiny can proxy both C&lt;http&gt; and C&lt;https&gt; requests.  Only Basic proxy
authorization is supported and it must be provided as part of the proxy URL:
C&lt;http://user:pass@proxy.example.com/&gt;.

HTTP::Tiny supports the following proxy environment variables:

=over 4

=item *

http_proxy or HTTP_PROXY

=item *

https_proxy or HTTPS_PROXY

=item *

all_proxy or ALL_PROXY

=back

If the C&lt;REQUEST_METHOD&gt; environment variable is set, then this might be a CGI
process and C&lt;HTTP_PROXY&gt; would be set from the C&lt;Proxy:&gt; header, which is a
security risk.  If C&lt;REQUEST_METHOD&gt; is set, C&lt;HTTP_PROXY&gt; (the upper case
variant only) is ignored.

Tunnelling C&lt;https&gt; over an C&lt;http&gt; proxy using the CONNECT method is
supported.  If your proxy uses C&lt;https&gt; itself, you can not tunnel C&lt;https&gt;
over it.

Be warned that proxying an C&lt;https&gt; connection opens you to the risk of a
man-in-the-middle attack by the proxy server.

The C&lt;no_proxy&gt; environment variable is supported in the format of a
comma-separated list of domain extensions proxy should not be used for.

Proxy arguments passed to C&lt;new&gt; will override their corresponding
environment variables.

=head1 LIMITATIONS

HTTP::Tiny is I&lt;conditionally compliant&gt; with the
L&lt;HTTP/1.1 specifications|http://www.w3.org/Protocols/&gt;:

=over 4

=item *

&quot;Message Syntax and Routing&quot; [RFC7230]

=item *

&quot;Semantics and Content&quot; [RFC7231]

=item *

&quot;Conditional Requests&quot; [RFC7232]

=item *

&quot;Range Requests&quot; [RFC7233]

=item *

&quot;Caching&quot; [RFC7234]

=item *

&quot;Authentication&quot; [RFC7235]

=back

It attempts to meet all &quot;MUST&quot; requirements of the specification, but does not
implement all &quot;SHOULD&quot; requirements.  (Note: it was developed against the
earlier RFC 2616 specification and may not yet meet the revised RFC 7230-7235
spec.)

Some particular limitations of note include:

=over

=item *

HTTP::Tiny focuses on correct transport.  Users are responsible for ensuring
that user-defined headers and content are compliant with the HTTP/1.1
specification.

=item *

Users must ensure that URLs are properly escaped for unsafe characters and that
international domain names are properly encoded to ASCII. See L&lt;URI::Escape&gt;,
L&lt;URI::_punycode&gt; and L&lt;Net::IDN::Encode&gt;.

=item *

Redirection is very strict against the specification.  Redirection is only
automatic for response codes 301, 302, 307 and 308 if the request method is
'GET' or 'HEAD'.  Response code 303 is always converted into a 'GET'
redirection, as mandated by the specification.  There is no automatic support
for status 305 (&quot;Use proxy&quot;) redirections.

=item *

There is no provision for delaying a request body using an C&lt;Expect&gt; header.
Unexpected C&lt;1XX&gt; responses are silently ignored as per the specification.

=item *

Only 'chunked' C&lt;Transfer-Encoding&gt; is supported.

=item *

There is no support for a Request-URI of '*' for the 'OPTIONS' request.

=item *

Headers mentioned in the RFCs and some other, well-known headers are
generated with their canonical case.  Other headers are sent in the
case provided by the user.  Except for control headers (which are sent first),
headers are sent in arbitrary order.

=back

Despite the limitations listed above, HTTP::Tiny is considered
feature-complete.  New feature requests should be directed to
L&lt;HTTP::Tiny::UA&gt;.

=head1 SEE ALSO

=over 4

=item *

L&lt;HTTP::Tiny::UA&gt; - Higher level UA features for HTTP::Tiny

=item *

L&lt;HTTP::Thin&gt; - HTTP::Tiny wrapper with L&lt;HTTP::Request&gt;/L&lt;HTTP::Response&gt; compatibility

=item *

L&lt;HTTP::Tiny::Mech&gt; - Wrap L&lt;WWW::Mechanize&gt; instance in HTTP::Tiny compatible interface

=item *

L&lt;IO::Socket::IP&gt; - Required for IPv6 support

=item *

L&lt;IO::Socket::SSL&gt; - Required for SSL support

=item *

L&lt;LWP::UserAgent&gt; - If HTTP::Tiny isn't enough for you, this is the &quot;standard&quot; way to do things

=item *

L&lt;Mozilla::CA&gt; - Required if you want to validate SSL certificates

=item *

L&lt;Net::SSLeay&gt; - Required for SSL support

=back

=for :stopwords cpan testmatrix url annocpan anno bugtracker rt cpants kwalitee diff irc mailto metadata placeholders metacpan

=head1 SUPPORT

=head2 Bugs / Feature Requests

Please report any bugs or feature requests through the issue tracker
at L&lt;https://github.com/chansen/p5-http-tiny/issues&gt;.
You will be notified automatically of any progress on your issue.

=head2 Source Code

This is open source software.  The code repository is available for
public review and contribution under the terms of the license.

L&lt;https://github.com/chansen/p5-http-tiny&gt;

  git clone https://github.com/chansen/p5-http-tiny.git

=head1 AUTHORS

=over 4

=item *

Christian Hansen &lt;chansen@cpan.org&gt;

=item *

David Golden &lt;dagolden@cpan.org&gt;

=back

=head1 CONTRIBUTORS

=for stopwords Alan Gardner Alessandro Ghedini A. Sinan Unur Brad Gilbert brian m. carlson Chris Nehren Weyl Claes Jakobsson Clinton Gormley Craig Berry David Golden Mitchell Dean Pearce Edward Zborowski James Raspass Jeremy Mates Jess Robinson Karen Etheridge Lukas Eklund Martin J. Evans Martin-Louis Bright Mike Doherty Nicolas Rochelemagne Olaf Alders Olivier Mengué Petr Písař Serguei Trouchelle Shoichi Kaji SkyMarshal Sören Kornetzki Steve Grazzini Syohei YOSHIDA Tatsuhiko Miyagawa Tom Hukins Tony Cook

=over 4

=item *

Alan Gardner &lt;gardner@pythian.com&gt;

=item *

Alessandro Ghedini &lt;al3xbio@gmail.com&gt;

=item *

A. Sinan Unur &lt;nanis@cpan.org&gt;

=item *

Brad Gilbert &lt;bgills@cpan.org&gt;

=item *

brian m. carlson &lt;sandals@crustytoothpaste.net&gt;

=item *

Chris Nehren &lt;apeiron@cpan.org&gt;

=item *

Chris Weyl &lt;cweyl@alumni.drew.edu&gt;

=item *

Claes Jakobsson &lt;claes@surfar.nu&gt;

=item *

Clinton Gormley &lt;clint@traveljury.com&gt;

=item *

Craig A. Berry &lt;craigberry@mac.com&gt;

=item *

Craig Berry &lt;cberry@cpan.org&gt;

=item *

David Golden &lt;xdg@xdg.me&gt;

=item *

David Mitchell &lt;davem@iabyn.com&gt;

=item *

Dean Pearce &lt;pearce@pythian.com&gt;

=item *

Edward Zborowski &lt;ed@rubensteintech.com&gt;

=item *

James Raspass &lt;jraspass@gmail.com&gt;

=item *

Jeremy Mates &lt;jmates@cpan.org&gt;

=item *

Jess Robinson &lt;castaway@desert-island.me.uk&gt;

=item *

Karen Etheridge &lt;ether@cpan.org&gt;

=item *

Lukas Eklund &lt;leklund@gmail.com&gt;

=item *

Martin J. Evans &lt;mjegh@ntlworld.com&gt;

=item *

Martin-Louis Bright &lt;mlbright@gmail.com&gt;

=item *

Mike Doherty &lt;doherty@cpan.org&gt;

=item *

Nicolas Rochelemagne &lt;rochelemagne@cpanel.net&gt;

=item *

Olaf Alders &lt;olaf@wundersolutions.com&gt;

=item *

Olivier Mengué &lt;dolmen@cpan.org&gt;

=item *

Petr Písař &lt;ppisar@redhat.com&gt;

=item *

Serguei Trouchelle &lt;stro@cpan.org&gt;

=item *

Shoichi Kaji &lt;skaji@cpan.org&gt;

=item *

SkyMarshal &lt;skymarshal1729@gmail.com&gt;

=item *

Sören Kornetzki &lt;soeren.kornetzki@delti.com&gt;

=item *

Steve Grazzini &lt;steve.grazzini@grantstreet.com&gt;

=item *

Syohei YOSHIDA &lt;syohex@gmail.com&gt;

=item *

Tatsuhiko Miyagawa &lt;miyagawa@bulknews.net&gt;

=item *

Tom Hukins &lt;tom@eborcom.com&gt;

=item *

Tony Cook &lt;tony@develop-help.com&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2018 by Christian Hansen.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FHTTP'>Back to Directory</a>