<h2>Editing File: /usr/share/perl5/pod/perlvar.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perlvar - Perl predefined variables

=head1 DESCRIPTION

=head2 The Syntax of Variable Names

Variable names in Perl can have several formats.  Usually, they
must begin with a letter or underscore, in which case they can be
arbitrarily long (up to an internal limit of 251 characters) and
may contain letters, digits, underscores, or the special sequence
C&lt;::&gt; or C&lt;'&gt;.  In this case, the part before the last C&lt;::&gt; or
C&lt;'&gt; is taken to be a I&lt;package qualifier&gt;; see L&lt;perlmod&gt;.
A Unicode letter that is not ASCII is not considered to be a letter
unless S&lt;C&lt;&quot;use utf8&quot;&gt;&gt; is in effect, and somewhat more complicated
rules apply; see L&lt;perldata/Identifier parsing&gt; for details.

Perl variable names may also be a sequence of digits, a single
punctuation character, or the two-character sequence: C&lt;^&gt; (caret or
CIRCUMFLEX ACCENT) followed by any one of the characters C&lt;[][A-Z^_?\]&gt;.
These names are all reserved for
special uses by Perl; for example, the all-digits names are used
to hold data captured by backreferences after a regular expression
match.

Since Perl v5.6.0, Perl variable names may also be alphanumeric strings
preceded by a caret.  These must all be written in the form C&lt;${^Foo}&gt;;
the braces are not optional.  C&lt;${^Foo}&gt; denotes the scalar variable
whose name is considered to be a control-C&lt;F&gt; followed by two C&lt;o&gt;'s.
These variables are
reserved for future special uses by Perl, except for the ones that
begin with C&lt;^_&gt; (caret-underscore).  No
name that begins with C&lt;^_&gt; will acquire a special
meaning in any future version of Perl; such names may therefore be
used safely in programs.  C&lt;$^_&gt; itself, however, I&lt;is&gt; reserved.

Perl identifiers that begin with digits or
punctuation characters are exempt from the effects of the C&lt;package&gt;
declaration and are always forced to be in package C&lt;main&gt;; they are
also exempt from C&lt;strict 'vars'&gt; errors.  A few other names are also
exempt in these ways:

    ENV      STDIN
    INC      STDOUT
    ARGV     STDERR
    ARGVOUT
    SIG

In particular, the special C&lt;${^_XYZ}&gt; variables are always taken
to be in package C&lt;main&gt;, regardless of any C&lt;package&gt; declarations
presently in scope.

=head1 SPECIAL VARIABLES

The following names have special meaning to Perl.  Most punctuation
names have reasonable mnemonics, or analogs in the shells.
Nevertheless, if you wish to use long variable names, you need only say:

    use English;

at the top of your program.  This aliases all the short names to the long
names in the current package.  Some even have medium names, generally
borrowed from B&lt;awk&gt;.  For more info, please see L&lt;English&gt;.

Before you continue, note the sort order for variables.  In general, we
first list the variables in case-insensitive, almost-lexigraphical
order (ignoring the C&lt;{&gt; or C&lt;^&gt; preceding words, as in C&lt;${^UNICODE}&gt;
or C&lt;$^T&gt;), although C&lt;$_&gt; and C&lt;@_&gt; move up to the top of the pile.
For variables with the same identifier, we list it in order of scalar,
array, hash, and bareword.

=head2 General Variables

=over 8

=item $ARG

=item $_
X&lt;$_&gt; X&lt;$ARG&gt;

The default input and pattern-searching space.  The following pairs are
equivalent:

    while (&lt;&gt;) {...}    # equivalent only in while!
    while (defined($_ = &lt;&gt;)) {...}

    /^Subject:/
    $_ =~ /^Subject:/

    tr/a-z/A-Z/
    $_ =~ tr/a-z/A-Z/

    chomp
    chomp($_)

Here are the places where Perl will assume C&lt;$_&gt; even if you don't use it:

=over 3

=item *

The following functions use C&lt;$_&gt; as a default argument:

abs, alarm, chomp, chop, chr, chroot,
cos, defined, eval, evalbytes, exp, fc, glob, hex, int, lc,
lcfirst, length, log, lstat, mkdir, oct, ord, pos, print, printf,
quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
rmdir, say, sin, split (for its second
argument), sqrt, stat, study, uc, ucfirst,
unlink, unpack.

=item *

All file tests (C&lt;-f&gt;, C&lt;-d&gt;) except for C&lt;-t&gt;, which defaults to STDIN.
See L&lt;perlfunc/-X&gt;

=item *

The pattern matching operations C&lt;m//&gt;, C&lt;s///&gt; and C&lt;tr///&gt; (aka C&lt;y///&gt;)
when used without an C&lt;=~&gt; operator.

=item *

The default iterator variable in a C&lt;foreach&gt; loop if no other
variable is supplied.

=item *

The implicit iterator variable in the C&lt;grep()&gt; and C&lt;map()&gt; functions.

=item *

The implicit variable of C&lt;given()&gt;.

=item *

The default place to put the next value or input record
when a C&lt;&lt; &lt;FH&gt; &gt;&gt;, C&lt;readline&gt;, C&lt;readdir&gt; or C&lt;each&gt;
operation's result is tested by itself as the sole criterion of a C&lt;while&gt;
test.  Outside a C&lt;while&gt; test, this will not happen.

=back

C&lt;$_&gt; is by default a global variable.  However, as
of perl v5.10.0, you can use a lexical version of
C&lt;$_&gt; by declaring it in a file or in a block with C&lt;my&gt;.  Moreover,
declaring C&lt;our $_&gt; restores the global C&lt;$_&gt; in the current scope.  Though
this seemed like a good idea at the time it was introduced, lexical C&lt;$_&gt;
actually causes more problems than it solves.  If you call a function that
expects to be passed information via C&lt;$_&gt;, it may or may not work,
depending on how the function is written, there not being any easy way to
solve this.  Just avoid lexical C&lt;$_&gt;, unless you are feeling particularly
masochistic.  For this reason lexical C&lt;$_&gt; is still experimental and will
produce a warning unless warnings have been disabled.  As with other
experimental features, the behavior of lexical C&lt;$_&gt; is subject to change
without notice, including change into a fatal error.

Mnemonic: underline is understood in certain operations.

=item @ARG

=item @_
X&lt;@_&gt; X&lt;@ARG&gt;

Within a subroutine the array C&lt;@_&gt; contains the parameters passed to
that subroutine.  Inside a subroutine, C&lt;@_&gt; is the default array for
the array operators C&lt;pop&gt; and C&lt;shift&gt;.

See L&lt;perlsub&gt;.

=item $LIST_SEPARATOR

=item $&quot;
X&lt;$&quot;&gt; X&lt;$LIST_SEPARATOR&gt;

When an array or an array slice is interpolated into a double-quoted
string or a similar context such as C&lt;/.../&gt;, its elements are
separated by this value.  Default is a space.  For example, this:

    print &quot;The array is: @array\n&quot;;

is equivalent to this:

    print &quot;The array is: &quot; . join($&quot;, @array) . &quot;\n&quot;;

Mnemonic: works in double-quoted context.

=item $PROCESS_ID

=item $PID

=item $$
X&lt;$$&gt; X&lt;$PID&gt; X&lt;$PROCESS_ID&gt;

The process number of the Perl running this script.  Though you I&lt;can&gt; set
this variable, doing so is generally discouraged, although it can be
invaluable for some testing purposes.  It will be reset automatically
across C&lt;fork()&gt; calls.

Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
would emulate POSIX semantics on Linux systems using LinuxThreads, a
partial implementation of POSIX Threads that has since been superseded
by the Native POSIX Thread Library (NPTL).

LinuxThreads is now obsolete on Linux, and caching C&lt;getpid()&gt;
like this made embedding perl unnecessarily complex (since you'd have
to manually update the value of $$), so now C&lt;$$&gt; and C&lt;getppid()&gt;
will always return the same values as the underlying C library.

Debian GNU/kFreeBSD systems also used LinuxThreads up until and
including the 6.0 release, but after that moved to FreeBSD thread
semantics, which are POSIX-like.

To see if your system is affected by this discrepancy check if
C&lt;getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL&gt; returns a false
value.  NTPL threads preserve the POSIX semantics.

Mnemonic: same as shells.

=item $PROGRAM_NAME

=item $0
X&lt;$0&gt; X&lt;$PROGRAM_NAME&gt;

Contains the name of the program being executed.

On some (but not all) operating systems assigning to C&lt;$0&gt; modifies
the argument area that the C&lt;ps&gt; program sees.  On some platforms you
may have to use special C&lt;ps&gt; options or a different C&lt;ps&gt; to see the
changes.  Modifying the C&lt;$0&gt; is more useful as a way of indicating the
current program state than it is for hiding the program you're
running.

Note that there are platform-specific limitations on the maximum
length of C&lt;$0&gt;.  In the most extreme case it may be limited to the
space occupied by the original C&lt;$0&gt;.

In some platforms there may be arbitrary amount of padding, for
example space characters, after the modified name as shown by C&lt;ps&gt;.
In some platforms this padding may extend all the way to the original
length of the argument area, no matter what you do (this is the case
for example with Linux 2.2).

Note for BSD users: setting C&lt;$0&gt; does not completely remove &quot;perl&quot;
from the ps(1) output.  For example, setting C&lt;$0&gt; to C&lt;&quot;foobar&quot;&gt; may
result in C&lt;&quot;perl: foobar (perl)&quot;&gt; (whether both the C&lt;&quot;perl: &quot;&gt; prefix
and the &quot; (perl)&quot; suffix are shown depends on your exact BSD variant
and version).  This is an operating system feature, Perl cannot help it.

In multithreaded scripts Perl coordinates the threads so that any
thread may modify its copy of the C&lt;$0&gt; and the change becomes visible
to ps(1) (assuming the operating system plays along).  Note that
the view of C&lt;$0&gt; the other threads have will not change since they
have their own copies of it.

If the program has been given to perl via the switches C&lt;-e&gt; or C&lt;-E&gt;,
C&lt;$0&gt; will contain the string C&lt;&quot;-e&quot;&gt;.

On Linux as of perl v5.14.0 the legacy process name will be set with
C&lt;prctl(2)&gt;, in addition to altering the POSIX name via C&lt;argv[0]&gt; as
perl has done since version 4.000.  Now system utilities that read the
legacy process name such as ps, top and killall will recognize the
name you set when assigning to C&lt;$0&gt;.  The string you supply will be
cut off at 16 bytes, this is a limitation imposed by Linux.

Mnemonic: same as B&lt;sh&gt; and B&lt;ksh&gt;.

=item $REAL_GROUP_ID

=item $GID

=item $(
X&lt;$(&gt; X&lt;$GID&gt; X&lt;$REAL_GROUP_ID&gt;

The real gid of this process.  If you are on a machine that supports
membership in multiple groups simultaneously, gives a space separated
list of groups you are in.  The first number is the one returned by
C&lt;getgid()&gt;, and the subsequent ones by C&lt;getgroups()&gt;, one of which may be
the same as the first number.

However, a value assigned to C&lt;$(&gt; must be a single number used to
set the real gid.  So the value given by C&lt;$(&gt; should I&lt;not&gt; be assigned
back to C&lt;$(&gt; without being forced numeric, such as by adding zero.  Note
that this is different to the effective gid (C&lt;$)&gt;) which does take a
list.

You can change both the real gid and the effective gid at the same
time by using C&lt;POSIX::setgid()&gt;.  Changes
to C&lt;$(&gt; require a check to C&lt;$!&gt;
to detect any possible errors after an attempted change.

Mnemonic: parentheses are used to I&lt;group&gt; things.  The real gid is the
group you I&lt;left&gt;, if you're running setgid.

=item $EFFECTIVE_GROUP_ID

=item $EGID

=item $)
X&lt;$)&gt; X&lt;$EGID&gt; X&lt;$EFFECTIVE_GROUP_ID&gt;

The effective gid of this process.  If you are on a machine that
supports membership in multiple groups simultaneously, gives a space
separated list of groups you are in.  The first number is the one
returned by C&lt;getegid()&gt;, and the subsequent ones by C&lt;getgroups()&gt;,
one of which may be the same as the first number.

Similarly, a value assigned to C&lt;$)&gt; must also be a space-separated
list of numbers.  The first number sets the effective gid, and
the rest (if any) are passed to C&lt;setgroups()&gt;.  To get the effect of an
empty list for C&lt;setgroups()&gt;, just repeat the new effective gid; that is,
to force an effective gid of 5 and an effectively empty C&lt;setgroups()&gt;
list, say C&lt; $) = &quot;5 5&quot; &gt;.

You can change both the effective gid and the real gid at the same
time by using C&lt;POSIX::setgid()&gt; (use only a single numeric argument).
Changes to C&lt;$)&gt; require a check to C&lt;$!&gt; to detect any possible errors
after an attempted change.

C&lt;&lt; $&lt; &gt;&gt;, C&lt;&lt; $&gt; &gt;&gt;, C&lt;$(&gt; and C&lt;$)&gt; can be set only on
machines that support the corresponding I&lt;set[re][ug]id()&gt; routine.  C&lt;$(&gt;
and C&lt;$)&gt; can be swapped only on machines supporting C&lt;setregid()&gt;.

Mnemonic: parentheses are used to I&lt;group&gt; things.  The effective gid
is the group that's I&lt;right&gt; for you, if you're running setgid.

=item $REAL_USER_ID

=item $UID

=item $&lt;
X&lt;&lt; $&lt; &gt;&gt; X&lt;$UID&gt; X&lt;$REAL_USER_ID&gt;

The real uid of this process.  You can change both the real uid and the
effective uid at the same time by using C&lt;POSIX::setuid()&gt;.  Since
changes to C&lt;&lt; $&lt; &gt;&gt; require a system call, check C&lt;$!&gt; after a change
attempt to detect any possible errors.

Mnemonic: it's the uid you came I&lt;from&gt;, if you're running setuid.

=item $EFFECTIVE_USER_ID

=item $EUID

=item $&gt;
X&lt;&lt; $&gt; &gt;&gt; X&lt;$EUID&gt; X&lt;$EFFECTIVE_USER_ID&gt;

The effective uid of this process.  For example:

    $&lt; = $&gt;;            # set real to effective uid
    ($&lt;,$&gt;) = ($&gt;,$&lt;);  # swap real and effective uids

You can change both the effective uid and the real uid at the same
time by using C&lt;POSIX::setuid()&gt;.  Changes to C&lt;&lt; $&gt; &gt;&gt; require a check
to C&lt;$!&gt; to detect any possible errors after an attempted change.

C&lt;&lt; $&lt; &gt;&gt; and C&lt;&lt; $&gt; &gt;&gt; can be swapped only on machines
supporting C&lt;setreuid()&gt;.

Mnemonic: it's the uid you went I&lt;to&gt;, if you're running setuid.

=item $SUBSCRIPT_SEPARATOR

=item $SUBSEP

=item $;
X&lt;$;&gt; X&lt;$SUBSEP&gt; X&lt;SUBSCRIPT_SEPARATOR&gt;

The subscript separator for multidimensional array emulation.  If you
refer to a hash element as

    $foo{$x,$y,$z}

it really means

    $foo{join($;, $x, $y, $z)}

But don't put

    @foo{$x,$y,$z}	# a slice--note the @

which means

    ($foo{$x},$foo{$y},$foo{$z})

Default is &quot;\034&quot;, the same as SUBSEP in B&lt;awk&gt;.  If your keys contain
binary data there might not be any safe value for C&lt;$;&gt;.

Consider using &quot;real&quot; multidimensional arrays as described
in L&lt;perllol&gt;.

Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.

=item $a

=item $b
X&lt;$a&gt; X&lt;$b&gt;

Special package variables when using C&lt;sort()&gt;, see L&lt;perlfunc/sort&gt;.
Because of this specialness C&lt;$a&gt; and C&lt;$b&gt; don't need to be declared
(using C&lt;use vars&gt;, or C&lt;our()&gt;) even when using the C&lt;strict 'vars'&gt;
pragma.  Don't lexicalize them with C&lt;my $a&gt; or C&lt;my $b&gt; if you want to
be able to use them in the C&lt;sort()&gt; comparison block or function.

=item %ENV
X&lt;%ENV&gt;

The hash C&lt;%ENV&gt; contains your current environment.  Setting a
value in C&lt;ENV&gt; changes the environment for any child processes
you subsequently C&lt;fork()&gt; off.

As of v5.18.0, both keys and values stored in C&lt;%ENV&gt; are stringified.

    my $foo = 1;
    $ENV{'bar'} = \$foo;
    if( ref $ENV{'bar'} ) {
        say &quot;Pre 5.18.0 Behaviour&quot;;
    } else {
        say &quot;Post 5.18.0 Behaviour&quot;;
    }

Previously, only child processes received stringified values:

    my $foo = 1;
    $ENV{'bar'} = \$foo;

    # Always printed 'non ref'
    system($^X, '-e',
           q/print ( ref $ENV{'bar'}  ? 'ref' : 'non ref' ) /);

This happens because you can't really share arbitrary data structures with
foreign processes.

=item $OLD_PERL_VERSION

=item $]
X&lt;$]&gt; X&lt;$OLD_PERL_VERSION&gt;

