<h2>Editing File: /usr/share/perl5/vendor_perl/Data/OptList.pm</h2><form method='post'><textarea name='content' class='file-edit'>use strict;
use warnings;
package Data::OptList;
# ABSTRACT: parse and validate simple name/value option pairs
$Data::OptList::VERSION = '0.110';
use List::Util ();
use Params::Util ();
use Sub::Install 0.921 ();

#pod =head1 SYNOPSIS
#pod
#pod   use Data::OptList;
#pod
#pod   my $options = Data::OptList::mkopt([
#pod     qw(key1 key2 key3 key4),
#pod     key5 =&gt; { ... },
#pod     key6 =&gt; [ ... ],
#pod     key7 =&gt; sub { ... },
#pod     key8 =&gt; { ... },
#pod     key8 =&gt; [ ... ],
#pod   ]);
#pod
#pod ...is the same thing, more or less, as:
#pod
#pod   my $options = [
#pod     [ key1 =&gt; undef,        ],
#pod     [ key2 =&gt; undef,        ],
#pod     [ key3 =&gt; undef,        ],
#pod     [ key4 =&gt; undef,        ],
#pod     [ key5 =&gt; { ... },      ],
#pod     [ key6 =&gt; [ ... ],      ],
#pod     [ key7 =&gt; sub { ... },  ],
#pod     [ key8 =&gt; { ... },      ],
#pod     [ key8 =&gt; [ ... ],      ],
#pod   ]);
#pod
#pod =head1 DESCRIPTION
#pod
#pod Hashes are great for storing named data, but if you want more than one entry
#pod for a name, you have to use a list of pairs.  Even then, this is really boring
#pod to write:
#pod
#pod   $values = [
#pod     foo =&gt; undef,
#pod     bar =&gt; undef,
#pod     baz =&gt; undef,
#pod     xyz =&gt; { ... },
#pod   ];
#pod
#pod Just look at all those undefs!  Don't worry, we can get rid of those:
#pod
#pod   $values = [
#pod     map { $_ =&gt; undef } qw(foo bar baz),
#pod     xyz =&gt; { ... },
#pod   ];
#pod
#pod Aaaauuugh!  We've saved a little typing, but now it requires thought to read,
#pod and thinking is even worse than typing... and it's got a bug!  It looked right,
#pod didn't it?  Well, the C&lt;&lt; xyz =&gt; { ... } &gt;&gt; gets consumed by the map, and we
#pod don't get the data we wanted.
#pod
#pod With Data::OptList, you can do this instead:
#pod
#pod   $values = Data::OptList::mkopt([
#pod     qw(foo bar baz),
#pod     xyz =&gt; { ... },
#pod   ]);
#pod
#pod This works by assuming that any defined scalar is a name and any reference
#pod following a name is its value.
#pod
#pod =func mkopt
#pod
#pod   my $opt_list = Data::OptList::mkopt($input, \%arg);
#pod
#pod Valid arguments are:
#pod
#pod   moniker        - a word used in errors to describe the opt list; encouraged
#pod   require_unique - if true, no name may appear more than once
#pod   must_be        - types to which opt list values are limited (described below)
#pod   name_test      - a coderef used to test whether a value can be a name
#pod                    (described below, but you probably don't want this)
#pod
#pod This produces an array of arrays; the inner arrays are name/value pairs.
#pod Values will be either &quot;undef&quot; or a reference.
#pod
#pod Positional parameters may be used for compatibility with the old C&lt;mkopt&gt;
#pod interface:
#pod
#pod   my $opt_list = Data::OptList::mkopt($input, $moniker, $req_uni, $must_be);
#pod
#pod Valid values for C&lt;$input&gt;:
#pod
#pod  undef    -&gt; []
#pod  hashref  -&gt; [ [ key1 =&gt; value1 ] ... ] # non-ref values become undef
#pod  arrayref -&gt; every name followed by a non-name becomes a pair: [ name =&gt; ref ]
#pod              every name followed by undef becomes a pair: [ name =&gt; undef ]
#pod              otherwise, it becomes [ name =&gt; undef ] like so:
#pod              [ &quot;a&quot;, &quot;b&quot;, [ 1, 2 ] ] -&gt; [ [ a =&gt; undef ], [ b =&gt; [ 1, 2 ] ] ]
#pod
#pod By default, a I&lt;name&gt; is any defined non-reference.  The C&lt;name_test&gt; parameter
#pod can be a code ref that tests whether the argument passed it is a name or not.
#pod This should be used rarely.  Interactions between C&lt;require_unique&gt; and
#pod C&lt;name_test&gt; are not yet particularly elegant, as C&lt;require_unique&gt; just tests
#pod string equality.  B&lt;This may change.&gt;
#pod
#pod The C&lt;must_be&gt; parameter is either a scalar or array of scalars; it defines
#pod what kind(s) of refs may be values.  If an invalid value is found, an exception
#pod is thrown.  If no value is passed for this argument, any reference is valid.
#pod If C&lt;must_be&gt; specifies that values must be CODE, HASH, ARRAY, or SCALAR, then
#pod Params::Util is used to check whether the given value can provide that
#pod interface.  Otherwise, it checks that the given value is an object of the kind.
#pod
#pod In other words:
#pod
#pod   [ qw(SCALAR HASH Object::Known) ]
#pod
#pod Means:
#pod
#pod   _SCALAR0($value) or _HASH($value) or _INSTANCE($value, 'Object::Known')
#pod
#pod =cut

