<h2>Editing File: /usr/share/perl5/vendor_perl/Archive/Zip/Member.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Archive::Zip::Member;

# A generic member of an archive

use strict;
use vars qw( $VERSION @ISA );

BEGIN {
    $VERSION = '1.60';
    @ISA     = qw( Archive::Zip );

    if ($^O eq 'MSWin32') {
        require Win32;
        require Encode;
        Encode-&gt;import(qw{ decode_utf8 });
    }
}

use Archive::Zip qw(
  :CONSTANTS
  :MISC_CONSTANTS
  :ERROR_CODES
  :PKZIP_CONSTANTS
  :UTILITY_METHODS
);

use Time::Local ();
use Compress::Raw::Zlib qw( Z_OK Z_STREAM_END MAX_WBITS );
use File::Path;
use File::Basename;

# Unix perms for default creation of files/dirs.
use constant DEFAULT_DIRECTORY_PERMISSIONS =&gt; 040755;
use constant DEFAULT_FILE_PERMISSIONS      =&gt; 0100666;
use constant DIRECTORY_ATTRIB              =&gt; 040000;
use constant FILE_ATTRIB                   =&gt; 0100000;

# Returns self if successful, else undef
# Assumes that fh is positioned at beginning of central directory file header.
# Leaves fh positioned immediately after file header or EOCD signature.
sub _newFromZipFile {
    my $class = shift;
    my $self  = Archive::Zip::ZipFileMember-&gt;_newFromZipFile(@_);
    return $self;
}

sub newFromString {
    my $class = shift;

    my ($stringOrStringRef, $fileName);
    if (ref($_[0]) eq 'HASH') {
        $stringOrStringRef = $_[0]-&gt;{string};
        $fileName          = $_[0]-&gt;{zipName};
    } else {
        ($stringOrStringRef, $fileName) = @_;
    }

    my $self =
      Archive::Zip::StringMember-&gt;_newFromString($stringOrStringRef, $fileName);
    return $self;
}

sub newFromFile {
    my $class = shift;

    my ($fileName, $zipName);
    if (ref($_[0]) eq 'HASH') {
        $fileName = $_[0]-&gt;{fileName};
        $zipName  = $_[0]-&gt;{zipName};
    } else {
        ($fileName, $zipName) = @_;
    }

    my $self =
      Archive::Zip::NewFileMember-&gt;_newFromFileNamed($fileName, $zipName);
    return $self;
}

sub newDirectoryNamed {
    my $class = shift;

    my ($directoryName, $newName);
    if (ref($_[0]) eq 'HASH') {
        $directoryName = $_[0]-&gt;{directoryName};
        $newName       = $_[0]-&gt;{zipName};
    } else {
        ($directoryName, $newName) = @_;
    }

    my $self =
      Archive::Zip::DirectoryMember-&gt;_newNamed($directoryName, $newName);
    return $self;
}

sub new {
    my $class = shift;
    my $self  = {
        'lastModFileDateTime'      =&gt; 0,
        'fileAttributeFormat'      =&gt; FA_UNIX,
        'versionMadeBy'            =&gt; 20,
        'versionNeededToExtract'   =&gt; 20,
        'bitFlag'                  =&gt; ($Archive::Zip::UNICODE ? 0x0800 : 0),
        'compressionMethod'        =&gt; COMPRESSION_STORED,
        'desiredCompressionMethod' =&gt; COMPRESSION_STORED,
        'desiredCompressionLevel'  =&gt; COMPRESSION_LEVEL_NONE,
        'internalFileAttributes'   =&gt; 0,
        'externalFileAttributes'   =&gt; 0,                        # set later
        'fileName'                 =&gt; '',
        'cdExtraField'             =&gt; '',
        'localExtraField'          =&gt; '',
        'fileComment'              =&gt; '',
        'crc32'                    =&gt; 0,
        'compressedSize'           =&gt; 0,
        'uncompressedSize'         =&gt; 0,
        'isSymbolicLink'           =&gt; 0,
        'password' =&gt; undef,    # password for encrypted data
        'crc32c'   =&gt; -1,       # crc for decrypted data
        @_
    };
    bless($self, $class);
    $self-&gt;unixFileAttributes($self-&gt;DEFAULT_FILE_PERMISSIONS);
    return $self;
}

sub _becomeDirectoryIfNecessary {
    my $self = shift;
    $self-&gt;_become('Archive::Zip::DirectoryMember')
      if $self-&gt;isDirectory();
    return $self;
}

# Morph into given class (do whatever cleanup I need to do)
sub _become {
    return bless($_[0], $_[1]);
}

sub versionMadeBy {
    shift-&gt;{'versionMadeBy'};
}

sub fileAttributeFormat {
    my $self = shift;

    if (@_) {
        $self-&gt;{fileAttributeFormat} =
          (ref($_[0]) eq 'HASH') ? $_[0]-&gt;{format} : $_[0];
    } else {
        return $self-&gt;{fileAttributeFormat};
    }
}

sub versionNeededToExtract {
    shift-&gt;{'versionNeededToExtract'};
}

sub bitFlag {
    my $self = shift;

# Set General Purpose Bit Flags according to the desiredCompressionLevel setting
    if (   $self-&gt;desiredCompressionLevel == 1
        || $self-&gt;desiredCompressionLevel == 2) {
        $self-&gt;{'bitFlag'} |= DEFLATING_COMPRESSION_FAST;
    } elsif ($self-&gt;desiredCompressionLevel == 3
        || $self-&gt;desiredCompressionLevel == 4
        || $self-&gt;desiredCompressionLevel == 5
        || $self-&gt;desiredCompressionLevel == 6
        || $self-&gt;desiredCompressionLevel == 7) {
        $self-&gt;{'bitFlag'} |= DEFLATING_COMPRESSION_NORMAL;
    } elsif ($self-&gt;desiredCompressionLevel == 8
        || $self-&gt;desiredCompressionLevel == 9) {
        $self-&gt;{'bitFlag'} |= DEFLATING_COMPRESSION_MAXIMUM;
    }

    if ($Archive::Zip::UNICODE) {
        $self-&gt;{'bitFlag'} |= 0x0800;
    }
    $self-&gt;{'bitFlag'};
}