The revision, version, and subversion of the Perl interpreter, represented
as a decimal of the form 5.XXXYYY, where XXX is the version / 1e3 and YYY
is the subversion / 1e6.  For example, Perl v5.10.1 would be &quot;5.010001&quot;.

This variable can be used to determine whether the Perl interpreter
executing a script is in the right range of versions:

    warn &quot;No PerlIO!\n&quot; if $] lt '5.008';

When comparing C&lt;$]&gt;, string comparison operators are B&lt;highly
recommended&gt;.  The inherent limitations of binary floating point
representation can sometimes lead to incorrect comparisons for some
numbers on some architectures.

See also the documentation of C&lt;use VERSION&gt; and C&lt;require VERSION&gt;
for a convenient way to fail if the running Perl interpreter is too old.

See L&lt;/$^V&gt; for a representation of the Perl version as a L&lt;version&gt;
object, which allows more flexible string comparisons.

The main advantage of C&lt;$]&gt; over C&lt;$^V&gt; is that it works the same on any
version of Perl.  The disadvantages are that it can't easily be compared
to versions in other formats (e.g. literal v-strings, &quot;v1.2.3&quot; or
version objects) and numeric comparisons can occasionally fail; it's good
for string literal version checks and bad for comparing to a variable
that hasn't been sanity-checked.

The C&lt;$OLD_PERL_VERSION&gt; form was added in Perl v5.20.0 for historical
reasons but its use is discouraged. (If your reason to use C&lt;$]&gt; is to
run code on old perls then referring to it as C&lt;$OLD_PERL_VERSION&gt; would
be self-defeating.)

Mnemonic: Is this version of perl in the right bracket?

=item $SYSTEM_FD_MAX

=item $^F
X&lt;$^F&gt; X&lt;$SYSTEM_FD_MAX&gt;

The maximum system file descriptor, ordinarily 2.  System file
descriptors are passed to C&lt;exec()&gt;ed processes, while higher file
descriptors are not.  Also, during an
C&lt;open()&gt;, system file descriptors are
preserved even if the C&lt;open()&gt; fails (ordinary file descriptors are
closed before the C&lt;open()&gt; is attempted).  The close-on-exec
status of a file descriptor will be decided according to the value of
C&lt;$^F&gt; when the corresponding file, pipe, or socket was opened, not the
time of the C&lt;exec()&gt;.

=item @F
X&lt;@F&gt;

The array C&lt;@F&gt; contains the fields of each line read in when autosplit
mode is turned on.  See L&lt;perlrun&gt; for the B&lt;-a&gt; switch.  This array
is package-specific, and must be declared or given a full package name
if not in package main when running under C&lt;strict 'vars'&gt;.

=item @INC
X&lt;@INC&gt;

The array C&lt;@INC&gt; contains the list of places that the C&lt;do EXPR&gt;,
C&lt;require&gt;, or C&lt;use&gt; constructs look for their library files.  It
initially consists of the arguments to any B&lt;-I&gt; command-line
switches, followed by the default Perl library, probably
F&lt;/usr/local/lib/perl&gt;, followed by &quot;.&quot;, to represent the current
directory.  (&quot;.&quot; will not be appended if taint checks are enabled,
either by C&lt;-T&gt; or by C&lt;-t&gt;, or if configured not to do so by the
C&lt;-Ddefault_inc_excludes_dot&gt; compile time option.)  If you need to
modify this at runtime, you should use the C&lt;use lib&gt; pragma to get
the machine-dependent library properly loaded also:

    use lib '/mypath/libdir/';
    use SomeMod;

You can also insert hooks into the file inclusion system by putting Perl
code directly into C&lt;@INC&gt;.  Those hooks may be subroutine references,
array references or blessed objects.  See L&lt;perlfunc/require&gt; for details.

=item %INC
X&lt;%INC&gt;

The hash C&lt;%INC&gt; contains entries for each filename included via the
C&lt;do&gt;, C&lt;require&gt;, or C&lt;use&gt; operators.  The key is the filename
you specified (with module names converted to pathnames), and the
value is the location of the file found.  The C&lt;require&gt;
operator uses this hash to determine whether a particular file has
already been included.

If the file was loaded via a hook (e.g. a subroutine reference, see
L&lt;perlfunc/require&gt; for a description of these hooks), this hook is
by default inserted into C&lt;%INC&gt; in place of a filename.  Note, however,
that the hook may have set the C&lt;%INC&gt; entry by itself to provide some more
specific info.

=item $INPLACE_EDIT

=item $^I
X&lt;$^I&gt; X&lt;$INPLACE_EDIT&gt;

The current value of the inplace-edit extension.  Use C&lt;undef&gt; to disable
inplace editing.

Mnemonic: value of B&lt;-i&gt; switch.

=item @ISA
X&lt;@ISA&gt;

Each package contains a special array called C&lt;@ISA&gt; which contains a list
of that class's parent classes, if any. This array is simply a list of
scalars, each of which is a string that corresponds to a package name. The
array is examined when Perl does method resolution, which is covered in
L&lt;perlobj&gt;.

To load packages while adding them to C&lt;@ISA&gt;, see the L&lt;parent&gt; pragma. The
discouraged L&lt;base&gt; pragma does this as well, but should not be used except
when compatibility with the discouraged L&lt;fields&gt; pragma is required.

=item $^M
X&lt;$^M&gt;

By default, running out of memory is an untrappable, fatal error.
However, if suitably built, Perl can use the contents of C&lt;$^M&gt;
as an emergency memory pool after C&lt;die()&gt;ing.  Suppose that your Perl
were compiled with C&lt;-DPERL_EMERGENCY_SBRK&gt; and used Perl's malloc.
Then

    $^M = 'a' x (1 &lt;&lt; 16);

