<h2>Editing File: /usr/share/perl5/vendor_perl/Digest.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Digest;

use strict;
use vars qw($VERSION %MMAP $AUTOLOAD);

$VERSION = &quot;1.17&quot;;

%MMAP = (
  &quot;SHA-1&quot;      =&gt; [[&quot;Digest::SHA&quot;, 1], &quot;Digest::SHA1&quot;, [&quot;Digest::SHA2&quot;, 1]],
  &quot;SHA-224&quot;    =&gt; [[&quot;Digest::SHA&quot;, 224]],
  &quot;SHA-256&quot;    =&gt; [[&quot;Digest::SHA&quot;, 256], [&quot;Digest::SHA2&quot;, 256]],
  &quot;SHA-384&quot;    =&gt; [[&quot;Digest::SHA&quot;, 384], [&quot;Digest::SHA2&quot;, 384]],
  &quot;SHA-512&quot;    =&gt; [[&quot;Digest::SHA&quot;, 512], [&quot;Digest::SHA2&quot;, 512]],
  &quot;HMAC-MD5&quot;   =&gt; &quot;Digest::HMAC_MD5&quot;,
  &quot;HMAC-SHA-1&quot; =&gt; &quot;Digest::HMAC_SHA1&quot;,
  &quot;CRC-16&quot;     =&gt; [[&quot;Digest::CRC&quot;, type =&gt; &quot;crc16&quot;]],
  &quot;CRC-32&quot;     =&gt; [[&quot;Digest::CRC&quot;, type =&gt; &quot;crc32&quot;]],
  &quot;CRC-CCITT&quot;  =&gt; [[&quot;Digest::CRC&quot;, type =&gt; &quot;crcccitt&quot;]],
  &quot;RIPEMD-160&quot; =&gt; &quot;Crypt::RIPEMD160&quot;,
);

sub new
{
    shift;  # class ignored
    my $algorithm = shift;
    my $impl = $MMAP{$algorithm} || do {
        $algorithm =~ s/\W+//g;
        &quot;Digest::$algorithm&quot;;
    };
    $impl = [$impl] unless ref($impl);
    local $@;  # don't clobber it for our caller
    my $err;
    for  (@$impl) {
        my $class = $_;
        my @args;
        ($class, @args) = @$class if ref($class);
        no strict 'refs';
        unless (exists ${&quot;$class\::&quot;}{&quot;VERSION&quot;}) {
            my $pm_file = $class . &quot;.pm&quot;;
            $pm_file =~ s{::}{/}g;
            eval {
                local @INC = @INC;
                pop @INC if $INC[-1] eq '.';
                require $pm_file;
            };
            if ($@) {
                $err ||= $@;
                next;
            }
        }
        return $class-&gt;new(@args, @_);
    }
    die $err;
}

sub AUTOLOAD
{
    my $class = shift;
    my $algorithm = substr($AUTOLOAD, rindex($AUTOLOAD, '::')+2);
    $class-&gt;new($algorithm, @_);
}

1;

__END__

=head1 NAME

Digest - Modules that calculate message digests

=head1 SYNOPSIS

  $md5  = Digest-&gt;new(&quot;MD5&quot;);
  $sha1 = Digest-&gt;new(&quot;SHA-1&quot;);
  $sha256 = Digest-&gt;new(&quot;SHA-256&quot;);
  $sha384 = Digest-&gt;new(&quot;SHA-384&quot;);
  $sha512 = Digest-&gt;new(&quot;SHA-512&quot;);

  $hmac = Digest-&gt;HMAC_MD5($key);

=head1 DESCRIPTION

The C&lt;Digest::&gt; modules calculate digests, also called &quot;fingerprints&quot;
or &quot;hashes&quot;, of some data, called a message.  The digest is (usually)
some small/fixed size string.  The actual size of the digest depend of
the algorithm used.  The message is simply a sequence of arbitrary
bytes or bits.

An important property of the digest algorithms is that the digest is
I&lt;likely&gt; to change if the message change in some way.  Another
property is that digest functions are one-way functions, that is it
should be I&lt;hard&gt; to find a message that correspond to some given
digest.  Algorithms differ in how &quot;likely&quot; and how &quot;hard&quot;, as well as
how efficient they are to compute.

