<h2>Editing File: /usr/share/perl5/pod/perluniintro.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perluniintro - Perl Unicode introduction

=head1 DESCRIPTION

This document gives a general idea of Unicode and how to use Unicode
in Perl.  See L&lt;/Further Resources&gt; for references to more in-depth
treatments of Unicode.

=head2 Unicode

Unicode is a character set standard which plans to codify all of the
writing systems of the world, plus many other symbols.

Unicode and ISO/IEC 10646 are coordinated standards that unify
almost all other modern character set standards,
covering more than 80 writing systems and hundreds of languages,
including all commercially-important modern languages.  All characters
in the largest Chinese, Japanese, and Korean dictionaries are also
encoded. The standards will eventually cover almost all characters in
more than 250 writing systems and thousands of languages.
Unicode 1.0 was released in October 1991, and 6.0 in October 2010.

A Unicode I&lt;character&gt; is an abstract entity.  It is not bound to any
particular integer width, especially not to the C language C&lt;char&gt;.
Unicode is language-neutral and display-neutral: it does not encode the
language of the text, and it does not generally define fonts or other graphical
layout details.  Unicode operates on characters and on text built from
those characters.

Unicode defines characters like C&lt;LATIN CAPITAL LETTER A&gt; or C&lt;GREEK
SMALL LETTER ALPHA&gt; and unique numbers for the characters, in this
case 0x0041 and 0x03B1, respectively.  These unique numbers are called
I&lt;code points&gt;.  A code point is essentially the position of the
character within the set of all possible Unicode characters, and thus in
Perl, the term I&lt;ordinal&gt; is often used interchangeably with it.

The Unicode standard prefers using hexadecimal notation for the code
points.  If numbers like C&lt;0x0041&gt; are unfamiliar to you, take a peek
at a later section, L&lt;/&quot;Hexadecimal Notation&quot;&gt;.  The Unicode standard
uses the notation C&lt;U+0041 LATIN CAPITAL LETTER A&gt;, to give the
hexadecimal code point and the normative name of the character.

Unicode also defines various I&lt;properties&gt; for the characters, like
&quot;uppercase&quot; or &quot;lowercase&quot;, &quot;decimal digit&quot;, or &quot;punctuation&quot;;
these properties are independent of the names of the characters.
Furthermore, various operations on the characters like uppercasing,
lowercasing, and collating (sorting) are defined.

A Unicode I&lt;logical&gt; &quot;character&quot; can actually consist of more than one internal
I&lt;actual&gt; &quot;character&quot; or code point.  For Western languages, this is adequately
modelled by a I&lt;base character&gt; (like C&lt;LATIN CAPITAL LETTER A&gt;) followed
by one or more I&lt;modifiers&gt; (like C&lt;COMBINING ACUTE ACCENT&gt;).  This sequence of
base character and modifiers is called a I&lt;combining character
sequence&gt;.  Some non-western languages require more complicated
models, so Unicode created the I&lt;grapheme cluster&gt; concept, which was
later further refined into the I&lt;extended grapheme cluster&gt;.  For
example, a Korean Hangul syllable is considered a single logical
character, but most often consists of three actual
Unicode characters: a leading consonant followed by an interior vowel followed
by a trailing consonant.

Whether to call these extended grapheme clusters &quot;characters&quot; depends on your
point of view. If you are a programmer, you probably would tend towards seeing
each element in the sequences as one unit, or &quot;character&quot;.  However from
the user's point of view, the whole sequence could be seen as one
&quot;character&quot; since that's probably what it looks like in the context of the
user's language.  In this document, we take the programmer's point of
view: one &quot;character&quot; is one Unicode code point.

For some combinations of base character and modifiers, there are
I&lt;precomposed&gt; characters.  There is a single character equivalent, for
example, for the sequence C&lt;LATIN CAPITAL LETTER A&gt; followed by
C&lt;COMBINING ACUTE ACCENT&gt;.  It is called  C&lt;LATIN CAPITAL LETTER A WITH
ACUTE&gt;.  These precomposed characters are, however, only available for
some combinations, and are mainly meant to support round-trip
conversions between Unicode and legacy standards (like ISO 8859).  Using
sequences, as Unicode does, allows for needing fewer basic building blocks
(code points) to express many more potential grapheme clusters.  To
support conversion between equivalent forms, various I&lt;normalization
forms&gt; are also defined.  Thus, C&lt;LATIN CAPITAL LETTER A WITH ACUTE&gt; is
in I&lt;Normalization Form Composed&gt;, (abbreviated NFC), and the sequence
C&lt;LATIN CAPITAL LETTER A&gt; followed by C&lt;COMBINING ACUTE ACCENT&gt;
represents the same character in I&lt;Normalization Form Decomposed&gt; (NFD).

Because of backward compatibility with legacy encodings, the &quot;a unique
number for every character&quot; idea breaks down a bit: instead, there is
&quot;at least one number for every character&quot;.  The same character could
be represented differently in several legacy encodings.  The
converse is not true: some code points do not have an assigned
character.  Firstly, there are unallocated code points within
otherwise used blocks.  Secondly, there are special Unicode control
characters that do not represent true characters.

When Unicode was first conceived, it was thought that all the world's
characters could be represented using a 16-bit word; that is a maximum of
C&lt;0x10000&gt; (or 65,536) characters would be needed, from C&lt;0x0000&gt; to
C&lt;0xFFFF&gt;.  This soon proved to be wrong, and since Unicode 2.0 (July
1996), Unicode has been defined all the way up to 21 bits (C&lt;0x10FFFF&gt;),
and Unicode 3.1 (March 2001) defined the first characters above C&lt;0xFFFF&gt;.
The first C&lt;0x10000&gt; characters are called the I&lt;Plane 0&gt;, or the
I&lt;Basic Multilingual Plane&gt; (BMP).  With Unicode 3.1, 17 (yes,
seventeen) planes in all were defined--but they are nowhere near full of
defined characters, yet.

