<h2>Editing File: /usr/share/perl5/vendor_perl/CPAN/Meta/Requirements.pm</h2><form method='post'><textarea name='content' class='file-edit'>use 5.006; # keep at v5.6 for CPAN.pm
use strict;
use warnings;
package CPAN::Meta::Requirements;
# ABSTRACT: a set of version requirements for a CPAN dist

our $VERSION = '2.140';

#pod =head1 SYNOPSIS
#pod
#pod   use CPAN::Meta::Requirements;
#pod
#pod   my $build_requires = CPAN::Meta::Requirements-&gt;new;
#pod
#pod   $build_requires-&gt;add_minimum('Library::Foo' =&gt; 1.208);
#pod
#pod   $build_requires-&gt;add_minimum('Library::Foo' =&gt; 2.602);
#pod
#pod   $build_requires-&gt;add_minimum('Module::Bar'  =&gt; 'v1.2.3');
#pod
#pod   $METAyml-&gt;{build_requires} = $build_requires-&gt;as_string_hash;
#pod
#pod =head1 DESCRIPTION
#pod
#pod A CPAN::Meta::Requirements object models a set of version constraints like
#pod those specified in the F&lt;META.yml&gt; or F&lt;META.json&gt; files in CPAN distributions,
#pod and as defined by L&lt;CPAN::Meta::Spec&gt;;
#pod It can be built up by adding more and more constraints, and it will reduce them
#pod to the simplest representation.
#pod
#pod Logically impossible constraints will be identified immediately by thrown
#pod exceptions.
#pod
#pod =cut

use Carp ();

# To help ExtUtils::MakeMaker bootstrap CPAN::Meta::Requirements on perls
# before 5.10, we fall back to the EUMM bundled compatibility version module if
# that's the only thing available.  This shouldn't ever happen in a normal CPAN
# install of CPAN::Meta::Requirements, as version.pm will be picked up from
# prereqs and be available at runtime.

BEGIN {
  eval &quot;use version ()&quot;; ## no critic
  if ( my $err = $@ ) {
    eval &quot;use ExtUtils::MakeMaker::version&quot; or die $err; ## no critic
  }
}

# Perl 5.10.0 didn't have &quot;is_qv&quot; in version.pm
*_is_qv = version-&gt;can('is_qv') ? sub { $_[0]-&gt;is_qv } : sub { exists $_[0]-&gt;{qv} };

# construct once, reuse many times
my $V0 = version-&gt;new(0);

#pod =method new
#pod
#pod   my $req = CPAN::Meta::Requirements-&gt;new;
#pod
#pod This returns a new CPAN::Meta::Requirements object.  It takes an optional
#pod hash reference argument.  Currently, only one key is supported:
#pod
#pod =for :list
#pod * C&lt;bad_version_hook&gt; -- if provided, when a version cannot be parsed into
#pod   a version object, this code reference will be called with the invalid
#pod   version string as first argument, and the module name as second
#pod   argument.  It must return a valid version object.
#pod
#pod All other keys are ignored.
#pod
#pod =cut

my @valid_options = qw( bad_version_hook );

sub new {
  my ($class, $options) = @_;
  $options ||= {};
  Carp::croak &quot;Argument to $class\-&gt;new() must be a hash reference&quot;
    unless ref $options eq 'HASH';
  my %self = map {; $_ =&gt; $options-&gt;{$_}} @valid_options;

  return bless \%self =&gt; $class;
}

# from version::vpp
sub _find_magic_vstring {
  my $value = shift;
  my $tvalue = '';
  require B;
  my $sv = B::svref_2object(\$value);
  my $magic = ref($sv) eq 'B::PVMG' ? $sv-&gt;MAGIC : undef;
  while ( $magic ) {
    if ( $magic-&gt;TYPE eq 'V' ) {
      $tvalue = $magic-&gt;PTR;
      $tvalue =~ s/^v?(.+)$/v$1/;
      last;
    }
    else {
      $magic = $magic-&gt;MOREMAGIC;
    }
  }
  return $tvalue;
}

# safe if given an unblessed reference
sub _isa_version {
  UNIVERSAL::isa( $_[0], 'UNIVERSAL' ) &amp;&amp; $_[0]-&gt;isa('version')
}