would allocate a 64K buffer for use in an emergency.  See the
F&lt;INSTALL&gt; file in the Perl distribution for information on how to
add custom C compilation flags when compiling perl.  To discourage casual
use of this advanced feature, there is no L&lt;English|English&gt; long name for
this variable.

This variable was added in Perl 5.004.

=item $OSNAME

=item $^O
X&lt;$^O&gt; X&lt;$OSNAME&gt;

The name of the operating system under which this copy of Perl was
built, as determined during the configuration process.  For examples
see L&lt;perlport/PLATFORMS&gt;.

The value is identical to C&lt;$Config{'osname'}&gt;.  See also L&lt;Config&gt;
and the B&lt;-V&gt; command-line switch documented in L&lt;perlrun&gt;.

In Windows platforms, C&lt;$^O&gt; is not very helpful: since it is always
C&lt;MSWin32&gt;, it doesn't tell the difference between
95/98/ME/NT/2000/XP/CE/.NET.  Use C&lt;Win32::GetOSName()&gt; or
Win32::GetOSVersion() (see L&lt;Win32&gt; and L&lt;perlport&gt;) to distinguish
between the variants.

This variable was added in Perl 5.003.

=item %SIG
X&lt;%SIG&gt;

The hash C&lt;%SIG&gt; contains signal handlers for signals.  For example:

    sub handler {   # 1st argument is signal name
	my($sig) = @_;
	print &quot;Caught a SIG$sig--shutting down\n&quot;;
	close(LOG);
	exit(0);
	}

    $SIG{'INT'}  = \&amp;handler;
    $SIG{'QUIT'} = \&amp;handler;
    ...
    $SIG{'INT'}  = 'DEFAULT';   # restore default action
    $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT

Using a value of C&lt;'IGNORE'&gt; usually has the effect of ignoring the
signal, except for the C&lt;CHLD&gt; signal.  See L&lt;perlipc&gt; for more about
this special case.

Here are some other examples:

    $SIG{&quot;PIPE&quot;} = &quot;Plumber&quot;;   # assumes main::Plumber (not
				# recommended)
    $SIG{&quot;PIPE&quot;} = \&amp;Plumber;   # just fine; assume current
				# Plumber
    $SIG{&quot;PIPE&quot;} = *Plumber;    # somewhat esoteric
    $SIG{&quot;PIPE&quot;} = Plumber();   # oops, what did Plumber()
				# return??

Be sure not to use a bareword as the name of a signal handler,
lest you inadvertently call it.

If your system has the C&lt;sigaction()&gt; function then signal handlers
are installed using it.  This means you get reliable signal handling.

The default delivery policy of signals changed in Perl v5.8.0 from
immediate (also known as &quot;unsafe&quot;) to deferred, also known as &quot;safe
signals&quot;.  See L&lt;perlipc&gt; for more information.

Certain internal hooks can be also set using the C&lt;%SIG&gt; hash.  The
routine indicated by C&lt;$SIG{__WARN__}&gt; is called when a warning
message is about to be printed.  The warning message is passed as the
first argument.  The presence of a C&lt;__WARN__&gt; hook causes the
ordinary printing of warnings to C&lt;STDERR&gt; to be suppressed.  You can
use this to save warnings in a variable, or turn warnings into fatal
errors, like this:

    local $SIG{__WARN__} = sub { die $_[0] };
    eval $proggie;

As the C&lt;'IGNORE'&gt; hook is not supported by C&lt;__WARN__&gt;, you can
disable warnings using the empty subroutine:

    local $SIG{__WARN__} = sub {};

The routine indicated by C&lt;$SIG{__DIE__}&gt; is called when a fatal
exception is about to be thrown.  The error message is passed as the
first argument.  When a C&lt;__DIE__&gt; hook routine returns, the exception
processing continues as it would have in the absence of the hook,
unless the hook routine itself exits via a C&lt;goto &amp;sub&gt;, a loop exit,
or a C&lt;die()&gt;.  The C&lt;__DIE__&gt; handler is explicitly disabled during
the call, so that you can die from a C&lt;__DIE__&gt; handler.  Similarly
for C&lt;__WARN__&gt;.

The C&lt;$SIG{__DIE__}&gt; hook is called even inside an C&lt;eval()&gt;. It was
never intended to happen this way, but an implementation glitch made
this possible. This used to be deprecated, as it allowed strange action
at a distance like rewriting a pending exception in C&lt;$@&gt;. Plans to
rectify this have been scrapped, as users found that rewriting a 
pending exception is actually a useful feature, and not a bug.

C&lt;__DIE__&gt;/C&lt;__WARN__&gt; handlers are very special in one respect: they
may be called to report (probable) errors found by the parser.  In such
a case the parser may be in inconsistent state, so any attempt to
evaluate Perl code from such a handler will probably result in a
segfault.  This means that warnings or errors that result from parsing
Perl should be used with extreme caution, like this:

    require Carp if defined $^S;
    Carp::confess(&quot;Something wrong&quot;) if defined &amp;Carp::confess;
    die &quot;Something wrong, but could not load Carp to give &quot;
      . &quot;backtrace...\n\t&quot;
      . &quot;To see backtrace try starting Perl with -MCarp switch&quot;;

Here the first line will load C&lt;Carp&gt; I&lt;unless&gt; it is the parser who
called the handler.  The second line will print backtrace and die if
C&lt;Carp&gt; was available.  The third line will be executed only if C&lt;Carp&gt; was
not available.

Having to even think about the C&lt;$^S&gt; variable in your exception
handlers is simply wrong.  C&lt;$SIG{__DIE__}&gt; as currently implemented
invites grievous and difficult to track down errors.  Avoid it
and use an C&lt;END{}&gt; or CORE::GLOBAL::die override instead.

See L&lt;perlfunc/die&gt;, L&lt;perlfunc/warn&gt;, L&lt;perlfunc/eval&gt;, and
L&lt;warnings&gt; for additional information.

=item $BASETIME

=item $^T
X&lt;$^T&gt; X&lt;$BASETIME&gt;

The time at which the program began running, in seconds since the
epoch (beginning of 1970).  The values returned by the B&lt;-M&gt;, B&lt;-A&gt;,
and B&lt;-C&gt; filetests are based on this value.

=item $PERL_VERSION

=item $^V
X&lt;$^V&gt; X&lt;$PERL_VERSION&gt;

The revision, version, and subversion of the Perl interpreter,
represented as a L&lt;version&gt; object.

This variable first appeared in perl v5.6.0; earlier versions of perl
will see an undefined value.  Before perl v5.10.0 C&lt;$^V&gt; was represented
as a v-string rather than a L&lt;version&gt; object.

C&lt;$^V&gt; can be used to determine whether the Perl interpreter executing
a script is in the right range of versions.  For example:

    warn &quot;Hashes not randomized!\n&quot; if !$^V or $^V lt v5.8.1

While version objects overload stringification, to portably convert
C&lt;$^V&gt; into its string representation, use C&lt;sprintf()&gt;'s C&lt;&quot;%vd&quot;&gt;
conversion, which works for both v-strings or version objects:

    printf &quot;version is v%vd\n&quot;, $^V;  # Perl's version

See the documentation of C&lt;use VERSION&gt; and C&lt;require VERSION&gt;
for a convenient way to fail if the running Perl interpreter is too old.

See also C&lt;L&lt;/$]&gt;&gt; for a decimal representation of the Perl version.

The main advantage of C&lt;$^V&gt; over C&lt;$]&gt; is that, for Perl v5.10.0 or
later, it overloads operators, allowing easy comparison against other
version representations (e.g. decimal, literal v-string, &quot;v1.2.3&quot;, or
objects).  The disadvantage is that prior to v5.10.0, it was only a
literal v-string, which can't be easily printed or compared, whereas
the behavior of C&lt;$]&gt; is unchanged on all versions of Perl.

Mnemonic: use ^V for a version object.

=item ${^WIN32_SLOPPY_STAT}
X&lt;${^WIN32_SLOPPY_STAT}&gt; X&lt;sitecustomize&gt; X&lt;sitecustomize.pl&gt;

If this variable is set to a true value, then C&lt;stat()&gt; on Windows will
not try to open the file.  This means that the link count cannot be
determined and file attributes may be out of date if additional
hardlinks to the file exist.  On the other hand, not opening the file
is considerably faster, especially for files on network drives.

This variable could be set in the F&lt;sitecustomize.pl&gt; file to
configure the local Perl installation to use &quot;sloppy&quot; C&lt;stat()&gt; by
default.  See the documentation for B&lt;-f&gt; in
L&lt;perlrun|perlrun/&quot;Command Switches&quot;&gt; for more information about site
customization.

This variable was added in Perl v5.10.0.

=item $EXECUTABLE_NAME

=item $^X
X&lt;$^X&gt; X&lt;$EXECUTABLE_NAME&gt;

The name used to execute the current copy of Perl, from C's
C&lt;argv[0]&gt; or (where supported) F&lt;/proc/self/exe&gt;.

Depending on the host operating system, the value of C&lt;$^X&gt; may be
a relative or absolute pathname of the perl program file, or may
be the string used to invoke perl but not the pathname of the
perl program file.  Also, most operating systems permit invoking
programs that are not in the PATH environment variable, so there
is no guarantee that the value of C&lt;$^X&gt; is in PATH.  For VMS, the
value may or may not include a version number.

You usually can use the value of C&lt;$^X&gt; to re-invoke an independent
copy of the same perl that is currently running, e.g.,

    @first_run = `$^X -le &quot;print int rand 100 for 1..100&quot;`;

But recall that not all operating systems support forking or
capturing of the output of commands, so this complex statement
may not be portable.

It is not safe to use the value of C&lt;$^X&gt; as a path name of a file,
as some operating systems that have a mandatory suffix on
executable files do not require use of the suffix when invoking
a command.  To convert the value of C&lt;$^X&gt; to a path name, use the
following statements:

    # Build up a set of file names (not command names).
    use Config;
    my $this_perl = $^X;
    if ($^O ne 'VMS') {
	$this_perl .= $Config{_exe}
	  unless $this_perl =~ m/$Config{_exe}$/i;
	}

Because many operating systems permit anyone with read access to
the Perl program file to make a copy of it, patch the copy, and
then execute the copy, the security-conscious Perl programmer
should take care to invoke the installed copy of perl, not the
copy referenced by C&lt;$^X&gt;.  The following statements accomplish
this goal, and produce a pathname that can be invoked as a
command or referenced as a file.

    use Config;
    my $secure_perl_path = $Config{perlpath};
    if ($^O ne 'VMS') {
	$secure_perl_path .= $Config{_exe}
	    unless $secure_perl_path =~ m/$Config{_exe}$/i;
	}

=back

=head2 Variables related to regular expressions

Most of the special variables related to regular expressions are side
effects.  Perl sets these variables when it has a successful match, so
you should check the match result before using them.  For instance:

    if( /P(A)TT(ER)N/ ) {
	print &quot;I found $1 and $2\n&quot;;
	}

These variables are read-only and dynamically-scoped, unless we note
otherwise.

The dynamic nature of the regular expression variables means that
their value is limited to the block that they are in, as demonstrated
by this bit of code:

    my $outer = 'Wallace and Grommit';
    my $inner = 'Mutt and Jeff';

    my $pattern = qr/(\S+) and (\S+)/;

    sub show_n { print &quot;\$1 is $1; \$2 is $2\n&quot; }

    {
    OUTER:
	show_n() if $outer =~ m/$pattern/;

	INNER: {
	    show_n() if $inner =~ m/$pattern/;
	    }

	show_n();
    }

