<h2>Editing File: /usr/share/perl5/vendor_perl/Archive/Zip/MemberRead.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Archive::Zip::MemberRead;

=head1 NAME

Archive::Zip::MemberRead - A wrapper that lets you read Zip archive members as if they were files.

=cut

=head1 SYNOPSIS

  use Archive::Zip;
  use Archive::Zip::MemberRead;
  $zip = Archive::Zip-&gt;new(&quot;file.zip&quot;);
  $fh  = Archive::Zip::MemberRead-&gt;new($zip, &quot;subdir/abc.txt&quot;);
  while (defined($line = $fh-&gt;getline()))
  {
      print $fh-&gt;input_line_number . &quot;#: $line\n&quot;;
  }

  $read = $fh-&gt;read($buffer, 32*1024);
  print &quot;Read $read bytes as :$buffer:\n&quot;;

=head1 DESCRIPTION

The Archive::Zip::MemberRead module lets you read Zip archive member data
just like you read data from files.

=head1 METHODS

=over 4

=cut

use strict;

use Archive::Zip qw( :ERROR_CODES :CONSTANTS );

use vars qw{$VERSION};

my $nl;

BEGIN {
    $VERSION = '1.60';
    $VERSION = eval $VERSION;

# Requirement for newline conversion. Should check for e.g., DOS and OS/2 as well, but am too lazy.
    $nl = $^O eq 'MSWin32' ? &quot;\r\n&quot; : &quot;\n&quot;;
}

=item Archive::Zip::Member::readFileHandle()

You can get a C&lt;Archive::Zip::MemberRead&gt; from an archive member by
calling C&lt;readFileHandle()&gt;:

  my $member = $zip-&gt;memberNamed('abc/def.c');
  my $fh = $member-&gt;readFileHandle();
  while (defined($line = $fh-&gt;getline()))
  {
      # ...
  }
  $fh-&gt;close();

=cut

sub Archive::Zip::Member::readFileHandle {
    return Archive::Zip::MemberRead-&gt;new(shift());
}

=item Archive::Zip::MemberRead-&gt;new($zip, $fileName)

=item Archive::Zip::MemberRead-&gt;new($zip, $member)

=item Archive::Zip::MemberRead-&gt;new($member)

Construct a new Archive::Zip::MemberRead on the specified member.

  my $fh = Archive::Zip::MemberRead-&gt;new($zip, 'fred.c')

=cut

sub new {
    my ($class, $zip, $file) = @_;
    my ($self, $member);

    if ($zip &amp;&amp; $file)    # zip and filename, or zip and member
    {
        $member = ref($file) ? $file : $zip-&gt;memberNamed($file);
    } elsif ($zip &amp;&amp; !$file &amp;&amp; ref($zip))    # just member
    {
        $member = $zip;
    } else {
        die(
            'Archive::Zip::MemberRead::new needs a zip and filename, zip and member, or member'
        );
    }

    $self = {};
    bless($self, $class);
    $self-&gt;set_member($member);
    return $self;
}

sub set_member {
    my ($self, $member) = @_;

    $self-&gt;{member} = $member;
    $self-&gt;set_compression(COMPRESSION_STORED);
    $self-&gt;rewind();
}

sub set_compression {
    my ($self, $compression) = @_;
    $self-&gt;{member}-&gt;desiredCompressionMethod($compression) if $self-&gt;{member};
}

=item setLineEnd(expr)

Set the line end character to use. This is set to \n by default
except on Windows systems where it is set to \r\n. You will
only need to set this on systems which are not Windows or Unix
based and require a line end different from \n.
This is a class method so call as C&lt;Archive::Zip::MemberRead&gt;-&gt;C&lt;setLineEnd($nl)&gt;

=cut

sub setLineEnd {
    shift;
    $nl = shift;
}

=item rewind()

Rewinds an C&lt;Archive::Zip::MemberRead&gt; so that you can read from it again
starting at the beginning.

=cut

sub rewind {
    my $self = shift;

    $self-&gt;_reset_vars();
    $self-&gt;{member}-&gt;rewindData() if $self-&gt;{member};
}

sub _reset_vars {
    my $self = shift;

    $self-&gt;{line_no} = 0;
    $self-&gt;{at_end}  = 0;

    delete $self-&gt;{buffer};
}

=item input_record_separator(expr)

If the argument is given, input_record_separator for this
instance is set to it. The current setting (which may be
the global $/) is always returned.

=cut

sub input_record_separator {
    my $self = shift;
    if (@_) {
        $self-&gt;{sep} = shift;
        $self-&gt;{sep_re} =
          _sep_as_re($self-&gt;{sep});    # Cache the RE as an optimization
    }
    return exists $self-&gt;{sep} ? $self-&gt;{sep} : $/;
}