Note that the properties of the algorithms change over time, as the
algorithms are analyzed and machines grow faster.  If your application
for instance depends on it being &quot;impossible&quot; to generate the same
digest for a different message it is wise to make it easy to plug in
stronger algorithms as the one used grow weaker.  Using the interface
documented here should make it easy to change algorithms later.

All C&lt;Digest::&gt; modules provide the same programming interface.  A
functional interface for simple use, as well as an object oriented
interface that can handle messages of arbitrary length and which can
read files directly.

The digest can be delivered in three formats:

=over 8

=item I&lt;binary&gt;

This is the most compact form, but it is not well suited for printing
or embedding in places that can't handle arbitrary data.

=item I&lt;hex&gt;

A twice as long string of lowercase hexadecimal digits.

=item I&lt;base64&gt;

A string of portable printable characters.  This is the base64 encoded
representation of the digest with any trailing padding removed.  The
string will be about 30% longer than the binary version.
L&lt;MIME::Base64&gt; tells you more about this encoding.

=back


The functional interface is simply importable functions with the same
name as the algorithm.  The functions take the message as argument and
return the digest.  Example:

  use Digest::MD5 qw(md5);
  $digest = md5($message);

There are also versions of the functions with &quot;_hex&quot; or &quot;_base64&quot;
appended to the name, which returns the digest in the indicated form.

=head1 OO INTERFACE

The following methods are available for all C&lt;Digest::&gt; modules:

=over 4

=item $ctx = Digest-&gt;XXX($arg,...)

=item $ctx = Digest-&gt;new(XXX =&gt; $arg,...)

=item $ctx = Digest::XXX-&gt;new($arg,...)

The constructor returns some object that encapsulate the state of the
message-digest algorithm.  You can add data to the object and finally
ask for the digest.  The &quot;XXX&quot; should of course be replaced by the proper
name of the digest algorithm you want to use.

The two first forms are simply syntactic sugar which automatically
load the right module on first use.  The second form allow you to use
algorithm names which contains letters which are not legal perl
identifiers, e.g. &quot;SHA-1&quot;.  If no implementation for the given algorithm
can be found, then an exception is raised.

If new() is called as an instance method (i.e. $ctx-&gt;new) it will just
reset the state the object to the state of a newly created object.  No
new object is created in this case, and the return value is the
reference to the object (i.e. $ctx).

=item $other_ctx = $ctx-&gt;clone

The clone method creates a copy of the digest state object and returns
a reference to the copy.

=item $ctx-&gt;reset

This is just an alias for $ctx-&gt;new.

=item $ctx-&gt;add( $data )

=item $ctx-&gt;add( $chunk1, $chunk2, ... )

The string value of the $data provided as argument is appended to the
message we calculate the digest for.  The return value is the $ctx
object itself.

If more arguments are provided then they are all appended to the
message, thus all these lines will have the same effect on the state
of the $ctx object:

  $ctx-&gt;add(&quot;a&quot;); $ctx-&gt;add(&quot;b&quot;); $ctx-&gt;add(&quot;c&quot;);
  $ctx-&gt;add(&quot;a&quot;)-&gt;add(&quot;b&quot;)-&gt;add(&quot;c&quot;);
  $ctx-&gt;add(&quot;a&quot;, &quot;b&quot;, &quot;c&quot;);
  $ctx-&gt;add(&quot;abc&quot;);

Most algorithms are only defined for strings of bytes and this method
might therefore croak if the provided arguments contain chars with
ordinal number above 255.

=item $ctx-&gt;addfile( $io_handle )

The $io_handle is read until EOF and the content is appended to the
message we calculate the digest for.  The return value is the $ctx
object itself.

The addfile() method will croak() if it fails reading data for some
reason.  If it croaks it is unpredictable what the state of the $ctx
object will be in. The addfile() method might have been able to read
the file partially before it failed.  It is probably wise to discard
or reset the $ctx object if this occurs.

In most cases you want to make sure that the $io_handle is in
&quot;binmode&quot; before you pass it as argument to the addfile() method.

=item $ctx-&gt;add_bits( $data, $nbits )

=item $ctx-&gt;add_bits( $bitstring )

The add_bits() method is an alternative to add() that allow partial
bytes to be appended to the message.  Most users should just ignore
this method as partial bytes is very unlikely to be of any practical
use.