The output shows that while in the C&lt;OUTER&gt; block, the values of C&lt;$1&gt;
and C&lt;$2&gt; are from the match against C&lt;$outer&gt;.  Inside the C&lt;INNER&gt;
block, the values of C&lt;$1&gt; and C&lt;$2&gt; are from the match against
C&lt;$inner&gt;, but only until the end of the block (i.e. the dynamic
scope).  After the C&lt;INNER&gt; block completes, the values of C&lt;$1&gt; and
C&lt;$2&gt; return to the values for the match against C&lt;$outer&gt; even though
we have not made another match:

    $1 is Wallace; $2 is Grommit
    $1 is Mutt; $2 is Jeff
    $1 is Wallace; $2 is Grommit

=head3 Performance issues

Traditionally in Perl, any use of any of the three variables  C&lt;$`&gt;, C&lt;$&amp;&gt;
or C&lt;$'&gt; (or their C&lt;use English&gt; equivalents) anywhere in the code, caused
all subsequent successful pattern matches to make a copy of the matched
string, in case the code might subsequently access one of those variables.
This imposed a considerable performance penalty across the whole program,
so generally the use of these variables has been discouraged.

In Perl 5.6.0 the C&lt;@-&gt; and C&lt;@+&gt; dynamic arrays were introduced that
supply the indices of successful matches. So you could for example do
this:

    $str =~ /pattern/;

    print $`, $&amp;, $'; # bad: perfomance hit

    print             # good: no perfomance hit
	substr($str, 0,     $-[0]),
	substr($str, $-[0], $+[0]-$-[0]),
	substr($str, $+[0]);

In Perl 5.10.0 the C&lt;/p&gt; match operator flag and the C&lt;${^PREMATCH}&gt;,
C&lt;${^MATCH}&gt;, and C&lt;${^POSTMATCH}&gt; variables were introduced, that allowed
you to suffer the penalties only on patterns marked with C&lt;/p&gt;.

In Perl 5.18.0 onwards, perl started noting the presence of each of the
three variables separately, and only copied that part of the string
required; so in

    $`; $&amp;; &quot;abcdefgh&quot; =~ /d/

perl would only copy the &quot;abcd&quot; part of the string. That could make a big
difference in something like

    $str = 'x' x 1_000_000;
    $&amp;; # whoops
    $str =~ /x/g # one char copied a million times, not a million chars

In Perl 5.20.0 a new copy-on-write system was enabled by default, which
finally fixes all performance issues with these three variables, and makes
them safe to use anywhere.

The C&lt;Devel::NYTProf&gt; and C&lt;Devel::FindAmpersand&gt; modules can help you
find uses of these problematic match variables in your code.

=over 8

=item $&lt;I&lt;digits&gt;&gt; ($1, $2, ...)
X&lt;$1&gt; X&lt;$2&gt; X&lt;$3&gt; X&lt;$I&lt;digits&gt;&gt;

Contains the subpattern from the corresponding set of capturing
parentheses from the last successful pattern match, not counting patterns
matched in nested blocks that have been exited already.

Note there is a distinction between a capture buffer which matches
the empty string a capture buffer which is optional. Eg, C&lt;(x?)&gt; and
C&lt;(x)?&gt; The latter may be undef, the former not.

These variables are read-only and dynamically-scoped.

Mnemonic: like \digits.

=item @{^CAPTURE}
X&lt;@{^CAPTURE}&gt; X&lt;@^CAPTURE&gt;

An array which exposes the contents of the capture buffers, if any, of
the last successful pattern match, not counting patterns matched
in nested blocks that have been exited already.

Note that the 0 index of @{^CAPTURE} is equivalent to $1, the 1 index
is equivalent to $2, etc.

    if (&quot;foal&quot;=~/(.)(.)(.)(.)/) {
        print join &quot;-&quot;, @{^CAPTURE};
    }

should output &quot;f-o-a-l&quot;.

See also L&lt;/$I&lt;digits&gt;&gt;, L&lt;/%{^CAPTURE}&gt; and L&lt;/%{^CAPTURE_ALL}&gt;.

Note that unlike most other regex magic variables there is no single
letter equivalent to C&lt;@{^CAPTURE}&gt;.

This variable was added in 5.25.7

=item $MATCH

=item $&amp;
X&lt;$&amp;&gt; X&lt;$MATCH&gt;

The string matched by the last successful pattern match (not counting
any matches hidden within a BLOCK or C&lt;eval()&gt; enclosed by the current
BLOCK).

See L&lt;/Performance issues&gt; above for the serious performance implications
of using this variable (even once) in your code.

This variable is read-only and dynamically-scoped.

Mnemonic: like C&lt;&amp;&gt; in some editors.

=item ${^MATCH}
X&lt;${^MATCH}&gt;

This is similar to C&lt;$&amp;&gt; (C&lt;$MATCH&gt;) except that it does not incur the
performance penalty associated with that variable.

See L&lt;/Performance issues&gt; above.

In Perl v5.18 and earlier, it is only guaranteed
to return a defined value when the pattern was compiled or executed with
the C&lt;/p&gt; modifier.  In Perl v5.20, the C&lt;/p&gt; modifier does nothing, so
C&lt;${^MATCH}&gt; does the same thing as C&lt;$MATCH&gt;.

This variable was added in Perl v5.10.0.

This variable is read-only and dynamically-scoped.

=item $PREMATCH

=item $`
X&lt;$`&gt; X&lt;$PREMATCH&gt; X&lt;${^PREMATCH}&gt;

The string preceding whatever was matched by the last successful
pattern match, not counting any matches hidden within a BLOCK or C&lt;eval&gt;
enclosed by the current BLOCK.

See L&lt;/Performance issues&gt; above for the serious performance implications
of using this variable (even once) in your code.

This variable is read-only and dynamically-scoped.

Mnemonic: C&lt;`&gt; often precedes a quoted string.

=item ${^PREMATCH}
X&lt;$`&gt; X&lt;${^PREMATCH}&gt;

This is similar to C&lt;$`&gt; ($PREMATCH) except that it does not incur the
performance penalty associated with that variable.

See L&lt;/Performance issues&gt; above.

In Perl v5.18 and earlier, it is only guaranteed
to return a defined value when the pattern was compiled or executed with
the C&lt;/p&gt; modifier.  In Perl v5.20, the C&lt;/p&gt; modifier does nothing, so
C&lt;${^PREMATCH}&gt; does the same thing as C&lt;$PREMATCH&gt;.

This variable was added in Perl v5.10.0.

This variable is read-only and dynamically-scoped.

=item $POSTMATCH

=item $'
X&lt;$'&gt; X&lt;$POSTMATCH&gt; X&lt;${^POSTMATCH}&gt; X&lt;@-&gt;

The string following whatever was matched by the last successful
pattern match (not counting any matches hidden within a BLOCK or C&lt;eval()&gt;
enclosed by the current BLOCK).  Example:

    local $_ = 'abcdefghi';
    /def/;
    print &quot;$`:$&amp;:$'\n&quot;;  	# prints abc:def:ghi

See L&lt;/Performance issues&gt; above for the serious performance implications
of using this variable (even once) in your code.

This variable is read-only and dynamically-scoped.

Mnemonic: C&lt;'&gt; often follows a quoted string.

=item ${^POSTMATCH}
X&lt;${^POSTMATCH}&gt; X&lt;$'&gt; X&lt;$POSTMATCH&gt;

This is similar to C&lt;$'&gt; (C&lt;$POSTMATCH&gt;) except that it does not incur the
performance penalty associated with that variable.

See L&lt;/Performance issues&gt; above.

In Perl v5.18 and earlier, it is only guaranteed
to return a defined value when the pattern was compiled or executed with
the C&lt;/p&gt; modifier.  In Perl v5.20, the C&lt;/p&gt; modifier does nothing, so
C&lt;${^POSTMATCH}&gt; does the same thing as C&lt;$POSTMATCH&gt;.

This variable was added in Perl v5.10.0.

This variable is read-only and dynamically-scoped.

=item $LAST_PAREN_MATCH

=item $+
X&lt;$+&gt; X&lt;$LAST_PAREN_MATCH&gt;

The text matched by the last bracket of the last successful search pattern.
This is useful if you don't know which one of a set of alternative patterns
matched.  For example:

    /Version: (.*)|Revision: (.*)/ &amp;&amp; ($rev = $+);

This variable is read-only and dynamically-scoped.

Mnemonic: be positive and forward looking.

=item $LAST_SUBMATCH_RESULT

=item $^N
X&lt;$^N&gt; X&lt;$LAST_SUBMATCH_RESULT&gt;

The text matched by the used group most-recently closed (i.e. the group
with the rightmost closing parenthesis) of the last successful search
pattern.

This is primarily used inside C&lt;(?{...})&gt; blocks for examining text
recently matched.  For example, to effectively capture text to a variable
(in addition to C&lt;$1&gt;, C&lt;$2&gt;, etc.), replace C&lt;(...)&gt; with

    (?:(...)(?{ $var = $^N }))

By setting and then using C&lt;$var&gt; in this way relieves you from having to
worry about exactly which numbered set of parentheses they are.

This variable was added in Perl v5.8.0.

Mnemonic: the (possibly) Nested parenthesis that most recently closed.

=item @LAST_MATCH_END

=item @+
X&lt;@+&gt; X&lt;@LAST_MATCH_END&gt;

This array holds the offsets of the ends of the last successful
submatches in the currently active dynamic scope.  C&lt;$+[0]&gt; is
the offset into the string of the end of the entire match.  This
is the same value as what the C&lt;pos&gt; function returns when called
on the variable that was matched against.  The I&lt;n&gt;th element
of this array holds the offset of the I&lt;n&gt;th submatch, so
C&lt;$+[1]&gt; is the offset past where C&lt;$1&gt; ends, C&lt;$+[2]&gt; the offset
past where C&lt;$2&gt; ends, and so on.  You can use C&lt;$#+&gt; to determine
how many subgroups were in the last successful match.  See the
examples given for the C&lt;@-&gt; variable.

This variable was added in Perl v5.6.0.

=item %{^CAPTURE}

=item %LAST_PAREN_MATCH

=item %+
X&lt;%+&gt; X&lt;%LAST_PAREN_MATCH&gt; X&lt;%{^CAPTURE}&gt;

Similar to C&lt;@+&gt;, the C&lt;%+&gt; hash allows access to the named capture
buffers, should they exist, in the last successful match in the
currently active dynamic scope.

For example, C&lt;$+{foo}&gt; is equivalent to C&lt;$1&gt; after the following match:

    'foo' =~ /(?&lt;foo&gt;foo)/;

The keys of the C&lt;%+&gt; hash list only the names of buffers that have
captured (and that are thus associated to defined values).

The underlying behaviour of C&lt;%+&gt; is provided by the
L&lt;Tie::Hash::NamedCapture&gt; module.

B&lt;Note:&gt; C&lt;%-&gt; and C&lt;%+&gt; are tied views into a common internal hash
associated with the last successful regular expression.  Therefore mixing
iterative access to them via C&lt;each&gt; may have unpredictable results.
Likewise, if the last successful match changes, then the results may be
surprising.

This variable was added in Perl v5.10.0. The C&lt;%{^CAPTURE}&gt; alias was
added in 5.25.7.

This variable is read-only and dynamically-scoped.

=item @LAST_MATCH_START

=item @-
X&lt;@-&gt; X&lt;@LAST_MATCH_START&gt;

C&lt;$-[0]&gt; is the offset of the start of the last successful match.
C&lt;$-[&gt;I&lt;n&gt;C&lt;]&gt; is the offset of the start of the substring matched by
I&lt;n&gt;-th subpattern, or undef if the subpattern did not match.

Thus, after a match against C&lt;$_&gt;, C&lt;$&amp;&gt; coincides with C&lt;substr $_, $-[0],
$+[0] - $-[0]&gt;.  Similarly, $I&lt;n&gt; coincides with C&lt;substr $_, $-[n],
$+[n] - $-[n]&gt; if C&lt;$-[n]&gt; is defined, and $+ coincides with
C&lt;substr $_, $-[$#-], $+[$#-] - $-[$#-]&gt;.  One can use C&lt;$#-&gt; to find the
last matched subgroup in the last successful match.  Contrast with
C&lt;$#+&gt;, the number of subgroups in the regular expression.  Compare
with C&lt;@+&gt;.

This array holds the offsets of the beginnings of the last
successful submatches in the currently active dynamic scope.
C&lt;$-[0]&gt; is the offset into the string of the beginning of the
entire match.  The I&lt;n&gt;th element of this array holds the offset
of the I&lt;n&gt;th submatch, so C&lt;$-[1]&gt; is the offset where C&lt;$1&gt;
begins, C&lt;$-[2]&gt; the offset where C&lt;$2&gt; begins, and so on.

After a match against some variable C&lt;$var&gt;:

=over 5

=item C&lt;$`&gt; is the same as C&lt;substr($var, 0, $-[0])&gt;