# Return the input_record_separator in use as an RE fragment
# Note that if we have a per-instance input_record_separator
# we can just return the already converted value. Otherwise,
# the conversion must be done on $/ every time since we cannot
# know whether it has changed or not.
sub _sep_re {
    my $self = shift;

    # Important to phrase this way: sep's value may be undef.
    return exists $self-&gt;{sep} ? $self-&gt;{sep_re} : _sep_as_re($/);
}

# Convert the input record separator into an RE and return it.
sub _sep_as_re {
    my $sep = shift;
    if (defined $sep) {
        if ($sep eq '') {
            return &quot;(?:$nl){2,}&quot;;
        } else {
            $sep =~ s/\n/$nl/og;
            return quotemeta $sep;
        }
    } else {
        return undef;
    }
}

=item input_line_number()

Returns the current line number, but only if you're using C&lt;getline()&gt;.
Using C&lt;read()&gt; will not update the line number.

=cut

sub input_line_number {
    my $self = shift;
    return $self-&gt;{line_no};
}

=item close()

Closes the given file handle.

=cut

sub close {
    my $self = shift;

    $self-&gt;_reset_vars();
    $self-&gt;{member}-&gt;endRead();
}

=item buffer_size([ $size ])

Gets or sets the buffer size used for reads.
Default is the chunk size used by Archive::Zip.

=cut

sub buffer_size {
    my ($self, $size) = @_;

    if (!$size) {
        return $self-&gt;{chunkSize} || Archive::Zip::chunkSize();
    } else {
        $self-&gt;{chunkSize} = $size;
    }
}

=item getline()

Returns the next line from the currently open member.
Makes sense only for text files.
A read error is considered fatal enough to die.
Returns undef on eof. All subsequent calls would return undef,
unless a rewind() is called.
Note: The line returned has the input_record_separator (default: newline) removed.

=item getline( { preserve_line_ending =&gt; 1 } )

Returns the next line including the line ending.

=cut

sub getline {
    my ($self, $argref) = @_;

    my $size = $self-&gt;buffer_size();
    my $sep  = $self-&gt;_sep_re();

    my $preserve_line_ending;
    if (ref $argref eq 'HASH') {
        $preserve_line_ending = $argref-&gt;{'preserve_line_ending'};
        $sep =~ s/\\([^A-Za-z_0-9])+/$1/g;
    }

    for (; ;) {
        if (   $sep
            &amp;&amp; defined($self-&gt;{buffer})
            &amp;&amp; $self-&gt;{buffer} =~ s/^(.*?)$sep//s) {
            my $line = $1;
            $self-&gt;{line_no}++;
            if ($preserve_line_ending) {
                return $line . $sep;
            } else {
                return $line;
            }
        } elsif ($self-&gt;{at_end}) {
            $self-&gt;{line_no}++ if $self-&gt;{buffer};
            return delete $self-&gt;{buffer};
        }
        my ($temp, $status) = $self-&gt;{member}-&gt;readChunk($size);
        if ($status != AZ_OK &amp;&amp; $status != AZ_STREAM_END) {
            die &quot;ERROR: Error reading chunk from archive - $status&quot;;
        }
        $self-&gt;{at_end} = $status == AZ_STREAM_END;
        $self-&gt;{buffer} .= $$temp;
    }
}

=item read($buffer, $num_bytes_to_read)

Simulates a normal C&lt;read()&gt; system call.
Returns the no. of bytes read. C&lt;undef&gt; on error, 0 on eof, I&lt;e.g.&gt;:

  $fh = Archive::Zip::MemberRead-&gt;new($zip, &quot;sreeji/secrets.bin&quot;);
  while (1)
  {
    $read = $fh-&gt;read($buffer, 1024);
    die &quot;FATAL ERROR reading my secrets !\n&quot; if (!defined($read));
    last if (!$read);
    # Do processing.
    ....
   }

=cut

#
# All these $_ are required to emulate read().
#
sub read {
    my $self = $_[0];
    my $size = $_[2];
    my ($temp, $status, $ret);

    ($temp, $status) = $self-&gt;{member}-&gt;readChunk($size);
    if ($status != AZ_OK &amp;&amp; $status != AZ_STREAM_END) {
        $_[1] = undef;
        $ret = undef;
    } else {
        $_[1] = $$temp;
        $ret = length($$temp);
    }
    return $ret;
}

1;

=back

=head1 AUTHOR

Sreeji K. Das E&lt;lt&gt;sreeji_k@yahoo.comE&lt;gt&gt;

See L&lt;Archive::Zip&gt; by Ned Konz without which this module does not make
any sense! 

Minor mods by Ned Konz.

=head1 COPYRIGHT

Copyright 2002 Sreeji K. Das.

This program is free software; you can redistribute it and/or modify it under
the same terms as Perl itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FArchive%2FZip'>Back to Directory</a>