sub _version_object {
  my ($self, $module, $version) = @_;

  my ($vobj, $err);

  if (not defined $version or (!ref($version) &amp;&amp; $version eq '0')) {
    return $V0;
  }
  elsif ( ref($version) eq 'version' || ( ref($version) &amp;&amp; _isa_version($version) ) ) {
    $vobj = $version;
  }
  else {
    # hack around version::vpp not handling &lt;3 character vstring literals
    if ( $INC{'version/vpp.pm'} || $INC{'ExtUtils/MakeMaker/version/vpp.pm'} ) {
      my $magic = _find_magic_vstring( $version );
      $version = $magic if length $magic;
    }
    # pad to 3 characters if before 5.8.1 and appears to be a v-string
    if ( $] &lt; 5.008001 &amp;&amp; $version !~ /\A[0-9]/ &amp;&amp; substr($version,0,1) ne 'v' &amp;&amp; length($version) &lt; 3 ) {
      $version .= &quot;\0&quot; x (3 - length($version));
    }
    eval {
      local $SIG{__WARN__} = sub { die &quot;Invalid version: $_[0]&quot; };
      # avoid specific segfault on some older version.pm versions
      die &quot;Invalid version: $version&quot; if $version eq 'version';
      $vobj = version-&gt;new($version);
    };
    if ( my $err = $@ ) {
      my $hook = $self-&gt;{bad_version_hook};
      $vobj = eval { $hook-&gt;($version, $module) }
        if ref $hook eq 'CODE';
      unless (eval { $vobj-&gt;isa(&quot;version&quot;) }) {
        $err =~ s{ at .* line \d+.*$}{};
        die &quot;Can't convert '$version': $err&quot;;
      }
    }
  }

  # ensure no leading '.'
  if ( $vobj =~ m{\A\.} ) {
    $vobj = version-&gt;new(&quot;0$vobj&quot;);
  }

  # ensure normal v-string form
  if ( _is_qv($vobj) ) {
    $vobj = version-&gt;new($vobj-&gt;normal);
  }

  return $vobj;
}

#pod =method add_minimum
#pod
#pod   $req-&gt;add_minimum( $module =&gt; $version );
#pod
#pod This adds a new minimum version requirement.  If the new requirement is
#pod redundant to the existing specification, this has no effect.
#pod
#pod Minimum requirements are inclusive.  C&lt;$version&gt; is required, along with any
#pod greater version number.
#pod
#pod This method returns the requirements object.
#pod
#pod =method add_maximum
#pod
#pod   $req-&gt;add_maximum( $module =&gt; $version );
#pod
#pod This adds a new maximum version requirement.  If the new requirement is
#pod redundant to the existing specification, this has no effect.
#pod
#pod Maximum requirements are inclusive.  No version strictly greater than the given
#pod version is allowed.
#pod
#pod This method returns the requirements object.
#pod
#pod =method add_exclusion
#pod
#pod   $req-&gt;add_exclusion( $module =&gt; $version );
#pod
#pod This adds a new excluded version.  For example, you might use these three
#pod method calls:
#pod
#pod   $req-&gt;add_minimum( $module =&gt; '1.00' );
#pod   $req-&gt;add_maximum( $module =&gt; '1.82' );
#pod
#pod   $req-&gt;add_exclusion( $module =&gt; '1.75' );
#pod
#pod Any version between 1.00 and 1.82 inclusive would be acceptable, except for
#pod 1.75.
#pod
#pod This method returns the requirements object.
#pod
#pod =method exact_version
#pod
#pod   $req-&gt;exact_version( $module =&gt; $version );
#pod
#pod This sets the version required for the given module to I&lt;exactly&gt; the given
#pod version.  No other version would be considered acceptable.
#pod
#pod This method returns the requirements object.
#pod
#pod =cut

BEGIN {
  for my $type (qw(maximum exclusion exact_version)) {
    my $method = &quot;with_$type&quot;;
    my $to_add = $type eq 'exact_version' ? $type : &quot;add_$type&quot;;

    my $code = sub {
      my ($self, $name, $version) = @_;

      $version = $self-&gt;_version_object( $name, $version );

      $self-&gt;__modify_entry_for($name, $method, $version);

      return $self;
    };

    no strict 'refs';
    *$to_add = $code;
  }
}