sub password {
    my $self = shift;
    $self-&gt;{'password'} = shift if @_;
    $self-&gt;{'password'};
}

sub compressionMethod {
    shift-&gt;{'compressionMethod'};
}

sub desiredCompressionMethod {
    my $self = shift;
    my $newDesiredCompressionMethod =
      (ref($_[0]) eq 'HASH') ? shift-&gt;{compressionMethod} : shift;
    my $oldDesiredCompressionMethod = $self-&gt;{'desiredCompressionMethod'};
    if (defined($newDesiredCompressionMethod)) {
        $self-&gt;{'desiredCompressionMethod'} = $newDesiredCompressionMethod;
        if ($newDesiredCompressionMethod == COMPRESSION_STORED) {
            $self-&gt;{'desiredCompressionLevel'} = 0;
            $self-&gt;{'bitFlag'} &amp;= ~GPBF_HAS_DATA_DESCRIPTOR_MASK
                if $self-&gt;uncompressedSize() == 0;
        } elsif ($oldDesiredCompressionMethod == COMPRESSION_STORED) {
            $self-&gt;{'desiredCompressionLevel'} = COMPRESSION_LEVEL_DEFAULT;
        }
    }
    return $oldDesiredCompressionMethod;
}

sub desiredCompressionLevel {
    my $self = shift;
    my $newDesiredCompressionLevel =
      (ref($_[0]) eq 'HASH') ? shift-&gt;{compressionLevel} : shift;
    my $oldDesiredCompressionLevel = $self-&gt;{'desiredCompressionLevel'};
    if (defined($newDesiredCompressionLevel)) {
        $self-&gt;{'desiredCompressionLevel'}  = $newDesiredCompressionLevel;
        $self-&gt;{'desiredCompressionMethod'} = (
            $newDesiredCompressionLevel
            ? COMPRESSION_DEFLATED
            : COMPRESSION_STORED
        );
    }
    return $oldDesiredCompressionLevel;
}

sub fileName {
    my $self    = shift;
    my $newName = shift;
    if (defined $newName) {
        $newName =~ s{[\\/]+}{/}g;    # deal with dos/windoze problems
        $self-&gt;{'fileName'} = $newName;
    }
    return $self-&gt;{'fileName'};
}

sub fileNameAsBytes {
    my $self  = shift;
    my $bytes = $self-&gt;{'fileName'};
    if($self-&gt;{'bitFlag'} &amp; 0x800){
        $bytes = Encode::encode_utf8($bytes);
    }
    return $bytes;
}

sub lastModFileDateTime {
    my $modTime = shift-&gt;{'lastModFileDateTime'};
    $modTime =~ m/^(\d+)$/;           # untaint
    return $1;
}

sub lastModTime {
    my $self = shift;
    return _dosToUnixTime($self-&gt;lastModFileDateTime());
}

sub setLastModFileDateTimeFromUnix {
    my $self   = shift;
    my $time_t = shift;
    $self-&gt;{'lastModFileDateTime'} = _unixToDosTime($time_t);
}

sub internalFileAttributes {
    shift-&gt;{'internalFileAttributes'};
}

sub externalFileAttributes {
    shift-&gt;{'externalFileAttributes'};
}

# Convert UNIX permissions into proper value for zip file
# Usable as a function or a method
sub _mapPermissionsFromUnix {
    my $self    = shift;
    my $mode    = shift;
    my $attribs = $mode &lt;&lt; 16;

    # Microsoft Windows Explorer needs this bit set for directories
    if ($mode &amp; DIRECTORY_ATTRIB) {
        $attribs |= 16;
    }

    return $attribs;

    # TODO: map more MS-DOS perms
}

# Convert ZIP permissions into Unix ones
#
# This was taken from Info-ZIP group's portable UnZip
# zipfile-extraction program, version 5.50.
# http://www.info-zip.org/pub/infozip/
#
# See the mapattr() function in unix/unix.c
# See the attribute format constants in unzpriv.h
#
# XXX Note that there's one situation that is not implemented
# yet that depends on the &quot;extra field.&quot;
sub _mapPermissionsToUnix {
    my $self = shift;

    my $format  = $self-&gt;{'fileAttributeFormat'};
    my $attribs = $self-&gt;{'externalFileAttributes'};

    my $mode = 0;

    if ($format == FA_AMIGA) {
        $attribs = $attribs &gt;&gt; 17 &amp; 7;                         # Amiga RWE bits
        $mode    = $attribs &lt;&lt; 6 | $attribs &lt;&lt; 3 | $attribs;
        return $mode;
    }

    if ($format == FA_THEOS) {
        $attribs &amp;= 0xF1FFFFFF;
        if (($attribs &amp; 0xF0000000) != 0x40000000) {
            $attribs &amp;= 0x01FFFFFF;    # not a dir, mask all ftype bits
        } else {
            $attribs &amp;= 0x41FFFFFF;    # leave directory bit as set
        }
    }

    if (   $format == FA_UNIX
        || $format == FA_VAX_VMS
        || $format == FA_ACORN
        || $format == FA_ATARI_ST
        || $format == FA_BEOS
        || $format == FA_QDOS
        || $format == FA_TANDEM) {
        $mode = $attribs &gt;&gt; 16;
        return $mode if $mode != 0 or not $self-&gt;localExtraField;

        # warn(&quot;local extra field is: &quot;, $self-&gt;localExtraField, &quot;\n&quot;);

        # XXX This condition is not implemented
        # I'm just including the comments from the info-zip section for now.

        # Some (non-Info-ZIP) implementations of Zip for Unix and
        # VMS (and probably others ??) leave 0 in the upper 16-bit
        # part of the external_file_attributes field. Instead, they
        # store file permission attributes in some extra field.
        # As a work-around, we search for the presence of one of
        # these extra fields and fall back to the MSDOS compatible
        # part of external_file_attributes if one of the known
        # e.f. types has been detected.
        # Later, we might implement extraction of the permission
        # bits from the VMS extra field. But for now, the work-around
        # should be sufficient to provide &quot;readable&quot; extracted files.
        # (For ASI Unix e.f., an experimental remap from the e.f.
        # mode value IS already provided!)
    }

    # PKWARE's PKZip for Unix marks entries as FA_MSDOS, but stores the
    # Unix attributes in the upper 16 bits of the external attributes
    # field, just like Info-ZIP's Zip for Unix.  We try to use that
    # value, after a check for consistency with the MSDOS attribute
    # bits (see below).
    if ($format == FA_MSDOS) {
        $mode = $attribs &gt;&gt; 16;
    }

    # FA_MSDOS, FA_OS2_HPFS, FA_WINDOWS_NTFS, FA_MACINTOSH, FA_TOPS20
    $attribs = !($attribs &amp; 1) &lt;&lt; 1 | ($attribs &amp; 0x10) &gt;&gt; 4;

    # keep previous $mode setting when its &quot;owner&quot;
    # part appears to be consistent with DOS attribute flags!
    return $mode if ($mode &amp; 0700) == (0400 | $attribs &lt;&lt; 6);
    $mode = 0444 | $attribs &lt;&lt; 6 | $attribs &lt;&lt; 3 | $attribs;
    return $mode;
}