=item C&lt;$&amp;&gt; is the same as C&lt;substr($var, $-[0], $+[0] - $-[0])&gt;

=item C&lt;$'&gt; is the same as C&lt;substr($var, $+[0])&gt;

=item C&lt;$1&gt; is the same as C&lt;substr($var, $-[1], $+[1] - $-[1])&gt;

=item C&lt;$2&gt; is the same as C&lt;substr($var, $-[2], $+[2] - $-[2])&gt;

=item C&lt;$3&gt; is the same as C&lt;substr($var, $-[3], $+[3] - $-[3])&gt;

=back

This variable was added in Perl v5.6.0.

=item %{^CAPTURE_ALL}
X&lt;%{^CAPTURE_ALL}&gt;

=item %-
X&lt;%-&gt;

Similar to C&lt;%+&gt;, this variable allows access to the named capture groups
in the last successful match in the currently active dynamic scope.  To
each capture group name found in the regular expression, it associates a
reference to an array containing the list of values captured by all
buffers with that name (should there be several of them), in the order
where they appear.

Here's an example:

    if ('1234' =~ /(?&lt;A&gt;1)(?&lt;B&gt;2)(?&lt;A&gt;3)(?&lt;B&gt;4)/) {
        foreach my $bufname (sort keys %-) {
            my $ary = $-{$bufname};
            foreach my $idx (0..$#$ary) {
                print &quot;\$-{$bufname}[$idx] : &quot;,
                      (defined($ary-&gt;[$idx])
                          ? &quot;'$ary-&gt;[$idx]'&quot;
                          : &quot;undef&quot;),
                      &quot;\n&quot;;
            }
        }
    }

would print out:

    $-{A}[0] : '1'
    $-{A}[1] : '3'
    $-{B}[0] : '2'
    $-{B}[1] : '4'

The keys of the C&lt;%-&gt; hash correspond to all buffer names found in
the regular expression.

The behaviour of C&lt;%-&gt; is implemented via the
L&lt;Tie::Hash::NamedCapture&gt; module.

B&lt;Note:&gt; C&lt;%-&gt; and C&lt;%+&gt; are tied views into a common internal hash
associated with the last successful regular expression.  Therefore mixing
iterative access to them via C&lt;each&gt; may have unpredictable results.
Likewise, if the last successful match changes, then the results may be
surprising.

This variable was added in Perl v5.10.0. The C&lt;%{^CAPTURE_ALL}&gt; alias was
added in 5.25.7.

This variable is read-only and dynamically-scoped.

=item $LAST_REGEXP_CODE_RESULT

=item $^R
X&lt;$^R&gt; X&lt;$LAST_REGEXP_CODE_RESULT&gt;

The result of evaluation of the last successful C&lt;(?{ code })&gt;
regular expression assertion (see L&lt;perlre&gt;).  May be written to.

This variable was added in Perl 5.005.

=item ${^RE_DEBUG_FLAGS}
X&lt;${^RE_DEBUG_FLAGS}&gt;

The current value of the regex debugging flags.  Set to 0 for no debug output
even when the C&lt;re 'debug'&gt; module is loaded.  See L&lt;re&gt; for details.

This variable was added in Perl v5.10.0.

=item ${^RE_TRIE_MAXBUF}
X&lt;${^RE_TRIE_MAXBUF}&gt;

Controls how certain regex optimisations are applied and how much memory they
utilize.  This value by default is 65536 which corresponds to a 512kB
temporary cache.  Set this to a higher value to trade
memory for speed when matching large alternations.  Set
it to a lower value if you want the optimisations to
be as conservative of memory as possible but still occur, and set it to a
negative value to prevent the optimisation and conserve the most memory.
Under normal situations this variable should be of no interest to you.

This variable was added in Perl v5.10.0.

=back

=head2 Variables related to filehandles

Variables that depend on the currently selected filehandle may be set
by calling an appropriate object method on the C&lt;IO::Handle&gt; object,
although this is less efficient than using the regular built-in
variables.  (Summary lines below for this contain the word HANDLE.)
First you must say

    use IO::Handle;

after which you may use either

    method HANDLE EXPR

or more safely,

    HANDLE-&gt;method(EXPR)

Each method returns the old value of the C&lt;IO::Handle&gt; attribute.  The
methods each take an optional EXPR, which, if supplied, specifies the
new value for the C&lt;IO::Handle&gt; attribute in question.  If not
supplied, most methods do nothing to the current value--except for
C&lt;autoflush()&gt;, which will assume a 1 for you, just to be different.

Because loading in the C&lt;IO::Handle&gt; class is an expensive operation,
you should learn how to use the regular built-in variables.

A few of these variables are considered &quot;read-only&quot;.  This means that
if you try to assign to this variable, either directly or indirectly
through a reference, you'll raise a run-time exception.

You should be very careful when modifying the default values of most
special variables described in this document.  In most cases you want
to localize these variables before changing them, since if you don't,
the change may affect other modules which rely on the default values
of the special variables that you have changed.  This is one of the
correct ways to read the whole file at once:

    open my $fh, &quot;&lt;&quot;, &quot;foo&quot; or die $!;
    local $/; # enable localized slurp mode
    my $content = &lt;$fh&gt;;
    close $fh;

But the following code is quite bad:

    open my $fh, &quot;&lt;&quot;, &quot;foo&quot; or die $!;
    undef $/; # enable slurp mode
    my $content = &lt;$fh&gt;;
    close $fh;

since some other module, may want to read data from some file in the
default &quot;line mode&quot;, so if the code we have just presented has been
executed, the global value of C&lt;$/&gt; is now changed for any other code
running inside the same Perl interpreter.

Usually when a variable is localized you want to make sure that this
change affects the shortest scope possible.  So unless you are already
inside some short C&lt;{}&gt; block, you should create one yourself.  For
example:

    my $content = '';
    open my $fh, &quot;&lt;&quot;, &quot;foo&quot; or die $!;
    {
	local $/;
	$content = &lt;$fh&gt;;
    }
    close $fh;

Here is an example of how your own code can go broken:

    for ( 1..3 ){
	$\ = &quot;\r\n&quot;;
	nasty_break();
	print &quot;$_&quot;;
    }

    sub nasty_break {
	$\ = &quot;\f&quot;;
	# do something with $_
    }

You probably expect this code to print the equivalent of

    &quot;1\r\n2\r\n3\r\n&quot;

but instead you get:

    &quot;1\f2\f3\f&quot;

Why? Because C&lt;nasty_break()&gt; modifies C&lt;$\&gt; without localizing it
first.  The value you set in  C&lt;nasty_break()&gt; is still there when you
return.  The fix is to add C&lt;local()&gt; so the value doesn't leak out of
C&lt;nasty_break()&gt;:

    local $\ = &quot;\f&quot;;

It's easy to notice the problem in such a short example, but in more
complicated code you are looking for trouble if you don't localize
changes to the special variables.

=over 8

=item $ARGV
X&lt;$ARGV&gt;

Contains the name of the current file when reading from C&lt;&lt; &lt;&gt; &gt;&gt;.

=item @ARGV
X&lt;@ARGV&gt;

The array C&lt;@ARGV&gt; contains the command-line arguments intended for
the script.  C&lt;$#ARGV&gt; is generally the number of arguments minus
one, because C&lt;$ARGV[0]&gt; is the first argument, I&lt;not&gt; the program's
command name itself.  See L&lt;/$0&gt; for the command name.

=item ARGV
X&lt;ARGV&gt;

The special filehandle that iterates over command-line filenames in
C&lt;@ARGV&gt;.  Usually written as the null filehandle in the angle operator
C&lt;&lt; &lt;&gt; &gt;&gt;.  Note that currently C&lt;ARGV&gt; only has its magical effect
within the C&lt;&lt; &lt;&gt; &gt;&gt; operator; elsewhere it is just a plain filehandle
corresponding to the last file opened by C&lt;&lt; &lt;&gt; &gt;&gt;.  In particular,
passing C&lt;\*ARGV&gt; as a parameter to a function that expects a filehandle
may not cause your function to automatically read the contents of all the
files in C&lt;@ARGV&gt;.

=item ARGVOUT
X&lt;ARGVOUT&gt;

The special filehandle that points to the currently open output file
when doing edit-in-place processing with B&lt;-i&gt;.  Useful when you have
to do a lot of inserting and don't want to keep modifying C&lt;$_&gt;.  See
L&lt;perlrun&gt; for the B&lt;-i&gt; switch.

=item IO::Handle-&gt;output_field_separator( EXPR )

=item $OUTPUT_FIELD_SEPARATOR

=item $OFS

=item $,
X&lt;$,&gt; X&lt;$OFS&gt; X&lt;$OUTPUT_FIELD_SEPARATOR&gt;

The output field separator for the print operator.  If defined, this
value is printed between each of print's arguments.  Default is C&lt;undef&gt;.

You cannot call C&lt;output_field_separator()&gt; on a handle, only as a
static method.  See L&lt;IO::Handle|IO::Handle&gt;.

Mnemonic: what is printed when there is a &quot;,&quot; in your print statement.

=item HANDLE-&gt;input_line_number( EXPR )

=item $INPUT_LINE_NUMBER

=item $NR

=item $.
X&lt;$.&gt; X&lt;$NR&gt; X&lt;$INPUT_LINE_NUMBER&gt; X&lt;line number&gt;

Current line number for the last filehandle accessed.

Each filehandle in Perl counts the number of lines that have been read
from it.  (Depending on the value of C&lt;$/&gt;, Perl's idea of what
constitutes a line may not match yours.)  When a line is read from a
filehandle (via C&lt;readline()&gt; or C&lt;&lt; &lt;&gt; &gt;&gt;), or when C&lt;tell()&gt; or
C&lt;seek()&gt; is called on it, C&lt;$.&gt; becomes an alias to the line counter
for that filehandle.