When a new language is being encoded, Unicode generally will choose a
C&lt;block&gt; of consecutive unallocated code points for its characters.  So
far, the number of code points in these blocks has always been evenly
divisible by 16.  Extras in a block, not currently needed, are left
unallocated, for future growth.  But there have been occasions when
a later release needed more code points than the available extras, and a
new block had to allocated somewhere else, not contiguous to the initial
one, to handle the overflow.  Thus, it became apparent early on that
&quot;block&quot; wasn't an adequate organizing principle, and so the C&lt;Script&gt;
property was created.  (Later an improved script property was added as
well, the C&lt;Script_Extensions&gt; property.)  Those code points that are in
overflow blocks can still
have the same script as the original ones.  The script concept fits more
closely with natural language: there is C&lt;Latin&gt; script, C&lt;Greek&gt;
script, and so on; and there are several artificial scripts, like
C&lt;Common&gt; for characters that are used in multiple scripts, such as
mathematical symbols.  Scripts usually span varied parts of several
blocks.  For more information about scripts, see L&lt;perlunicode/Scripts&gt;.
The division into blocks exists, but it is almost completely
accidental--an artifact of how the characters have been and still are
allocated.  (Note that this paragraph has oversimplified things for the
sake of this being an introduction.  Unicode doesn't really encode
languages, but the writing systems for them--their scripts; and one
script can be used by many languages.  Unicode also encodes things that
aren't really about languages, such as symbols like C&lt;BAGGAGE CLAIM&gt;.)

The Unicode code points are just abstract numbers.  To input and
output these abstract numbers, the numbers must be I&lt;encoded&gt; or
I&lt;serialised&gt; somehow.  Unicode defines several I&lt;character encoding
forms&gt;, of which I&lt;UTF-8&gt; is the most popular.  UTF-8 is a
variable length encoding that encodes Unicode characters as 1 to 4
bytes.  Other encodings
include UTF-16 and UTF-32 and their big- and little-endian variants
(UTF-8 is byte-order independent).  The ISO/IEC 10646 defines the UCS-2
and UCS-4 encoding forms.

For more information about encodings--for instance, to learn what
I&lt;surrogates&gt; and I&lt;byte order marks&gt; (BOMs) are--see L&lt;perlunicode&gt;.

=head2 Perl's Unicode Support

Starting from Perl v5.6.0, Perl has had the capacity to handle Unicode
natively.  Perl v5.8.0, however, is the first recommended release for
serious Unicode work.  The maintenance release 5.6.1 fixed many of the
problems of the initial Unicode implementation, but for example
regular expressions still do not work with Unicode in 5.6.1.
Perl v5.14.0 is the first release where Unicode support is
(almost) seamlessly integrable without some gotchas. (There are a few
exceptions. Firstly, some differences in L&lt;quotemeta|perlfunc/quotemeta&gt;
were fixed starting in Perl 5.16.0. Secondly, some differences in
L&lt;the range operator|perlop/Range Operators&gt; were fixed starting in
Perl 5.26.0. Thirdly, some differences in L&lt;split|perlfunc/split&gt; were fixed
started in Perl 5.28.0.)

To enable this
seamless support, you should C&lt;use feature 'unicode_strings'&gt; (which is
automatically selected if you C&lt;use 5.012&gt; or higher).  See L&lt;feature&gt;.
(5.14 also fixes a number of bugs and departures from the Unicode
standard.)

Before Perl v5.8.0, the use of C&lt;use utf8&gt; was used to declare
that operations in the current block or file would be Unicode-aware.
This model was found to be wrong, or at least clumsy: the &quot;Unicodeness&quot;
is now carried with the data, instead of being attached to the
operations.
Starting with Perl v5.8.0, only one case remains where an explicit C&lt;use
utf8&gt; is needed: if your Perl script itself is encoded in UTF-8, you can
use UTF-8 in your identifier names, and in string and regular expression
literals, by saying C&lt;use utf8&gt;.  This is not the default because
scripts with legacy 8-bit data in them would break.  See L&lt;utf8&gt;.

=head2 Perl's Unicode Model

Perl supports both pre-5.6 strings of eight-bit native bytes, and
strings of Unicode characters.  The general principle is that Perl tries
to keep its data as eight-bit bytes for as long as possible, but as soon
as Unicodeness cannot be avoided, the data is transparently upgraded
to Unicode.  Prior to Perl v5.14.0, the upgrade was not completely
transparent (see L&lt;perlunicode/The &quot;Unicode Bug&quot;&gt;), and for backwards
compatibility, full transparency is not gained unless C&lt;use feature
'unicode_strings'&gt; (see L&lt;feature&gt;) or C&lt;use 5.012&gt; (or higher) is
selected.

Internally, Perl currently uses either whatever the native eight-bit
character set of the platform (for example Latin-1) is, defaulting to
UTF-8, to encode Unicode strings. Specifically, if all code points in
the string are C&lt;0xFF&gt; or less, Perl uses the native eight-bit
character set.  Otherwise, it uses UTF-8.

A user of Perl does not normally need to know nor care how Perl
happens to encode its internal strings, but it becomes relevant when
outputting Unicode strings to a stream without a PerlIO layer (one with
the &quot;default&quot; encoding).  In such a case, the raw bytes used internally
(the native character set or UTF-8, as appropriate for each string)
will be used, and a &quot;Wide character&quot; warning will be issued if those
strings contain a character beyond 0x00FF.

For example,

      perl -e 'print &quot;\x{DF}\n&quot;, &quot;\x{0100}\x{DF}\n&quot;'

produces a fairly useless mixture of native bytes and UTF-8, as well
as a warning:

     Wide character in print at ...

To output UTF-8, use the C&lt;:encoding&gt; or C&lt;:utf8&gt; output layer.  Prepending

      binmode(STDOUT, &quot;:utf8&quot;);

to this sample program ensures that the output is completely UTF-8,
and removes the program's warning.

You can enable automatic UTF-8-ification of your standard file
handles, default C&lt;open()&gt; layer, and C&lt;@ARGV&gt; by using either
the C&lt;-C&gt; command line switch or the C&lt;PERL_UNICODE&gt; environment
variable, see L&lt;perlrun&gt; for the documentation of the C&lt;-C&gt; switch.

Note that this means that Perl expects other software to work the same
way:
if Perl has been led to believe that STDIN should be UTF-8, but then
STDIN coming in from another command is not UTF-8, Perl will likely
complain about the malformed UTF-8.

All features that combine Unicode and I/O also require using the new
PerlIO feature.  Almost all Perl 5.8 platforms do use PerlIO, though:
you can see whether yours is by running &quot;perl -V&quot; and looking for
C&lt;useperlio=define&gt;.

=head2 Unicode and EBCDIC

Perl 5.8.0 added support for Unicode on EBCDIC platforms.  This support
was allowed to lapse in later releases, but was revived in 5.22.
Unicode support is somewhat more complex to implement since additional
conversions are needed.  See L&lt;perlebcdic&gt; for more information.

On EBCDIC platforms, the internal Unicode encoding form is UTF-EBCDIC
instead of UTF-8.  The difference is that as UTF-8 is &quot;ASCII-safe&quot; in
that ASCII characters encode to UTF-8 as-is, while UTF-EBCDIC is
&quot;EBCDIC-safe&quot;, in that all the basic characters (which includes all
those that have ASCII equivalents (like C&lt;&quot;A&quot;&gt;, C&lt;&quot;0&quot;&gt;, C&lt;&quot;%&quot;&gt;, I&lt;etc.&gt;)
are the same in both EBCDIC and UTF-EBCDIC.  Often, documentation
will use the term &quot;UTF-8&quot; to mean UTF-EBCDIC as well.  This is the case
in this document.

=head2 Creating Unicode

This section applies fully to Perls starting with v5.22.  Various
caveats for earlier releases are in the L&lt;/Earlier releases caveats&gt;
subsection below.

To create Unicode characters in literals,
use the C&lt;\N{...}&gt; notation in double-quoted strings:

 my $smiley_from_name = &quot;\N{WHITE SMILING FACE}&quot;;
 my $smiley_from_code_point = &quot;\N{U+263a}&quot;;

Similarly, they can be used in regular expression literals

 $smiley =~ /\N{WHITE SMILING FACE}/;
 $smiley =~ /\N{U+263a}/;

At run-time you can use:

 use charnames ();
 my $hebrew_alef_from_name
                      = charnames::string_vianame(&quot;HEBREW LETTER ALEF&quot;);
 my $hebrew_alef_from_code_point = charnames::string_vianame(&quot;U+05D0&quot;);

Naturally, C&lt;ord()&gt; will do the reverse: it turns a character into
a code point.

There are other runtime options as well.  You can use C&lt;pack()&gt;:

 my $hebrew_alef_from_code_point = pack(&quot;U&quot;, 0x05d0);

Or you can use C&lt;chr()&gt;, though it is less convenient in the general
case:

 $hebrew_alef_from_code_point = chr(utf8::unicode_to_native(0x05d0));
 utf8::upgrade($hebrew_alef_from_code_point);

The C&lt;utf8::unicode_to_native()&gt; and C&lt;utf8::upgrade()&gt; aren't needed if
the argument is above 0xFF, so the above could have been written as

 $hebrew_alef_from_code_point = chr(0x05d0);

since 0x5d0 is above 255.

C&lt;\x{}&gt; and C&lt;\o{}&gt; can also be used to specify code points at compile
time in double-quotish strings, but, for backward compatibility with
older Perls, the same rules apply as with C&lt;chr()&gt; for code points less
than 256.

C&lt;utf8::unicode_to_native()&gt; is used so that the Perl code is portable
to EBCDIC platforms.  You can omit it if you're I&lt;really&gt; sure no one
will ever want to use your code on a non-ASCII platform.  Starting in
Perl v5.22, calls to it on ASCII platforms are optimized out, so there's
no performance penalty at all in adding it.  Or you can simply use the
other constructs that don't require it.

See L&lt;/&quot;Further Resources&quot;&gt; for how to find all these names and numeric
codes.

=head3 Earlier releases caveats

On EBCDIC platforms, prior to v5.22, using C&lt;\N{U+...}&gt; doesn't work
properly.

Prior to v5.16, using C&lt;\N{...}&gt; with a character name (as opposed to a
C&lt;U+...&gt; code point) required a S&lt;C&lt;use charnames :full&gt;&gt;.

Prior to v5.14, there were some bugs in C&lt;\N{...}&gt; with a character name
(as opposed to a C&lt;U+...&gt; code point).

C&lt;charnames::string_vianame()&gt; was introduced in v5.14.  Prior to that,
C&lt;charnames::vianame()&gt; should work, but only if the argument is of the
form C&lt;&quot;U+...&quot;&gt;.  Your best bet there for runtime Unicode by character
name is probably:

 use charnames ();
 my $hebrew_alef_from_name
                  = pack(&quot;U&quot;, charnames::vianame(&quot;HEBREW LETTER ALEF&quot;));

=head2 Handling Unicode

Handling Unicode is for the most part transparent: just use the
strings as usual.  Functions like C&lt;index()&gt;, C&lt;length()&gt;, and
C&lt;substr()&gt; will work on the Unicode characters; regular expressions
will work on the Unicode characters (see L&lt;perlunicode&gt; and L&lt;perlretut&gt;).

Note that Perl considers grapheme clusters to be separate characters, so for
example

 print length(&quot;\N{LATIN CAPITAL LETTER A}\N{COMBINING ACUTE ACCENT}&quot;),
       &quot;\n&quot;;

will print 2, not 1.  The only exception is that regular expressions
have C&lt;\X&gt; for matching an extended grapheme cluster.  (Thus C&lt;\X&gt; in a
regular expression would match the entire sequence of both the example
characters.)

Life is not quite so transparent, however, when working with legacy
encodings, I/O, and certain special cases:

=head2 Legacy Encodings

When you combine legacy data and Unicode, the legacy data needs
to be upgraded to Unicode.  Normally the legacy data is assumed to be
ISO 8859-1 (or EBCDIC, if applicable).

The C&lt;Encode&gt; module knows about many encodings and has interfaces
for doing conversions between those encodings:

    use Encode 'decode';
    $data = decode(&quot;iso-8859-3&quot;, $data); # convert from legacy

=head2 Unicode I/O

Normally, writing out Unicode data

    print FH $some_string_with_unicode, &quot;\n&quot;;

produces raw bytes that Perl happens to use to internally encode the
Unicode string.  Perl's internal encoding depends on the system as
well as what characters happen to be in the string at the time. If
any of the characters are at code points C&lt;0x100&gt; or above, you will get
a warning.  To ensure that the output is explicitly rendered in the
encoding you desire--and to avoid the warning--open the stream with
the desired encoding. Some examples:

    open FH, &quot;&gt;:utf8&quot;, &quot;file&quot;;

    open FH, &quot;&gt;:encoding(ucs2)&quot;,      &quot;file&quot;;
    open FH, &quot;&gt;:encoding(UTF-8)&quot;,     &quot;file&quot;;
    open FH, &quot;&gt;:encoding(shift_jis)&quot;, &quot;file&quot;;

and on already open streams, use C&lt;binmode()&gt;:

    binmode(STDOUT, &quot;:utf8&quot;);

    binmode(STDOUT, &quot;:encoding(ucs2)&quot;);
    binmode(STDOUT, &quot;:encoding(UTF-8)&quot;);
    binmode(STDOUT, &quot;:encoding(shift_jis)&quot;);

The matching of encoding names is loose: case does not matter, and
many encodings have several aliases.  Note that the C&lt;:utf8&gt; layer
must always be specified exactly like that; it is I&lt;not&gt; subject to
the loose matching of encoding names. Also note that currently C&lt;:utf8&gt; is unsafe for
input, because it accepts the data without validating that it is indeed valid
UTF-8; you should instead use C&lt;:encoding(UTF-8)&gt; (with or without a
hyphen).

See L&lt;PerlIO&gt; for the C&lt;:utf8&gt; layer, L&lt;PerlIO::encoding&gt; and
L&lt;Encode::PerlIO&gt; for the C&lt;:encoding()&gt; layer, and
L&lt;Encode::Supported&gt; for many encodings supported by the C&lt;Encode&gt;
module.

Reading in a file that you know happens to be encoded in one of the
Unicode or legacy encodings does not magically turn the data into
Unicode in Perl's eyes.  To do that, specify the appropriate
layer when opening files

    open(my $fh,'&lt;:encoding(UTF-8)', 'anything');
    my $line_of_unicode = &lt;$fh&gt;;

    open(my $fh,'&lt;:encoding(Big5)', 'anything');
    my $line_of_unicode = &lt;$fh&gt;;

The I/O layers can also be specified more flexibly with
the C&lt;open&gt; pragma.  See L&lt;open&gt;, or look at the following example.

    use open ':encoding(UTF-8)'; # input/output default encoding will be
                                 # UTF-8
    open X, &quot;&gt;file&quot;;
    print X chr(0x100), &quot;\n&quot;;
    close X;
    open Y, &quot;&lt;file&quot;;
    printf &quot;%#x\n&quot;, ord(&lt;Y&gt;); # this should print 0x100
    close Y;

With the C&lt;open&gt; pragma you can use the C&lt;:locale&gt; layer

    BEGIN { $ENV{LC_ALL} = $ENV{LANG} = 'ru_RU.KOI8-R' }
    # the :locale will probe the locale environment variables like
    # LC_ALL
    use open OUT =&gt; ':locale'; # russki parusski
    open(O, &quot;&gt;koi8&quot;);
    print O chr(0x430); # Unicode CYRILLIC SMALL LETTER A = KOI8-R 0xc1
    close O;
    open(I, &quot;&lt;koi8&quot;);
    printf &quot;%#x\n&quot;, ord(&lt;I&gt;), &quot;\n&quot;; # this should print 0xc1
    close I;

These methods install a transparent filter on the I/O stream that
converts data from the specified encoding when it is read in from the
stream.  The result is always Unicode.

The L&lt;open&gt; pragma affects all the C&lt;open()&gt; calls after the pragma by
setting default layers.  If you want to affect only certain
streams, use explicit layers directly in the C&lt;open()&gt; call.

You can switch encodings on an already opened stream by using
C&lt;binmode()&gt;; see L&lt;perlfunc/binmode&gt;.

The C&lt;:locale&gt; does not currently work with
C&lt;open()&gt; and C&lt;binmode()&gt;, only with the C&lt;open&gt; pragma.  The
C&lt;:utf8&gt; and C&lt;:encoding(...)&gt; methods do work with all of C&lt;open()&gt;,
C&lt;binmode()&gt;, and the C&lt;open&gt; pragma.

Similarly, you may use these I/O layers on output streams to
automatically convert Unicode to the specified encoding when it is
written to the stream. For example, the following snippet copies the
contents of the file &quot;text.jis&quot; (encoded as ISO-2022-JP, aka JIS) to
the file &quot;text.utf8&quot;, encoded as UTF-8:

    open(my $nihongo, '&lt;:encoding(iso-2022-jp)', 'text.jis');
    open(my $unicode, '&gt;:utf8',                  'text.utf8');
    while (&lt;$nihongo&gt;) { print $unicode $_ }

The naming of encodings, both by the C&lt;open()&gt; and by the C&lt;open&gt;
pragma allows for flexible names: C&lt;koi8-r&gt; and C&lt;KOI8R&gt; will both be
understood.

Common encodings recognized by ISO, MIME, IANA, and various other
standardisation organisations are recognised; for a more detailed
list see L&lt;Encode::Supported&gt;.

C&lt;read()&gt; reads characters and returns the number of characters.
C&lt;seek()&gt; and C&lt;tell()&gt; operate on byte counts, as do C&lt;sysread()&gt;
and C&lt;sysseek()&gt;.

Notice that because of the default behaviour of not doing any
conversion upon input if there is no default layer,
it is easy to mistakenly write code that keeps on expanding a file
by repeatedly encoding the data:

    # BAD CODE WARNING
    open F, &quot;file&quot;;
    local $/; ## read in the whole file of 8-bit characters
    $t = &lt;F&gt;;
    close F;
    open F, &quot;&gt;:encoding(UTF-8)&quot;, &quot;file&quot;;
    print F $t; ## convert to UTF-8 on output
    close F;

If you run this code twice, the contents of the F&lt;file&gt; will be twice
UTF-8 encoded.  A C&lt;use open ':encoding(UTF-8)'&gt; would have avoided the
bug, or explicitly opening also the F&lt;file&gt; for input as UTF-8.

B&lt;NOTE&gt;: the C&lt;:utf8&gt; and C&lt;:encoding&gt; features work only if your
Perl has been built with L&lt;PerlIO&gt;, which is the default
on most systems.

=head2 Displaying Unicode As Text

Sometimes you might want to display Perl scalars containing Unicode as
simple ASCII (or EBCDIC) text.  The following subroutine converts
its argument so that Unicode characters with code points greater than
255 are displayed as C&lt;\x{...}&gt;, control characters (like C&lt;\n&gt;) are
displayed as C&lt;\x..&gt;, and the rest of the characters as themselves:

 sub nice_string {
        join(&quot;&quot;,
        map { $_ &gt; 255                    # if wide character...
              ? sprintf(&quot;\\x{%04X}&quot;, $_)  # \x{...}
              : chr($_) =~ /[[:cntrl:]]/  # else if control character...
                ? sprintf(&quot;\\x%02X&quot;, $_)  # \x..
                : quotemeta(chr($_))      # else quoted or as themselves
        } unpack(&quot;W*&quot;, $_[0]));           # unpack Unicode characters
   }

For example,

   nice_string(&quot;foo\x{100}bar\n&quot;)

returns the string

   'foo\x{0100}bar\x0A'

which is ready to be printed.

(C&lt;\\x{}&gt; is used here instead of C&lt;\\N{}&gt;, since it's most likely that
you want to see what the native values are.)

=head2 Special Cases

=over 4

=item *

Bit Complement Operator ~ And vec()

The bit complement operator C&lt;~&gt; may produce surprising results if
used on strings containing characters with ordinal values above
255. In such a case, the results are consistent with the internal
encoding of the characters, but not with much else. So don't do
that. Similarly for C&lt;vec()&gt;: you will be operating on the
internally-encoded bit patterns of the Unicode characters, not on
the code point values, which is very probably not what you want.

=item *

Peeking At Perl's Internal Encoding

Normal users of Perl should never care how Perl encodes any particular
Unicode string (because the normal ways to get at the contents of a
string with Unicode--via input and output--should always be via
explicitly-defined I/O layers). But if you must, there are two
ways of looking behind the scenes.

One way of peeking inside the internal encoding of Unicode characters
is to use C&lt;unpack(&quot;C*&quot;, ...&gt; to get the bytes of whatever the string
encoding happens to be, or C&lt;unpack(&quot;U0..&quot;, ...)&gt; to get the bytes of the
UTF-8 encoding:

    # this prints  c4 80  for the UTF-8 bytes 0xc4 0x80
    print join(&quot; &quot;, unpack(&quot;U0(H2)*&quot;, pack(&quot;U&quot;, 0x100))), &quot;\n&quot;;

Yet another way would be to use the Devel::Peek module:

    perl -MDevel::Peek -e 'Dump(chr(0x100))'

That shows the C&lt;UTF8&gt; flag in FLAGS and both the UTF-8 bytes
and Unicode characters in C&lt;PV&gt;.  See also later in this document
the discussion about the C&lt;utf8::is_utf8()&gt; function.

=back

=head2 Advanced Topics

=over 4

=item *

String Equivalence

The question of string equivalence turns somewhat complicated
in Unicode: what do you mean by &quot;equal&quot;?

(Is C&lt;LATIN CAPITAL LETTER A WITH ACUTE&gt; equal to
C&lt;LATIN CAPITAL LETTER A&gt;?)

The short answer is that by default Perl compares equivalence (C&lt;eq&gt;,
C&lt;ne&gt;) based only on code points of the characters.  In the above
case, the answer is no (because 0x00C1 != 0x0041).  But sometimes, any
CAPITAL LETTER A's should be considered equal, or even A's of any case.

The long answer is that you need to consider character normalization
and casing issues: see L&lt;Unicode::Normalize&gt;, Unicode Technical Report #15,
L&lt;Unicode Normalization Forms|http://www.unicode.org/unicode/reports/tr15&gt; and
sections on case mapping in the L&lt;Unicode Standard|http://www.unicode.org&gt;.

As of Perl 5.8.0, the &quot;Full&quot; case-folding of I&lt;Case
Mappings/SpecialCasing&gt; is implemented, but bugs remain in C&lt;qr//i&gt; with them,
mostly fixed by 5.14, and essentially entirely by 5.18.

=item *

String Collation

People like to see their strings nicely sorted--or as Unicode
parlance goes, collated.  But again, what do you mean by collate?

(Does C&lt;LATIN CAPITAL LETTER A WITH ACUTE&gt; come before or after
C&lt;LATIN CAPITAL LETTER A WITH GRAVE&gt;?)

The short answer is that by default, Perl compares strings (C&lt;lt&gt;,
C&lt;le&gt;, C&lt;cmp&gt;, C&lt;ge&gt;, C&lt;gt&gt;) based only on the code points of the
characters.  In the above case, the answer is &quot;after&quot;, since
C&lt;0x00C1&gt; &gt; C&lt;0x00C0&gt;.

The long answer is that &quot;it depends&quot;, and a good answer cannot be
given without knowing (at the very least) the language context.
See L&lt;Unicode::Collate&gt;, and I&lt;Unicode Collation Algorithm&gt;
L&lt;http://www.unicode.org/unicode/reports/tr10/&gt;

=back

=head2 Miscellaneous

=over 4

=item *

Character Ranges and Classes

Character ranges in regular expression bracketed character classes ( e.g.,
C&lt;/[a-z]/&gt;) and in the C&lt;tr///&gt; (also known as C&lt;y///&gt;) operator are not
magically Unicode-aware.  What this means is that C&lt;[A-Za-z]&gt; will not
magically start to mean &quot;all alphabetic letters&quot; (not that it does mean that
even for 8-bit characters; for those, if you are using locales (L&lt;perllocale&gt;),
use C&lt;/[[:alpha:]]/&gt;; and if not, use the 8-bit-aware property C&lt;\p{alpha}&gt;).

All the properties that begin with C&lt;\p&gt; (and its inverse C&lt;\P&gt;) are actually
character classes that are Unicode-aware.  There are dozens of them, see
L&lt;perluniprops&gt;.

Starting in v5.22, you can use Unicode code points as the end points of
regular expression pattern character ranges, and the range will include
all Unicode code points that lie between those end points, inclusive.

 qr/ [ \N{U+03} - \N{U+20} ] /xx

includes the code points
C&lt;\N{U+03}&gt;, C&lt;\N{U+04}&gt;, ..., C&lt;\N{U+20}&gt;.

This also works for ranges in C&lt;tr///&gt; starting in Perl v5.24.

=item *

String-To-Number Conversions

Unicode does define several other decimal--and numeric--characters
besides the familiar 0 to 9, such as the Arabic and Indic digits.
Perl does not support string-to-number conversion for digits other
than ASCII C&lt;0&gt; to C&lt;9&gt; (and ASCII C&lt;a&gt; to C&lt;f&gt; for hexadecimal).
To get safe conversions from any Unicode string, use
L&lt;Unicode::UCD/num()&gt;.

=back

=head2 Questions With Answers

=over 4

=item *

Will My Old Scripts Break?

Very probably not.  Unless you are generating Unicode characters
somehow, old behaviour should be preserved.  About the only behaviour
that has changed and which could start generating Unicode is the old
behaviour of C&lt;chr()&gt; where supplying an argument more than 255
produced a character modulo 255.  C&lt;chr(300)&gt;, for example, was equal
to C&lt;chr(45)&gt; or &quot;-&quot; (in ASCII), now it is LATIN CAPITAL LETTER I WITH
BREVE.

=item *

How Do I Make My Scripts Work With Unicode?

Very little work should be needed since nothing changes until you
generate Unicode data.  The most important thing is getting input as
Unicode; for that, see the earlier I/O discussion.
To get full seamless Unicode support, add
C&lt;use feature 'unicode_strings'&gt; (or C&lt;use 5.012&gt; or higher) to your
script.

=item *

How Do I Know Whether My String Is In Unicode?

You shouldn't have to care.  But you may if your Perl is before 5.14.0
or you haven't specified C&lt;use feature 'unicode_strings'&gt; or C&lt;use
5.012&gt; (or higher) because otherwise the rules for the code points
in the range 128 to 255 are different depending on
whether the string they are contained within is in Unicode or not.
(See L&lt;perlunicode/When Unicode Does Not Happen&gt;.)

To determine if a string is in Unicode, use:

    print utf8::is_utf8($string) ? 1 : 0, &quot;\n&quot;;

But note that this doesn't mean that any of the characters in the
string are necessary UTF-8 encoded, or that any of the characters have
code points greater than 0xFF (255) or even 0x80 (128), or that the
string has any characters at all.  All the C&lt;is_utf8()&gt; does is to
return the value of the internal &quot;utf8ness&quot; flag attached to the
C&lt;$string&gt;.  If the flag is off, the bytes in the scalar are interpreted
as a single byte encoding.  If the flag is on, the bytes in the scalar
are interpreted as the (variable-length, potentially multi-byte) UTF-8 encoded
code points of the characters.  Bytes added to a UTF-8 encoded string are
automatically upgraded to UTF-8.  If mixed non-UTF-8 and UTF-8 scalars
are merged (double-quoted interpolation, explicit concatenation, or
printf/sprintf parameter substitution), the result will be UTF-8 encoded
as if copies of the byte strings were upgraded to UTF-8: for example,

    $a = &quot;ab\x80c&quot;;
    $b = &quot;\x{100}&quot;;
    print &quot;$a = $b\n&quot;;

the output string will be UTF-8-encoded C&lt;ab\x80c = \x{100}\n&gt;, but
C&lt;$a&gt; will stay byte-encoded.

Sometimes you might really need to know the byte length of a string
instead of the character length. For that use the C&lt;bytes&gt; pragma
and the C&lt;length()&gt; function:

    my $unicode = chr(0x100);
    print length($unicode), &quot;\n&quot;; # will print 1
    use bytes;
    print length($unicode), &quot;\n&quot;; # will print 2
                                  # (the 0xC4 0x80 of the UTF-8)
    no bytes;

=item *

How Do I Find Out What Encoding a File Has?

You might try L&lt;Encode::Guess&gt;, but it has a number of limitations.

=item *

How Do I Detect Data That's Not Valid In a Particular Encoding?

Use the C&lt;Encode&gt; package to try converting it.
For example,

    use Encode 'decode';

    if (eval { decode('UTF-8', $string, Encode::FB_CROAK); 1 }) {
        # $string is valid UTF-8
    } else {
        # $string is not valid UTF-8
    }

Or use C&lt;unpack&gt; to try decoding it:

    use warnings;
    @chars = unpack(&quot;C0U*&quot;, $string_of_bytes_that_I_think_is_utf8);

If invalid, a C&lt;Malformed UTF-8 character&gt; warning is produced. The &quot;C0&quot; means
&quot;process the string character per character&quot;.  Without that, the
C&lt;unpack(&quot;U*&quot;, ...)&gt; would work in C&lt;U0&gt; mode (the default if the format
string starts with C&lt;U&gt;) and it would return the bytes making up the UTF-8
encoding of the target string, something that will always work.

=item *

How Do I Convert Binary Data Into a Particular Encoding, Or Vice Versa?

This probably isn't as useful as you might think.
Normally, you shouldn't need to.

In one sense, what you are asking doesn't make much sense: encodings
are for characters, and binary data are not &quot;characters&quot;, so converting
&quot;data&quot; into some encoding isn't meaningful unless you know in what
character set and encoding the binary data is in, in which case it's
not just binary data, now is it?

If you have a raw sequence of bytes that you know should be
interpreted via a particular encoding, you can use C&lt;Encode&gt;:

    use Encode 'from_to';
    from_to($data, &quot;iso-8859-1&quot;, &quot;UTF-8&quot;); # from latin-1 to UTF-8

The call to C&lt;from_to()&gt; changes the bytes in C&lt;$data&gt;, but nothing
material about the nature of the string has changed as far as Perl is
concerned.  Both before and after the call, the string C&lt;$data&gt;
contains just a bunch of 8-bit bytes. As far as Perl is concerned,
the encoding of the string remains as &quot;system-native 8-bit bytes&quot;.

You might relate this to a fictional 'Translate' module:

   use Translate;
   my $phrase = &quot;Yes&quot;;
   Translate::from_to($phrase, 'english', 'deutsch');
   ## phrase now contains &quot;Ja&quot;

The contents of the string changes, but not the nature of the string.
Perl doesn't know any more after the call than before that the
contents of the string indicates the affirmative.

Back to converting data.  If you have (or want) data in your system's
native 8-bit encoding (e.g. Latin-1, EBCDIC, etc.), you can use
pack/unpack to convert to/from Unicode.

    $native_string  = pack(&quot;W*&quot;, unpack(&quot;U*&quot;, $Unicode_string));
    $Unicode_string = pack(&quot;U*&quot;, unpack(&quot;W*&quot;, $native_string));

If you have a sequence of bytes you B&lt;know&gt; is valid UTF-8,
but Perl doesn't know it yet, you can make Perl a believer, too:

    $Unicode = $bytes;
    utf8::decode($Unicode);

or:

    $Unicode = pack(&quot;U0a*&quot;, $bytes);

You can find the bytes that make up a UTF-8 sequence with

    @bytes = unpack(&quot;C*&quot;, $Unicode_string)

and you can create well-formed Unicode with

    $Unicode_string = pack(&quot;U*&quot;, 0xff, ...)

=item *

How Do I Display Unicode?  How Do I Input Unicode?

See L&lt;http://www.alanwood.net/unicode/&gt; and
L&lt;http://www.cl.cam.ac.uk/~mgk25/unicode.html&gt;

=item *

How Does Unicode Work With Traditional Locales?

If your locale is a UTF-8 locale, starting in Perl v5.26, Perl works
well for all categories; before this, starting with Perl v5.20, it works
for all categories but C&lt;LC_COLLATE&gt;, which deals with
sorting and the C&lt;cmp&gt; operator.  But note that the standard
C&lt;L&lt;Unicode::Collate&gt;&gt; and C&lt;L&lt;Unicode::Collate::Locale&gt;&gt; modules offer
much more powerful solutions to collation issues, and work on earlier
releases.

For other locales, starting in Perl 5.16, you can specify

    use locale ':not_characters';

to get Perl to work well with them.  The catch is that you
have to translate from the locale character set to/from Unicode
yourself.  See L&lt;/Unicode IE&lt;sol&gt;O&gt; above for how to

    use open ':locale';

to accomplish this, but full details are in L&lt;perllocale/Unicode and
UTF-8&gt;, including gotchas that happen if you don't specify
C&lt;:not_characters&gt;.

=back

=head2 Hexadecimal Notation

The Unicode standard prefers using hexadecimal notation because
that more clearly shows the division of Unicode into blocks of 256 characters.
Hexadecimal is also simply shorter than decimal.  You can use decimal
notation, too, but learning to use hexadecimal just makes life easier
with the Unicode standard.  The C&lt;U+HHHH&gt; notation uses hexadecimal,
for example.

The C&lt;0x&gt; prefix means a hexadecimal number, the digits are 0-9 I&lt;and&gt;
a-f (or A-F, case doesn't matter).  Each hexadecimal digit represents
four bits, or half a byte.  C&lt;print 0x..., &quot;\n&quot;&gt; will show a
hexadecimal number in decimal, and C&lt;printf &quot;%x\n&quot;, $decimal&gt; will
show a decimal number in hexadecimal.  If you have just the
&quot;hex digits&quot; of a hexadecimal number, you can use the C&lt;hex()&gt; function.

    print 0x0009, &quot;\n&quot;;    # 9
    print 0x000a, &quot;\n&quot;;    # 10
    print 0x000f, &quot;\n&quot;;    # 15
    print 0x0010, &quot;\n&quot;;    # 16
    print 0x0011, &quot;\n&quot;;    # 17
    print 0x0100, &quot;\n&quot;;    # 256

    print 0x0041, &quot;\n&quot;;    # 65

    printf &quot;%x\n&quot;,  65;    # 41
    printf &quot;%#x\n&quot;, 65;    # 0x41

    print hex(&quot;41&quot;), &quot;\n&quot;; # 65

=head2 Further Resources

=over 4

=item *

Unicode Consortium

L&lt;http://www.unicode.org/&gt;

=item *

Unicode FAQ

L&lt;http://www.unicode.org/unicode/faq/&gt;

=item *

Unicode Glossary

L&lt;http://www.unicode.org/glossary/&gt;

=item *

Unicode Recommended Reading List

The Unicode Consortium has a list of articles and books, some of which
give a much more in depth treatment of Unicode:
L&lt;http://unicode.org/resources/readinglist.html&gt;

=item *

Unicode Useful Resources

L&lt;http://www.unicode.org/unicode/onlinedat/resources.html&gt;

=item *

Unicode and Multilingual Support in HTML, Fonts, Web Browsers and Other Applications

L&lt;http://www.alanwood.net/unicode/&gt;

=item *

UTF-8 and Unicode FAQ for Unix/Linux

L&lt;http://www.cl.cam.ac.uk/~mgk25/unicode.html&gt;

=item *

Legacy Character Sets

L&lt;http://www.czyborra.com/&gt;
L&lt;http://www.eki.ee/letter/&gt;

=item *

You can explore various information from the Unicode data files using
the C&lt;Unicode::UCD&gt; module.

=back

=head1 UNICODE IN OLDER PERLS

If you cannot upgrade your Perl to 5.8.0 or later, you can still
do some Unicode processing by using the modules C&lt;Unicode::String&gt;,
C&lt;Unicode::Map8&gt;, and C&lt;Unicode::Map&gt;, available from CPAN.
If you have the GNU recode installed, you can also use the
Perl front-end C&lt;Convert::Recode&gt; for character conversions.

The following are fast conversions from ISO 8859-1 (Latin-1) bytes
to UTF-8 bytes and back, the code works even with older Perl 5 versions.

    # ISO 8859-1 to UTF-8
    s/([\x80-\xFF])/chr(0xC0|ord($1)&gt;&gt;6).chr(0x80|ord($1)&amp;0x3F)/eg;

    # UTF-8 to ISO 8859-1
    s/([\xC2\xC3])([\x80-\xBF])/chr(ord($1)&lt;&lt;6&amp;0xC0|ord($2)&amp;0x3F)/eg;

=head1 SEE ALSO

L&lt;perlunitut&gt;, L&lt;perlunicode&gt;, L&lt;Encode&gt;, L&lt;open&gt;, L&lt;utf8&gt;, L&lt;bytes&gt;,
L&lt;perlretut&gt;, L&lt;perlrun&gt;, L&lt;Unicode::Collate&gt;, L&lt;Unicode::Normalize&gt;,
L&lt;Unicode::UCD&gt;

=head1 ACKNOWLEDGMENTS

Thanks to the kind readers of the perl5-porters@perl.org,
perl-unicode@perl.org, linux-utf8@nl.linux.org, and unicore@unicode.org
mailing lists for their valuable feedback.

=head1 AUTHOR, COPYRIGHT, AND LICENSE

Copyright 2001-2011 Jarkko Hietaniemi E&lt;lt&gt;jhi@iki.fiE&lt;gt&gt;.
Now maintained by Perl 5 Porters.

This document may be distributed under the same terms as Perl itself.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>