sub unixFileAttributes {
    my $self     = shift;
    my $oldPerms = $self-&gt;_mapPermissionsToUnix;

    my $perms;
    if (@_) {
        $perms = (ref($_[0]) eq 'HASH') ? $_[0]-&gt;{attributes} : $_[0];

        if ($self-&gt;isDirectory) {
            $perms &amp;= ~FILE_ATTRIB;
            $perms |= DIRECTORY_ATTRIB;
        } else {
            $perms &amp;= ~DIRECTORY_ATTRIB;
            $perms |= FILE_ATTRIB;
        }
        $self-&gt;{externalFileAttributes} =
          $self-&gt;_mapPermissionsFromUnix($perms);
    }

    return $oldPerms;
}

sub localExtraField {
    my $self = shift;

    if (@_) {
        $self-&gt;{localExtraField} =
          (ref($_[0]) eq 'HASH') ? $_[0]-&gt;{field} : $_[0];
    } else {
        return $self-&gt;{localExtraField};
    }
}

sub cdExtraField {
    my $self = shift;

    if (@_) {
        $self-&gt;{cdExtraField} = (ref($_[0]) eq 'HASH') ? $_[0]-&gt;{field} : $_[0];
    } else {
        return $self-&gt;{cdExtraField};
    }
}

sub extraFields {
    my $self = shift;
    return $self-&gt;localExtraField() . $self-&gt;cdExtraField();
}

sub fileComment {
    my $self = shift;

    if (@_) {
        $self-&gt;{fileComment} =
          (ref($_[0]) eq 'HASH')
          ? pack('C0a*', $_[0]-&gt;{comment})
          : pack('C0a*', $_[0]);
    } else {
        return $self-&gt;{fileComment};
    }
}

sub hasDataDescriptor {
    my $self = shift;
    if (@_) {
        my $shouldHave = shift;
        if ($shouldHave) {
            $self-&gt;{'bitFlag'} |= GPBF_HAS_DATA_DESCRIPTOR_MASK;
        } else {
            $self-&gt;{'bitFlag'} &amp;= ~GPBF_HAS_DATA_DESCRIPTOR_MASK;
        }
    }
    return $self-&gt;{'bitFlag'} &amp; GPBF_HAS_DATA_DESCRIPTOR_MASK;
}

sub crc32 {
    shift-&gt;{'crc32'};
}

sub crc32String {
    sprintf(&quot;%08x&quot;, shift-&gt;{'crc32'});
}

sub compressedSize {
    shift-&gt;{'compressedSize'};
}

sub uncompressedSize {
    shift-&gt;{'uncompressedSize'};
}

sub isEncrypted {
    shift-&gt;{'bitFlag'} &amp; GPBF_ENCRYPTED_MASK;
}

sub isTextFile {
    my $self = shift;
    my $bit  = $self-&gt;internalFileAttributes() &amp; IFA_TEXT_FILE_MASK;
    if (@_) {
        my $flag = (ref($_[0]) eq 'HASH') ? shift-&gt;{flag} : shift;
        $self-&gt;{'internalFileAttributes'} &amp;= ~IFA_TEXT_FILE_MASK;
        $self-&gt;{'internalFileAttributes'} |=
          ($flag ? IFA_TEXT_FILE : IFA_BINARY_FILE);
    }
    return $bit == IFA_TEXT_FILE;
}

sub isBinaryFile {
    my $self = shift;
    my $bit  = $self-&gt;internalFileAttributes() &amp; IFA_TEXT_FILE_MASK;
    if (@_) {
        my $flag = shift;
        $self-&gt;{'internalFileAttributes'} &amp;= ~IFA_TEXT_FILE_MASK;
        $self-&gt;{'internalFileAttributes'} |=
          ($flag ? IFA_BINARY_FILE : IFA_TEXT_FILE);
    }
    return $bit == IFA_BINARY_FILE;
}