# add_minimum is optimized compared to generated subs above because
# it is called frequently and with &quot;0&quot; or equivalent input
sub add_minimum {
  my ($self, $name, $version) = @_;

  # stringify $version so that version-&gt;new(&quot;0.00&quot;)-&gt;stringify ne &quot;0&quot;
  # which preserves the user's choice of &quot;0.00&quot; as the requirement
  if (not defined $version or &quot;$version&quot; eq '0') {
    return $self if $self-&gt;__entry_for($name);
    Carp::confess(&quot;can't add new requirements to finalized requirements&quot;)
      if $self-&gt;is_finalized;

    $self-&gt;{requirements}{ $name } =
      CPAN::Meta::Requirements::_Range::Range-&gt;with_minimum($V0, $name);
  }
  else {
    $version = $self-&gt;_version_object( $name, $version );

    $self-&gt;__modify_entry_for($name, 'with_minimum', $version);
  }
  return $self;
}

#pod =method add_requirements
#pod
#pod   $req-&gt;add_requirements( $another_req_object );
#pod
#pod This method adds all the requirements in the given CPAN::Meta::Requirements
#pod object to the requirements object on which it was called.  If there are any
#pod conflicts, an exception is thrown.
#pod
#pod This method returns the requirements object.
#pod
#pod =cut

sub add_requirements {
  my ($self, $req) = @_;

  for my $module ($req-&gt;required_modules) {
    my $modifiers = $req-&gt;__entry_for($module)-&gt;as_modifiers;
    for my $modifier (@$modifiers) {
      my ($method, @args) = @$modifier;
      $self-&gt;$method($module =&gt; @args);
    };
  }

  return $self;
}

#pod =method accepts_module
#pod
#pod   my $bool = $req-&gt;accepts_module($module =&gt; $version);
#pod
#pod Given an module and version, this method returns true if the version
#pod specification for the module accepts the provided version.  In other words,
#pod given:
#pod
#pod   Module =&gt; '&gt;= 1.00, &lt; 2.00'
#pod
#pod We will accept 1.00 and 1.75 but not 0.50 or 2.00.
#pod
#pod For modules that do not appear in the requirements, this method will return
#pod true.
#pod
#pod =cut

sub accepts_module {
  my ($self, $module, $version) = @_;

  $version = $self-&gt;_version_object( $module, $version );

  return 1 unless my $range = $self-&gt;__entry_for($module);
  return $range-&gt;_accepts($version);
}

#pod =method clear_requirement
#pod
#pod   $req-&gt;clear_requirement( $module );
#pod
#pod This removes the requirement for a given module from the object.
#pod
#pod This method returns the requirements object.
#pod
#pod =cut

sub clear_requirement {
  my ($self, $module) = @_;

  return $self unless $self-&gt;__entry_for($module);

  Carp::confess(&quot;can't clear requirements on finalized requirements&quot;)
    if $self-&gt;is_finalized;

  delete $self-&gt;{requirements}{ $module };

  return $self;
}

#pod =method requirements_for_module
#pod
#pod   $req-&gt;requirements_for_module( $module );
#pod
#pod This returns a string containing the version requirements for a given module in
#pod the format described in L&lt;CPAN::Meta::Spec&gt; or undef if the given module has no
#pod requirements. This should only be used for informational purposes such as error
#pod messages and should not be interpreted or used for comparison (see
#pod L&lt;/accepts_module&gt; instead).
#pod
#pod =cut

sub requirements_for_module {
  my ($self, $module) = @_;
  my $entry = $self-&gt;__entry_for($module);
  return unless $entry;
  return $entry-&gt;as_string;
}

#pod =method structured_requirements_for_module
#pod
#pod   $req-&gt;structured_requirements_for_module( $module );
#pod
#pod This returns a data structure containing the version requirements for a given
#pod module or undef if the given module has no requirements.  This should
#pod not be used for version checks (see L&lt;/accepts_module&gt; instead).
#pod
#pod Added in version 2.134.
#pod
#pod =cut

sub structured_requirements_for_module {
  my ($self, $module) = @_;
  my $entry = $self-&gt;__entry_for($module);
  return unless $entry;
  return $entry-&gt;as_struct;
}

#pod =method required_modules
#pod
#pod This method returns a list of all the modules for which requirements have been
#pod specified.
#pod
#pod =cut

sub required_modules { keys %{ $_[0]{requirements} } }

#pod =method clone
#pod
#pod   $req-&gt;clone;
#pod
#pod This method returns a clone of the invocant.  The clone and the original object
#pod can then be changed independent of one another.
#pod
#pod =cut

sub clone {
  my ($self) = @_;
  my $new = (ref $self)-&gt;new;

  return $new-&gt;add_requirements($self);
}

sub __entry_for     { $_[0]{requirements}{ $_[1] } }

sub __modify_entry_for {
  my ($self, $name, $method, $version) = @_;

  my $fin = $self-&gt;is_finalized;
  my $old = $self-&gt;__entry_for($name);

  Carp::confess(&quot;can't add new requirements to finalized requirements&quot;)
    if $fin and not $old;

  my $new = ($old || 'CPAN::Meta::Requirements::_Range::Range')
          -&gt;$method($version, $name);

  Carp::confess(&quot;can't modify finalized requirements&quot;)
    if $fin and $old-&gt;as_string ne $new-&gt;as_string;

  $self-&gt;{requirements}{ $name } = $new;
}

#pod =method is_simple
#pod
#pod This method returns true if and only if all requirements are inclusive minimums
#pod -- that is, if their string expression is just the version number.
#pod
#pod =cut

sub is_simple {
  my ($self) = @_;
  for my $module ($self-&gt;required_modules) {
    # XXX: This is a complete hack, but also entirely correct.
    return if $self-&gt;__entry_for($module)-&gt;as_string =~ /\s/;
  }

  return 1;
}

#pod =method is_finalized
#pod
#pod This method returns true if the requirements have been finalized by having the
#pod C&lt;finalize&gt; method called on them.
#pod
#pod =cut

sub is_finalized { $_[0]{finalized} }

#pod =method finalize
#pod
#pod This method marks the requirements finalized.  Subsequent attempts to change
#pod the requirements will be fatal, I&lt;if&gt; they would result in a change.  If they
#pod would not alter the requirements, they have no effect.
#pod
#pod If a finalized set of requirements is cloned, the cloned requirements are not
#pod also finalized.
#pod
#pod =cut

sub finalize { $_[0]{finalized} = 1 }

#pod =method as_string_hash
#pod
#pod This returns a reference to a hash describing the requirements using the
#pod strings in the L&lt;CPAN::Meta::Spec&gt; specification.
#pod
#pod For example after the following program:
#pod
#pod   my $req = CPAN::Meta::Requirements-&gt;new;
#pod
#pod   $req-&gt;add_minimum('CPAN::Meta::Requirements' =&gt; 0.102);
#pod
#pod   $req-&gt;add_minimum('Library::Foo' =&gt; 1.208);
#pod
#pod   $req-&gt;add_maximum('Library::Foo' =&gt; 2.602);
#pod
#pod   $req-&gt;add_minimum('Module::Bar'  =&gt; 'v1.2.3');
#pod
#pod   $req-&gt;add_exclusion('Module::Bar'  =&gt; 'v1.2.8');
#pod
#pod   $req-&gt;exact_version('Xyzzy'  =&gt; '6.01');
#pod
#pod   my $hashref = $req-&gt;as_string_hash;
#pod
#pod C&lt;$hashref&gt; would contain:
#pod
#pod   {
#pod     'CPAN::Meta::Requirements' =&gt; '0.102',
#pod     'Library::Foo' =&gt; '&gt;= 1.208, &lt;= 2.206',
#pod     'Module::Bar'  =&gt; '&gt;= v1.2.3, != v1.2.8',
#pod     'Xyzzy'        =&gt; '== 6.01',
#pod   }
#pod
#pod =cut

sub as_string_hash {
  my ($self) = @_;

  my %hash = map {; $_ =&gt; $self-&gt;{requirements}{$_}-&gt;as_string }
             $self-&gt;required_modules;

  return \%hash;
}

#pod =method add_string_requirement
#pod
#pod   $req-&gt;add_string_requirement('Library::Foo' =&gt; '&gt;= 1.208, &lt;= 2.206');
#pod   $req-&gt;add_string_requirement('Library::Foo' =&gt; v1.208);
#pod
#pod This method parses the passed in string and adds the appropriate requirement
#pod for the given module.  A version can be a Perl &quot;v-string&quot;.  It understands
#pod version ranges as described in the L&lt;CPAN::Meta::Spec/Version Ranges&gt;. For
#pod example:
#pod
#pod =over 4
#pod
#pod =item 1.3
#pod
#pod =item &gt;= 1.3
#pod
#pod =item &lt;= 1.3
#pod
#pod =item == 1.3
#pod
#pod =item != 1.3
#pod
#pod =item &gt; 1.3
#pod
#pod =item &lt; 1.3
#pod
#pod =item &gt;= 1.3, != 1.5, &lt;= 2.0
#pod
#pod A version number without an operator is equivalent to specifying a minimum
#pod (C&lt;E&lt;gt&gt;=&gt;).  Extra whitespace is allowed.
#pod
#pod =back
#pod
#pod =cut

my %methods_for_op = (
  '==' =&gt; [ qw(exact_version) ],
  '!=' =&gt; [ qw(add_exclusion) ],
  '&gt;=' =&gt; [ qw(add_minimum)   ],
  '&lt;=' =&gt; [ qw(add_maximum)   ],
  '&gt;'  =&gt; [ qw(add_minimum add_exclusion) ],
  '&lt;'  =&gt; [ qw(add_maximum add_exclusion) ],
);

sub add_string_requirement {
  my ($self, $module, $req) = @_;

  unless ( defined $req &amp;&amp; length $req ) {
    $req = 0;
    $self-&gt;_blank_carp($module);
  }

  my $magic = _find_magic_vstring( $req );
  if (length $magic) {
    $self-&gt;add_minimum($module =&gt; $magic);
    return;
  }

  my @parts = split qr{\s*,\s*}, $req;

  for my $part (@parts) {
    my ($op, $ver) = $part =~ m{\A\s*(==|&gt;=|&gt;|&lt;=|&lt;|!=)\s*(.*)\z};

    if (! defined $op) {
      $self-&gt;add_minimum($module =&gt; $part);
    } else {
      Carp::confess(&quot;illegal requirement string: $req&quot;)
        unless my $methods = $methods_for_op{ $op };

      $self-&gt;$_($module =&gt; $ver) for @$methods;
    }
  }
}

#pod =method from_string_hash
#pod
#pod   my $req = CPAN::Meta::Requirements-&gt;from_string_hash( \%hash );
#pod   my $req = CPAN::Meta::Requirements-&gt;from_string_hash( \%hash, \%opts );
#pod
#pod This is an alternate constructor for a CPAN::Meta::Requirements
#pod object. It takes a hash of module names and version requirement
#pod strings and returns a new CPAN::Meta::Requirements object. As with
#pod add_string_requirement, a version can be a Perl &quot;v-string&quot;. Optionally,
#pod you can supply a hash-reference of options, exactly as with the L&lt;/new&gt;
#pod method.
#pod
#pod =cut

sub _blank_carp {
  my ($self, $module) = @_;
  Carp::carp(&quot;Undefined requirement for $module treated as '0'&quot;);
}

sub from_string_hash {
  my ($class, $hash, $options) = @_;

  my $self = $class-&gt;new($options);

  for my $module (keys %$hash) {
    my $req = $hash-&gt;{$module};
    unless ( defined $req &amp;&amp; length $req ) {
      $req = 0;
      $class-&gt;_blank_carp($module);
    }
    $self-&gt;add_string_requirement($module, $req);
  }

  return $self;
}

##############################################################

{
  package
    CPAN::Meta::Requirements::_Range::Exact;
  sub _new     { bless { version =&gt; $_[1] } =&gt; $_[0] }

  sub _accepts { return $_[0]{version} == $_[1] }

  sub as_string { return &quot;== $_[0]{version}&quot; }

  sub as_struct { return [ [ '==', &quot;$_[0]{version}&quot; ] ] }

  sub as_modifiers { return [ [ exact_version =&gt; $_[0]{version} ] ] }

  sub _reject_requirements {
    my ($self, $module, $error) = @_;
    Carp::confess(&quot;illegal requirements for $module: $error&quot;)
  }

  sub _clone {
    (ref $_[0])-&gt;_new( version-&gt;new( $_[0]{version} ) )
  }

  sub with_exact_version {
    my ($self, $version, $module) = @_;
    $module = 'module' unless defined $module;

    return $self-&gt;_clone if $self-&gt;_accepts($version);

    $self-&gt;_reject_requirements(
      $module,
      &quot;can't be exactly $version when exact requirement is already $self-&gt;{version}&quot;,
    );
  }

  sub with_minimum {
    my ($self, $minimum, $module) = @_;
    $module = 'module' unless defined $module;

    return $self-&gt;_clone if $self-&gt;{version} &gt;= $minimum;
    $self-&gt;_reject_requirements(
      $module,
      &quot;minimum $minimum exceeds exact specification $self-&gt;{version}&quot;,
    );
  }

  sub with_maximum {
    my ($self, $maximum, $module) = @_;
    $module = 'module' unless defined $module;

    return $self-&gt;_clone if $self-&gt;{version} &lt;= $maximum;
    $self-&gt;_reject_requirements(
      $module,
      &quot;maximum $maximum below exact specification $self-&gt;{version}&quot;,
    );
  }

  sub with_exclusion {
    my ($self, $exclusion, $module) = @_;
    $module = 'module' unless defined $module;

    return $self-&gt;_clone unless $exclusion == $self-&gt;{version};
    $self-&gt;_reject_requirements(
      $module,
      &quot;tried to exclude $exclusion, which is already exactly specified&quot;,
    );
  }
}

##############################################################

{
  package
    CPAN::Meta::Requirements::_Range::Range;

  sub _self { ref($_[0]) ? $_[0] : (bless { } =&gt; $_[0]) }

  sub _clone {
    return (bless { } =&gt; $_[0]) unless ref $_[0];

    my ($s) = @_;
    my %guts = (
      (exists $s-&gt;{minimum} ? (minimum =&gt; version-&gt;new($s-&gt;{minimum})) : ()),
      (exists $s-&gt;{maximum} ? (maximum =&gt; version-&gt;new($s-&gt;{maximum})) : ()),

      (exists $s-&gt;{exclusions}
        ? (exclusions =&gt; [ map { version-&gt;new($_) } @{ $s-&gt;{exclusions} } ])
        : ()),
    );

    bless \%guts =&gt; ref($s);
  }

  sub as_modifiers {
    my ($self) = @_;
    my @mods;
    push @mods, [ add_minimum =&gt; $self-&gt;{minimum} ] if exists $self-&gt;{minimum};
    push @mods, [ add_maximum =&gt; $self-&gt;{maximum} ] if exists $self-&gt;{maximum};
    push @mods, map {; [ add_exclusion =&gt; $_ ] } @{$self-&gt;{exclusions} || []};
    return \@mods;
  }

  sub as_struct {
    my ($self) = @_;

    return 0 if ! keys %$self;

    my @exclusions = @{ $self-&gt;{exclusions} || [] };

    my @parts;

    for my $tuple (
      [ qw( &gt;= &gt; minimum ) ],
      [ qw( &lt;= &lt; maximum ) ],
    ) {
      my ($op, $e_op, $k) = @$tuple;
      if (exists $self-&gt;{$k}) {
        my @new_exclusions = grep { $_ != $self-&gt;{ $k } } @exclusions;
        if (@new_exclusions == @exclusions) {
          push @parts, [ $op, &quot;$self-&gt;{ $k }&quot; ];
        } else {
          push @parts, [ $e_op, &quot;$self-&gt;{ $k }&quot; ];
          @exclusions = @new_exclusions;
        }
      }
    }

    push @parts, map {; [ &quot;!=&quot;, &quot;$_&quot; ] } @exclusions;

    return \@parts;
  }

  sub as_string {
    my ($self) = @_;

    my @parts = @{ $self-&gt;as_struct };

    return $parts[0][1] if @parts == 1 and $parts[0][0] eq '&gt;=';

    return join q{, }, map {; join q{ }, @$_ } @parts;
  }

  sub _reject_requirements {
    my ($self, $module, $error) = @_;
    Carp::confess(&quot;illegal requirements for $module: $error&quot;)
  }

  sub with_exact_version {
    my ($self, $version, $module) = @_;
    $module = 'module' unless defined $module;
    $self = $self-&gt;_clone;

    unless ($self-&gt;_accepts($version)) {
      $self-&gt;_reject_requirements(
        $module,
        &quot;exact specification $version outside of range &quot; . $self-&gt;as_string
      );
    }

    return CPAN::Meta::Requirements::_Range::Exact-&gt;_new($version);
  }

  sub _simplify {
    my ($self, $module) = @_;

    if (defined $self-&gt;{minimum} and defined $self-&gt;{maximum}) {
      if ($self-&gt;{minimum} == $self-&gt;{maximum}) {
        if (grep { $_ == $self-&gt;{minimum} } @{ $self-&gt;{exclusions} || [] }) {
          $self-&gt;_reject_requirements(
            $module,
            &quot;minimum and maximum are both $self-&gt;{minimum}, which is excluded&quot;,
          );
        }

        return CPAN::Meta::Requirements::_Range::Exact-&gt;_new($self-&gt;{minimum})
      }

      if ($self-&gt;{minimum} &gt; $self-&gt;{maximum}) {
        $self-&gt;_reject_requirements(
          $module,
          &quot;minimum $self-&gt;{minimum} exceeds maximum $self-&gt;{maximum}&quot;,
        );
      }
    }

    # eliminate irrelevant exclusions
    if ($self-&gt;{exclusions}) {
      my %seen;
      @{ $self-&gt;{exclusions} } = grep {
        (! defined $self-&gt;{minimum} or $_ &gt;= $self-&gt;{minimum})
        and
        (! defined $self-&gt;{maximum} or $_ &lt;= $self-&gt;{maximum})
        and
        ! $seen{$_}++
      } @{ $self-&gt;{exclusions} };
    }

    return $self;
  }

  sub with_minimum {
    my ($self, $minimum, $module) = @_;
    $module = 'module' unless defined $module;
    $self = $self-&gt;_clone;

    if (defined (my $old_min = $self-&gt;{minimum})) {
      $self-&gt;{minimum} = (sort { $b cmp $a } ($minimum, $old_min))[0];
    } else {
      $self-&gt;{minimum} = $minimum;
    }

    return $self-&gt;_simplify($module);
  }

  sub with_maximum {
    my ($self, $maximum, $module) = @_;
    $module = 'module' unless defined $module;
    $self = $self-&gt;_clone;

    if (defined (my $old_max = $self-&gt;{maximum})) {
      $self-&gt;{maximum} = (sort { $a cmp $b } ($maximum, $old_max))[0];
    } else {
      $self-&gt;{maximum} = $maximum;
    }

    return $self-&gt;_simplify($module);
  }

  sub with_exclusion {
    my ($self, $exclusion, $module) = @_;
    $module = 'module' unless defined $module;
    $self = $self-&gt;_clone;

    push @{ $self-&gt;{exclusions} ||= [] }, $exclusion;

    return $self-&gt;_simplify($module);
  }

  sub _accepts {
    my ($self, $version) = @_;

    return if defined $self-&gt;{minimum} and $version &lt; $self-&gt;{minimum};
    return if defined $self-&gt;{maximum} and $version &gt; $self-&gt;{maximum};
    return if defined $self-&gt;{exclusions}
          and grep { $version == $_ } @{ $self-&gt;{exclusions} };

    return 1;
  }
}

1;
# vim: ts=2 sts=2 sw=2 et:

__END__

=pod

=encoding UTF-8

=head1 NAME

CPAN::Meta::Requirements - a set of version requirements for a CPAN dist

=head1 VERSION

version 2.140

=head1 SYNOPSIS

  use CPAN::Meta::Requirements;

  my $build_requires = CPAN::Meta::Requirements-&gt;new;

  $build_requires-&gt;add_minimum('Library::Foo' =&gt; 1.208);

  $build_requires-&gt;add_minimum('Library::Foo' =&gt; 2.602);

  $build_requires-&gt;add_minimum('Module::Bar'  =&gt; 'v1.2.3');

  $METAyml-&gt;{build_requires} = $build_requires-&gt;as_string_hash;

=head1 DESCRIPTION

A CPAN::Meta::Requirements object models a set of version constraints like
those specified in the F&lt;META.yml&gt; or F&lt;META.json&gt; files in CPAN distributions,
and as defined by L&lt;CPAN::Meta::Spec&gt;;
It can be built up by adding more and more constraints, and it will reduce them
to the simplest representation.

Logically impossible constraints will be identified immediately by thrown
exceptions.

=head1 METHODS

=head2 new

  my $req = CPAN::Meta::Requirements-&gt;new;

This returns a new CPAN::Meta::Requirements object.  It takes an optional
hash reference argument.  Currently, only one key is supported:

=over 4

=item *

C&lt;bad_version_hook&gt; -- if provided, when a version cannot be parsed into a version object, this code reference will be called with the invalid version string as first argument, and the module name as second argument.  It must return a valid version object.

=back

All other keys are ignored.

=head2 add_minimum

  $req-&gt;add_minimum( $module =&gt; $version );

This adds a new minimum version requirement.  If the new requirement is
redundant to the existing specification, this has no effect.

Minimum requirements are inclusive.  C&lt;$version&gt; is required, along with any
greater version number.

This method returns the requirements object.

=head2 add_maximum

  $req-&gt;add_maximum( $module =&gt; $version );

This adds a new maximum version requirement.  If the new requirement is
redundant to the existing specification, this has no effect.

Maximum requirements are inclusive.  No version strictly greater than the given
version is allowed.

This method returns the requirements object.

=head2 add_exclusion

  $req-&gt;add_exclusion( $module =&gt; $version );

This adds a new excluded version.  For example, you might use these three
method calls:

  $req-&gt;add_minimum( $module =&gt; '1.00' );
  $req-&gt;add_maximum( $module =&gt; '1.82' );

  $req-&gt;add_exclusion( $module =&gt; '1.75' );

Any version between 1.00 and 1.82 inclusive would be acceptable, except for
1.75.

This method returns the requirements object.

=head2 exact_version

  $req-&gt;exact_version( $module =&gt; $version );

This sets the version required for the given module to I&lt;exactly&gt; the given
version.  No other version would be considered acceptable.

This method returns the requirements object.

=head2 add_requirements

  $req-&gt;add_requirements( $another_req_object );

This method adds all the requirements in the given CPAN::Meta::Requirements
object to the requirements object on which it was called.  If there are any
conflicts, an exception is thrown.

This method returns the requirements object.

=head2 accepts_module

  my $bool = $req-&gt;accepts_module($module =&gt; $version);

Given an module and version, this method returns true if the version
specification for the module accepts the provided version.  In other words,
given:

  Module =&gt; '&gt;= 1.00, &lt; 2.00'

We will accept 1.00 and 1.75 but not 0.50 or 2.00.

For modules that do not appear in the requirements, this method will return
true.

=head2 clear_requirement

  $req-&gt;clear_requirement( $module );

This removes the requirement for a given module from the object.

This method returns the requirements object.

=head2 requirements_for_module

  $req-&gt;requirements_for_module( $module );

This returns a string containing the version requirements for a given module in
the format described in L&lt;CPAN::Meta::Spec&gt; or undef if the given module has no
requirements. This should only be used for informational purposes such as error
messages and should not be interpreted or used for comparison (see
L&lt;/accepts_module&gt; instead).

=head2 structured_requirements_for_module

  $req-&gt;structured_requirements_for_module( $module );

This returns a data structure containing the version requirements for a given
module or undef if the given module has no requirements.  This should
not be used for version checks (see L&lt;/accepts_module&gt; instead).

Added in version 2.134.

=head2 required_modules

This method returns a list of all the modules for which requirements have been
specified.

=head2 clone

  $req-&gt;clone;

This method returns a clone of the invocant.  The clone and the original object
can then be changed independent of one another.

=head2 is_simple

This method returns true if and only if all requirements are inclusive minimums
-- that is, if their string expression is just the version number.

=head2 is_finalized

This method returns true if the requirements have been finalized by having the
C&lt;finalize&gt; method called on them.

=head2 finalize

This method marks the requirements finalized.  Subsequent attempts to change
the requirements will be fatal, I&lt;if&gt; they would result in a change.  If they
would not alter the requirements, they have no effect.

If a finalized set of requirements is cloned, the cloned requirements are not
also finalized.

=head2 as_string_hash

This returns a reference to a hash describing the requirements using the
strings in the L&lt;CPAN::Meta::Spec&gt; specification.

For example after the following program:

  my $req = CPAN::Meta::Requirements-&gt;new;

  $req-&gt;add_minimum('CPAN::Meta::Requirements' =&gt; 0.102);

  $req-&gt;add_minimum('Library::Foo' =&gt; 1.208);

  $req-&gt;add_maximum('Library::Foo' =&gt; 2.602);

  $req-&gt;add_minimum('Module::Bar'  =&gt; 'v1.2.3');

  $req-&gt;add_exclusion('Module::Bar'  =&gt; 'v1.2.8');

  $req-&gt;exact_version('Xyzzy'  =&gt; '6.01');

  my $hashref = $req-&gt;as_string_hash;

C&lt;$hashref&gt; would contain:

  {
    'CPAN::Meta::Requirements' =&gt; '0.102',
    'Library::Foo' =&gt; '&gt;= 1.208, &lt;= 2.206',
    'Module::Bar'  =&gt; '&gt;= v1.2.3, != v1.2.8',
    'Xyzzy'        =&gt; '== 6.01',
  }

=head2 add_string_requirement

  $req-&gt;add_string_requirement('Library::Foo' =&gt; '&gt;= 1.208, &lt;= 2.206');
  $req-&gt;add_string_requirement('Library::Foo' =&gt; v1.208);

This method parses the passed in string and adds the appropriate requirement
for the given module.  A version can be a Perl &quot;v-string&quot;.  It understands
version ranges as described in the L&lt;CPAN::Meta::Spec/Version Ranges&gt;. For
example:

=over 4

=item 1.3

=item &gt;= 1.3

=item &lt;= 1.3

=item == 1.3

=item != 1.3

=item &gt; 1.3

=item &lt; 1.3

=item &gt;= 1.3, != 1.5, &lt;= 2.0

A version number without an operator is equivalent to specifying a minimum
(C&lt;E&lt;gt&gt;=&gt;).  Extra whitespace is allowed.

=back

=head2 from_string_hash

  my $req = CPAN::Meta::Requirements-&gt;from_string_hash( \%hash );
  my $req = CPAN::Meta::Requirements-&gt;from_string_hash( \%hash, \%opts );

This is an alternate constructor for a CPAN::Meta::Requirements
object. It takes a hash of module names and version requirement
strings and returns a new CPAN::Meta::Requirements object. As with
add_string_requirement, a version can be a Perl &quot;v-string&quot;. Optionally,
you can supply a hash-reference of options, exactly as with the L&lt;/new&gt;
method.

=for :stopwords cpan testmatrix url annocpan anno bugtracker rt cpants kwalitee diff irc mailto metadata placeholders metacpan

=head1 SUPPORT

=head2 Bugs / Feature Requests

Please report any bugs or feature requests through the issue tracker
at L&lt;https://github.com/Perl-Toolchain-Gang/CPAN-Meta-Requirements/issues&gt;.
You will be notified automatically of any progress on your issue.

=head2 Source Code

This is open source software.  The code repository is available for
public review and contribution under the terms of the license.

L&lt;https://github.com/Perl-Toolchain-Gang/CPAN-Meta-Requirements&gt;

  git clone https://github.com/Perl-Toolchain-Gang/CPAN-Meta-Requirements.git

=head1 AUTHORS

=over 4

=item *

David Golden &lt;dagolden@cpan.org&gt;

=item *

Ricardo Signes &lt;rjbs@cpan.org&gt;

=back

=head1 CONTRIBUTORS

=for stopwords Ed J Karen Etheridge Leon Timmermans robario

=over 4

=item *

Ed J &lt;mohawk2@users.noreply.github.com&gt;

=item *

Karen Etheridge &lt;ether@cpan.org&gt;

=item *

Leon Timmermans &lt;fawaka@gmail.com&gt;

=item *

robario &lt;webmaster@robario.com&gt;

=back

=head1 COPYRIGHT AND LICENSE

This software is copyright (c) 2010 by David Golden and Ricardo Signes.

This is free software; you can redistribute it and/or modify it under
the same terms as the Perl 5 programming language system itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FCPAN%2FMeta'>Back to Directory</a>