You can adjust the counter by assigning to C&lt;$.&gt;, but this will not
actually move the seek pointer.  I&lt;Localizing C&lt;$.&gt; will not localize
the filehandle's line count&gt;.  Instead, it will localize perl's notion
of which filehandle C&lt;$.&gt; is currently aliased to.

C&lt;$.&gt; is reset when the filehandle is closed, but B&lt;not&gt; when an open
filehandle is reopened without an intervening C&lt;close()&gt;.  For more
details, see L&lt;perlop/&quot;IE&lt;sol&gt;O Operators&quot;&gt;.  Because C&lt;&lt; &lt;&gt; &gt;&gt; never does
an explicit close, line numbers increase across C&lt;ARGV&gt; files (but see
examples in L&lt;perlfunc/eof&gt;).

You can also use C&lt;&lt; HANDLE-&gt;input_line_number(EXPR) &gt;&gt; to access the
line counter for a given filehandle without having to worry about
which handle you last accessed.

Mnemonic: many programs use &quot;.&quot; to mean the current line number.

=item IO::Handle-&gt;input_record_separator( EXPR )

=item $INPUT_RECORD_SEPARATOR

=item $RS

=item $/
X&lt;$/&gt; X&lt;$RS&gt; X&lt;$INPUT_RECORD_SEPARATOR&gt;

The input record separator, newline by default.  This influences Perl's
idea of what a &quot;line&quot; is.  Works like B&lt;awk&gt;'s RS variable, including
treating empty lines as a terminator if set to the null string (an
empty line cannot contain any spaces or tabs).  You may set it to a
multi-character string to match a multi-character terminator, or to
C&lt;undef&gt; to read through the end of file.  Setting it to C&lt;&quot;\n\n&quot;&gt;
means something slightly different than setting to C&lt;&quot;&quot;&gt;, if the file
contains consecutive empty lines.  Setting to C&lt;&quot;&quot;&gt; will treat two or
more consecutive empty lines as a single empty line.  Setting to
C&lt;&quot;\n\n&quot;&gt; will blindly assume that the next input character belongs to
the next paragraph, even if it's a newline.

    local $/;           # enable &quot;slurp&quot; mode
    local $_ = &lt;FH&gt;;    # whole file now here
    s/\n[ \t]+/ /g;

Remember: the value of C&lt;$/&gt; is a string, not a regex.  B&lt;awk&gt; has to
be better for something. :-)

Setting C&lt;$/&gt; to a reference to an integer, scalar containing an
integer, or scalar that's convertible to an integer will attempt to
read records instead of lines, with the maximum record size being the
referenced integer number of characters.  So this:

    local $/ = \32768; # or \&quot;32768&quot;, or \$var_containing_32768
    open my $fh, &quot;&lt;&quot;, $myfile or die $!;
    local $_ = &lt;$fh&gt;;

will read a record of no more than 32768 characters from $fh.  If you're
not reading from a record-oriented file (or your OS doesn't have
record-oriented files), then you'll likely get a full chunk of data
with every read.  If a record is larger than the record size you've
set, you'll get the record back in pieces.  Trying to set the record
size to zero or less is deprecated and will cause $/ to have the value
of &quot;undef&quot;, which will cause reading in the (rest of the) whole file.

As of 5.19.9 setting C&lt;$/&gt; to any other form of reference will throw a
fatal exception. This is in preparation for supporting new ways to set
C&lt;$/&gt; in the future.

On VMS only, record reads bypass PerlIO layers and any associated
buffering, so you must not mix record and non-record reads on the
same filehandle.  Record mode mixes with line mode only when the
same buffering layer is in use for both modes.

You cannot call C&lt;input_record_separator()&gt; on a handle, only as a
static method.  See L&lt;IO::Handle|IO::Handle&gt;.

See also L&lt;perlport/&quot;Newlines&quot;&gt;.  Also see L&lt;/$.&gt;.

Mnemonic: / delimits line boundaries when quoting poetry.

=item IO::Handle-&gt;output_record_separator( EXPR )

=item $OUTPUT_RECORD_SEPARATOR

=item $ORS

=item $\
X&lt;$\&gt; X&lt;$ORS&gt; X&lt;$OUTPUT_RECORD_SEPARATOR&gt;

The output record separator for the print operator.  If defined, this
value is printed after the last of print's arguments.  Default is C&lt;undef&gt;.

You cannot call C&lt;output_record_separator()&gt; on a handle, only as a
static method.  See L&lt;IO::Handle|IO::Handle&gt;.

Mnemonic: you set C&lt;$\&gt; instead of adding &quot;\n&quot; at the end of the print.
Also, it's just like C&lt;$/&gt;, but it's what you get &quot;back&quot; from Perl.

=item HANDLE-&gt;autoflush( EXPR )

=item $OUTPUT_AUTOFLUSH

=item $|
X&lt;$|&gt; X&lt;autoflush&gt; X&lt;flush&gt; X&lt;$OUTPUT_AUTOFLUSH&gt;

If set to nonzero, forces a flush right away and after every write or
print on the currently selected output channel.  Default is 0
(regardless of whether the channel is really buffered by the system or
not; C&lt;$|&gt; tells you only whether you've asked Perl explicitly to
flush after each write).  STDOUT will typically be line buffered if
output is to the terminal and block buffered otherwise.  Setting this
variable is useful primarily when you are outputting to a pipe or
socket, such as when you are running a Perl program under B&lt;rsh&gt; and
want to see the output as it's happening.  This has no effect on input
buffering.  See L&lt;perlfunc/getc&gt; for that.  See L&lt;perlfunc/select&gt; on
how to select the output channel.  See also L&lt;IO::Handle&gt;.

Mnemonic: when you want your pipes to be piping hot.

=item ${^LAST_FH}
X&lt;${^LAST_FH}&gt;

This read-only variable contains a reference to the last-read filehandle.
This is set by C&lt;&lt; &lt;HANDLE&gt; &gt;&gt;, C&lt;readline&gt;, C&lt;tell&gt;, C&lt;eof&gt; and C&lt;seek&gt;.
This is the same handle that C&lt;$.&gt; and C&lt;tell&gt; and C&lt;eof&gt; without arguments
use.  It is also the handle used when Perl appends &quot;, &lt;STDIN&gt; line 1&quot; to
an error or warning message.

This variable was added in Perl v5.18.0.

=back

=head3 Variables related to formats

The special variables for formats are a subset of those for
filehandles.  See L&lt;perlform&gt; for more information about Perl's
formats.

=over 8

=item $ACCUMULATOR

=item $^A
X&lt;$^A&gt; X&lt;$ACCUMULATOR&gt;

The current value of the C&lt;write()&gt; accumulator for C&lt;format()&gt; lines.
A format contains C&lt;formline()&gt; calls that put their result into
C&lt;$^A&gt;.  After calling its format, C&lt;write()&gt; prints out the contents
of C&lt;$^A&gt; and empties.  So you never really see the contents of C&lt;$^A&gt;
unless you call C&lt;formline()&gt; yourself and then look at it.  See
L&lt;perlform&gt; and L&lt;perlfunc/&quot;formline PICTURE,LIST&quot;&gt;.

=item IO::Handle-&gt;format_formfeed(EXPR)

=item $FORMAT_FORMFEED

=item $^L
X&lt;$^L&gt; X&lt;$FORMAT_FORMFEED&gt;

What formats output as a form feed.  The default is C&lt;\f&gt;.

You cannot call C&lt;format_formfeed()&gt; on a handle, only as a static
method.  See L&lt;IO::Handle|IO::Handle&gt;.

=item HANDLE-&gt;format_page_number(EXPR)

=item $FORMAT_PAGE_NUMBER

=item $%
X&lt;$%&gt; X&lt;$FORMAT_PAGE_NUMBER&gt;

The current page number of the currently selected output channel.

Mnemonic: C&lt;%&gt; is page number in B&lt;nroff&gt;.

=item HANDLE-&gt;format_lines_left(EXPR)

=item $FORMAT_LINES_LEFT

=item $-
X&lt;$-&gt; X&lt;$FORMAT_LINES_LEFT&gt;

The number of lines left on the page of the currently selected output
channel.

Mnemonic: lines_on_page - lines_printed.

=item IO::Handle-&gt;format_line_break_characters EXPR

=item $FORMAT_LINE_BREAK_CHARACTERS

=item $:
X&lt;$:&gt; X&lt;FORMAT_LINE_BREAK_CHARACTERS&gt;

The current set of characters after which a string may be broken to
fill continuation fields (starting with C&lt;^&gt;) in a format.  The default is
S&lt;&quot; \n-&quot;&gt;, to break on a space, newline, or a hyphen.

You cannot call C&lt;format_line_break_characters()&gt; on a handle, only as
a static method.  See L&lt;IO::Handle|IO::Handle&gt;.

Mnemonic: a &quot;colon&quot; in poetry is a part of a line.

=item HANDLE-&gt;format_lines_per_page(EXPR)

=item $FORMAT_LINES_PER_PAGE

=item $=
X&lt;$=&gt; X&lt;$FORMAT_LINES_PER_PAGE&gt;

The current page length (printable lines) of the currently selected
output channel.  The default is 60.

Mnemonic: = has horizontal lines.

=item HANDLE-&gt;format_top_name(EXPR)

=item $FORMAT_TOP_NAME

=item $^
X&lt;$^&gt; X&lt;$FORMAT_TOP_NAME&gt;

The name of the current top-of-page format for the currently selected
output channel.  The default is the name of the filehandle with C&lt;_TOP&gt;
appended.  For example, the default format top name for the C&lt;STDOUT&gt;
filehandle is C&lt;STDOUT_TOP&gt;.

Mnemonic: points to top of page.

=item HANDLE-&gt;format_name(EXPR)

=item $FORMAT_NAME

=item $~
X&lt;$~&gt; X&lt;$FORMAT_NAME&gt;

The name of the current report format for the currently selected
output channel.  The default format name is the same as the filehandle
name.  For example, the default format name for the C&lt;STDOUT&gt;
filehandle is just C&lt;STDOUT&gt;.

Mnemonic: brother to C&lt;$^&gt;.

=back

=head2 Error Variables
X&lt;error&gt; X&lt;exception&gt;

The variables C&lt;$@&gt;, C&lt;$!&gt;, C&lt;$^E&gt;, and C&lt;$?&gt; contain information
about different types of error conditions that may appear during
execution of a Perl program.  The variables are shown ordered by
the &quot;distance&quot; between the subsystem which reported the error and
the Perl process.  They correspond to errors detected by the Perl
interpreter, C library, operating system, or an external program,
respectively.

To illustrate the differences between these variables, consider the
following Perl expression, which uses a single-quoted string.  After
execution of this statement, perl may have set all four special error
variables:

    eval q{
	open my $pipe, &quot;/cdrom/install |&quot; or die $!;
	my @res = &lt;$pipe&gt;;
	close $pipe or die &quot;bad pipe: $?, $!&quot;;
    };

When perl executes the C&lt;eval()&gt; expression, it translates the
C&lt;open()&gt;, C&lt;&lt; &lt;PIPE&gt; &gt;&gt;, and C&lt;close&gt; calls in the C run-time library
and thence to the operating system kernel.  perl sets C&lt;$!&gt; to
the C library's C&lt;errno&gt; if one of these calls fails.

C&lt;$@&gt; is set if the string to be C&lt;eval&gt;-ed did not compile (this may
happen if C&lt;open&gt; or C&lt;close&gt; were imported with bad prototypes), or
if Perl code executed during evaluation C&lt;die()&gt;d.  In these cases the
value of C&lt;$@&gt; is the compile error, or the argument to C&lt;die&gt; (which
will interpolate C&lt;$!&gt; and C&lt;$?&gt;).  (See also L&lt;Fatal&gt;, though.)