sub extractToFileNamed {
    my $self = shift;

    # local FS name
    my $name = (ref($_[0]) eq 'HASH') ? $_[0]-&gt;{name} : $_[0];
    $self-&gt;{'isSymbolicLink'} = 0;

    # Check if the file / directory is a symbolic link or not
    if ($self-&gt;{'externalFileAttributes'} == 0xA1FF0000) {
        $self-&gt;{'isSymbolicLink'} = 1;
        $self-&gt;{'newName'}        = $name;
        my ($status, $fh) = _newFileHandle($name, 'r');
        my $retval = $self-&gt;extractToFileHandle($fh);
        $fh-&gt;close();
    } else {

        #return _writeSymbolicLink($self, $name) if $self-&gt;isSymbolicLink();

        my ($status, $fh);
        if ($^O eq 'MSWin32' &amp;&amp; $Archive::Zip::UNICODE) {
            $name = decode_utf8(Win32::GetFullPathName($name));
            mkpath_win32($name);
            Win32::CreateFile($name);
            ($status, $fh) = _newFileHandle(Win32::GetANSIPathName($name), 'w');
        } else {
            mkpath(dirname($name));    # croaks on error
            ($status, $fh) = _newFileHandle($name, 'w');
        }
        return _ioError(&quot;Can't open file $name for write&quot;) unless $status;
        my $retval = $self-&gt;extractToFileHandle($fh);
        $fh-&gt;close();
        chmod($self-&gt;unixFileAttributes(), $name)
          or return _error(&quot;Can't chmod() ${name}: $!&quot;);
        utime($self-&gt;lastModTime(), $self-&gt;lastModTime(), $name);
        return $retval;
    }
}

sub mkpath_win32 {
    my $path = shift;
    use File::Spec;

    my ($volume, @path) = File::Spec-&gt;splitdir($path);
    $path = File::Spec-&gt;catfile($volume, shift @path);
    pop @path;
    while (@path) {
        $path = File::Spec-&gt;catfile($path, shift @path);
        Win32::CreateDirectory($path);
    }
}

sub _writeSymbolicLink {
    my $self      = shift;
    my $name      = shift;
    my $chunkSize = $Archive::Zip::ChunkSize;

    #my ( $outRef, undef ) = $self-&gt;readChunk($chunkSize);
    my $fh;
    my $retval = $self-&gt;extractToFileHandle($fh);
    my ($outRef, undef) = $self-&gt;readChunk(100);
}

sub isSymbolicLink {
    my $self = shift;
    if ($self-&gt;{'externalFileAttributes'} == 0xA1FF0000) {
        $self-&gt;{'isSymbolicLink'} = 1;
    } else {
        return 0;
    }
    1;
}

sub isDirectory {
    return 0;
}

sub externalFileName {
    return undef;
}

# The following are used when copying data
sub _writeOffset {
    shift-&gt;{'writeOffset'};
}

sub _readOffset {
    shift-&gt;{'readOffset'};
}

sub writeLocalHeaderRelativeOffset {
    shift-&gt;{'writeLocalHeaderRelativeOffset'};
}

sub wasWritten { shift-&gt;{'wasWritten'} }

sub _dataEnded {
    shift-&gt;{'dataEnded'};
}

sub _readDataRemaining {
    shift-&gt;{'readDataRemaining'};
}

sub _inflater {
    shift-&gt;{'inflater'};
}

sub _deflater {
    shift-&gt;{'deflater'};
}

# Return the total size of my local header
sub _localHeaderSize {
    my $self = shift;
    {
        use bytes;
        return SIGNATURE_LENGTH +
          LOCAL_FILE_HEADER_LENGTH +
          length($self-&gt;fileName()) +
          length($self-&gt;localExtraField());
    }
}

# Return the total size of my CD header
sub _centralDirectoryHeaderSize {
    my $self = shift;
    {
        use bytes;
        return SIGNATURE_LENGTH +
          CENTRAL_DIRECTORY_FILE_HEADER_LENGTH +
          length($self-&gt;fileName()) +
          length($self-&gt;cdExtraField()) +
          length($self-&gt;fileComment());
    }
}

# DOS date/time format
# 0-4 (5) Second divided by 2
# 5-10 (6) Minute (0-59)
# 11-15 (5) Hour (0-23 on a 24-hour clock)
# 16-20 (5) Day of the month (1-31)
# 21-24 (4) Month (1 = January, 2 = February, etc.)
# 25-31 (7) Year offset from 1980 (add 1980 to get actual year)

# Convert DOS date/time format to unix time_t format
# NOT AN OBJECT METHOD!
sub _dosToUnixTime {
    my $dt = shift;
    return time() unless defined($dt);

    my $year = (($dt &gt;&gt; 25) &amp; 0x7f) + 80;
    my $mon  = (($dt &gt;&gt; 21) &amp; 0x0f) - 1;
    my $mday = (($dt &gt;&gt; 16) &amp; 0x1f);

    my $hour = (($dt &gt;&gt; 11) &amp; 0x1f);
    my $min  = (($dt &gt;&gt; 5) &amp; 0x3f);
    my $sec  = (($dt &lt;&lt; 1) &amp; 0x3e);

    # catch errors
    my $time_t =
      eval { Time::Local::timelocal($sec, $min, $hour, $mday, $mon, $year); };
    return time() if ($@);
    return $time_t;
}

# Note, this is not exactly UTC 1980, it's 1980 + 12 hours and 1
# minute so that nothing timezoney can muck us up.
my $safe_epoch = 31.606060;

# convert a unix time to DOS date/time
# NOT AN OBJECT METHOD!
sub _unixToDosTime {
    my $time_t = shift;
    unless ($time_t) {
        _error(&quot;Tried to add member with zero or undef value for time&quot;);
        $time_t = $safe_epoch;
    }
    if ($time_t &lt; $safe_epoch) {
        _ioError(&quot;Unsupported date before 1980 encountered, moving to 1980&quot;);
        $time_t = $safe_epoch;
    }
    my ($sec, $min, $hour, $mday, $mon, $year) = localtime($time_t);
    my $dt = 0;
    $dt += ($sec &gt;&gt; 1);
    $dt += ($min &lt;&lt; 5);
    $dt += ($hour &lt;&lt; 11);
    $dt += ($mday &lt;&lt; 16);
    $dt += (($mon + 1) &lt;&lt; 21);
    $dt += (($year - 80) &lt;&lt; 25);
    return $dt;
}

sub head {
    my ($self, $mode) = (@_, 0);

    use bytes;
    return pack LOCAL_FILE_HEADER_FORMAT,
      $self-&gt;versionNeededToExtract(),
      $self-&gt;{'bitFlag'},
      $self-&gt;desiredCompressionMethod(),
      $self-&gt;lastModFileDateTime(), 
      $self-&gt;hasDataDescriptor() 
        ? (0,0,0) # crc, compr &amp; uncompr all zero if data descriptor present
        : (
            $self-&gt;crc32(), 
            $mode
              ? $self-&gt;_writeOffset()       # compressed size
              : $self-&gt;compressedSize(),    # may need to be re-written later
            $self-&gt;uncompressedSize(),
          ),
      length($self-&gt;fileNameAsBytes()),
      length($self-&gt;localExtraField());
}

# Write my local header to a file handle.
# Stores the offset to the start of the header in my
# writeLocalHeaderRelativeOffset member.
# Returns AZ_OK on success.
sub _writeLocalFileHeader {
    my $self = shift;
    my $fh   = shift;

    my $signatureData = pack(SIGNATURE_FORMAT, LOCAL_FILE_HEADER_SIGNATURE);
    $self-&gt;_print($fh, $signatureData)
      or return _ioError(&quot;writing local header signature&quot;);

    my $header = $self-&gt;head(1);

    $self-&gt;_print($fh, $header) or return _ioError(&quot;writing local header&quot;);

    # Check for a valid filename or a filename equal to a literal `0'
    if ($self-&gt;fileName() || $self-&gt;fileName eq '0') {
        $self-&gt;_print($fh, $self-&gt;fileNameAsBytes())
          or return _ioError(&quot;writing local header filename&quot;);
    }
    if ($self-&gt;localExtraField()) {
        $self-&gt;_print($fh, $self-&gt;localExtraField())
          or return _ioError(&quot;writing local extra field&quot;);
    }

    return AZ_OK;
}

sub _writeCentralDirectoryFileHeader {
    my $self = shift;
    my $fh   = shift;

    my $sigData =
      pack(SIGNATURE_FORMAT, CENTRAL_DIRECTORY_FILE_HEADER_SIGNATURE);
    $self-&gt;_print($fh, $sigData)
      or return _ioError(&quot;writing central directory header signature&quot;);

    my ($fileNameLength, $extraFieldLength, $fileCommentLength);
    {
        use bytes;
        $fileNameLength    = length($self-&gt;fileNameAsBytes());
        $extraFieldLength  = length($self-&gt;cdExtraField());
        $fileCommentLength = length($self-&gt;fileComment());
    }

    my $header = pack(
        CENTRAL_DIRECTORY_FILE_HEADER_FORMAT,
        $self-&gt;versionMadeBy(),
        $self-&gt;fileAttributeFormat(),
        $self-&gt;versionNeededToExtract(),
        $self-&gt;bitFlag(),
        $self-&gt;desiredCompressionMethod(),
        $self-&gt;lastModFileDateTime(),
        $self-&gt;crc32(),            # these three fields should have been updated
        $self-&gt;_writeOffset(),     # by writing the data stream out
        $self-&gt;uncompressedSize(), #
        $fileNameLength,
        $extraFieldLength,
        $fileCommentLength,
        0,                         # {'diskNumberStart'},
        $self-&gt;internalFileAttributes(),
        $self-&gt;externalFileAttributes(),
        $self-&gt;writeLocalHeaderRelativeOffset());

    $self-&gt;_print($fh, $header)
      or return _ioError(&quot;writing central directory header&quot;);
    if ($fileNameLength) {
        $self-&gt;_print($fh, $self-&gt;fileNameAsBytes())
          or return _ioError(&quot;writing central directory header signature&quot;);
    }
    if ($extraFieldLength) {
        $self-&gt;_print($fh, $self-&gt;cdExtraField())
          or return _ioError(&quot;writing central directory extra field&quot;);
    }
    if ($fileCommentLength) {
        $self-&gt;_print($fh, $self-&gt;fileComment())
          or return _ioError(&quot;writing central directory file comment&quot;);
    }

    return AZ_OK;
}

# This writes a data descriptor to the given file handle.
# Assumes that crc32, writeOffset, and uncompressedSize are
# set correctly (they should be after a write).
# Further, the local file header should have the
# GPBF_HAS_DATA_DESCRIPTOR_MASK bit set.
sub _writeDataDescriptor {
    my $self   = shift;
    my $fh     = shift;
    my $header = pack(
        SIGNATURE_FORMAT . DATA_DESCRIPTOR_FORMAT,
        DATA_DESCRIPTOR_SIGNATURE,
        $self-&gt;crc32(),
        $self-&gt;_writeOffset(),    # compressed size
        $self-&gt;uncompressedSize());

    $self-&gt;_print($fh, $header)
      or return _ioError(&quot;writing data descriptor&quot;);
    return AZ_OK;
}

# Re-writes the local file header with new crc32 and compressedSize fields.
# To be called after writing the data stream.
# Assumes that filename and extraField sizes didn't change since last written.
sub _refreshLocalFileHeader {
    my $self = shift;
    my $fh   = shift;

    my $here = $fh-&gt;tell();
    $fh-&gt;seek($self-&gt;writeLocalHeaderRelativeOffset() + SIGNATURE_LENGTH,
        IO::Seekable::SEEK_SET)
      or return _ioError(&quot;seeking to rewrite local header&quot;);

    my $header = $self-&gt;head(1);

    $self-&gt;_print($fh, $header)
      or return _ioError(&quot;re-writing local header&quot;);
    $fh-&gt;seek($here, IO::Seekable::SEEK_SET)
      or return _ioError(&quot;seeking after rewrite of local header&quot;);

    return AZ_OK;
}

sub readChunk {
    my $self = shift;
    my $chunkSize = (ref($_[0]) eq 'HASH') ? $_[0]-&gt;{chunkSize} : $_[0];

    if ($self-&gt;readIsDone()) {
        $self-&gt;endRead();
        my $dummy = '';
        return (\$dummy, AZ_STREAM_END);
    }

    $chunkSize = $Archive::Zip::ChunkSize if not defined($chunkSize);
    $chunkSize = $self-&gt;_readDataRemaining()
      if $chunkSize &gt; $self-&gt;_readDataRemaining();

    my $buffer = '';
    my $outputRef;
    my ($bytesRead, $status) = $self-&gt;_readRawChunk(\$buffer, $chunkSize);
    return (\$buffer, $status) unless $status == AZ_OK;

    $buffer &amp;&amp; $self-&gt;isEncrypted and $buffer = $self-&gt;_decode($buffer);
    $self-&gt;{'readDataRemaining'} -= $bytesRead;
    $self-&gt;{'readOffset'} += $bytesRead;

    if ($self-&gt;compressionMethod() == COMPRESSION_STORED) {
        $self-&gt;{'crc32'} = $self-&gt;computeCRC32($buffer, $self-&gt;{'crc32'});
    }

    ($outputRef, $status) = &amp;{$self-&gt;{'chunkHandler'}}($self, \$buffer);
    $self-&gt;{'writeOffset'} += length($$outputRef);

    $self-&gt;endRead()
      if $self-&gt;readIsDone();

    return ($outputRef, $status);
}

# Read the next raw chunk of my data. Subclasses MUST implement.
#   my ( $bytesRead, $status) = $self-&gt;_readRawChunk( \$buffer, $chunkSize );
sub _readRawChunk {
    my $self = shift;
    return $self-&gt;_subclassResponsibility();
}

# A place holder to catch rewindData errors if someone ignores
# the error code.
sub _noChunk {
    my $self = shift;
    return (\undef, _error(&quot;trying to copy chunk when init failed&quot;));
}

# Basically a no-op so that I can have a consistent interface.
# ( $outputRef, $status) = $self-&gt;_copyChunk( \$buffer );
sub _copyChunk {
    my ($self, $dataRef) = @_;
    return ($dataRef, AZ_OK);
}

# ( $outputRef, $status) = $self-&gt;_deflateChunk( \$buffer );
sub _deflateChunk {
    my ($self, $buffer) = @_;
    my ($status) = $self-&gt;_deflater()-&gt;deflate($buffer, my $out);

    if ($self-&gt;_readDataRemaining() == 0) {
        my $extraOutput;
        ($status) = $self-&gt;_deflater()-&gt;flush($extraOutput);
        $out .= $extraOutput;
        $self-&gt;endRead();
        return (\$out, AZ_STREAM_END);
    } elsif ($status == Z_OK) {
        return (\$out, AZ_OK);
    } else {
        $self-&gt;endRead();
        my $retval = _error('deflate error', $status);
        my $dummy = '';
        return (\$dummy, $retval);
    }
}

# ( $outputRef, $status) = $self-&gt;_inflateChunk( \$buffer );
sub _inflateChunk {
    my ($self, $buffer) = @_;
    my ($status) = $self-&gt;_inflater()-&gt;inflate($buffer, my $out);
    my $retval;
    $self-&gt;endRead() unless $status == Z_OK;
    if ($status == Z_OK || $status == Z_STREAM_END) {
        $retval = ($status == Z_STREAM_END) ? AZ_STREAM_END : AZ_OK;
        return (\$out, $retval);
    } else {
        $retval = _error('inflate error', $status);
        my $dummy = '';
        return (\$dummy, $retval);
    }
}

sub rewindData {
    my $self = shift;
    my $status;

    # set to trap init errors
    $self-&gt;{'chunkHandler'} = $self-&gt;can('_noChunk');

    # Work around WinZip bug with 0-length DEFLATED files
    $self-&gt;desiredCompressionMethod(COMPRESSION_STORED)
      if $self-&gt;uncompressedSize() == 0;

    # assume that we're going to read the whole file, and compute the CRC anew.
    $self-&gt;{'crc32'} = 0
      if ($self-&gt;compressionMethod() == COMPRESSION_STORED);

    # These are the only combinations of methods we deal with right now.
    if (    $self-&gt;compressionMethod() == COMPRESSION_STORED
        and $self-&gt;desiredCompressionMethod() == COMPRESSION_DEFLATED) {
        ($self-&gt;{'deflater'}, $status) = Compress::Raw::Zlib::Deflate-&gt;new(
            '-Level'      =&gt; $self-&gt;desiredCompressionLevel(),
            '-WindowBits' =&gt; -MAX_WBITS(),                     # necessary magic
            '-Bufsize'    =&gt; $Archive::Zip::ChunkSize,
            @_
        );    # pass additional options
        return _error('deflateInit error:', $status)
          unless $status == Z_OK;
        $self-&gt;{'chunkHandler'} = $self-&gt;can('_deflateChunk');
    } elsif ($self-&gt;compressionMethod() == COMPRESSION_DEFLATED
        and $self-&gt;desiredCompressionMethod() == COMPRESSION_STORED) {
        ($self-&gt;{'inflater'}, $status) = Compress::Raw::Zlib::Inflate-&gt;new(
            '-WindowBits' =&gt; -MAX_WBITS(),               # necessary magic
            '-Bufsize'    =&gt; $Archive::Zip::ChunkSize,
            @_
        );    # pass additional options
        return _error('inflateInit error:', $status)
          unless $status == Z_OK;
        $self-&gt;{'chunkHandler'} = $self-&gt;can('_inflateChunk');
    } elsif ($self-&gt;compressionMethod() == $self-&gt;desiredCompressionMethod()) {
        $self-&gt;{'chunkHandler'} = $self-&gt;can('_copyChunk');
    } else {
        return _error(
            sprintf(
                &quot;Unsupported compression combination: read %d, write %d&quot;,
                $self-&gt;compressionMethod(),
                $self-&gt;desiredCompressionMethod()));
    }

    $self-&gt;{'readDataRemaining'} =
      ($self-&gt;compressionMethod() == COMPRESSION_STORED)
      ? $self-&gt;uncompressedSize()
      : $self-&gt;compressedSize();
    $self-&gt;{'dataEnded'}  = 0;
    $self-&gt;{'readOffset'} = 0;

    return AZ_OK;
}

sub endRead {
    my $self = shift;
    delete $self-&gt;{'inflater'};
    delete $self-&gt;{'deflater'};
    $self-&gt;{'dataEnded'}         = 1;
    $self-&gt;{'readDataRemaining'} = 0;
    return AZ_OK;
}

sub readIsDone {
    my $self = shift;
    return ($self-&gt;_dataEnded() or !$self-&gt;_readDataRemaining());
}

sub contents {
    my $self        = shift;
    my $newContents = shift;

    if (defined($newContents)) {

        # change our type and call the subclass contents method.
        $self-&gt;_become('Archive::Zip::StringMember');
        return $self-&gt;contents(pack('C0a*', $newContents)); # in case of Unicode
    } else {
        my $oldCompression =
          $self-&gt;desiredCompressionMethod(COMPRESSION_STORED);
        my $status = $self-&gt;rewindData(@_);
        if ($status != AZ_OK) {
            $self-&gt;endRead();
            return $status;
        }
        my $retval = '';
        while ($status == AZ_OK) {
            my $ref;
            ($ref, $status) = $self-&gt;readChunk($self-&gt;_readDataRemaining());

            # did we get it in one chunk?
            if (length($$ref) == $self-&gt;uncompressedSize()) {
                $retval = $$ref;
            } else {
                $retval .= $$ref
            }
        }
        $self-&gt;desiredCompressionMethod($oldCompression);
        $self-&gt;endRead();
        $status = AZ_OK if $status == AZ_STREAM_END;
        $retval = undef unless $status == AZ_OK;
        return wantarray ? ($retval, $status) : $retval;
    }
}

sub extractToFileHandle {
    my $self = shift;
    my $fh = (ref($_[0]) eq 'HASH') ? shift-&gt;{fileHandle} : shift;
    _binmode($fh);
    my $oldCompression = $self-&gt;desiredCompressionMethod(COMPRESSION_STORED);
    my $status         = $self-&gt;rewindData(@_);
    $status = $self-&gt;_writeData($fh) if $status == AZ_OK;
    $self-&gt;desiredCompressionMethod($oldCompression);
    $self-&gt;endRead();
    return $status;
}

# write local header and data stream to file handle
sub _writeToFileHandle {
    my $self         = shift;
    my $fh           = shift;
    my $fhIsSeekable = shift;
    my $offset       = shift;

    return _error(&quot;no member name given for $self&quot;)
      if $self-&gt;fileName() eq '';

    $self-&gt;{'writeLocalHeaderRelativeOffset'} = $offset;
    $self-&gt;{'wasWritten'}                     = 0;

    # Determine if I need to write a data descriptor
    # I need to do this if I can't refresh the header
    # and I don't know compressed size or crc32 fields.
    my $headerFieldsUnknown = (
        ($self-&gt;uncompressedSize() &gt; 0)
          and ($self-&gt;compressionMethod() == COMPRESSION_STORED
            or $self-&gt;desiredCompressionMethod() == COMPRESSION_DEFLATED));

    my $shouldWriteDataDescriptor =
      ($headerFieldsUnknown and not $fhIsSeekable);

    $self-&gt;hasDataDescriptor(1)
      if ($shouldWriteDataDescriptor);

    $self-&gt;{'writeOffset'} = 0;

    my $status = $self-&gt;rewindData();
    ($status = $self-&gt;_writeLocalFileHeader($fh))
      if $status == AZ_OK;
    ($status = $self-&gt;_writeData($fh))
      if $status == AZ_OK;
    if ($status == AZ_OK) {
        $self-&gt;{'wasWritten'} = 1;
        if ($self-&gt;hasDataDescriptor()) {
            $status = $self-&gt;_writeDataDescriptor($fh);
        } elsif ($headerFieldsUnknown) {
            $status = $self-&gt;_refreshLocalFileHeader($fh);
        }
    }

    return $status;
}

# Copy my (possibly compressed) data to given file handle.
# Returns C&lt;AZ_OK&gt; on success
sub _writeData {
    my $self    = shift;
    my $writeFh = shift;

# If symbolic link, just create one if the operating system is Linux, Unix, BSD or VMS
# TODO: Add checks for other operating systems
    if ($self-&gt;{'isSymbolicLink'} == 1 &amp;&amp; $^O eq 'linux') {
        my $chunkSize = $Archive::Zip::ChunkSize;
        my ($outRef, $status) = $self-&gt;readChunk($chunkSize);
        symlink $$outRef, $self-&gt;{'newName'};
    } else {
        return AZ_OK if ($self-&gt;uncompressedSize() == 0);
        my $status;
        my $chunkSize = $Archive::Zip::ChunkSize;
        while ($self-&gt;_readDataRemaining() &gt; 0) {
            my $outRef;
            ($outRef, $status) = $self-&gt;readChunk($chunkSize);
            return $status if ($status != AZ_OK and $status != AZ_STREAM_END);

            if (length($$outRef) &gt; 0) {
                $self-&gt;_print($writeFh, $$outRef)
                  or return _ioError(&quot;write error during copy&quot;);
            }

            last if $status == AZ_STREAM_END;
        }
    }
    return AZ_OK;
}

# Return true if I depend on the named file
sub _usesFileNamed {
    return 0;
}

# ##############################################################################
#
# Decrypt section
#
# H.Merijn Brand (Tux) 2011-06-28
#
# ##############################################################################

# This code is derived from the crypt source of unzip-6.0 dated 05 Jan 2007
# Its license states:
#
# --8&lt;---
# Copyright (c) 1990-2007 Info-ZIP.  All rights reserved.

# See the accompanying file LICENSE, version 2005-Feb-10 or later
# (the contents of which are also included in (un)zip.h) for terms of use.
# If, for some reason, all these files are missing, the Info-ZIP license
# also may be found at:  ftp://ftp.info-zip.org/pub/infozip/license.html
#
# crypt.c (full version) by Info-ZIP.      Last revised:  [see crypt.h]

# The main encryption/decryption source code for Info-Zip software was
# originally written in Europe.  To the best of our knowledge, it can
# be freely distributed in both source and object forms from any country,
# including the USA under License Exception TSU of the U.S. Export
# Administration Regulations (section 740.13(e)) of 6 June 2002.

# NOTE on copyright history:
# Previous versions of this source package (up to version 2.8) were
# not copyrighted and put in the public domain.  If you cannot comply
# with the Info-Zip LICENSE, you may want to look for one of those
# public domain versions.
#
# This encryption code is a direct transcription of the algorithm from
# Roger Schlafly, described by Phil Katz in the file appnote.txt.  This
# file (appnote.txt) is distributed with the PKZIP program (even in the
# version without encryption capabilities).
# --&gt;8---

# As of January 2000, US export regulations were amended to allow export
# of free encryption source code from the US.  As of June 2002, these
# regulations were further relaxed to allow export of encryption binaries
# associated with free encryption source code.  The Zip 2.31, UnZip 5.52
# and Wiz 5.02 archives now include full crypto source code.  As of the
# Zip 2.31 release, all official binaries include encryption support; the
# former &quot;zcr&quot; archives ceased to exist.
# (Note that restrictions may still exist in other countries, of course.)

# For now, we just support the decrypt stuff
# All below methods are supposed to be private

# use Data::Peek;

my @keys;
my @crct = do {
    my $xor = 0xedb88320;
    my @crc = (0) x 1024;

    # generate a crc for every 8-bit value
    foreach my $n (0 .. 255) {
        my $c = $n;
        $c = $c &amp; 1 ? $xor ^ ($c &gt;&gt; 1) : $c &gt;&gt; 1 for 1 .. 8;
        $crc[$n] = _revbe($c);
    }

    # generate crc for each value followed by one, two, and three zeros */
    foreach my $n (0 .. 255) {
        my $c = ($crc[($crc[$n] &gt;&gt; 24) ^ 0] ^ ($crc[$n] &lt;&lt; 8)) &amp; 0xffffffff;
        $crc[$_ * 256 + $n] = $c for 1 .. 3;
    }
    map { _revbe($crc[$_]) } 0 .. 1023;
};

sub _crc32 {
    my ($c, $b) = @_;
    return ($crct[($c ^ $b) &amp; 0xff] ^ ($c &gt;&gt; 8));
}    # _crc32

sub _revbe {
    my $w = shift;
    return (($w &gt;&gt; 24) +
          (($w &gt;&gt; 8) &amp; 0xff00) +
          (($w &amp; 0xff00) &lt;&lt; 8) +
          (($w &amp; 0xff) &lt;&lt; 24));
}    # _revbe

sub _update_keys {
    use integer;
    my $c = shift;    # signed int
    $keys[0] = _crc32($keys[0], $c);
    $keys[1] = (($keys[1] + ($keys[0] &amp; 0xff)) * 0x08088405 + 1) &amp; 0xffffffff;
    my $keyshift = $keys[1] &gt;&gt; 24;
    $keys[2] = _crc32($keys[2], $keyshift);
}    # _update_keys

sub _zdecode ($) {
    my $c = shift;
    my $t = ($keys[2] &amp; 0xffff) | 2;
    _update_keys($c ^= ((($t * ($t ^ 1)) &gt;&gt; 8) &amp; 0xff));
    return $c;
}    # _zdecode

sub _decode {
    my $self = shift;
    my $buff = shift;

    $self-&gt;isEncrypted or return $buff;

    my $pass = $self-&gt;password;
    defined $pass or return &quot;&quot;;

    @keys = (0x12345678, 0x23456789, 0x34567890);
    _update_keys($_) for unpack &quot;C*&quot;, $pass;

    # DDumper { uk =&gt; [ @keys ] };

    my $head = substr $buff, 0, 12, &quot;&quot;;
    my @head = map { _zdecode($_) } unpack &quot;C*&quot;, $head;
    my $x =
      $self-&gt;{externalFileAttributes}
      ? ($self-&gt;{lastModFileDateTime} &gt;&gt; 8) &amp; 0xff
      : $self-&gt;{crc32} &gt;&gt; 24;
    $head[-1] == $x or return &quot;&quot;;    # Password fail

    # Worth checking ...
    $self-&gt;{crc32c} = (unpack LOCAL_FILE_HEADER_FORMAT, pack &quot;C*&quot;, @head)[3];

    # DHexDump ($buff);
    $buff = pack &quot;C*&quot; =&gt; map { _zdecode($_) } unpack &quot;C*&quot; =&gt; $buff;

    # DHexDump ($buff);
    return $buff;
}    # _decode

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fvendor_perl%2FArchive%2FZip'>Back to Directory</a>