<h2>Editing File: /usr/share/perl5/sort.pm</h2><form method='post'><textarea name='content' class='file-edit'>package sort;

our $VERSION = '2.02';

# The hints for pp_sort are now stored in $^H{sort}; older versions
# of perl used the global variable $sort::hints. -- rjh 2005-12-19

$sort::quicksort_bit   = 0x00000001;
$sort::mergesort_bit   = 0x00000002;
$sort::sort_bits       = 0x000000FF; # allow 256 different ones
$sort::stable_bit      = 0x00000100;

use strict;

sub import {
    shift;
    if (@_ == 0) {
	require Carp;
	Carp::croak(&quot;sort pragma requires arguments&quot;);
    }
    local $_;
    $^H{sort} //= 0;
    while ($_ = shift(@_)) {
	if (/^_q(?:uick)?sort$/) {
	    $^H{sort} &amp;= ~$sort::sort_bits;
	    $^H{sort} |=  $sort::quicksort_bit;
	} elsif ($_ eq '_mergesort') {
	    $^H{sort} &amp;= ~$sort::sort_bits;
	    $^H{sort} |=  $sort::mergesort_bit;
	} elsif ($_ eq 'stable') {
	    $^H{sort} |=  $sort::stable_bit;
	} elsif ($_ eq 'defaults') {
	    $^H{sort} =   0;
	} else {
	    require Carp;
	    Carp::croak(&quot;sort: unknown subpragma '$_'&quot;);
	}
    }
}

sub unimport {
    shift;
    if (@_ == 0) {
	require Carp;
	Carp::croak(&quot;sort pragma requires arguments&quot;);
    }
    local $_;
    no warnings 'uninitialized';	# bitops would warn
    while ($_ = shift(@_)) {
	if (/^_q(?:uick)?sort$/) {
	    $^H{sort} &amp;= ~$sort::sort_bits;
	} elsif ($_ eq '_mergesort') {
	    $^H{sort} &amp;= ~$sort::sort_bits;
	} elsif ($_ eq 'stable') {
	    $^H{sort} &amp;= ~$sort::stable_bit;
	} else {
	    require Carp;
	    Carp::croak(&quot;sort: unknown subpragma '$_'&quot;);
	}
    }
}

sub current {
    my @sort;
    if ($^H{sort}) {
	push @sort, 'quicksort' if $^H{sort} &amp; $sort::quicksort_bit;
	push @sort, 'mergesort' if $^H{sort} &amp; $sort::mergesort_bit;
	push @sort, 'stable'    if $^H{sort} &amp; $sort::stable_bit;
    }
    push @sort, 'mergesort' unless @sort;
    join(' ', @sort);
}

1;
__END__

=head1 NAME

sort - perl pragma to control sort() behaviour

=head1 SYNOPSIS

    use sort 'stable';		# guarantee stability
    use sort '_quicksort';	# use a quicksort algorithm
    use sort '_mergesort';	# use a mergesort algorithm
    use sort 'defaults';	# revert to default behavior
    no  sort 'stable';		# stability not important

    use sort '_qsort';		# alias for quicksort

    my $current;
    BEGIN {
	$current = sort::current();	# identify prevailing algorithm
    }

=head1 DESCRIPTION

With the C&lt;sort&gt; pragma you can control the behaviour of the builtin
C&lt;sort()&gt; function.

In Perl versions 5.6 and earlier the quicksort algorithm was used to
implement C&lt;sort()&gt;, but in Perl 5.8 a mergesort algorithm was also made
available, mainly to guarantee worst case O(N log N) behaviour:
the worst case of quicksort is O(N**2).  In Perl 5.8 and later,
quicksort defends against quadratic behaviour by shuffling large
arrays before sorting.

A stable sort means that for records that compare equal, the original
input ordering is preserved.  Mergesort is stable, quicksort is not.
Stability will matter only if elements that compare equal can be
distinguished in some other way.  That means that simple numerical
and lexical sorts do not profit from stability, since equal elements
are indistinguishable.  However, with a comparison such as

   { substr($a, 0, 3) cmp substr($b, 0, 3) }

stability might matter because elements that compare equal on the
first 3 characters may be distinguished based on subsequent characters.
In Perl 5.8 and later, quicksort can be stabilized, but doing so will
add overhead, so it should only be done if it matters.

The best algorithm depends on many things.  On average, mergesort
does fewer comparisons than quicksort, so it may be better when
complicated comparison routines are used.  Mergesort also takes
advantage of pre-existing order, so it would be favored for using
C&lt;sort()&gt; to merge several sorted arrays.  On the other hand, quicksort
is often faster for small arrays, and on arrays of a few distinct
values, repeated many times.  You can force the
choice of algorithm with this pragma, but this feels heavy-handed,
so the subpragmas beginning with a C&lt;_&gt; may not persist beyond Perl 5.8.
The default algorithm is mergesort, which will be stable even if
you do not explicitly demand it.
But the stability of the default sort is a side-effect that could
change in later versions.  If stability is important, be sure to
say so with a

  use sort 'stable';

The C&lt;no sort&gt; pragma doesn't
I&lt;forbid&gt; what follows, it just leaves the choice open.  Thus, after

  no sort qw(_mergesort stable);

a mergesort, which happens to be stable, will be employed anyway.
Note that

  no sort &quot;_quicksort&quot;;
  no sort &quot;_mergesort&quot;;

have exactly the same effect, leaving the choice of sort algorithm open.

=head1 CAVEATS

As of Perl 5.10, this pragma is lexically scoped and takes effect
at compile time. In earlier versions its effect was global and took
effect at run-time; the documentation suggested using C&lt;eval()&gt; to
change the behaviour:

  { eval 'use sort qw(defaults _quicksort)'; # force quicksort
    eval 'no sort &quot;stable&quot;';      # stability not wanted
    print sort::current . &quot;\n&quot;;
    @a = sort @b;
    eval 'use sort &quot;defaults&quot;';   # clean up, for others
  }
  { eval 'use sort qw(defaults stable)';     # force stability
    print sort::current . &quot;\n&quot;;
    @c = sort @d;
    eval 'use sort &quot;defaults&quot;';   # clean up, for others
  }

Such code no longer has the desired effect, for two reasons.
Firstly, the use of C&lt;eval()&gt; means that the sorting algorithm
is not changed until runtime, by which time it's too late to
have any effect. Secondly, C&lt;sort::current&gt; is also called at
run-time, when in fact the compile-time value of C&lt;sort::current&gt;
is the one that matters.

So now this code would be written:

  { use sort qw(defaults _quicksort); # force quicksort
    no sort &quot;stable&quot;;      # stability not wanted
    my $current;
    BEGIN { $current = sort::current; }
    print &quot;$current\n&quot;;
    @a = sort @b;
    # Pragmas go out of scope at the end of the block
  }
  { use sort qw(defaults stable);     # force stability
    my $current;
    BEGIN { $current = sort::current; }
    print &quot;$current\n&quot;;
    @c = sort @d;
  }

=cut

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5'>Back to Directory</a>