The two argument form of add_bits() will add the first $nbits bits
from $data.  For the last potentially partial byte only the high order
C&lt;&lt; $nbits % 8 &gt;&gt; bits are used.  If $nbits is greater than C&lt;&lt;
length($data) * 8 &gt;&gt;, then this method would do the same as C&lt;&lt;
$ctx-&gt;add($data) &gt;&gt;.

The one argument form of add_bits() takes a $bitstring of &quot;1&quot; and &quot;0&quot;
chars as argument.  It's a shorthand for C&lt;&lt; $ctx-&gt;add_bits(pack(&quot;B*&quot;,
$bitstring), length($bitstring)) &gt;&gt;.

The return value is the $ctx object itself.

This example shows two calls that should have the same effect:

   $ctx-&gt;add_bits(&quot;111100001010&quot;);
   $ctx-&gt;add_bits(&quot;\xF0\xA0&quot;, 12);

Most digest algorithms are byte based and for these it is not possible
to add bits that are not a multiple of 8, and the add_bits() method
will croak if you try.

=item $ctx-&gt;digest

Return the binary digest for the message.

Note that the C&lt;digest&gt; operation is effectively a destructive,
read-once operation. Once it has been performed, the $ctx object is
automatically C&lt;reset&gt; and can be used to calculate another digest
value.  Call $ctx-&gt;clone-&gt;digest if you want to calculate the digest
without resetting the digest state.

=item $ctx-&gt;hexdigest

Same as $ctx-&gt;digest, but will return the digest in hexadecimal form.

=item $ctx-&gt;b64digest

Same as $ctx-&gt;digest, but will return the digest as a base64 encoded
string.

=back

=head1 Digest speed

This table should give some indication on the relative speed of
different algorithms.  It is sorted by throughput based on a benchmark
done with of some implementations of this API:

 Algorithm      Size    Implementation                  MB/s

 MD4            128     Digest::MD4 v1.3               165.0
 MD5            128     Digest::MD5 v2.33               98.8
 SHA-256        256     Digest::SHA2 v1.1.0             66.7
 SHA-1          160     Digest::SHA v4.3.1              58.9
 SHA-1          160     Digest::SHA1 v2.10              48.8
 SHA-256        256     Digest::SHA v4.3.1              41.3
 Haval-256      256     Digest::Haval256 v1.0.4         39.8
 SHA-384        384     Digest::SHA2 v1.1.0             19.6
 SHA-512        512     Digest::SHA2 v1.1.0             19.3
 SHA-384        384     Digest::SHA v4.3.1              19.2
 SHA-512        512     Digest::SHA v4.3.1              19.2
 Whirlpool      512     Digest::Whirlpool v1.0.2        13.0
 MD2            128     Digest::MD2 v2.03                9.5

 Adler-32        32     Digest::Adler32 v0.03            1.3
 CRC-16          16     Digest::CRC v0.05                1.1
 CRC-32          32     Digest::CRC v0.05                1.1
 MD5            128     Digest::Perl::MD5 v1.5           1.0
 CRC-CCITT       16     Digest::CRC v0.05                0.8

These numbers was achieved Apr 2004 with ActivePerl-5.8.3 running
under Linux on a P4 2.8 GHz CPU.  The last 5 entries differ by being
pure perl implementations of the algorithms, which explains why they
are so slow.

=head1 SEE ALSO

L&lt;Digest::Adler32&gt;, L&lt;Digest::CRC&gt;, L&lt;Digest::Haval256&gt;,
L&lt;Digest::HMAC&gt;, L&lt;Digest::MD2&gt;, L&lt;Digest::MD4&gt;, L&lt;Digest::MD5&gt;,
L&lt;Digest::SHA&gt;, L&lt;Digest::SHA1&gt;, L&lt;Digest::SHA2&gt;, L&lt;Digest::Whirlpool&gt;

New digest implementations should consider subclassing from L&lt;Digest::base&gt;.

L&lt;MIME::Base64&gt;

http://en.wikipedia.org/wiki/Cryptographic_hash_function

=head1 AUTHOR

Gisle Aas &lt;gisle@aas.no&gt;

The C&lt;Digest::&gt; interface is based on the interface originally
developed by Neil Winton for his C&lt;MD5&gt; module.

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

    Copyright 1998-2006 Gisle Aas.
    Copyright 1995,1996 Neil Winton.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl'>Back to Directory</a>