my %test_for;
BEGIN {
  %test_for = (
    CODE   =&gt; \&amp;Params::Util::_CODELIKE,  ## no critic
    HASH   =&gt; \&amp;Params::Util::_HASHLIKE,  ## no critic
    ARRAY  =&gt; \&amp;Params::Util::_ARRAYLIKE, ## no critic
    SCALAR =&gt; \&amp;Params::Util::_SCALAR0,   ## no critic
  );
}

sub mkopt {
  my ($opt_list) = shift;

  my ($moniker, $require_unique, $must_be); # the old positional args
  my ($name_test, $is_a);

  if (@_) {
    if (@_ == 1 and Params::Util::_HASHLIKE($_[0])) {
      ($moniker, $require_unique, $must_be, $name_test)
        = @{$_[0]}{ qw(moniker require_unique must_be name_test) };
    } else {
      ($moniker, $require_unique, $must_be) = @_;
    }

    # Transform the $must_be specification into a closure $is_a
    # that will check if a value matches the spec

    if (defined $must_be) {
      $must_be = [ $must_be ] unless ref $must_be;
      my @checks = map {
          my $class = $_;
          $test_for{$_}
          || sub { $_[1] = $class; goto \&amp;Params::Util::_INSTANCE }
      } @$must_be;

      $is_a = (@checks == 1)
            ? $checks[0]
            : sub {
                my $value = $_[0];
                List::Util::first { defined($_-&gt;($value)) } @checks
              };

      $moniker = 'unnamed' unless defined $moniker;
    }
  }

  return [] unless $opt_list;

  $name_test ||= sub { ! ref $_[0] };

  $opt_list = [
    map { $_ =&gt; (ref $opt_list-&gt;{$_} ? $opt_list-&gt;{$_} : ()) } keys %$opt_list
  ] if ref $opt_list eq 'HASH';

  my @return;
  my %seen;

  for (my $i = 0; $i &lt; @$opt_list; $i++) { ## no critic
    my $name = $opt_list-&gt;[$i];

    if ($require_unique) {
      Carp::croak &quot;multiple definitions provided for $name&quot; if $seen{$name}++;
    }

    my $value;

    if ($i &lt; $#$opt_list) {
      if (not defined $opt_list-&gt;[$i+1]) {
        $i++
      } elsif (! $name_test-&gt;($opt_list-&gt;[$i+1])) {
        $value = $opt_list-&gt;[++$i];
        if ($is_a &amp;&amp; !$is_a-&gt;($value)) {
          my $ref = ref $value;
          Carp::croak &quot;$ref-ref values are not valid in $moniker opt list&quot;;
        }
      }
    }

    push @return, [ $name =&gt; $value ];
  }

  return \@return;
}

#pod =func mkopt_hash
#pod
#pod   my $opt_hash = Data::OptList::mkopt_hash($input, $moniker, $must_be);
#pod
#pod Given valid C&lt;L&lt;/mkopt&gt;&gt; input, this routine returns a reference to a hash.  It
#pod will throw an exception if any name has more than one value.
#pod
#pod =cut

sub mkopt_hash {
  my ($opt_list, $moniker, $must_be) = @_;
  return {} unless $opt_list;

  $opt_list = mkopt($opt_list, $moniker, 1, $must_be);
  my %hash = map { $_-&gt;[0] =&gt; $_-&gt;[1] } @$opt_list;
  return \%hash;
}

#pod =head1 EXPORTS
#pod
#pod Both C&lt;mkopt&gt; and C&lt;mkopt_hash&gt; may be exported on request.
#pod
#pod =cut

BEGIN {
  *import = Sub::Install::exporter {
    exports =&gt; [qw(mkopt mkopt_hash)],
  };
}

1;

__END__

=pod

=encoding UTF-8

=head1 NAME

Data::OptList - parse and validate simple name/value option pairs

=head1 VERSION

version 0.110

=head1 SYNOPSIS

  use Data::OptList;

  my $options = Data::OptList::mkopt([
    qw(key1 key2 key3 key4),
    key5 =&gt; { ... },
    key6 =&gt; [ ... ],
    key7 =&gt; sub { ... },
    key8 =&gt; { ... },
    key8 =&gt; [ ... ],
  ]);