Under a few operating systems, C&lt;$^E&gt; may contain a more verbose error
indicator, such as in this case, &quot;CDROM tray not closed.&quot;  Systems that
do not support extended error messages leave C&lt;$^E&gt; the same as C&lt;$!&gt;.

Finally, C&lt;$?&gt; may be set to a non-0 value if the external program
F&lt;/cdrom/install&gt; fails.  The upper eight bits reflect specific error
conditions encountered by the program (the program's C&lt;exit()&gt; value).
The lower eight bits reflect mode of failure, like signal death and
core dump information.  See L&lt;wait(2)&gt; for details.  In contrast to
C&lt;$!&gt; and C&lt;$^E&gt;, which are set only if an error condition is detected,
the variable C&lt;$?&gt; is set on each C&lt;wait&gt; or pipe C&lt;close&gt;,
overwriting the old value.  This is more like C&lt;$@&gt;, which on every
C&lt;eval()&gt; is always set on failure and cleared on success.

For more details, see the individual descriptions at C&lt;$@&gt;, C&lt;$!&gt;,
C&lt;$^E&gt;, and C&lt;$?&gt;.

=over 8

=item ${^CHILD_ERROR_NATIVE}
X&lt;$^CHILD_ERROR_NATIVE&gt;

The native status returned by the last pipe close, backtick (C&lt;``&gt;)
command, successful call to C&lt;wait()&gt; or C&lt;waitpid()&gt;, or from the
C&lt;system()&gt; operator.  On POSIX-like systems this value can be decoded
with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
WSTOPSIG and WIFCONTINUED functions provided by the L&lt;POSIX&gt; module.

Under VMS this reflects the actual VMS exit status; i.e. it is the
same as C&lt;$?&gt; when the pragma C&lt;use vmsish 'status'&gt; is in effect.

This variable was added in Perl v5.10.0.

=item $EXTENDED_OS_ERROR

=item $^E
X&lt;$^E&gt; X&lt;$EXTENDED_OS_ERROR&gt;

Error information specific to the current operating system.  At the
moment, this differs from C&lt;L&lt;/$!&gt;&gt; under only VMS, OS/2, and Win32 (and
for MacPerl).  On all other platforms, C&lt;$^E&gt; is always just the same
as C&lt;$!&gt;.

Under VMS, C&lt;$^E&gt; provides the VMS status value from the last system
error.  This is more specific information about the last system error
than that provided by C&lt;$!&gt;.  This is particularly important when C&lt;$!&gt;
is set to B&lt;EVMSERR&gt;.

Under OS/2, C&lt;$^E&gt; is set to the error code of the last call to OS/2
API either via CRT, or directly from perl.

Under Win32, C&lt;$^E&gt; always returns the last error information reported
by the Win32 call C&lt;GetLastError()&gt; which describes the last error
from within the Win32 API.  Most Win32-specific code will report errors
via C&lt;$^E&gt;.  ANSI C and Unix-like calls set C&lt;errno&gt; and so most
portable Perl code will report errors via C&lt;$!&gt;.

Caveats mentioned in the description of C&lt;L&lt;/$!&gt;&gt; generally apply to
C&lt;$^E&gt;, also.

This variable was added in Perl 5.003.

Mnemonic: Extra error explanation.

=item $EXCEPTIONS_BEING_CAUGHT

=item $^S
X&lt;$^S&gt; X&lt;$EXCEPTIONS_BEING_CAUGHT&gt;

Current state of the interpreter.

	$^S         State
	---------   -------------------------------------
	undef       Parsing module, eval, or main program
	true (1)    Executing an eval
	false (0)   Otherwise

The first state may happen in C&lt;$SIG{__DIE__}&gt; and C&lt;$SIG{__WARN__}&gt;
handlers.

The English name $EXCEPTIONS_BEING_CAUGHT is slightly misleading, because
the C&lt;undef&gt; value does not indicate whether exceptions are being caught,
since compilation of the main program does not catch exceptions.

This variable was added in Perl 5.004.

=item $WARNING

=item $^W
X&lt;$^W&gt; X&lt;$WARNING&gt;

The current value of the warning switch, initially true if B&lt;-w&gt; was
used, false otherwise, but directly modifiable.

See also L&lt;warnings&gt;.

Mnemonic: related to the B&lt;-w&gt; switch.

=item ${^WARNING_BITS}
X&lt;${^WARNING_BITS}&gt;

The current set of warning checks enabled by the C&lt;use warnings&gt; pragma.
It has the same scoping as the C&lt;$^H&gt; and C&lt;%^H&gt; variables.  The exact
values are considered internal to the L&lt;warnings&gt; pragma and may change
between versions of Perl.

This variable was added in Perl v5.6.0.

=item $OS_ERROR

=item $ERRNO

=item $!
X&lt;$!&gt; X&lt;$ERRNO&gt; X&lt;$OS_ERROR&gt;

When referenced, C&lt;$!&gt; retrieves the current value
of the C C&lt;errno&gt; integer variable.
If C&lt;$!&gt; is assigned a numerical value, that value is stored in C&lt;errno&gt;.
When referenced as a string, C&lt;$!&gt; yields the system error string
corresponding to C&lt;errno&gt;.

Many system or library calls set C&lt;errno&gt; if they fail,
to indicate the cause of failure.  They usually do B&lt;not&gt;
set C&lt;errno&gt; to zero if they succeed.  This means C&lt;errno&gt;,
hence C&lt;$!&gt;, is meaningful only I&lt;immediately&gt; after a B&lt;failure&gt;:

    if (open my $fh, &quot;&lt;&quot;, $filename) {
		# Here $! is meaningless.
		...
    }
    else {
		# ONLY here is $! meaningful.
		...
		# Already here $! might be meaningless.
    }
    # Since here we might have either success or failure,
    # $! is meaningless.

Here, I&lt;meaningless&gt; means that C&lt;$!&gt; may be unrelated to the outcome
of the C&lt;open()&gt; operator.  Assignment to C&lt;$!&gt; is similarly ephemeral.
It can be used immediately before invoking the C&lt;die()&gt; operator,
to set the exit value, or to inspect the system error string
corresponding to error I&lt;n&gt;, or to restore C&lt;$!&gt; to a meaningful state.

Mnemonic: What just went bang?

=item %OS_ERROR

=item %ERRNO

=item %!
X&lt;%!&gt; X&lt;%OS_ERROR&gt; X&lt;%ERRNO&gt;

Each element of C&lt;%!&gt; has a true value only if C&lt;$!&gt; is set to that
value.  For example, C&lt;$!{ENOENT}&gt; is true if and only if the current
value of C&lt;$!&gt; is C&lt;ENOENT&gt;; that is, if the most recent error was &quot;No
such file or directory&quot; (or its moral equivalent: not all operating
systems give that exact error, and certainly not all languages).  The
specific true value is not guaranteed, but in the past has generally
been the numeric value of C&lt;$!&gt;.  To check if a particular key is
meaningful on your system, use C&lt;exists $!{the_key}&gt;; for a list of legal
keys, use C&lt;keys %!&gt;.  See L&lt;Errno&gt; for more information, and also see
L&lt;/$!&gt;.

This variable was added in Perl 5.005.

=item $CHILD_ERROR

=item $?
X&lt;$?&gt; X&lt;$CHILD_ERROR&gt;

The status returned by the last pipe close, backtick (C&lt;``&gt;) command,
successful call to C&lt;wait()&gt; or C&lt;waitpid()&gt;, or from the C&lt;system()&gt;
operator.  This is just the 16-bit status word returned by the
traditional Unix C&lt;wait()&gt; system call (or else is made up to look
like it).  Thus, the exit value of the subprocess is really (C&lt;&lt;&lt; $? &gt;&gt;
8 &gt;&gt;&gt;), and C&lt;$? &amp; 127&gt; gives which signal, if any, the process died
from, and C&lt;$? &amp; 128&gt; reports whether there was a core dump.

Additionally, if the C&lt;h_errno&gt; variable is supported in C, its value
is returned via C&lt;$?&gt; if any C&lt;gethost*()&gt; function fails.

If you have installed a signal handler for C&lt;SIGCHLD&gt;, the
value of C&lt;$?&gt; will usually be wrong outside that handler.

Inside an C&lt;END&gt; subroutine C&lt;$?&gt; contains the value that is going to be
given to C&lt;exit()&gt;.  You can modify C&lt;$?&gt; in an C&lt;END&gt; subroutine to
change the exit status of your program.  For example:

    END {
	$? = 1 if $? == 255;  # die would make it 255
    }

Under VMS, the pragma C&lt;use vmsish 'status'&gt; makes C&lt;$?&gt; reflect the
actual VMS exit status, instead of the default emulation of POSIX
status; see L&lt;perlvms/$?&gt; for details.

Mnemonic: similar to B&lt;sh&gt; and B&lt;ksh&gt;.

=item $EVAL_ERROR

=item $@
X&lt;$@&gt; X&lt;$EVAL_ERROR&gt;

The Perl error from the last C&lt;eval&gt; operator, i.e. the last exception that
was caught.  For C&lt;eval BLOCK&gt;, this is either a runtime error message or the
string or reference C&lt;die&gt; was called with.  The C&lt;eval STRING&gt; form also
catches syntax errors and other compile time exceptions.

If no error occurs, C&lt;eval&gt; sets C&lt;$@&gt; to the empty string.

Warning messages are not collected in this variable.  You can, however,
set up a routine to process warnings by setting C&lt;$SIG{__WARN__}&gt; as
described in L&lt;/%SIG&gt;.

Mnemonic: Where was the error &quot;at&quot;?

=back

=head2 Variables related to the interpreter state

These variables provide information about the current interpreter state.

=over 8

=item $COMPILING

=item $^C
X&lt;$^C&gt; X&lt;$COMPILING&gt;

The current value of the flag associated with the B&lt;-c&gt; switch.
Mainly of use with B&lt;-MO=...&gt; to allow code to alter its behavior
when being compiled, such as for example to C&lt;AUTOLOAD&gt; at compile
time rather than normal, deferred loading.  Setting
C&lt;$^C = 1&gt; is similar to calling C&lt;B::minus_c&gt;.

This variable was added in Perl v5.6.0.

=item $DEBUGGING

=item $^D
X&lt;$^D&gt; X&lt;$DEBUGGING&gt;

The current value of the debugging flags.  May be read or set.  Like its
L&lt;command-line equivalent|perlrun/B&lt;-D&gt;I&lt;letters&gt;&gt;, you can use numeric
or symbolic values, e.g. C&lt;$^D = 10&gt; or C&lt;$^D = &quot;st&quot;&gt;.  See
L&lt;perlrun/B&lt;-D&gt;I&lt;number&gt;&gt;.  The contents of this variable also affects the
debugger operation.  See L&lt;perldebguts/Debugger Internals&gt;.

Mnemonic: value of B&lt;-D&gt; switch.

=item ${^ENCODING}
X&lt;${^ENCODING}&gt;

This variable is no longer supported.

It used to hold the I&lt;object reference&gt; to the C&lt;Encode&gt; object that was
used to convert the source code to Unicode.

Its purpose was to allow your non-ASCII Perl
scripts not to have to be written in UTF-8; this was
useful before editors that worked on UTF-8 encoded text were common, but
that was long ago.  It caused problems, such as affecting the operation
of other modules that weren't expecting it, causing general mayhem.

If you need something like this functionality, it is recommended that use
you a simple source filter, such as L&lt;Filter::Encoding&gt;.

If you are coming here because code of yours is being adversely affected
by someone's use of this variable, you can usually work around it by
doing this:

 local ${^ENCODING};

near the beginning of the functions that are getting broken.  This
undefines the variable during the scope of execution of the including
function.

This variable was added in Perl 5.8.2 and removed in 5.26.0.

=item ${^GLOBAL_PHASE}
X&lt;${^GLOBAL_PHASE}&gt;

The current phase of the perl interpreter.

Possible values are:

=over 8

=item CONSTRUCT

The C&lt;PerlInterpreter*&gt; is being constructed via C&lt;perl_construct&gt;.  This
value is mostly there for completeness and for use via the
underlying C variable C&lt;PL_phase&gt;.  It's not really possible for Perl
code to be executed unless construction of the interpreter is
finished.

=item START

This is the global compile-time.  That includes, basically, every
C&lt;BEGIN&gt; block executed directly or indirectly from during the
compile-time of the top-level program.

This phase is not called &quot;BEGIN&quot; to avoid confusion with
C&lt;BEGIN&gt;-blocks, as those are executed during compile-time of any
compilation unit, not just the top-level program.  A new, localised
compile-time entered at run-time, for example by constructs as
C&lt;eval &quot;use SomeModule&quot;&gt; are not global interpreter phases, and
therefore aren't reflected by C&lt;${^GLOBAL_PHASE}&gt;.

=item CHECK

Execution of any C&lt;CHECK&gt; blocks.

=item INIT

Similar to &quot;CHECK&quot;, but for C&lt;INIT&gt;-blocks, not C&lt;CHECK&gt; blocks.

=item RUN

The main run-time, i.e. the execution of C&lt;PL_main_root&gt;.

=item END

Execution of any C&lt;END&gt; blocks.

=item DESTRUCT

Global destruction.

=back

Also note that there's no value for UNITCHECK-blocks.  That's because
those are run for each compilation unit individually, and therefore is
not a global interpreter phase.

Not every program has to go through each of the possible phases, but
transition from one phase to another can only happen in the order
described in the above list.

An example of all of the phases Perl code can see:

    BEGIN { print &quot;compile-time: ${^GLOBAL_PHASE}\n&quot; }

    INIT  { print &quot;init-time: ${^GLOBAL_PHASE}\n&quot; }

    CHECK { print &quot;check-time: ${^GLOBAL_PHASE}\n&quot; }

    {
        package Print::Phase;

        sub new {
            my ($class, $time) = @_;
            return bless \$time, $class;
        }

        sub DESTROY {
            my $self = shift;
            print &quot;$$self: ${^GLOBAL_PHASE}\n&quot;;
        }
    }

    print &quot;run-time: ${^GLOBAL_PHASE}\n&quot;;

    my $runtime = Print::Phase-&gt;new(
        &quot;lexical variables are garbage collected before END&quot;
    );

    END   { print &quot;end-time: ${^GLOBAL_PHASE}\n&quot; }

    our $destruct = Print::Phase-&gt;new(
        &quot;package variables are garbage collected after END&quot;
    );

This will print out

    compile-time: START
    check-time: CHECK
    init-time: INIT
    run-time: RUN
    lexical variables are garbage collected before END: RUN
    end-time: END
    package variables are garbage collected after END: DESTRUCT

This variable was added in Perl 5.14.0.

=item $^H
X&lt;$^H&gt;

WARNING: This variable is strictly for
internal use only.  Its availability,
behavior, and contents are subject to change without notice.

This variable contains compile-time hints for the Perl interpreter.  At the
end of compilation of a BLOCK the value of this variable is restored to the
value when the interpreter started to compile the BLOCK.

When perl begins to parse any block construct that provides a lexical scope
(e.g., eval body, required file, subroutine body, loop body, or conditional
block), the existing value of C&lt;$^H&gt; is saved, but its value is left unchanged.
When the compilation of the block is completed, it regains the saved value.
Between the points where its value is saved and restored, code that
executes within BEGIN blocks is free to change the value of C&lt;$^H&gt;.

This behavior provides the semantic of lexical scoping, and is used in,
for instance, the C&lt;use strict&gt; pragma.

The contents should be an integer; different bits of it are used for
different pragmatic flags.  Here's an example:

    sub add_100 { $^H |= 0x100 }

    sub foo {
	BEGIN { add_100() }
	bar-&gt;baz($boon);
    }

Consider what happens during execution of the BEGIN block.  At this point
the BEGIN block has already been compiled, but the body of C&lt;foo()&gt; is still
being compiled.  The new value of C&lt;$^H&gt;
will therefore be visible only while
the body of C&lt;foo()&gt; is being compiled.

Substitution of C&lt;BEGIN { add_100() }&gt; block with:

    BEGIN { require strict; strict-&gt;import('vars') }

demonstrates how C&lt;use strict 'vars'&gt; is implemented.  Here's a conditional
version of the same lexical pragma:

    BEGIN {
	require strict; strict-&gt;import('vars') if $condition
    }

This variable was added in Perl 5.003.

=item %^H
X&lt;%^H&gt;

The C&lt;%^H&gt; hash provides the same scoping semantic as C&lt;$^H&gt;.  This makes
it useful for implementation of lexically scoped pragmas.  See
L&lt;perlpragma&gt;.   All the entries are stringified when accessed at
runtime, so only simple values can be accommodated.  This means no
pointers to objects, for example.

When putting items into C&lt;%^H&gt;, in order to avoid conflicting with other
users of the hash there is a convention regarding which keys to use.
A module should use only keys that begin with the module's name (the
name of its main package) and a &quot;/&quot; character.  For example, a module
C&lt;Foo::Bar&gt; should use keys such as C&lt;Foo::Bar/baz&gt;.

This variable was added in Perl v5.6.0.

=item ${^OPEN}
X&lt;${^OPEN}&gt;

An internal variable used by PerlIO.  A string in two parts, separated
by a C&lt;\0&gt; byte, the first part describes the input layers, the second
part describes the output layers.

This variable was added in Perl v5.8.0.

=item $PERLDB

=item $^P
X&lt;$^P&gt; X&lt;$PERLDB&gt;

The internal variable for debugging support.  The meanings of the
various bits are subject to change, but currently indicate:

=over 6

=item 0x01

Debug subroutine enter/exit.

=item 0x02

Line-by-line debugging.  Causes C&lt;DB::DB()&gt; subroutine to be called for
each statement executed.  Also causes saving source code lines (like
0x400).

=item 0x04

Switch off optimizations.

=item 0x08

Preserve more data for future interactive inspections.

=item 0x10

Keep info about source lines on which a subroutine is defined.

=item 0x20

Start with single-step on.

=item 0x40

Use subroutine address instead of name when reporting.

=item 0x80

Report C&lt;goto &amp;subroutine&gt; as well.

=item 0x100

Provide informative &quot;file&quot; names for evals based on the place they were compiled.

=item 0x200

Provide informative names to anonymous subroutines based on the place they
were compiled.

=item 0x400

Save source code lines into C&lt;@{&quot;_&lt;$filename&quot;}&gt;.

=item 0x800

When saving source, include evals that generate no subroutines.

=item 0x1000

When saving source, include source that did not compile.

=back

Some bits may be relevant at compile-time only, some at
run-time only.  This is a new mechanism and the details may change.
See also L&lt;perldebguts&gt;.

=item ${^TAINT}
X&lt;${^TAINT}&gt;

Reflects if taint mode is on or off.  1 for on (the program was run with
B&lt;-T&gt;), 0 for off, -1 when only taint warnings are enabled (i.e. with
B&lt;-t&gt; or B&lt;-TU&gt;).

This variable is read-only.

This variable was added in Perl v5.8.0.

=item ${^UNICODE}
X&lt;${^UNICODE}&gt;

Reflects certain Unicode settings of Perl.  See L&lt;perlrun&gt;
documentation for the C&lt;-C&gt; switch for more information about
the possible values.

This variable is set during Perl startup and is thereafter read-only.

This variable was added in Perl v5.8.2.

=item ${^UTF8CACHE}
X&lt;${^UTF8CACHE}&gt;

This variable controls the state of the internal UTF-8 offset caching code.
1 for on (the default), 0 for off, -1 to debug the caching code by checking
all its results against linear scans, and panicking on any discrepancy.

This variable was added in Perl v5.8.9.  It is subject to change or
removal without notice, but is currently used to avoid recalculating the
boundaries of multi-byte UTF-8-encoded characters.

=item ${^UTF8LOCALE}
X&lt;${^UTF8LOCALE}&gt;

This variable indicates whether a UTF-8 locale was detected by perl at
startup.  This information is used by perl when it's in
adjust-utf8ness-to-locale mode (as when run with the C&lt;-CL&gt; command-line
switch); see L&lt;perlrun&gt; for more info on this.

This variable was added in Perl v5.8.8.

=back

=head2 Deprecated and removed variables

Deprecating a variable announces the intent of the perl maintainers to
eventually remove the variable from the language.  It may still be
available despite its status.  Using a deprecated variable triggers
a warning.

Once a variable is removed, its use triggers an error telling you
the variable is unsupported.

See L&lt;perldiag&gt; for details about error messages.

=over 8

=item $#
X&lt;$#&gt;

C&lt;$#&gt; was a variable that could be used to format printed numbers.
After a deprecation cycle, its magic was removed in Perl v5.10.0 and
using it now triggers a warning: C&lt;$# is no longer supported&gt;.

This is not the sigil you use in front of an array name to get the
last index, like C&lt;$#array&gt;.  That's still how you get the last index
of an array in Perl.  The two have nothing to do with each other.

Deprecated in Perl 5.

Removed in Perl v5.10.0.

=item $*
X&lt;$*&gt;

C&lt;$*&gt; was a variable that you could use to enable multiline matching.
After a deprecation cycle, its magic was removed in Perl v5.10.0.
Using it now triggers a warning: C&lt;$* is no longer supported&gt;.
You should use the C&lt;/s&gt; and C&lt;/m&gt; regexp modifiers instead.

Deprecated in Perl 5.

Removed in Perl v5.10.0.

=item $[
X&lt;$[&gt;

This variable stores the index of the first element in an array, and
of the first character in a substring.  The default is 0, but you could
theoretically set it to 1 to make Perl behave more like B&lt;awk&gt; (or Fortran)
when subscripting and when evaluating the index() and substr() functions.

As of release 5 of Perl, assignment to C&lt;$[&gt; is treated as a compiler
directive, and cannot influence the behavior of any other file.
(That's why you can only assign compile-time constants to it.)
Its use is highly discouraged.

Prior to Perl v5.10.0, assignment to C&lt;$[&gt; could be seen from outer lexical
scopes in the same file, unlike other compile-time directives (such as
L&lt;strict&gt;).  Using local() on it would bind its value strictly to a lexical
block.  Now it is always lexically scoped.

As of Perl v5.16.0, it is implemented by the L&lt;arybase&gt; module.  See
L&lt;arybase&gt; for more details on its behaviour.

Under C&lt;use v5.16&gt;, or C&lt;no feature &quot;array_base&quot;&gt;, C&lt;$[&gt; no longer has any
effect, and always contains 0.  Assigning 0 to it is permitted, but any
other value will produce an error.

Mnemonic: [ begins subscripts.

Deprecated in Perl v5.12.0.

=back

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>