...is the same thing, more or less, as:

  my $options = [
    [ key1 =&gt; undef,        ],
    [ key2 =&gt; undef,        ],
    [ key3 =&gt; undef,        ],
    [ key4 =&gt; undef,        ],
    [ key5 =&gt; { ... },      ],
    [ key6 =&gt; [ ... ],      ],
    [ key7 =&gt; sub { ... },  ],
    [ key8 =&gt; { ... },      ],
    [ key8 =&gt; [ ... ],      ],
  ]);

=head1 DESCRIPTION

Hashes are great for storing named data, but if you want more than one entry
for a name, you have to use a list of pairs.  Even then, this is really boring
to write:

  $values = [
    foo =&gt; undef,
    bar =&gt; undef,
    baz =&gt; undef,
    xyz =&gt; { ... },
  ];

Just look at all those undefs!  Don't worry, we can get rid of those:

  $values = [
    map { $_ =&gt; undef } qw(foo bar baz),
    xyz =&gt; { ... },
  ];

Aaaauuugh!  We've saved a little typing, but now it requires thought to read,
and thinking is even worse than typing... and it's got a bug!  It looked right,
didn't it?  Well, the C&lt;&lt; xyz =&gt; { ... } &gt;&gt; gets consumed by the map, and we
don't get the data we wanted.

With Data::OptList, you can do this instead:

  $values = Data::OptList::mkopt([
    qw(foo bar baz),
    xyz =&gt; { ... },
  ]);

This works by assuming that any defined scalar is a name and any reference
following a name is its value.

=head1 FUNCTIONS

=head2 mkopt

  my $opt_list = Data::OptList::mkopt($input, \%arg);

Valid arguments are:

  moniker        - a word used in errors to describe the opt list; encouraged
  require_unique - if true, no name may appear more than once
  must_be        - types to which opt list values are limited (described below)
  name_test      - a coderef used to test whether a value can be a name
                   (described below, but you probably don't want this)

This produces an array of arrays; the inner arrays are name/value pairs.
Values will be either &quot;undef&quot; or a reference.

Positional parameters may be used for compatibility with the old C&lt;mkopt&gt;
interface:

  my $opt_list = Data::OptList::mkopt($input, $moniker, $req_uni, $must_be);

Valid values for C&lt;$input&gt;:

 undef    -&gt; []
 hashref  -&gt; [ [ key1 =&gt; value1 ] ... ] # non-ref values become undef
 arrayref -&gt; every name followed by a non-name becomes a pair: [ name =&gt; ref ]
             every name followed by undef becomes a pair: [ name =&gt; undef ]
             otherwise, it becomes [ name =&gt; undef ] like so:
             [ &quot;a&quot;, &quot;b&quot;, [ 1, 2 ] ] -&gt; [ [ a =&gt; undef ], [ b =&gt; [ 1, 2 ] ] ]

By default, a I&lt;name&gt; is any defined non-reference.  The C&lt;name_test&gt; parameter
can be a code ref that tests whether the argument passed it is a name or not.
This should be used rarely.  Interactions between C&lt;require_unique&gt; and
C&lt;name_test&gt; are not yet particularly elegant, as C&lt;require_unique&gt; just tests
string equality.  B&lt;This may change.&gt;

The C&lt;must_be&gt; parameter is either a scalar or array of scalars; it defines
what kind(s) of refs may be values.  If an invalid value is found, an exception
is thrown.  If no value is passed for this argument, any reference is valid.
If C&lt;must_be&gt; specifies that values must be CODE, HASH, ARRAY, or SCALAR, then
Params::Util is used to check whether the given value can provide that
interface.  Otherwise, it checks that the given value is an object of the kind.

In other words:

  [ qw(SCALAR HASH Object::Known) ]

Means:

  _SCALAR0($value) or _HASH($value) or _INSTANCE($value, 'Object::Known')

=head2 mkopt_hash

  my $opt_hash = Data::OptList::mkopt_hash($input, $moniker, $must_be);

Given valid C&lt;L&lt;/mkopt&gt;&gt; input, this routine returns a reference to a hash.  It
will throw an exception if any name has more than one value.

=head1 EXPORTS

Both C&lt;mkopt&gt; and C&lt;mkopt_hash&gt; may be exported on request.

=head1 AUTHOR

Ricardo Signes &lt;rjbs@cpan.org&gt;

=head1 CONTRIBUTORS

=for stopwords Olivier Mengué Ricardo SIGNES

=over 4

=item *

Olivier Mengué &lt;dolmen@cpan.org&gt;

=item *

Ricardo SIGNES &lt;rjbs@codesimply.com&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2006 by Ricardo Signes.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FData'>Back to Directory</a>