<h2>Editing File: /usr/share/perl5/pod/perlre.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME
X&lt;regular expression&gt; X&lt;regex&gt; X&lt;regexp&gt;

perlre - Perl regular expressions

=head1 DESCRIPTION

This page describes the syntax of regular expressions in Perl.

If you haven't used regular expressions before, a tutorial introduction
is available in L&lt;perlretut&gt;.  If you know just a little about them,
a quick-start introduction is available in L&lt;perlrequick&gt;.

Except for L&lt;/The Basics&gt; section, this page assumes you are familiar
with regular expression basics, like what is a &quot;pattern&quot;, what does it
look like, and how it is basically used.  For a reference on how they
are used, plus various examples of the same, see discussions of C&lt;m//&gt;,
C&lt;s///&gt;, C&lt;qr//&gt; and C&lt;&quot;??&quot;&gt; in L&lt;perlop/&quot;Regexp Quote-Like Operators&quot;&gt;.

New in v5.22, L&lt;C&lt;use re 'strict'&gt;|re/'strict' mode&gt; applies stricter
rules than otherwise when compiling regular expression patterns.  It can
find things that, while legal, may not be what you intended.

=head2 The Basics
X&lt;regular expression, version 8&gt; X&lt;regex, version 8&gt; X&lt;regexp, version 8&gt;

Regular expressions are strings with the very particular syntax and
meaning described in this document and auxiliary documents referred to
by this one.  The strings are called &quot;patterns&quot;.  Patterns are used to
determine if some other string, called the &quot;target&quot;, has (or doesn't
have) the characteristics specified by the pattern.  We call this
&quot;matching&quot; the target string against the pattern.  Usually the match is
done by having the target be the first operand, and the pattern be the
second operand, of one of the two binary operators C&lt;=~&gt; and C&lt;!~&gt;,
listed in L&lt;perlop/Binding Operators&gt;; and the pattern will have been
converted from an ordinary string by one of the operators in
L&lt;perlop/&quot;Regexp Quote-Like Operators&quot;&gt;, like so:

 $foo =~ m/abc/

This evaluates to true if and only if the string in the variable C&lt;$foo&gt;
contains somewhere in it, the sequence of characters &quot;a&quot;, &quot;b&quot;, then &quot;c&quot;.
(The C&lt;=~ m&gt;, or match operator, is described in
L&lt;perlop/m/PATTERN/msixpodualngc&gt;.)

Patterns that aren't already stored in some variable must be delimitted,
at both ends, by delimitter characters.  These are often, as in the
example above, forward slashes, and the typical way a pattern is written
in documentation is with those slashes.  In most cases, the delimitter
is the same character, fore and aft, but there are a few cases where a
character looks like it has a mirror-image mate, where the opening
version is the beginning delimiter, and the closing one is the ending
delimiter, like

 $foo =~ m&lt;abc&gt;

Most times, the pattern is evaluated in double-quotish context, but it
is possible to choose delimiters to force single-quotish, like

 $foo =~ m'abc'

If the pattern contains its delimiter within it, that delimiter must be
escaped.  Prefixing it with a backslash (I&lt;e.g.&gt;, C&lt;&quot;/foo\/bar/&quot;&gt;)
serves this purpose.

Any single character in a pattern matches that same character in the
target string, unless the character is a I&lt;metacharacter&gt; with a special
meaning described in this document.  A sequence of non-metacharacters
matches the same sequence in the target string, as we saw above with
C&lt;m/abc/&gt;.

Only a few characters (all of them being ASCII punctuation characters)
are metacharacters.  The most commonly used one is a dot C&lt;&quot;.&quot;&gt;, which
normally matches almost any character (including a dot itself).

You can cause characters that normally function as metacharacters to be
interpreted literally by prefixing them with a C&lt;&quot;\&quot;&gt;, just like the
pattern's delimiter must be escaped if it also occurs within the
pattern.  Thus, C&lt;&quot;\.&quot;&gt; matches just a literal dot, C&lt;&quot;.&quot;&gt; instead of
its normal meaning.  This means that the backslash is also a
metacharacter, so C&lt;&quot;\\&quot;&gt; matches a single C&lt;&quot;\&quot;&gt;.  And a sequence that
contains an escaped metacharacter matches the same sequence (but without
the escape) in the target string.  So, the pattern C&lt;/blur\\fl/&gt; would
match any target string that contains the sequence C&lt;&quot;blur\fl&quot;&gt;.

The metacharacter C&lt;&quot;|&quot;&gt; is used to match one thing or another.  Thus

 $foo =~ m/this|that/

is TRUE if and only if C&lt;$foo&gt; contains either the sequence C&lt;&quot;this&quot;&gt; or
the sequence C&lt;&quot;that&quot;&gt;.  Like all metacharacters, prefixing the C&lt;&quot;|&quot;&gt;
with a backslash makes it match the plain punctuation character; in its
case, the VERTICAL LINE.

 $foo =~ m/this\|that/

is TRUE if and only if C&lt;$foo&gt; contains the sequence C&lt;&quot;this|that&quot;&gt;.

You aren't limited to just a single C&lt;&quot;|&quot;&gt;.

 $foo =~ m/fee|fie|foe|fum/

is TRUE if and only if C&lt;$foo&gt; contains any of those 4 sequences from
the children's story &quot;Jack and the Beanstalk&quot;.

As you can see, the C&lt;&quot;|&quot;&gt; binds less tightly than a sequence of
ordinary characters.  We can override this by using the grouping
metacharacters, the parentheses C&lt;&quot;(&quot;&gt; and C&lt;&quot;)&quot;&gt;.

 $foo =~ m/th(is|at) thing/

is TRUE if and only if C&lt;$foo&gt; contains either the sequence S&lt;C&lt;&quot;this
thing&quot;&gt;&gt; or the sequence S&lt;C&lt;&quot;that thing&quot;&gt;&gt;.  The portions of the string
that match the portions of the pattern enclosed in parentheses are
normally made available separately for use later in the pattern,
substitution, or program.  This is called &quot;capturing&quot;, and it can get
complicated.  See L&lt;/Capture groups&gt;.

The first alternative includes everything from the last pattern
delimiter (C&lt;&quot;(&quot;&gt;, C&lt;&quot;(?:&quot;&gt; (described later), I&lt;etc&gt;. or the beginning
of the pattern) up to the first C&lt;&quot;|&quot;&gt;, and the last alternative
contains everything from the last C&lt;&quot;|&quot;&gt; to the next closing pattern
delimiter.  That's why it's common practice to include alternatives in
parentheses: to minimize confusion about where they start and end.

Alternatives are tried from left to right, so the first
alternative found for which the entire expression matches, is the one that
is chosen. This means that alternatives are not necessarily greedy. For
example: when matching C&lt;foo|foot&gt; against C&lt;&quot;barefoot&quot;&gt;, only the C&lt;&quot;foo&quot;&gt;
part will match, as that is the first alternative tried, and it successfully
matches the target string. (This might not seem important, but it is
important when you are capturing matched text using parentheses.)

Besides taking away the special meaning of a metacharacter, a prefixed
backslash changes some letter and digit characters away from matching
just themselves to instead have special meaning.  These are called
&quot;escape sequences&quot;, and all such are described in L&lt;perlrebackslash&gt;.  A
backslash sequence (of a letter or digit) that doesn't currently have
special meaning to Perl will raise a warning if warnings are enabled,
as those are reserved for potential future use.

One such sequence is C&lt;\b&gt;, which matches a boundary of some sort.
C&lt;\b{wb}&gt; and a few others give specialized types of boundaries.
(They are all described in detail starting at
L&lt;perlrebackslash/\b{}, \b, \B{}, \B&gt;.)  Note that these don't match
characters, but the zero-width spaces between characters.  They are an
example of a L&lt;zero-width assertion|/Assertions&gt;.  Consider again,

 $foo =~ m/fee|fie|foe|fum/

It evaluates to TRUE if, besides those 4 words, any of the sequences
&quot;feed&quot;, &quot;field&quot;, &quot;Defoe&quot;, &quot;fume&quot;, and many others are in C&lt;$foo&gt;.  By
judicious use of C&lt;\b&gt; (or better (because it is designed to handle
natural language) C&lt;\b{wb}&gt;), we can make sure that only the Giant's
words are matched:

 $foo =~ m/\b(fee|fie|foe|fum)\b/
 $foo =~ m/\b{wb}(fee|fie|foe|fum)\b{wb}/

The final example shows that the characters C&lt;&quot;{&quot;&gt; and C&lt;&quot;}&quot;&gt; are
metacharacters.

Another use for escape sequences is to specify characters that cannot
(or which you prefer not to) be written literally.  These are described
in detail in L&lt;perlrebackslash/Character Escapes&gt;, but the next three
paragraphs briefly describe some of them.

Various control characters can be written in C language style: C&lt;&quot;\n&quot;&gt;
matches a newline, C&lt;&quot;\t&quot;&gt; a tab, C&lt;&quot;\r&quot;&gt; a carriage return, C&lt;&quot;\f&quot;&gt; a
form feed, I&lt;etc&gt;.

More generally, C&lt;\I&lt;nnn&gt;&gt;, where I&lt;nnn&gt; is a string of three octal
digits, matches the character whose native code point is I&lt;nnn&gt;.  You
can easily run into trouble if you don't have exactly three digits.  So
always use three, or since Perl 5.14, you can use C&lt;\o{...}&gt; to specify
any number of octal digits.

Similarly, C&lt;\xI&lt;nn&gt;&gt;, where I&lt;nn&gt; are hexadecimal digits, matches the
character whose native ordinal is I&lt;nn&gt;.  Again, not using exactly two
digits is a recipe for disaster, but you can use C&lt;\x{...}&gt; to specify
any number of hex digits.

Besides being a metacharacter, the C&lt;&quot;.&quot;&gt; is an example of a &quot;character
class&quot;, something that can match any single character of a given set of
them.  In its case, the set is just about all possible characters.  Perl
predefines several character classes besides the C&lt;&quot;.&quot;&gt;; there is a
separate reference page about just these, L&lt;perlrecharclass&gt;.

You can define your own custom character classes, by putting into your
pattern in the appropriate place(s), a list of all the characters you
want in the set.  You do this by enclosing the list within C&lt;[]&gt; bracket
characters.  These are called &quot;bracketed character classes&quot; when we are
being precise, but often the word &quot;bracketed&quot; is dropped.  (Dropping it
usually doesn't cause confusion.)  This means that the C&lt;&quot;[&quot;&gt; character
is another metacharacter.  It doesn't match anything just by itelf; it
is used only to tell Perl that what follows it is a bracketed character
class.  If you want to match a literal left square bracket, you must
escape it, like C&lt;&quot;\[&quot;&gt;.  The matching C&lt;&quot;]&quot;&gt; is also a metacharacter;
again it doesn't match anything by itself, but just marks the end of
your custom class to Perl.  It is an example of a &quot;sometimes
metacharacter&quot;.  It isn't a metacharacter if there is no corresponding
C&lt;&quot;[&quot;&gt;, and matches its literal self:

 print &quot;]&quot; =~ /]/;  # prints 1

The list of characters within the character class gives the set of
characters matched by the class.  C&lt;&quot;[abc]&quot;&gt; matches a single &quot;a&quot; or &quot;b&quot;
or &quot;c&quot;.  But if the first character after the C&lt;&quot;[&quot;&gt; is C&lt;&quot;^&quot;&gt;, the
class matches any character not in the list.  Within a list, the C&lt;&quot;-&quot;&gt;
character specifies a range of characters, so that C&lt;a-z&gt; represents all
characters between &quot;a&quot; and &quot;z&quot;, inclusive.  If you want either C&lt;&quot;-&quot;&gt; or
C&lt;&quot;]&quot;&gt; itself to be a member of a class, put it at the start of the list
(possibly after a C&lt;&quot;^&quot;&gt;), or escape it with a backslash.  C&lt;&quot;-&quot;&gt; is
also taken literally when it is at the end of the list, just before the
closing C&lt;&quot;]&quot;&gt;.  (The following all specify the same class of three
characters: C&lt;[-az]&gt;, C&lt;[az-]&gt;, and C&lt;[a\-z]&gt;.  All are different from
C&lt;[a-z]&gt;, which specifies a class containing twenty-six characters, even
on EBCDIC-based character sets.)

There is lots more to bracketed character classes; full details are in
L&lt;perlrecharclass/Bracketed Character Classes&gt;.

=head3 Metacharacters
X&lt;metacharacter&gt;
X&lt;\&gt; X&lt;^&gt; X&lt;.&gt; X&lt;$&gt; X&lt;|&gt; X&lt;(&gt; X&lt;()&gt; X&lt;[&gt; X&lt;[]&gt;

L&lt;/The Basics&gt; introduced some of the metacharacters.  This section
gives them all.  Most of them have the same meaning as in the I&lt;egrep&gt;
command.

Only the C&lt;&quot;\&quot;&gt; is always a metacharacter.  The others are metacharacters
just sometimes.  The following tables lists all of them, summarizes
their use, and gives the contexts where they are metacharacters.
Outside those contexts or if prefixed by a C&lt;&quot;\&quot;&gt;, they match their
corresponding punctuation character.  In some cases, their meaning
varies depending on various pattern modifiers that alter the default
behaviors.  See L&lt;/Modifiers&gt;.


            PURPOSE                                  WHERE
 \   Escape the next character                    Always, except when
                                                  escaped by another \
 ^   Match the beginning of the string            Not in []
       (or line, if /m is used)
 ^   Complement the [] class                      At the beginning of []
 .   Match any single character except newline    Not in []
       (under /s, includes newline)
 $   Match the end of the string                  Not in [], but can
       (or before newline at the end of the       mean interpolate a
       string; or before any newline if /m is     scalar
       used)
 |   Alternation                                  Not in []
 ()  Grouping                                     Not in []
 [   Start Bracketed Character class              Not in []
 ]   End Bracketed Character class                Only in [], and
                                                    not first
 *   Matches the preceding element 0 or more      Not in []
       times
 +   Matches the preceding element 1 or more      Not in []
       times
 ?   Matches the preceding element 0 or 1         Not in []
       times
 {   Starts a sequence that gives number(s)       Not in []
       of times the preceding element can be
       matched
 {   when following certain escape sequences
       starts a modifier to the meaning of the
       sequence
 }   End sequence started by {
 -   Indicates a range                            Only in [] interior

Notice that most of the metacharacters lose their special meaning when
they occur in a bracketed character class, except C&lt;&quot;^&quot;&gt; has a different
meaning when it is at the beginning of such a class.  And C&lt;&quot;-&quot;&gt; and C&lt;&quot;]&quot;&gt;
are metacharacters only at restricted positions within bracketed
character classes; while C&lt;&quot;}&quot;&gt; is a metacharacter only when closing a
special construct started by C&lt;&quot;{&quot;&gt;.

In double-quotish context, as is usually the case,  you need to be
careful about C&lt;&quot;$&quot;&gt; and the non-metacharacter C&lt;&quot;@&quot;&gt;.  Those could
interpolate variables, which may or may not be what you intended.

These rules were designed for compactness of expression, rather than
legibility and maintainability.  The L&lt;/E&lt;sol&gt;x and E&lt;sol&gt;xx&gt; pattern
modifiers allow you to insert white space to improve readability.  And
use of S&lt;C&lt;L&lt;re 'strict'|re/'strict' mode&gt;&gt;&gt; adds extra checking to
catch some typos that might silently compile into something unintended.

By default, the C&lt;&quot;^&quot;&gt; character is guaranteed to match only the
beginning of the string, the C&lt;&quot;$&quot;&gt; character only the end (or before the
newline at the end), and Perl does certain optimizations with the
assumption that the string contains only one line.  Embedded newlines
will not be matched by C&lt;&quot;^&quot;&gt; or C&lt;&quot;$&quot;&gt;.  You may, however, wish to treat a
string as a multi-line buffer, such that the C&lt;&quot;^&quot;&gt; will match after any
newline within the string (except if the newline is the last character in
the string), and C&lt;&quot;$&quot;&gt; will match before any newline.  At the
cost of a little more overhead, you can do this by using the
L&lt;/C&lt;E&lt;sol&gt;m&gt;&gt; modifier on the pattern match operator.  (Older programs
did this by setting C&lt;$*&gt;, but this option was removed in perl 5.10.)
X&lt;^&gt; X&lt;$&gt; X&lt;/m&gt;

To simplify multi-line substitutions, the C&lt;&quot;.&quot;&gt; character never matches a
newline unless you use the L&lt;C&lt;E&lt;sol&gt;s&gt;|/s&gt; modifier, which in effect tells
Perl to pretend the string is a single line--even if it isn't.
X&lt;.&gt; X&lt;/s&gt;

=head2 Modifiers

=head3 Overview

The default behavior for matching can be changed, using various
modifiers.  Modifiers that relate to the interpretation of the pattern
are listed just below.  Modifiers that alter the way a pattern is used
by Perl are detailed in L&lt;perlop/&quot;Regexp Quote-Like Operators&quot;&gt; and
L&lt;perlop/&quot;Gory details of parsing quoted constructs&quot;&gt;.

=over 4

=item B&lt;C&lt;m&gt;&gt;
X&lt;/m&gt; X&lt;regex, multiline&gt; X&lt;regexp, multiline&gt; X&lt;regular expression, multiline&gt;

Treat the string being matched against as multiple lines.  That is, change C&lt;&quot;^&quot;&gt; and C&lt;&quot;$&quot;&gt; from matching
the start of the string's first line and the end of its last line to
matching the start and end of each line within the string.

=item B&lt;C&lt;s&gt;&gt;
X&lt;/s&gt; X&lt;regex, single-line&gt; X&lt;regexp, single-line&gt;
X&lt;regular expression, single-line&gt;

Treat the string as single line.  That is, change C&lt;&quot;.&quot;&gt; to match any character
whatsoever, even a newline, which normally it would not match.

Used together, as C&lt;/ms&gt;, they let the C&lt;&quot;.&quot;&gt; match any character whatsoever,
while still allowing C&lt;&quot;^&quot;&gt; and C&lt;&quot;$&quot;&gt; to match, respectively, just after
and just before newlines within the string.

=item B&lt;C&lt;i&gt;&gt;
X&lt;/i&gt; X&lt;regex, case-insensitive&gt; X&lt;regexp, case-insensitive&gt;
X&lt;regular expression, case-insensitive&gt;

Do case-insensitive pattern matching.  For example, &quot;A&quot; will match &quot;a&quot;
under C&lt;/i&gt;.

If locale matching rules are in effect, the case map is taken from the
current
locale for code points less than 255, and from Unicode rules for larger
code points.  However, matches that would cross the Unicode
rules/non-Unicode rules boundary (ords 255/256) will not succeed, unless
the locale is a UTF-8 one.  See L&lt;perllocale&gt;.

There are a number of Unicode characters that match a sequence of
multiple characters under C&lt;/i&gt;.  For example,
C&lt;LATIN SMALL LIGATURE FI&gt; should match the sequence C&lt;fi&gt;.  Perl is not
currently able to do this when the multiple characters are in the pattern and
are split between groupings, or when one or more are quantified.  Thus

 &quot;\N{LATIN SMALL LIGATURE FI}&quot; =~ /fi/i;          # Matches
 &quot;\N{LATIN SMALL LIGATURE FI}&quot; =~ /[fi][fi]/i;    # Doesn't match!
 &quot;\N{LATIN SMALL LIGATURE FI}&quot; =~ /fi*/i;         # Doesn't match!

 # The below doesn't match, and it isn't clear what $1 and $2 would
 # be even if it did!!
 &quot;\N{LATIN SMALL LIGATURE FI}&quot; =~ /(f)(i)/i;      # Doesn't match!

Perl doesn't match multiple characters in a bracketed
character class unless the character that maps to them is explicitly
mentioned, and it doesn't match them at all if the character class is
inverted, which otherwise could be highly confusing.  See
L&lt;perlrecharclass/Bracketed Character Classes&gt;, and
L&lt;perlrecharclass/Negation&gt;.

=item B&lt;C&lt;x&gt;&gt; and B&lt;C&lt;xx&gt;&gt;
X&lt;/x&gt;

Extend your pattern's legibility by permitting whitespace and comments.
Details in L&lt;/E&lt;sol&gt;x and  E&lt;sol&gt;xx&gt;

=item B&lt;C&lt;p&gt;&gt;
X&lt;/p&gt; X&lt;regex, preserve&gt; X&lt;regexp, preserve&gt;

Preserve the string matched such that C&lt;${^PREMATCH}&gt;, C&lt;${^MATCH}&gt;, and
C&lt;${^POSTMATCH}&gt; are available for use after matching.

In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
mechanism, C&lt;${^PREMATCH}&gt;, C&lt;${^MATCH}&gt;, and C&lt;${^POSTMATCH}&gt; will be available
after the match regardless of the modifier.

=item B&lt;C&lt;a&gt;&gt;, B&lt;C&lt;d&gt;&gt;, B&lt;C&lt;l&gt;&gt;, and B&lt;C&lt;u&gt;&gt;
X&lt;/a&gt; X&lt;/d&gt; X&lt;/l&gt; X&lt;/u&gt;

These modifiers, all new in 5.14, affect which character-set rules
(Unicode, I&lt;etc&gt;.) are used, as described below in
L&lt;/Character set modifiers&gt;.

=item B&lt;C&lt;n&gt;&gt;
X&lt;/n&gt; X&lt;regex, non-capture&gt; X&lt;regexp, non-capture&gt;
X&lt;regular expression, non-capture&gt;

Prevent the grouping metacharacters C&lt;()&gt; from capturing. This modifier,
new in 5.22, will stop C&lt;$1&gt;, C&lt;$2&gt;, I&lt;etc&gt;... from being filled in.

  &quot;hello&quot; =~ /(hi|hello)/;   # $1 is &quot;hello&quot;
  &quot;hello&quot; =~ /(hi|hello)/n;  # $1 is undef

This is equivalent to putting C&lt;?:&gt; at the beginning of every capturing group:

  &quot;hello&quot; =~ /(?:hi|hello)/; # $1 is undef

C&lt;/n&gt; can be negated on a per-group basis. Alternatively, named captures
may still be used.

  &quot;hello&quot; =~ /(?-n:(hi|hello))/n;   # $1 is &quot;hello&quot;
  &quot;hello&quot; =~ /(?&lt;greet&gt;hi|hello)/n; # $1 is &quot;hello&quot;, $+{greet} is
                                    # &quot;hello&quot;

=item Other Modifiers

There are a number of flags that can be found at the end of regular
expression constructs that are I&lt;not&gt; generic regular expression flags, but
apply to the operation being performed, like matching or substitution (C&lt;m//&gt;
or C&lt;s///&gt; respectively).

Flags described further in
L&lt;perlretut/&quot;Using regular expressions in Perl&quot;&gt; are:

  c  - keep the current position during repeated matching
  g  - globally match the pattern repeatedly in the string

Substitution-specific modifiers described in
L&lt;perlop/&quot;s/PATTERN/REPLACEMENT/msixpodualngcer&quot;&gt; are:

  e  - evaluate the right-hand side as an expression
  ee - evaluate the right side as a string then eval the result
  o  - pretend to optimize your code, but actually introduce bugs
  r  - perform non-destructive substitution and return the new value

=back

Regular expression modifiers are usually written in documentation
as I&lt;e.g.&gt;, &quot;the C&lt;/x&gt; modifier&quot;, even though the delimiter
in question might not really be a slash.  The modifiers C&lt;/imnsxadlup&gt;
may also be embedded within the regular expression itself using
the C&lt;(?...)&gt; construct, see L&lt;/Extended Patterns&gt; below.

=head3 Details on some modifiers

Some of the modifiers require more explanation than given in the
L&lt;/Overview&gt; above.

=head4 C&lt;/x&gt; and  C&lt;/xx&gt;

A single C&lt;/x&gt; tells
the regular expression parser to ignore most whitespace that is neither
backslashed nor within a bracketed character class.  You can use this to
break up your regular expression into more readable parts.
Also, the C&lt;&quot;#&quot;&gt; character is treated as a metacharacter introducing a
comment that runs up to the pattern's closing delimiter, or to the end
of the current line if the pattern extends onto the next line.  Hence,
this is very much like an ordinary Perl code comment.  (You can include
the closing delimiter within the comment only if you precede it with a
backslash, so be careful!)

Use of C&lt;/x&gt; means that if you want real
whitespace or C&lt;&quot;#&quot;&gt; characters in the pattern (outside a bracketed character
class, which is unaffected by C&lt;/x&gt;), then you'll either have to
escape them (using backslashes or C&lt;\Q...\E&gt;) or encode them using octal,
hex, or C&lt;\N{}&gt; escapes.
It is ineffective to try to continue a comment onto the next line by
escaping the C&lt;\n&gt; with a backslash or C&lt;\Q&gt;.

You can use L&lt;/(?#text)&gt; to create a comment that ends earlier than the
end of the current line, but C&lt;text&gt; also can't contain the closing
delimiter unless escaped with a backslash.

A common pitfall is to forget that C&lt;&quot;#&quot;&gt; characters begin a comment under
C&lt;/x&gt; and are not matched literally.  Just keep that in mind when trying
to puzzle out why a particular C&lt;/x&gt; pattern isn't working as expected.

Starting in Perl v5.26, if the modifier has a second C&lt;&quot;x&quot;&gt; within it,
it does everything that a single C&lt;/x&gt; does, but additionally
non-backslashed SPACE and TAB characters within bracketed character
classes are also generally ignored, and hence can be added to make the
classes more readable.

    / [d-e g-i 3-7]/xx
    /[ ! @ &quot; # $ % ^ &amp; * () = ? &lt;&gt; ' ]/xx

may be easier to grasp than the squashed equivalents

    /[d-eg-i3-7]/
    /[!@&quot;#$%^&amp;*()=?&lt;&gt;']/

Taken together, these features go a long way towards
making Perl's regular expressions more readable.  Here's an example:

    # Delete (most) C comments.
    $program =~ s {
	/\*	# Match the opening delimiter.
	.*?	# Match a minimal number of characters.
	\*/	# Match the closing delimiter.
    } []gsx;

Note that anything inside
a C&lt;\Q...\E&gt; stays unaffected by C&lt;/x&gt;.  And note that C&lt;/x&gt; doesn't affect
space interpretation within a single multi-character construct.  For
example in C&lt;\x{...}&gt;, regardless of the C&lt;/x&gt; modifier, there can be no
spaces.  Same for a L&lt;quantifier|/Quantifiers&gt; such as C&lt;{3}&gt; or
C&lt;{5,}&gt;.  Similarly, C&lt;(?:...)&gt; can't have a space between the C&lt;&quot;(&quot;&gt;,
C&lt;&quot;?&quot;&gt;, and C&lt;&quot;:&quot;&gt;.  Within any delimiters for such a
construct, allowed spaces are not affected by C&lt;/x&gt;, and depend on the
construct.  For example, C&lt;\x{...}&gt; can't have spaces because hexadecimal
numbers don't have spaces in them.  But, Unicode properties can have spaces, so
in C&lt;\p{...}&gt; there can be spaces that follow the Unicode rules, for which see
L&lt;perluniprops/Properties accessible through \p{} and \P{}&gt;.
X&lt;/x&gt;

The set of characters that are deemed whitespace are those that Unicode
calls &quot;Pattern White Space&quot;, namely:

 U+0009 CHARACTER TABULATION
 U+000A LINE FEED
 U+000B LINE TABULATION
 U+000C FORM FEED
 U+000D CARRIAGE RETURN
 U+0020 SPACE
 U+0085 NEXT LINE
 U+200E LEFT-TO-RIGHT MARK
 U+200F RIGHT-TO-LEFT MARK
 U+2028 LINE SEPARATOR
 U+2029 PARAGRAPH SEPARATOR

=head4 Character set modifiers

C&lt;/d&gt;, C&lt;/u&gt;, C&lt;/a&gt;, and C&lt;/l&gt;, available starting in 5.14, are called
the character set modifiers; they affect the character set rules
used for the regular expression.

The C&lt;/d&gt;, C&lt;/u&gt;, and C&lt;/l&gt; modifiers are not likely to be of much use
to you, and so you need not worry about them very much.  They exist for
Perl's internal use, so that complex regular expression data structures
can be automatically serialized and later exactly reconstituted,
including all their nuances.  But, since Perl can't keep a secret, and
there may be rare instances where they are useful, they are documented
here.

The C&lt;/a&gt; modifier, on the other hand, may be useful.  Its purpose is to
allow code that is to work mostly on ASCII data to not have to concern
itself with Unicode.

Briefly, C&lt;/l&gt; sets the character set to that of whatever B&lt;L&gt;ocale is in
effect at the time of the execution of the pattern match.

C&lt;/u&gt; sets the character set to B&lt;U&gt;nicode.

C&lt;/a&gt; also sets the character set to Unicode, BUT adds several
restrictions for B&lt;A&gt;SCII-safe matching.

C&lt;/d&gt; is the old, problematic, pre-5.14 B&lt;D&gt;efault character set
behavior.  Its only use is to force that old behavior.

At any given time, exactly one of these modifiers is in effect.  Their
existence allows Perl to keep the originally compiled behavior of a
regular expression, regardless of what rules are in effect when it is
actually executed.  And if it is interpolated into a larger regex, the
original's rules continue to apply to it, and only it.

The C&lt;/l&gt; and C&lt;/u&gt; modifiers are automatically selected for
regular expressions compiled within the scope of various pragmas,
and we recommend that in general, you use those pragmas instead of
specifying these modifiers explicitly.  For one thing, the modifiers
affect only pattern matching, and do not extend to even any replacement
done, whereas using the pragmas gives consistent results for all
appropriate operations within their scopes.  For example,

 s/foo/\Ubar/il

will match &quot;foo&quot; using the locale's rules for case-insensitive matching,
but the C&lt;/l&gt; does not affect how the C&lt;\U&gt; operates.  Most likely you
want both of them to use locale rules.  To do this, instead compile the
regular expression within the scope of C&lt;use locale&gt;.  This both
implicitly adds the C&lt;/l&gt;, and applies locale rules to the C&lt;\U&gt;.   The
lesson is to C&lt;use locale&gt;, and not C&lt;/l&gt; explicitly.

Similarly, it would be better to use C&lt;use feature 'unicode_strings'&gt;
instead of,

 s/foo/\Lbar/iu

to get Unicode rules, as the C&lt;\L&gt; in the former (but not necessarily
the latter) would also use Unicode rules.

More detail on each of the modifiers follows.  Most likely you don't
need to know this detail for C&lt;/l&gt;, C&lt;/u&gt;, and C&lt;/d&gt;, and can skip ahead
to L&lt;E&lt;sol&gt;a|/E&lt;sol&gt;a (and E&lt;sol&gt;aa)&gt;.

=head4 /l

means to use the current locale's rules (see L&lt;perllocale&gt;) when pattern
matching.  For example, C&lt;\w&gt; will match the &quot;word&quot; characters of that
locale, and C&lt;&quot;/i&quot;&gt; case-insensitive matching will match according to
the locale's case folding rules.  The locale used will be the one in
effect at the time of execution of the pattern match.  This may not be
the same as the compilation-time locale, and can differ from one match
to another if there is an intervening call of the
L&lt;setlocale() function|perllocale/The setlocale function&gt;.

Prior to v5.20, Perl did not support multi-byte locales.  Starting then,
UTF-8 locales are supported.  No other multi byte locales are ever
likely to be supported.  However, in all locales, one can have code
points above 255 and these will always be treated as Unicode no matter
what locale is in effect.

Under Unicode rules, there are a few case-insensitive matches that cross
the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
later, these are disallowed under C&lt;/l&gt;.  For example, 0xFF (on ASCII
platforms) does not caselessly match the character at 0x178, C&lt;LATIN
CAPITAL LETTER Y WITH DIAERESIS&gt;, because 0xFF may not be C&lt;LATIN SMALL
LETTER Y WITH DIAERESIS&gt; in the current locale, and Perl has no way of
knowing if that character even exists in the locale, much less what code
point it is.

In a UTF-8 locale in v5.20 and later, the only visible difference
between locale and non-locale in regular expressions should be tainting
(see L&lt;perlsec&gt;).

This modifier may be specified to be the default by C&lt;use locale&gt;, but
see L&lt;/Which character set modifier is in effect?&gt;.
X&lt;/l&gt;

=head4 /u

means to use Unicode rules when pattern matching.  On ASCII platforms,
this means that the code points between 128 and 255 take on their
Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
(Otherwise Perl considers their meanings to be undefined.)  Thus,
under this modifier, the ASCII platform effectively becomes a Unicode
platform; and hence, for example, C&lt;\w&gt; will match any of the more than
100_000 word characters in Unicode.

Unlike most locales, which are specific to a language and country pair,
Unicode classifies all the characters that are letters I&lt;somewhere&gt; in
the world as
C&lt;\w&gt;.  For example, your locale might not think that C&lt;LATIN SMALL
LETTER ETH&gt; is a letter (unless you happen to speak Icelandic), but
Unicode does.  Similarly, all the characters that are decimal digits
somewhere in the world will match C&lt;\d&gt;; this is hundreds, not 10,
possible matches.  And some of those digits look like some of the 10
ASCII digits, but mean a different number, so a human could easily think
a number is a different quantity than it really is.  For example,
C&lt;BENGALI DIGIT FOUR&gt; (U+09EA) looks very much like an
C&lt;ASCII DIGIT EIGHT&gt; (U+0038).  And, C&lt;\d+&gt;, may match strings of digits
that are a mixture from different writing systems, creating a security
issue.  L&lt;Unicode::UCD/num()&gt; can be used to sort
this out.  Or the C&lt;/a&gt; modifier can be used to force C&lt;\d&gt; to match
just the ASCII 0 through 9.

Also, under this modifier, case-insensitive matching works on the full
set of Unicode
characters.  The C&lt;KELVIN SIGN&gt;, for example matches the letters &quot;k&quot; and
&quot;K&quot;; and C&lt;LATIN SMALL LIGATURE FF&gt; matches the sequence &quot;ff&quot;, which,
if you're not prepared, might make it look like a hexadecimal constant,
presenting another potential security issue.  See
L&lt;http://unicode.org/reports/tr36&gt; for a detailed discussion of Unicode
security issues.

This modifier may be specified to be the default by C&lt;use feature
'unicode_strings&gt;, C&lt;use locale ':not_characters'&gt;, or
C&lt;L&lt;use 5.012|perlfunc/use VERSION&gt;&gt; (or higher),
but see L&lt;/Which character set modifier is in effect?&gt;.
X&lt;/u&gt;

=head4 /d

This modifier means to use the &quot;Default&quot; native rules of the platform
except when there is cause to use Unicode rules instead, as follows:

=over 4

=item 1

the target string is encoded in UTF-8; or

=item 2

the pattern is encoded in UTF-8; or

=item 3

the pattern explicitly mentions a code point that is above 255 (say by
C&lt;\x{100}&gt;); or

=item 4

the pattern uses a Unicode name (C&lt;\N{...}&gt;);  or

=item 5

the pattern uses a Unicode property (C&lt;\p{...}&gt; or C&lt;\P{...}&gt;); or

=item 6

the pattern uses a Unicode break (C&lt;\b{...}&gt; or C&lt;\B{...}&gt;); or

=item 7

the pattern uses L&lt;/C&lt;(?[ ])&gt;&gt;

=back

Another mnemonic for this modifier is &quot;Depends&quot;, as the rules actually
used depend on various things, and as a result you can get unexpected
results.  See L&lt;perlunicode/The &quot;Unicode Bug&quot;&gt;.  The Unicode Bug has
become rather infamous, leading to yet another (printable) name for this
modifier, &quot;Dodgy&quot;.

Unless the pattern or string are encoded in UTF-8, only ASCII characters
can match positively.

Here are some examples of how that works on an ASCII platform:

 $str =  &quot;\xDF&quot;;      # $str is not in UTF-8 format.
 $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
 $str .= &quot;\x{0e0b}&quot;;  # Now $str is in UTF-8 format.
 $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
 chop $str;
 $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.

This modifier is automatically selected by default when none of the
others are, so yet another name for it is &quot;Default&quot;.

Because of the unexpected behaviors associated with this modifier, you
probably should only explicitly use it to maintain weird backward
compatibilities.

=head4 /a (and /aa)

This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier
may be doubled-up to increase its effect.

When it appears singly, it causes the sequences C&lt;\d&gt;, C&lt;\s&gt;, C&lt;\w&gt;, and
the Posix character classes to match only in the ASCII range.  They thus
revert to their pre-5.6, pre-Unicode meanings.  Under C&lt;/a&gt;,  C&lt;\d&gt;
always means precisely the digits C&lt;&quot;0&quot;&gt; to C&lt;&quot;9&quot;&gt;; C&lt;\s&gt; means the five
characters C&lt;[ \f\n\r\t]&gt;, and starting in Perl v5.18, the vertical tab;
C&lt;\w&gt; means the 63 characters
C&lt;[A-Za-z0-9_]&gt;; and likewise, all the Posix classes such as
C&lt;[[:print:]]&gt; match only the appropriate ASCII-range characters.

This modifier is useful for people who only incidentally use Unicode,
and who do not wish to be burdened with its complexities and security
concerns.

With C&lt;/a&gt;, one can write C&lt;\d&gt; with confidence that it will only match
ASCII characters, and should the need arise to match beyond ASCII, you
can instead use C&lt;\p{Digit}&gt; (or C&lt;\p{Word}&gt; for C&lt;\w&gt;).  There are
similar C&lt;\p{...}&gt; constructs that can match beyond ASCII both white
space (see L&lt;perlrecharclass/Whitespace&gt;), and Posix classes (see
L&lt;perlrecharclass/POSIX Character Classes&gt;).  Thus, this modifier
doesn't mean you can't use Unicode, it means that to get Unicode
matching you must explicitly use a construct (C&lt;\p{}&gt;, C&lt;\P{}&gt;) that
signals Unicode.

As you would expect, this modifier causes, for example, C&lt;\D&gt; to mean
the same thing as C&lt;[^0-9]&gt;; in fact, all non-ASCII characters match
C&lt;\D&gt;, C&lt;\S&gt;, and C&lt;\W&gt;.  C&lt;\b&gt; still means to match at the boundary
between C&lt;\w&gt; and C&lt;\W&gt;, using the C&lt;/a&gt; definitions of them (similarly
for C&lt;\B&gt;).

Otherwise, C&lt;/a&gt; behaves like the C&lt;/u&gt; modifier, in that
case-insensitive matching uses Unicode rules; for example, &quot;k&quot; will
match the Unicode C&lt;\N{KELVIN SIGN}&gt; under C&lt;/i&gt; matching, and code
points in the Latin1 range, above ASCII will have Unicode rules when it
comes to case-insensitive matching.

To forbid ASCII/non-ASCII matches (like &quot;k&quot; with C&lt;\N{KELVIN SIGN}&gt;),
specify the C&lt;&quot;a&quot;&gt; twice, for example C&lt;/aai&gt; or C&lt;/aia&gt;.  (The first
occurrence of C&lt;&quot;a&quot;&gt; restricts the C&lt;\d&gt;, I&lt;etc&gt;., and the second occurrence
adds the C&lt;/i&gt; restrictions.)  But, note that code points outside the
ASCII range will use Unicode rules for C&lt;/i&gt; matching, so the modifier
doesn't really restrict things to just ASCII; it just forbids the
intermixing of ASCII and non-ASCII.

To summarize, this modifier provides protection for applications that
don't wish to be exposed to all of Unicode.  Specifying it twice
gives added protection.

This modifier may be specified to be the default by C&lt;use re '/a'&gt;
or C&lt;use re '/aa'&gt;.  If you do so, you may actually have occasion to use
the C&lt;/u&gt; modifier explicitly if there are a few regular expressions
where you do want full Unicode rules (but even here, it's best if
everything were under feature C&lt;&quot;unicode_strings&quot;&gt;, along with the
C&lt;use re '/aa'&gt;).  Also see L&lt;/Which character set modifier is in
effect?&gt;.
X&lt;/a&gt;
X&lt;/aa&gt;

=head4 Which character set modifier is in effect?

Which of these modifiers is in effect at any given point in a regular
expression depends on a fairly complex set of interactions.  These have
been designed so that in general you don't have to worry about it, but
this section gives the gory details.  As
explained below in L&lt;/Extended Patterns&gt; it is possible to explicitly
specify modifiers that apply only to portions of a regular expression.
The innermost always has priority over any outer ones, and one applying
to the whole expression has priority over any of the default settings that are
described in the remainder of this section.

The C&lt;L&lt;use re 'E&lt;sol&gt;foo'|re/&quot;'/flags' mode&quot;&gt;&gt; pragma can be used to set
default modifiers (including these) for regular expressions compiled
within its scope.  This pragma has precedence over the other pragmas
listed below that also change the defaults.

Otherwise, C&lt;L&lt;use locale|perllocale&gt;&gt; sets the default modifier to C&lt;/l&gt;;
and C&lt;L&lt;use feature 'unicode_strings|feature&gt;&gt;, or
C&lt;L&lt;use 5.012|perlfunc/use VERSION&gt;&gt; (or higher) set the default to
C&lt;/u&gt; when not in the same scope as either C&lt;L&lt;use locale|perllocale&gt;&gt;
or C&lt;L&lt;use bytes|bytes&gt;&gt;.
(C&lt;L&lt;use locale ':not_characters'|perllocale/Unicode and UTF-8&gt;&gt; also
sets the default to C&lt;/u&gt;, overriding any plain C&lt;use locale&gt;.)
Unlike the mechanisms mentioned above, these
affect operations besides regular expressions pattern matching, and so
give more consistent results with other operators, including using
C&lt;\U&gt;, C&lt;\l&gt;, I&lt;etc&gt;. in substitution replacements.

If none of the above apply, for backwards compatibility reasons, the
C&lt;/d&gt; modifier is the one in effect by default.  As this can lead to
unexpected results, it is best to specify which other rule set should be
used.

=head4 Character set modifier behavior prior to Perl 5.14

Prior to 5.14, there were no explicit modifiers, but C&lt;/l&gt; was implied
for regexes compiled within the scope of C&lt;use locale&gt;, and C&lt;/d&gt; was
implied otherwise.  However, interpolating a regex into a larger regex
would ignore the original compilation in favor of whatever was in effect
at the time of the second compilation.  There were a number of
inconsistencies (bugs) with the C&lt;/d&gt; modifier, where Unicode rules
would be used when inappropriate, and vice versa.  C&lt;\p{}&gt; did not imply
Unicode rules, and neither did all occurrences of C&lt;\N{}&gt;, until 5.12.

=head2 Regular Expressions

=head3 Quantifiers

Quantifiers are used when a particular portion of a pattern needs to
match a certain number (or numbers) of times.  If there isn't a
quantifier the number of times to match is exactly one.  The following
standard quantifiers are recognized:
X&lt;metacharacter&gt; X&lt;quantifier&gt; X&lt;*&gt; X&lt;+&gt; X&lt;?&gt; X&lt;{n}&gt; X&lt;{n,}&gt; X&lt;{n,m}&gt;

    *           Match 0 or more times
    +           Match 1 or more times
    ?           Match 1 or 0 times
    {n}         Match exactly n times
    {n,}        Match at least n times
    {n,m}       Match at least n but not more than m times

(If a non-escaped curly bracket occurs in a context other than one of
the quantifiers listed above, where it does not form part of a
backslashed sequence like C&lt;\x{...}&gt;, it is either a fatal syntax error,
or treated as a regular character, generally with a deprecation warning
raised.  To escape it, you can precede it with a backslash (C&lt;&quot;\{&quot;&gt;) or
enclose it within square brackets  (C&lt;&quot;[{]&quot;&gt;).
This change will allow for future syntax extensions (like making the
lower bound of a quantifier optional), and better error checking of
quantifiers).

The C&lt;&quot;*&quot;&gt; quantifier is equivalent to C&lt;{0,}&gt;, the C&lt;&quot;+&quot;&gt;
quantifier to C&lt;{1,}&gt;, and the C&lt;&quot;?&quot;&gt; quantifier to C&lt;{0,1}&gt;.  I&lt;n&gt; and I&lt;m&gt; are limited
to non-negative integral values less than a preset limit defined when perl is built.
This is usually 32766 on the most common platforms.  The actual limit can
be seen in the error message generated by code such as this:

    $_ **= $_ , / {$_} / for 2 .. 42;

By default, a quantified subpattern is &quot;greedy&quot;, that is, it will match as
many times as possible (given a particular starting location) while still
allowing the rest of the pattern to match.  If you want it to match the
minimum number of times possible, follow the quantifier with a C&lt;&quot;?&quot;&gt;.  Note
that the meanings don't change, just the &quot;greediness&quot;:
X&lt;metacharacter&gt; X&lt;greedy&gt; X&lt;greediness&gt;
X&lt;?&gt; X&lt;*?&gt; X&lt;+?&gt; X&lt;??&gt; X&lt;{n}?&gt; X&lt;{n,}?&gt; X&lt;{n,m}?&gt;

    *?        Match 0 or more times, not greedily
    +?        Match 1 or more times, not greedily
    ??        Match 0 or 1 time, not greedily
    {n}?      Match exactly n times, not greedily (redundant)
    {n,}?     Match at least n times, not greedily
    {n,m}?    Match at least n but not more than m times, not greedily

Normally when a quantified subpattern does not allow the rest of the
overall pattern to match, Perl will backtrack. However, this behaviour is
sometimes undesirable. Thus Perl provides the &quot;possessive&quot; quantifier form
as well.

 *+     Match 0 or more times and give nothing back
 ++     Match 1 or more times and give nothing back
 ?+     Match 0 or 1 time and give nothing back
 {n}+   Match exactly n times and give nothing back (redundant)
 {n,}+  Match at least n times and give nothing back
 {n,m}+ Match at least n but not more than m times and give nothing back

For instance,

   'aaaa' =~ /a++a/

will never match, as the C&lt;a++&gt; will gobble up all the C&lt;&quot;a&quot;&gt;'s in the
string and won't leave any for the remaining part of the pattern. This
feature can be extremely useful to give perl hints about where it
shouldn't backtrack. For instance, the typical &quot;match a double-quoted
string&quot; problem can be most efficiently performed when written as:

   /&quot;(?:[^&quot;\\]++|\\.)*+&quot;/

as we know that if the final quote does not match, backtracking will not
help. See the independent subexpression
L&lt;/C&lt;&lt; (?&gt;pattern) &gt;&gt;&gt; for more details;
possessive quantifiers are just syntactic sugar for that construct. For
instance the above example could also be written as follows:

   /&quot;(?&gt;(?:(?&gt;[^&quot;\\]+)|\\.)*)&quot;/

Note that the possessive quantifier modifier can not be be combined
with the non-greedy modifier. This is because it would make no sense.
Consider the follow equivalency table:

    Illegal         Legal
    ------------    ------
    X??+            X{0}
    X+?+            X{1}
    X{min,max}?+    X{min}

=head3 Escape sequences

Because patterns are processed as double-quoted strings, the following
also work:

 \t          tab                   (HT, TAB)
 \n          newline               (LF, NL)
 \r          return                (CR)
 \f          form feed             (FF)
 \a          alarm (bell)          (BEL)
 \e          escape (think troff)  (ESC)
 \cK         control char          (example: VT)
 \x{}, \x00  character whose ordinal is the given hexadecimal number
 \N{name}    named Unicode character or character sequence
 \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
 \o{}, \000  character whose ordinal is the given octal number
 \l          lowercase next char (think vi)
 \u          uppercase next char (think vi)
 \L          lowercase until \E (think vi)
 \U          uppercase until \E (think vi)
 \Q          quote (disable) pattern metacharacters until \E
 \E          end either case modification or quoted section, think vi

Details are in L&lt;perlop/Quote and Quote-like Operators&gt;.

=head3 Character Classes and other Special Escapes

In addition, Perl defines the following:
X&lt;\g&gt; X&lt;\k&gt; X&lt;\K&gt; X&lt;backreference&gt;

 Sequence   Note    Description
  [...]     [1]  Match a character according to the rules of the
                   bracketed character class defined by the &quot;...&quot;.
                   Example: [a-z] matches &quot;a&quot; or &quot;b&quot; or &quot;c&quot; ... or &quot;z&quot;
  [[:...:]] [2]  Match a character according to the rules of the POSIX
                   character class &quot;...&quot; within the outer bracketed
                   character class.  Example: [[:upper:]] matches any
                   uppercase character.
  (?[...])  [8]  Extended bracketed character class
  \w        [3]  Match a &quot;word&quot; character (alphanumeric plus &quot;_&quot;, plus
                   other connector punctuation chars plus Unicode
                   marks)
  \W        [3]  Match a non-&quot;word&quot; character
  \s        [3]  Match a whitespace character
  \S        [3]  Match a non-whitespace character
  \d        [3]  Match a decimal digit character
  \D        [3]  Match a non-digit character
  \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
  \PP       [3]  Match non-P
  \X        [4]  Match Unicode &quot;eXtended grapheme cluster&quot;
  \1        [5]  Backreference to a specific capture group or buffer.
                   '1' may actually be any positive integer.
  \g1       [5]  Backreference to a specific or previous group,
  \g{-1}    [5]  The number may be negative indicating a relative
                   previous group and may optionally be wrapped in
                   curly brackets for safer parsing.
  \g{name}  [5]  Named backreference
  \k&lt;name&gt;  [5]  Named backreference
  \K        [6]  Keep the stuff left of the \K, don't include it in $&amp;
  \N        [7]  Any character but \n.  Not affected by /s modifier
  \v        [3]  Vertical whitespace
  \V        [3]  Not vertical whitespace
  \h        [3]  Horizontal whitespace
  \H        [3]  Not horizontal whitespace
  \R        [4]  Linebreak

=over 4

=item [1]

See L&lt;perlrecharclass/Bracketed Character Classes&gt; for details.

=item [2]

See L&lt;perlrecharclass/POSIX Character Classes&gt; for details.

=item [3]

See L&lt;perlrecharclass/Backslash sequences&gt; for details.

=item [4]

See L&lt;perlrebackslash/Misc&gt; for details.

=item [5]

See L&lt;/Capture groups&gt; below for details.

=item [6]

See L&lt;/Extended Patterns&gt; below for details.

=item [7]

Note that C&lt;\N&gt; has two meanings.  When of the form C&lt;\N{NAME}&gt;, it matches the
character or character sequence whose name is C&lt;NAME&gt;; and similarly
when of the form C&lt;\N{U+I&lt;hex&gt;}&gt;, it matches the character whose Unicode
code point is I&lt;hex&gt;.  Otherwise it matches any character but C&lt;\n&gt;.

=item [8]

See L&lt;perlrecharclass/Extended Bracketed Character Classes&gt; for details.

=back

=head3 Assertions

Besides L&lt;C&lt;&quot;^&quot;&gt; and C&lt;&quot;$&quot;&gt;|/Metacharacters&gt;, Perl defines the following
zero-width assertions:
X&lt;zero-width assertion&gt; X&lt;assertion&gt; X&lt;regex, zero-width assertion&gt;
X&lt;regexp, zero-width assertion&gt;
X&lt;regular expression, zero-width assertion&gt;
X&lt;\b&gt; X&lt;\B&gt; X&lt;\A&gt; X&lt;\Z&gt; X&lt;\z&gt; X&lt;\G&gt;

 \b{}   Match at Unicode boundary of specified type
 \B{}   Match where corresponding \b{} doesn't match
 \b     Match a \w\W or \W\w boundary
 \B     Match except at a \w\W or \W\w boundary
 \A     Match only at beginning of string
 \Z     Match only at end of string, or before newline at the end
 \z     Match only at end of string
 \G     Match only at pos() (e.g. at the end-of-match position
        of prior m//g)

A Unicode boundary (C&lt;\b{}&gt;), available starting in v5.22, is a spot
between two characters, or before the first character in the string, or
after the final character in the string where certain criteria defined
by Unicode are met.  See L&lt;perlrebackslash/\b{}, \b, \B{}, \B&gt; for
details.

A word boundary (C&lt;\b&gt;) is a spot between two characters
that has a C&lt;\w&gt; on one side of it and a C&lt;\W&gt; on the other side
of it (in either order), counting the imaginary characters off the
beginning and end of the string as matching a C&lt;\W&gt;.  (Within
character classes C&lt;\b&gt; represents backspace rather than a word
boundary, just as it normally does in any double-quoted string.)
The C&lt;\A&gt; and C&lt;\Z&gt; are just like C&lt;&quot;^&quot;&gt; and C&lt;&quot;$&quot;&gt;, except that they
won't match multiple times when the C&lt;/m&gt; modifier is used, while
C&lt;&quot;^&quot;&gt; and C&lt;&quot;$&quot;&gt; will match at every internal line boundary.  To match
the actual end of the string and not ignore an optional trailing
newline, use C&lt;\z&gt;.
X&lt;\b&gt; X&lt;\A&gt; X&lt;\Z&gt; X&lt;\z&gt; X&lt;/m&gt;

The C&lt;\G&gt; assertion can be used to chain global matches (using
C&lt;m//g&gt;), as described in L&lt;perlop/&quot;Regexp Quote-Like Operators&quot;&gt;.
It is also useful when writing C&lt;lex&gt;-like scanners, when you have
several patterns that you want to match against consequent substrings
of your string; see the previous reference.  The actual location
where C&lt;\G&gt; will match can also be influenced by using C&lt;pos()&gt; as
an lvalue: see L&lt;perlfunc/pos&gt;. Note that the rule for zero-length
matches (see L&lt;/&quot;Repeated Patterns Matching a Zero-length Substring&quot;&gt;)
is modified somewhat, in that contents to the left of C&lt;\G&gt; are
not counted when determining the length of the match. Thus the following
will not match forever:
X&lt;\G&gt;

     my $string = 'ABC';
     pos($string) = 1;
     while ($string =~ /(.\G)/g) {
         print $1;
     }

It will print 'A' and then terminate, as it considers the match to
be zero-width, and thus will not match at the same position twice in a
row.

It is worth noting that C&lt;\G&gt; improperly used can result in an infinite
loop. Take care when using patterns that include C&lt;\G&gt; in an alternation.

Note also that C&lt;s///&gt; will refuse to overwrite part of a substitution
that has already been replaced; so for example this will stop after the
first iteration, rather than iterating its way backwards through the
string:

    $_ = &quot;123456789&quot;;
    pos = 6;
    s/.(?=.\G)/X/g;
    print; 	# prints 1234X6789, not XXXXX6789


=head3 Capture groups

The grouping construct C&lt;( ... )&gt; creates capture groups (also referred to as
capture buffers). To refer to the current contents of a group later on, within
the same pattern, use C&lt;\g1&gt; (or C&lt;\g{1}&gt;) for the first, C&lt;\g2&gt; (or C&lt;\g{2}&gt;)
for the second, and so on.
This is called a I&lt;backreference&gt;.
X&lt;regex, capture buffer&gt; X&lt;regexp, capture buffer&gt;
X&lt;regex, capture group&gt; X&lt;regexp, capture group&gt;
X&lt;regular expression, capture buffer&gt; X&lt;backreference&gt;
X&lt;regular expression, capture group&gt; X&lt;backreference&gt;
X&lt;\g{1}&gt; X&lt;\g{-1}&gt; X&lt;\g{name}&gt; X&lt;relative backreference&gt; X&lt;named backreference&gt;
X&lt;named capture buffer&gt; X&lt;regular expression, named capture buffer&gt;
X&lt;named capture group&gt; X&lt;regular expression, named capture group&gt;
X&lt;%+&gt; X&lt;$+{name}&gt; X&lt;&lt; \k&lt;name&gt; &gt;&gt;
There is no limit to the number of captured substrings that you may use.
Groups are numbered with the leftmost open parenthesis being number 1, I&lt;etc&gt;.  If
a group did not match, the associated backreference won't match either. (This
can happen if the group is optional, or in a different branch of an
alternation.)
You can omit the C&lt;&quot;g&quot;&gt;, and write C&lt;&quot;\1&quot;&gt;, I&lt;etc&gt;, but there are some issues with
this form, described below.

You can also refer to capture groups relatively, by using a negative number, so
that C&lt;\g-1&gt; and C&lt;\g{-1}&gt; both refer to the immediately preceding capture
group, and C&lt;\g-2&gt; and C&lt;\g{-2}&gt; both refer to the group before it.  For
example:

        /
         (Y)            # group 1
         (              # group 2
            (X)         # group 3
            \g{-1}      # backref to group 3
            \g{-3}      # backref to group 1
         )
        /x

would match the same as C&lt;/(Y) ( (X) \g3 \g1 )/x&gt;.  This allows you to
interpolate regexes into larger regexes and not have to worry about the
capture groups being renumbered.

You can dispense with numbers altogether and create named capture groups.
The notation is C&lt;(?E&lt;lt&gt;I&lt;name&gt;E&lt;gt&gt;...)&gt; to declare and C&lt;\g{I&lt;name&gt;}&gt; to
reference.  (To be compatible with .Net regular expressions, C&lt;\g{I&lt;name&gt;}&gt; may
also be written as C&lt;\k{I&lt;name&gt;}&gt;, C&lt;\kE&lt;lt&gt;I&lt;name&gt;E&lt;gt&gt;&gt; or C&lt;\k'I&lt;name&gt;'&gt;.)
I&lt;name&gt; must not begin with a number, nor contain hyphens.
When different groups within the same pattern have the same name, any reference
to that name assumes the leftmost defined group.  Named groups count in
absolute and relative numbering, and so can also be referred to by those
numbers.
(It's possible to do things with named capture groups that would otherwise
require C&lt;(??{})&gt;.)

Capture group contents are dynamically scoped and available to you outside the
pattern until the end of the enclosing block or until the next successful
match, whichever comes first.  (See L&lt;perlsyn/&quot;Compound Statements&quot;&gt;.)
You can refer to them by absolute number (using C&lt;&quot;$1&quot;&gt; instead of C&lt;&quot;\g1&quot;&gt;,
I&lt;etc&gt;); or by name via the C&lt;%+&gt; hash, using C&lt;&quot;$+{I&lt;name&gt;}&quot;&gt;.

Braces are required in referring to named capture groups, but are optional for
absolute or relative numbered ones.  Braces are safer when creating a regex by
concatenating smaller strings.  For example if you have C&lt;qr/$a$b/&gt;, and C&lt;$a&gt;
contained C&lt;&quot;\g1&quot;&gt;, and C&lt;$b&gt; contained C&lt;&quot;37&quot;&gt;, you would get C&lt;/\g137/&gt; which
is probably not what you intended.

The C&lt;\g&gt; and C&lt;\k&gt; notations were introduced in Perl 5.10.0.  Prior to that
there were no named nor relative numbered capture groups.  Absolute numbered
groups were referred to using C&lt;\1&gt;,
C&lt;\2&gt;, I&lt;etc&gt;., and this notation is still
accepted (and likely always will be).  But it leads to some ambiguities if
there are more than 9 capture groups, as C&lt;\10&gt; could mean either the tenth
capture group, or the character whose ordinal in octal is 010 (a backspace in
ASCII).  Perl resolves this ambiguity by interpreting C&lt;\10&gt; as a backreference
only if at least 10 left parentheses have opened before it.  Likewise C&lt;\11&gt; is
a backreference only if at least 11 left parentheses have opened before it.
And so on.  C&lt;\1&gt; through C&lt;\9&gt; are always interpreted as backreferences.
There are several examples below that illustrate these perils.  You can avoid
the ambiguity by always using C&lt;\g{}&gt; or C&lt;\g&gt; if you mean capturing groups;
and for octal constants always using C&lt;\o{}&gt;, or for C&lt;\077&gt; and below, using 3
digits padded with leading zeros, since a leading zero implies an octal
constant.

The C&lt;\I&lt;digit&gt;&gt; notation also works in certain circumstances outside
the pattern.  See L&lt;/Warning on \1 Instead of $1&gt; below for details.

Examples:

    s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words

    /(.)\g1/                        # find first doubled char
         and print &quot;'$1' is the first doubled character\n&quot;;

    /(?&lt;char&gt;.)\k&lt;char&gt;/            # ... a different way
         and print &quot;'$+{char}' is the first doubled character\n&quot;;

    /(?'char'.)\g1/                 # ... mix and match
         and print &quot;'$1' is the first doubled character\n&quot;;

    if (/Time: (..):(..):(..)/) {   # parse out values
        $hours = $1;
        $minutes = $2;
        $seconds = $3;
    }

    /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
    /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
    /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
    /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal

    $a = '(.)\1';        # Creates problems when concatenated.
    $b = '(.)\g{1}';     # Avoids the problems.
    &quot;aa&quot; =~ /${a}/;      # True
    &quot;aa&quot; =~ /${b}/;      # True
    &quot;aa0&quot; =~ /${a}0/;    # False!
    &quot;aa0&quot; =~ /${b}0/;    # True
    &quot;aa\x08&quot; =~ /${a}0/;  # True!
    &quot;aa\x08&quot; =~ /${b}0/;  # False

Several special variables also refer back to portions of the previous
match.  C&lt;$+&gt; returns whatever the last bracket match matched.
C&lt;$&amp;&gt; returns the entire matched string.  (At one point C&lt;$0&gt; did
also, but now it returns the name of the program.)  C&lt;$`&gt; returns
everything before the matched string.  C&lt;$'&gt; returns everything
after the matched string. And C&lt;$^N&gt; contains whatever was matched by
the most-recently closed group (submatch). C&lt;$^N&gt; can be used in
extended patterns (see below), for example to assign a submatch to a
variable.
X&lt;$+&gt; X&lt;$^N&gt; X&lt;$&amp;&gt; X&lt;$`&gt; X&lt;$'&gt;

These special variables, like the C&lt;%+&gt; hash and the numbered match variables
(C&lt;$1&gt;, C&lt;$2&gt;, C&lt;$3&gt;, I&lt;etc&gt;.) are dynamically scoped
until the end of the enclosing block or until the next successful
match, whichever comes first.  (See L&lt;perlsyn/&quot;Compound Statements&quot;&gt;.)
X&lt;$+&gt; X&lt;$^N&gt; X&lt;$&amp;&gt; X&lt;$`&gt; X&lt;$'&gt;
X&lt;$1&gt; X&lt;$2&gt; X&lt;$3&gt; X&lt;$4&gt; X&lt;$5&gt; X&lt;$6&gt; X&lt;$7&gt; X&lt;$8&gt; X&lt;$9&gt;

B&lt;NOTE&gt;: Failed matches in Perl do not reset the match variables,
which makes it easier to write code that tests for a series of more
specific cases and remembers the best match.

B&lt;WARNING&gt;: If your code is to run on Perl 5.16 or earlier,
beware that once Perl sees that you need one of C&lt;$&amp;&gt;, C&lt;$`&gt;, or
C&lt;$'&gt; anywhere in the program, it has to provide them for every
pattern match.  This may substantially slow your program.

Perl uses the same mechanism to produce C&lt;$1&gt;, C&lt;$2&gt;, I&lt;etc&gt;, so you also
pay a price for each pattern that contains capturing parentheses.
(To avoid this cost while retaining the grouping behaviour, use the
extended regular expression C&lt;(?: ... )&gt; instead.)  But if you never
use C&lt;$&amp;&gt;, C&lt;$`&gt; or C&lt;$'&gt;, then patterns I&lt;without&gt; capturing
parentheses will not be penalized.  So avoid C&lt;$&amp;&gt;, C&lt;$'&gt;, and C&lt;$`&gt;
if you can, but if you can't (and some algorithms really appreciate
them), once you've used them once, use them at will, because you've
already paid the price.
X&lt;$&amp;&gt; X&lt;$`&gt; X&lt;$'&gt;

Perl 5.16 introduced a slightly more efficient mechanism that notes
separately whether each of C&lt;$`&gt;, C&lt;$&amp;&gt;, and C&lt;$'&gt; have been seen, and
thus may only need to copy part of the string.  Perl 5.20 introduced a
much more efficient copy-on-write mechanism which eliminates any slowdown.

As another workaround for this problem, Perl 5.10.0 introduced C&lt;${^PREMATCH}&gt;,
C&lt;${^MATCH}&gt; and C&lt;${^POSTMATCH}&gt;, which are equivalent to C&lt;$`&gt;, C&lt;$&amp;&gt;
and C&lt;$'&gt;, B&lt;except&gt; that they are only guaranteed to be defined after a
successful match that was executed with the C&lt;/p&gt; (preserve) modifier.
The use of these variables incurs no global performance penalty, unlike
their punctuation character equivalents, however at the trade-off that you
have to tell perl when you want to use them.  As of Perl 5.20, these three
variables are equivalent to C&lt;$`&gt;, C&lt;$&amp;&gt; and C&lt;$'&gt;, and C&lt;/p&gt; is ignored.
X&lt;/p&gt; X&lt;p modifier&gt;

=head2 Quoting metacharacters

Backslashed metacharacters in Perl are alphanumeric, such as C&lt;\b&gt;,
C&lt;\w&gt;, C&lt;\n&gt;.  Unlike some other regular expression languages, there
are no backslashed symbols that aren't alphanumeric.  So anything
that looks like C&lt;\\&gt;, C&lt;\(&gt;, C&lt;\)&gt;, C&lt;\[&gt;, C&lt;\]&gt;, C&lt;\{&gt;, or C&lt;\}&gt; is
always
interpreted as a literal character, not a metacharacter.  This was
once used in a common idiom to disable or quote the special meanings
of regular expression metacharacters in a string that you want to
use for a pattern. Simply quote all non-&quot;word&quot; characters:

    $pattern =~ s/(\W)/\\$1/g;

(If C&lt;use locale&gt; is set, then this depends on the current locale.)
Today it is more common to use the C&lt;L&lt;quotemeta()|perlfunc/quotemeta&gt;&gt;
function or the C&lt;\Q&gt; metaquoting escape sequence to disable all
metacharacters' special meanings like this:

    /$unquoted\Q$quoted\E$unquoted/

Beware that if you put literal backslashes (those not inside
interpolated variables) between C&lt;\Q&gt; and C&lt;\E&gt;, double-quotish
backslash interpolation may lead to confusing results.  If you
I&lt;need&gt; to use literal backslashes within C&lt;\Q...\E&gt;,
consult L&lt;perlop/&quot;Gory details of parsing quoted constructs&quot;&gt;.

C&lt;quotemeta()&gt; and C&lt;\Q&gt; are fully described in L&lt;perlfunc/quotemeta&gt;.

=head2 Extended Patterns

Perl also defines a consistent extension syntax for features not
found in standard tools like B&lt;awk&gt; and
B&lt;lex&gt;.  The syntax for most of these is a
pair of parentheses with a question mark as the first thing within
the parentheses.  The character after the question mark indicates
the extension.

A question mark was chosen for this and for the minimal-matching
construct because 1) question marks are rare in older regular
expressions, and 2) whenever you see one, you should stop and
&quot;question&quot; exactly what is going on.  That's psychology....

=over 4

=item C&lt;(?#text)&gt;
X&lt;(?#)&gt;

A comment.  The text is ignored.
Note that Perl closes
the comment as soon as it sees a C&lt;&quot;)&quot;&gt;, so there is no way to put a literal
C&lt;&quot;)&quot;&gt; in the comment.  The pattern's closing delimiter must be escaped by
a backslash if it appears in the comment.

See L&lt;/E&lt;sol&gt;x&gt; for another way to have comments in patterns.

Note that a comment can go just about anywhere, except in the middle of
an escape sequence.   Examples:

 qr/foo(?#comment)bar/'  # Matches 'foobar'

 # The pattern below matches 'abcd', 'abccd', or 'abcccd'
 qr/abc(?#comment between literal and its quantifier){1,3}d/

 # The pattern below generates a syntax error, because the '\p' must
 # be followed immediately by a '{'.
 qr/\p(?#comment between \p and its property name){Any}/

 # The pattern below generates a syntax error, because the initial
 # '\(' is a literal opening parenthesis, and so there is nothing
 # for the  closing ')' to match
 qr/\(?#the backslash means this isn't a comment)p{Any}/

=item C&lt;(?adlupimnsx-imnsx)&gt;

=item C&lt;(?^alupimnsx)&gt;
X&lt;(?)&gt; X&lt;(?^)&gt;

One or more embedded pattern-match modifiers, to be turned on (or
turned off if preceded by C&lt;&quot;-&quot;&gt;) for the remainder of the pattern or
the remainder of the enclosing pattern group (if any).

This is particularly useful for dynamically-generated patterns,
such as those read in from a
configuration file, taken from an argument, or specified in a table
somewhere.  Consider the case where some patterns want to be
case-sensitive and some do not:  The case-insensitive ones merely need to
include C&lt;(?i)&gt; at the front of the pattern.  For example:

    $pattern = &quot;foobar&quot;;
    if ( /$pattern/i ) { }

    # more flexible:

    $pattern = &quot;(?i)foobar&quot;;
    if ( /$pattern/ ) { }

These modifiers are restored at the end of the enclosing group. For example,

    ( (?i) blah ) \s+ \g1

will match C&lt;blah&gt; in any case, some spaces, and an exact (I&lt;including the case&gt;!)
repetition of the previous word, assuming the C&lt;/x&gt; modifier, and no C&lt;/i&gt;
modifier outside this group.

These modifiers do not carry over into named subpatterns called in the
enclosing group. In other words, a pattern such as C&lt;((?i)(?&amp;NAME))&gt; does not
change the case-sensitivity of the C&lt;&quot;NAME&quot;&gt; pattern.

A modifier is overridden by later occurrences of this construct in the
same scope containing the same modifier, so that

    /((?im)foo(?-m)bar)/

matches all of C&lt;foobar&gt; case insensitively, but uses C&lt;/m&gt; rules for
only the C&lt;foo&gt; portion.  The C&lt;&quot;a&quot;&gt; flag overrides C&lt;aa&gt; as well;
likewise C&lt;aa&gt; overrides C&lt;&quot;a&quot;&gt;.  The same goes for C&lt;&quot;x&quot;&gt; and C&lt;xx&gt;.
Hence, in

    /(?-x)foo/xx

both C&lt;/x&gt; and C&lt;/xx&gt; are turned off during matching C&lt;foo&gt;.  And in

    /(?x)foo/x

C&lt;/x&gt; but NOT C&lt;/xx&gt; is turned on for matching C&lt;foo&gt;.  (One might
mistakenly think that since the inner C&lt;(?x)&gt; is already in the scope of
C&lt;/x&gt;, that the result would effectively be the sum of them, yielding
C&lt;/xx&gt;.  It doesn't work that way.)  Similarly, doing something like
C&lt;(?xx-x)foo&gt; turns off all C&lt;&quot;x&quot;&gt; behavior for matching C&lt;foo&gt;, it is not
that you subtract 1 C&lt;&quot;x&quot;&gt; from 2 to get 1 C&lt;&quot;x&quot;&gt; remaining.

Any of these modifiers can be set to apply globally to all regular
expressions compiled within the scope of a C&lt;use re&gt;.  See
L&lt;re/&quot;'/flags' mode&quot;&gt;.

Starting in Perl 5.14, a C&lt;&quot;^&quot;&gt; (caret or circumflex accent) immediately
after the C&lt;&quot;?&quot;&gt; is a shorthand equivalent to C&lt;d-imnsx&gt;.  Flags (except
C&lt;&quot;d&quot;&gt;) may follow the caret to override it.
But a minus sign is not legal with it.

Note that the C&lt;&quot;a&quot;&gt;, C&lt;&quot;d&quot;&gt;, C&lt;&quot;l&quot;&gt;, C&lt;&quot;p&quot;&gt;, and C&lt;&quot;u&quot;&gt; modifiers are special in
that they can only be enabled, not disabled, and the C&lt;&quot;a&quot;&gt;, C&lt;&quot;d&quot;&gt;, C&lt;&quot;l&quot;&gt;, and
C&lt;&quot;u&quot;&gt; modifiers are mutually exclusive: specifying one de-specifies the
others, and a maximum of one (or two C&lt;&quot;a&quot;&gt;'s) may appear in the
construct.  Thus, for
example, C&lt;(?-p)&gt; will warn when compiled under C&lt;use warnings&gt;;
C&lt;(?-d:...)&gt; and C&lt;(?dl:...)&gt; are fatal errors.

Note also that the C&lt;&quot;p&quot;&gt; modifier is special in that its presence
anywhere in a pattern has a global effect.

=item C&lt;(?:pattern)&gt;
X&lt;(?:)&gt;

=item C&lt;(?adluimnsx-imnsx:pattern)&gt;

=item C&lt;(?^aluimnsx:pattern)&gt;
X&lt;(?^:)&gt;

This is for clustering, not capturing; it groups subexpressions like
C&lt;&quot;()&quot;&gt;, but doesn't make backreferences as C&lt;&quot;()&quot;&gt; does.  So

    @fields = split(/\b(?:a|b|c)\b/)

matches the same field delimiters as

    @fields = split(/\b(a|b|c)\b/)

but doesn't spit out the delimiters themselves as extra fields (even though
that's the behaviour of L&lt;perlfunc/split&gt; when its pattern contains capturing
groups).  It's also cheaper not to capture
characters if you don't need to.

Any letters between C&lt;&quot;?&quot;&gt; and C&lt;&quot;:&quot;&gt; act as flags modifiers as with
C&lt;(?adluimnsx-imnsx)&gt;.  For example,

    /(?s-i:more.*than).*million/i

is equivalent to the more verbose

    /(?:(?s-i)more.*than).*million/i

Note that any C&lt;()&gt; constructs enclosed within this one will still
capture unless the C&lt;/n&gt; modifier is in effect.

Like the L&lt;/(?adlupimnsx-imnsx)&gt; construct, C&lt;aa&gt; and C&lt;&quot;a&quot;&gt; override each
other, as do C&lt;xx&gt; and C&lt;&quot;x&quot;&gt;.  They are not additive.  So, doing
something like C&lt;(?xx-x:foo)&gt; turns off all C&lt;&quot;x&quot;&gt; behavior for matching
C&lt;foo&gt;.

Starting in Perl 5.14, a C&lt;&quot;^&quot;&gt; (caret or circumflex accent) immediately
after the C&lt;&quot;?&quot;&gt; is a shorthand equivalent to C&lt;d-imnsx&gt;.  Any positive
flags (except C&lt;&quot;d&quot;&gt;) may follow the caret, so

    (?^x:foo)

is equivalent to

    (?x-imns:foo)

The caret tells Perl that this cluster doesn't inherit the flags of any
surrounding pattern, but uses the system defaults (C&lt;d-imnsx&gt;),
modified by any flags specified.

The caret allows for simpler stringification of compiled regular
expressions.  These look like

    (?^:pattern)

with any non-default flags appearing between the caret and the colon.
A test that looks at such stringification thus doesn't need to have the
system default flags hard-coded in it, just the caret.  If new flags are
added to Perl, the meaning of the caret's expansion will change to include
the default for those flags, so the test will still work, unchanged.

Specifying a negative flag after the caret is an error, as the flag is
redundant.

Mnemonic for C&lt;(?^...)&gt;:  A fresh beginning since the usual use of a caret is
to match at the beginning.

=item C&lt;(?|pattern)&gt;
X&lt;(?|)&gt; X&lt;Branch reset&gt;

This is the &quot;branch reset&quot; pattern, which has the special property
that the capture groups are numbered from the same starting point
in each alternation branch. It is available starting from perl 5.10.0.

Capture groups are numbered from left to right, but inside this
construct the numbering is restarted for each branch.

The numbering within each branch will be as normal, and any groups
following this construct will be numbered as though the construct
contained only one branch, that being the one with the most capture
groups in it.

This construct is useful when you want to capture one of a
number of alternative matches.

Consider the following pattern.  The numbers underneath show in
which group the captured content will be stored.


    # before  ---------------branch-reset----------- after
    / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
    # 1            2         2  3        2     3     4

Be careful when using the branch reset pattern in combination with
named captures. Named captures are implemented as being aliases to
numbered groups holding the captures, and that interferes with the
implementation of the branch reset pattern. If you are using named
captures in a branch reset pattern, it's best to use the same names,
in the same order, in each of the alternations:

   /(?|  (?&lt;a&gt; x ) (?&lt;b&gt; y )
      |  (?&lt;a&gt; z ) (?&lt;b&gt; w )) /x

Not doing so may lead to surprises:

  &quot;12&quot; =~ /(?| (?&lt;a&gt; \d+ ) | (?&lt;b&gt; \D+))/x;
  say $+{a};    # Prints '12'
  say $+{b};    # *Also* prints '12'.

The problem here is that both the group named C&lt;&lt; a &gt;&gt; and the group
named C&lt;&lt; b &gt;&gt; are aliases for the group belonging to C&lt;&lt; $1 &gt;&gt;.

=item Lookaround Assertions
X&lt;look-around assertion&gt; X&lt;lookaround assertion&gt; X&lt;look-around&gt; X&lt;lookaround&gt;

Lookaround assertions are zero-width patterns which match a specific
pattern without including it in C&lt;$&amp;&gt;. Positive assertions match when
their subpattern matches, negative assertions match when their subpattern
fails. Lookbehind matches text up to the current match position,
lookahead matches text following the current match position.

=over 4

=item C&lt;(?=pattern)&gt;
X&lt;(?=)&gt; X&lt;look-ahead, positive&gt; X&lt;lookahead, positive&gt;

A zero-width positive lookahead assertion.  For example, C&lt;/\w+(?=\t)/&gt;
matches a word followed by a tab, without including the tab in C&lt;$&amp;&gt;.

=item C&lt;(?!pattern)&gt;
X&lt;(?!)&gt; X&lt;look-ahead, negative&gt; X&lt;lookahead, negative&gt;

A zero-width negative lookahead assertion.  For example C&lt;/foo(?!bar)/&gt;
matches any occurrence of &quot;foo&quot; that isn't followed by &quot;bar&quot;.  Note
however that lookahead and lookbehind are NOT the same thing.  You cannot
use this for lookbehind.

If you are looking for a &quot;bar&quot; that isn't preceded by a &quot;foo&quot;, C&lt;/(?!foo)bar/&gt;
will not do what you want.  That's because the C&lt;(?!foo)&gt; is just saying that
the next thing cannot be &quot;foo&quot;--and it's not, it's a &quot;bar&quot;, so &quot;foobar&quot; will
match.  Use lookbehind instead (see below).

=item C&lt;(?&lt;=pattern)&gt;

=item C&lt;\K&gt;
X&lt;(?&lt;=)&gt; X&lt;look-behind, positive&gt; X&lt;lookbehind, positive&gt; X&lt;\K&gt;

A zero-width positive lookbehind assertion.  For example, C&lt;/(?&lt;=\t)\w+/&gt;
matches a word that follows a tab, without including the tab in C&lt;$&amp;&gt;.
Works only for fixed-width lookbehind.

There is a special form of this construct, called C&lt;\K&gt; (available since
Perl 5.10.0), which causes the
regex engine to &quot;keep&quot; everything it had matched prior to the C&lt;\K&gt; and
not include it in C&lt;$&amp;&gt;. This effectively provides variable-length
lookbehind. The use of C&lt;\K&gt; inside of another lookaround assertion
is allowed, but the behaviour is currently not well defined.

For various reasons C&lt;\K&gt; may be significantly more efficient than the
equivalent C&lt;&lt; (?&lt;=...) &gt;&gt; construct, and it is especially useful in
situations where you want to efficiently remove something following
something else in a string. For instance

  s/(foo)bar/$1/g;

can be rewritten as the much more efficient

  s/foo\Kbar//g;

=item C&lt;(?&lt;!pattern)&gt;
X&lt;(?&lt;!)&gt; X&lt;look-behind, negative&gt; X&lt;lookbehind, negative&gt;

A zero-width negative lookbehind assertion.  For example C&lt;/(?&lt;!bar)foo/&gt;
matches any occurrence of &quot;foo&quot; that does not follow &quot;bar&quot;.  Works
only for fixed-width lookbehind.

=back

=item C&lt;&lt; (?&lt;NAME&gt;pattern) &gt;&gt;

=item C&lt;(?'NAME'pattern)&gt;
X&lt;&lt; (?&lt;NAME&gt;) &gt;&gt; X&lt;(?'NAME')&gt; X&lt;named capture&gt; X&lt;capture&gt;

A named capture group. Identical in every respect to normal capturing
parentheses C&lt;()&gt; but for the additional fact that the group
can be referred to by name in various regular expression
constructs (like C&lt;\g{NAME}&gt;) and can be accessed by name
after a successful match via C&lt;%+&gt; or C&lt;%-&gt;. See L&lt;perlvar&gt;
for more details on the C&lt;%+&gt; and C&lt;%-&gt; hashes.

If multiple distinct capture groups have the same name then the
C&lt;$+{NAME}&gt; will refer to the leftmost defined group in the match.

The forms C&lt;(?'NAME'pattern)&gt; and C&lt;&lt; (?&lt;NAME&gt;pattern) &gt;&gt; are equivalent.

B&lt;NOTE:&gt; While the notation of this construct is the same as the similar
function in .NET regexes, the behavior is not. In Perl the groups are
numbered sequentially regardless of being named or not. Thus in the
pattern

  /(x)(?&lt;foo&gt;y)(z)/

C&lt;$+{I&lt;foo&gt;}&gt; will be the same as C&lt;$2&gt;, and C&lt;$3&gt; will contain 'z' instead of
the opposite which is what a .NET regex hacker might expect.

Currently I&lt;NAME&gt; is restricted to simple identifiers only.
In other words, it must match C&lt;/^[_A-Za-z][_A-Za-z0-9]*\z/&gt; or
its Unicode extension (see L&lt;utf8&gt;),
though it isn't extended by the locale (see L&lt;perllocale&gt;).

B&lt;NOTE:&gt; In order to make things easier for programmers with experience
with the Python or PCRE regex engines, the pattern C&lt;&lt; (?PE&lt;lt&gt;NAMEE&lt;gt&gt;pattern) &gt;&gt;
may be used instead of C&lt;&lt; (?&lt;NAME&gt;pattern) &gt;&gt;; however this form does not
support the use of single quotes as a delimiter for the name.

=item C&lt;&lt; \k&lt;NAME&gt; &gt;&gt;

=item C&lt;&lt; \k'NAME' &gt;&gt;

Named backreference. Similar to numeric backreferences, except that
the group is designated by name and not number. If multiple groups
have the same name then it refers to the leftmost defined group in
the current match.

It is an error to refer to a name not defined by a C&lt;&lt; (?&lt;NAME&gt;) &gt;&gt;
earlier in the pattern.

Both forms are equivalent.

B&lt;NOTE:&gt; In order to make things easier for programmers with experience
with the Python or PCRE regex engines, the pattern C&lt;&lt; (?P=NAME) &gt;&gt;
may be used instead of C&lt;&lt; \k&lt;NAME&gt; &gt;&gt;.

=item C&lt;(?{ code })&gt;
X&lt;(?{})&gt; X&lt;regex, code in&gt; X&lt;regexp, code in&gt; X&lt;regular expression, code in&gt;

B&lt;WARNING&gt;: Using this feature safely requires that you understand its
limitations.  Code executed that has side effects may not perform identically
from version to version due to the effect of future optimisations in the regex
engine.  For more information on this, see L&lt;/Embedded Code Execution
Frequency&gt;.

This zero-width assertion executes any embedded Perl code.  It always
succeeds, and its return value is set as C&lt;$^R&gt;.

In literal patterns, the code is parsed at the same time as the
surrounding code. While within the pattern, control is passed temporarily
back to the perl parser, until the logically-balancing closing brace is
encountered. This is similar to the way that an array index expression in
a literal string is handled, for example

    &quot;abc$array[ 1 + f('[') + g()]def&quot;

In particular, braces do not need to be balanced:

    s/abc(?{ f('{'); })/def/

Even in a pattern that is interpolated and compiled at run-time, literal
code blocks will be compiled once, at perl compile time; the following
prints &quot;ABCD&quot;:

    print &quot;D&quot;;
    my $qr = qr/(?{ BEGIN { print &quot;A&quot; } })/;
    my $foo = &quot;foo&quot;;
    /$foo$qr(?{ BEGIN { print &quot;B&quot; } })/;
    BEGIN { print &quot;C&quot; }

In patterns where the text of the code is derived from run-time
information rather than appearing literally in a source code /pattern/,
the code is compiled at the same time that the pattern is compiled, and
for reasons of security, C&lt;use re 'eval'&gt; must be in scope. This is to
stop user-supplied patterns containing code snippets from being
executable.

In situations where you need to enable this with C&lt;use re 'eval'&gt;, you should
also have taint checking enabled.  Better yet, use the carefully
constrained evaluation within a Safe compartment.  See L&lt;perlsec&gt; for
details about both these mechanisms.

From the viewpoint of parsing, lexical variable scope and closures,

    /AAA(?{ BBB })CCC/

behaves approximately like

    /AAA/ &amp;&amp; do { BBB } &amp;&amp; /CCC/

Similarly,

    qr/AAA(?{ BBB })CCC/

behaves approximately like

    sub { /AAA/ &amp;&amp; do { BBB } &amp;&amp; /CCC/ }

In particular:

    { my $i = 1; $r = qr/(?{ print $i })/ }
    my $i = 2;
    /$r/; # prints &quot;1&quot;

Inside a C&lt;(?{...})&gt; block, C&lt;$_&gt; refers to the string the regular
expression is matching against. You can also use C&lt;pos()&gt; to know what is
the current position of matching within this string.

The code block introduces a new scope from the perspective of lexical
variable declarations, but B&lt;not&gt; from the perspective of C&lt;local&gt; and
similar localizing behaviours. So later code blocks within the same
pattern will still see the values which were localized in earlier blocks.
These accumulated localizations are undone either at the end of a
successful match, or if the assertion is backtracked (compare
L&lt;/&quot;Backtracking&quot;&gt;). For example,

  $_ = 'a' x 8;
  m&lt;
     (?{ $cnt = 0 })               # Initialize $cnt.
     (
       a
       (?{
           local $cnt = $cnt + 1;  # Update $cnt,
                                   # backtracking-safe.
       })
     )*
     aaaa
     (?{ $res = $cnt })            # On success copy to
                                   # non-localized location.
   &gt;x;

will initially increment C&lt;$cnt&gt; up to 8; then during backtracking, its
value will be unwound back to 4, which is the value assigned to C&lt;$res&gt;.
At the end of the regex execution, C&lt;$cnt&gt; will be wound back to its initial
value of 0.

This assertion may be used as the condition in a

    (?(condition)yes-pattern|no-pattern)

switch.  If I&lt;not&gt; used in this way, the result of evaluation of C&lt;code&gt;
is put into the special variable C&lt;$^R&gt;.  This happens immediately, so
C&lt;$^R&gt; can be used from other C&lt;(?{ code })&gt; assertions inside the same
regular expression.

The assignment to C&lt;$^R&gt; above is properly localized, so the old
value of C&lt;$^R&gt; is restored if the assertion is backtracked; compare
L&lt;/&quot;Backtracking&quot;&gt;.

Note that the special variable C&lt;$^N&gt;  is particularly useful with code
blocks to capture the results of submatches in variables without having to
keep track of the number of nested parentheses. For example:

  $_ = &quot;The brown fox jumps over the lazy dog&quot;;
  /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
  print &quot;color = $color, animal = $animal\n&quot;;


=item C&lt;(??{ code })&gt;
X&lt;(??{})&gt;
X&lt;regex, postponed&gt; X&lt;regexp, postponed&gt; X&lt;regular expression, postponed&gt;

B&lt;WARNING&gt;: Using this feature safely requires that you understand its
limitations.  Code executed that has side effects may not perform
identically from version to version due to the effect of future
optimisations in the regex engine.  For more information on this, see
L&lt;/Embedded Code Execution Frequency&gt;.

This is a &quot;postponed&quot; regular subexpression.  It behaves in I&lt;exactly&gt; the
same way as a C&lt;(?{ code })&gt; code block as described above, except that
its return value, rather than being assigned to C&lt;$^R&gt;, is treated as a
pattern, compiled if it's a string (or used as-is if its a qr// object),
then matched as if it were inserted instead of this construct.

During the matching of this sub-pattern, it has its own set of
captures which are valid during the sub-match, but are discarded once
control returns to the main pattern. For example, the following matches,
with the inner pattern capturing &quot;B&quot; and matching &quot;BB&quot;, while the outer
pattern captures &quot;A&quot;;

    my $inner = '(.)\1';
    &quot;ABBA&quot; =~ /^(.)(??{ $inner })\1/;
    print $1; # prints &quot;A&quot;;

Note that this means that  there is no way for the inner pattern to refer
to a capture group defined outside.  (The code block itself can use C&lt;$1&gt;,
I&lt;etc&gt;., to refer to the enclosing pattern's capture groups.)  Thus, although

    ('a' x 100)=~/(??{'(.)' x 100})/

I&lt;will&gt; match, it will I&lt;not&gt; set C&lt;$1&gt; on exit.

The following pattern matches a parenthesized group:

 $re = qr{
            \(
            (?:
               (?&gt; [^()]+ )  # Non-parens without backtracking
             |
               (??{ $re })   # Group with matching parens
            )*
            \)
         }x;

See also
L&lt;C&lt;(?I&lt;PARNO&gt;)&gt;|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)&gt;
for a different, more efficient way to accomplish
the same task.

Executing a postponed regular expression too many times without
consuming any input string will also result in a fatal error.  The depth
at which that happens is compiled into perl, so it can be changed with a
custom build.

=item C&lt;(?I&lt;PARNO&gt;)&gt; C&lt;(?-I&lt;PARNO&gt;)&gt; C&lt;(?+I&lt;PARNO&gt;)&gt; C&lt;(?R)&gt; C&lt;(?0)&gt;
X&lt;(?PARNO)&gt; X&lt;(?1)&gt; X&lt;(?R)&gt; X&lt;(?0)&gt; X&lt;(?-1)&gt; X&lt;(?+1)&gt; X&lt;(?-PARNO)&gt; X&lt;(?+PARNO)&gt;
X&lt;regex, recursive&gt; X&lt;regexp, recursive&gt; X&lt;regular expression, recursive&gt;
X&lt;regex, relative recursion&gt; X&lt;GOSUB&gt; X&lt;GOSTART&gt;

Recursive subpattern. Treat the contents of a given capture buffer in the
current pattern as an independent subpattern and attempt to match it at
the current position in the string. Information about capture state from
the caller for things like backreferences is available to the subpattern,
but capture buffers set by the subpattern are not visible to the caller.

Similar to C&lt;(??{ code })&gt; except that it does not involve executing any
code or potentially compiling a returned pattern string; instead it treats
the part of the current pattern contained within a specified capture group
as an independent pattern that must match at the current position. Also
different is the treatment of capture buffers, unlike C&lt;(??{ code })&gt;
recursive patterns have access to their caller's match state, so one can
use backreferences safely.

I&lt;PARNO&gt; is a sequence of digits (not starting with 0) whose value reflects
the paren-number of the capture group to recurse to. C&lt;(?R)&gt; recurses to
the beginning of the whole pattern. C&lt;(?0)&gt; is an alternate syntax for
C&lt;(?R)&gt;. If I&lt;PARNO&gt; is preceded by a plus or minus sign then it is assumed
to be relative, with negative numbers indicating preceding capture groups
and positive ones following. Thus C&lt;(?-1)&gt; refers to the most recently
declared group, and C&lt;(?+1)&gt; indicates the next group to be declared.
Note that the counting for relative recursion differs from that of
relative backreferences, in that with recursion unclosed groups B&lt;are&gt;
included.

The following pattern matches a function C&lt;foo()&gt; which may contain
balanced parentheses as the argument.

  $re = qr{ (                   # paren group 1 (full function)
              foo
              (                 # paren group 2 (parens)
                \(
                  (             # paren group 3 (contents of parens)
                  (?:
                   (?&gt; [^()]+ ) # Non-parens without backtracking
                  |
                   (?2)         # Recurse to start of paren group 2
                  )*
                  )
                \)
              )
            )
          }x;

If the pattern was used as follows

    'foo(bar(baz)+baz(bop))'=~/$re/
        and print &quot;\$1 = $1\n&quot;,
                  &quot;\$2 = $2\n&quot;,
                  &quot;\$3 = $3\n&quot;;

the output produced should be the following:

    $1 = foo(bar(baz)+baz(bop))
    $2 = (bar(baz)+baz(bop))
    $3 = bar(baz)+baz(bop)

If there is no corresponding capture group defined, then it is a
fatal error.  Recursing deeply without consuming any input string will
also result in a fatal error.  The depth at which that happens is
compiled into perl, so it can be changed with a custom build.

The following shows how using negative indexing can make it
easier to embed recursive patterns inside of a C&lt;qr//&gt; construct
for later use:

    my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
    if (/foo $parens \s+ \+ \s+ bar $parens/x) {
       # do something here...
    }

B&lt;Note&gt; that this pattern does not behave the same way as the equivalent
PCRE or Python construct of the same form. In Perl you can backtrack into
a recursed group, in PCRE and Python the recursed into group is treated
as atomic. Also, modifiers are resolved at compile time, so constructs
like C&lt;(?i:(?1))&gt; or C&lt;(?:(?i)(?1))&gt; do not affect how the sub-pattern will
be processed.

=item C&lt;(?&amp;NAME)&gt;
X&lt;(?&amp;NAME)&gt;

Recurse to a named subpattern. Identical to C&lt;(?I&lt;PARNO&gt;)&gt; except that the
parenthesis to recurse to is determined by name. If multiple parentheses have
the same name, then it recurses to the leftmost.

It is an error to refer to a name that is not declared somewhere in the
pattern.

B&lt;NOTE:&gt; In order to make things easier for programmers with experience
with the Python or PCRE regex engines the pattern C&lt;&lt; (?P&gt;NAME) &gt;&gt;
may be used instead of C&lt;&lt; (?&amp;NAME) &gt;&gt;.

=item C&lt;(?(condition)yes-pattern|no-pattern)&gt;
X&lt;(?()&gt;

=item C&lt;(?(condition)yes-pattern)&gt;

Conditional expression. Matches C&lt;yes-pattern&gt; if C&lt;condition&gt; yields
a true value, matches C&lt;no-pattern&gt; otherwise. A missing pattern always
matches.

C&lt;(condition)&gt; should be one of:

=over 4

=item an integer in parentheses

(which is valid if the corresponding pair of parentheses
matched);

=item a lookahead/lookbehind/evaluate zero-width assertion;

=item a name in angle brackets or single quotes

(which is valid if a group with the given name matched);

=item the special symbol C&lt;(R)&gt;

(true when evaluated inside of recursion or eval).  Additionally the
C&lt;&quot;R&quot;&gt; may be
followed by a number, (which will be true when evaluated when recursing
inside of the appropriate group), or by C&lt;&amp;NAME&gt;, in which case it will
be true only when evaluated during recursion in the named group.

=back

Here's a summary of the possible predicates:

=over 4

=item C&lt;(1)&gt; C&lt;(2)&gt; ...

Checks if the numbered capturing group has matched something.
Full syntax: C&lt;&lt; (?(1)then|else) &gt;&gt;

=item C&lt;(E&lt;lt&gt;I&lt;NAME&gt;E&lt;gt&gt;)&gt; C&lt;('I&lt;NAME&gt;')&gt;

Checks if a group with the given name has matched something.
Full syntax: C&lt;&lt; (?(&lt;name&gt;)then|else) &gt;&gt;

=item C&lt;(?=...)&gt; C&lt;(?!...)&gt; C&lt;(?&lt;=...)&gt; C&lt;(?&lt;!...)&gt;

Checks whether the pattern matches (or does not match, for the C&lt;&quot;!&quot;&gt;
variants).
Full syntax: C&lt;&lt; (?(?=lookahead)then|else) &gt;&gt;

=item C&lt;(?{ I&lt;CODE&gt; })&gt;

Treats the return value of the code block as the condition.
Full syntax: C&lt;&lt; (?(?{ code })then|else) &gt;&gt;

=item C&lt;(R)&gt;

Checks if the expression has been evaluated inside of recursion.
Full syntax: C&lt;&lt; (?(R)then|else) &gt;&gt;

=item C&lt;(R1)&gt; C&lt;(R2)&gt; ...

Checks if the expression has been evaluated while executing directly
inside of the n-th capture group. This check is the regex equivalent of

  if ((caller(0))[3] eq 'subname') { ... }

In other words, it does not check the full recursion stack.

Full syntax: C&lt;&lt; (?(R1)then|else) &gt;&gt;

=item C&lt;(R&amp;I&lt;NAME&gt;)&gt;

Similar to C&lt;(R1)&gt;, this predicate checks to see if we're executing
directly inside of the leftmost group with a given name (this is the same
logic used by C&lt;(?&amp;I&lt;NAME&gt;)&gt; to disambiguate). It does not check the full
stack, but only the name of the innermost active recursion.
Full syntax: C&lt;&lt; (?(R&amp;name)then|else) &gt;&gt;

=item C&lt;(DEFINE)&gt;

In this case, the yes-pattern is never directly executed, and no
no-pattern is allowed. Similar in spirit to C&lt;(?{0})&gt; but more efficient.
See below for details.
Full syntax: C&lt;&lt; (?(DEFINE)definitions...) &gt;&gt;

=back

For example:

    m{ ( \( )?
       [^()]+
       (?(1) \) )
     }x

matches a chunk of non-parentheses, possibly included in parentheses
themselves.

A special form is the C&lt;(DEFINE)&gt; predicate, which never executes its
yes-pattern directly, and does not allow a no-pattern. This allows one to
define subpatterns which will be executed only by the recursion mechanism.
This way, you can define a set of regular expression rules that can be
bundled into any pattern you choose.

It is recommended that for this usage you put the DEFINE block at the
end of the pattern, and that you name any subpatterns defined within it.

Also, it's worth noting that patterns defined this way probably will
not be as efficient, as the optimizer is not very clever about
handling them.

An example of how this might be used is as follows:

  /(?&lt;NAME&gt;(?&amp;NAME_PAT))(?&lt;ADDR&gt;(?&amp;ADDRESS_PAT))
   (?(DEFINE)
     (?&lt;NAME_PAT&gt;....)
     (?&lt;ADDRESS_PAT&gt;....)
   )/x

Note that capture groups matched inside of recursion are not accessible
after the recursion returns, so the extra layer of capturing groups is
necessary. Thus C&lt;$+{NAME_PAT}&gt; would not be defined even though
C&lt;$+{NAME}&gt; would be.

Finally, keep in mind that subpatterns created inside a DEFINE block
count towards the absolute and relative number of captures, so this:

    my @captures = &quot;a&quot; =~ /(.)                  # First capture
                           (?(DEFINE)
                               (?&lt;EXAMPLE&gt; 1 )  # Second capture
                           )/x;
    say scalar @captures;

Will output 2, not 1. This is particularly important if you intend to
compile the definitions with the C&lt;qr//&gt; operator, and later
interpolate them in another pattern.

=item C&lt;&lt; (?&gt;pattern) &gt;&gt;
X&lt;backtrack&gt; X&lt;backtracking&gt; X&lt;atomic&gt; X&lt;possessive&gt;

An &quot;independent&quot; subexpression, one which matches the substring
that a I&lt;standalone&gt; C&lt;pattern&gt; would match if anchored at the given
position, and it matches I&lt;nothing other than this substring&gt;.  This
construct is useful for optimizations of what would otherwise be
&quot;eternal&quot; matches, because it will not backtrack (see L&lt;/&quot;Backtracking&quot;&gt;).
It may also be useful in places where the &quot;grab all you can, and do not
give anything back&quot; semantic is desirable.

For example: C&lt;&lt; ^(?&gt;a*)ab &gt;&gt; will never match, since C&lt;&lt; (?&gt;a*) &gt;&gt;
(anchored at the beginning of string, as above) will match I&lt;all&gt;
characters C&lt;&quot;a&quot;&gt; at the beginning of string, leaving no C&lt;&quot;a&quot;&gt; for
C&lt;ab&gt; to match.  In contrast, C&lt;a*ab&gt; will match the same as C&lt;a+b&gt;,
since the match of the subgroup C&lt;a*&gt; is influenced by the following
group C&lt;ab&gt; (see L&lt;/&quot;Backtracking&quot;&gt;).  In particular, C&lt;a*&gt; inside
C&lt;a*ab&gt; will match fewer characters than a standalone C&lt;a*&gt;, since
this makes the tail match.

C&lt;&lt; (?&gt;pattern) &gt;&gt; does not disable backtracking altogether once it has
matched. It is still possible to backtrack past the construct, but not
into it. So C&lt;&lt; ((?&gt;a*)|(?&gt;b*))ar &gt;&gt; will still match &quot;bar&quot;.

An effect similar to C&lt;&lt; (?&gt;pattern) &gt;&gt; may be achieved by writing
C&lt;(?=(pattern))\g{-1}&gt;.  This matches the same substring as a standalone
C&lt;a+&gt;, and the following C&lt;\g{-1}&gt; eats the matched string; it therefore
makes a zero-length assertion into an analogue of C&lt;&lt; (?&gt;...) &gt;&gt;.
(The difference between these two constructs is that the second one
uses a capturing group, thus shifting ordinals of backreferences
in the rest of a regular expression.)

Consider this pattern:

    m{ \(
          (
            [^()]+           # x+
          |
            \( [^()]* \)
          )+
       \)
     }x

That will efficiently match a nonempty group with matching parentheses
two levels deep or less.  However, if there is no such group, it
will take virtually forever on a long string.  That's because there
are so many different ways to split a long string into several
substrings.  This is what C&lt;(.+)+&gt; is doing, and C&lt;(.+)+&gt; is similar
to a subpattern of the above pattern.  Consider how the pattern
above detects no-match on C&lt;((()aaaaaaaaaaaaaaaaaa&gt; in several
seconds, but that each extra letter doubles this time.  This
exponential performance will make it appear that your program has
hung.  However, a tiny change to this pattern

    m{ \(
          (
            (?&gt; [^()]+ )        # change x+ above to (?&gt; x+ )
          |
            \( [^()]* \)
          )+
       \)
     }x

which uses C&lt;&lt; (?&gt;...) &gt;&gt; matches exactly when the one above does (verifying
this yourself would be a productive exercise), but finishes in a fourth
the time when used on a similar string with 1000000 C&lt;&quot;a&quot;&gt;s.  Be aware,
however, that, when this construct is followed by a
quantifier, it currently triggers a warning message under
the C&lt;use warnings&gt; pragma or B&lt;-w&gt; switch saying it
C&lt;&quot;matches null string many times in regex&quot;&gt;.

On simple groups, such as the pattern C&lt;&lt; (?&gt; [^()]+ ) &gt;&gt;, a comparable
effect may be achieved by negative lookahead, as in C&lt;[^()]+ (?! [^()] )&gt;.
This was only 4 times slower on a string with 1000000 C&lt;&quot;a&quot;&gt;s.

The &quot;grab all you can, and do not give anything back&quot; semantic is desirable
in many situations where on the first sight a simple C&lt;()*&gt; looks like
the correct solution.  Suppose we parse text with comments being delimited
by C&lt;&quot;#&quot;&gt; followed by some optional (horizontal) whitespace.  Contrary to
its appearance, C&lt;#[ \t]*&gt; I&lt;is not&gt; the correct subexpression to match
the comment delimiter, because it may &quot;give up&quot; some whitespace if
the remainder of the pattern can be made to match that way.  The correct
answer is either one of these:

    (?&gt;#[ \t]*)
    #[ \t]*(?![ \t])

For example, to grab non-empty comments into C&lt;$1&gt;, one should use either
one of these:

    / (?&gt; \# [ \t]* ) (        .+ ) /x;
    /     \# [ \t]*   ( [^ \t] .* ) /x;

Which one you pick depends on which of these expressions better reflects
the above specification of comments.

In some literature this construct is called &quot;atomic matching&quot; or
&quot;possessive matching&quot;.

Possessive quantifiers are equivalent to putting the item they are applied
to inside of one of these constructs. The following equivalences apply:

    Quantifier Form     Bracketing Form
    ---------------     ---------------
    PAT*+               (?&gt;PAT*)
    PAT++               (?&gt;PAT+)
    PAT?+               (?&gt;PAT?)
    PAT{min,max}+       (?&gt;PAT{min,max})

=item C&lt;(?[ ])&gt;

See L&lt;perlrecharclass/Extended Bracketed Character Classes&gt;.

Note that this feature is currently L&lt;experimental|perlpolicy/experimental&gt;;
using it yields a warning in the C&lt;experimental::regex_sets&gt; category.

=back

=head2 Backtracking
X&lt;backtrack&gt; X&lt;backtracking&gt;

NOTE: This section presents an abstract approximation of regular
expression behavior.  For a more rigorous (and complicated) view of
the rules involved in selecting a match among possible alternatives,
see L&lt;/Combining RE Pieces&gt;.

A fundamental feature of regular expression matching involves the
notion called I&lt;backtracking&gt;, which is currently used (when needed)
by all regular non-possessive expression quantifiers, namely C&lt;&quot;*&quot;&gt;, C&lt;*?&gt;, C&lt;&quot;+&quot;&gt;,
C&lt;+?&gt;, C&lt;{n,m}&gt;, and C&lt;{n,m}?&gt;.  Backtracking is often optimized
internally, but the general principle outlined here is valid.

For a regular expression to match, the I&lt;entire&gt; regular expression must
match, not just part of it.  So if the beginning of a pattern containing a
quantifier succeeds in a way that causes later parts in the pattern to
fail, the matching engine backs up and recalculates the beginning
part--that's why it's called backtracking.

Here is an example of backtracking:  Let's say you want to find the
word following &quot;foo&quot; in the string &quot;Food is on the foo table.&quot;:

    $_ = &quot;Food is on the foo table.&quot;;
    if ( /\b(foo)\s+(\w+)/i ) {
        print &quot;$2 follows $1.\n&quot;;
    }

When the match runs, the first part of the regular expression (C&lt;\b(foo)&gt;)
finds a possible match right at the beginning of the string, and loads up
C&lt;$1&gt; with &quot;Foo&quot;.  However, as soon as the matching engine sees that there's
no whitespace following the &quot;Foo&quot; that it had saved in C&lt;$1&gt;, it realizes its
mistake and starts over again one character after where it had the
tentative match.  This time it goes all the way until the next occurrence
of &quot;foo&quot;. The complete regular expression matches this time, and you get
the expected output of &quot;table follows foo.&quot;

Sometimes minimal matching can help a lot.  Imagine you'd like to match
everything between &quot;foo&quot; and &quot;bar&quot;.  Initially, you write something
like this:

    $_ =  &quot;The food is under the bar in the barn.&quot;;
    if ( /foo(.*)bar/ ) {
        print &quot;got &lt;$1&gt;\n&quot;;
    }

Which perhaps unexpectedly yields:

  got &lt;d is under the bar in the &gt;

That's because C&lt;.*&gt; was greedy, so you get everything between the
I&lt;first&gt; &quot;foo&quot; and the I&lt;last&gt; &quot;bar&quot;.  Here it's more effective
to use minimal matching to make sure you get the text between a &quot;foo&quot;
and the first &quot;bar&quot; thereafter.

    if ( /foo(.*?)bar/ ) { print &quot;got &lt;$1&gt;\n&quot; }
  got &lt;d is under the &gt;

Here's another example. Let's say you'd like to match a number at the end
of a string, and you also want to keep the preceding part of the match.
So you write this:

    $_ = &quot;I have 2 numbers: 53147&quot;;
    if ( /(.*)(\d*)/ ) {                                # Wrong!
        print &quot;Beginning is &lt;$1&gt;, number is &lt;$2&gt;.\n&quot;;
    }

That won't work at all, because C&lt;.*&gt; was greedy and gobbled up the
whole string. As C&lt;\d*&gt; can match on an empty string the complete
regular expression matched successfully.

    Beginning is &lt;I have 2 numbers: 53147&gt;, number is &lt;&gt;.

Here are some variants, most of which don't work:

    $_ = &quot;I have 2 numbers: 53147&quot;;
    @pats = qw{
        (.*)(\d*)
        (.*)(\d+)
        (.*?)(\d*)
        (.*?)(\d+)
        (.*)(\d+)$
        (.*?)(\d+)$
        (.*)\b(\d+)$
        (.*\D)(\d+)$
    };

    for $pat (@pats) {
        printf &quot;%-12s &quot;, $pat;
        if ( /$pat/ ) {
            print &quot;&lt;$1&gt; &lt;$2&gt;\n&quot;;
        } else {
            print &quot;FAIL\n&quot;;
        }
    }

That will print out:

    (.*)(\d*)    &lt;I have 2 numbers: 53147&gt; &lt;&gt;
    (.*)(\d+)    &lt;I have 2 numbers: 5314&gt; &lt;7&gt;
    (.*?)(\d*)   &lt;&gt; &lt;&gt;
    (.*?)(\d+)   &lt;I have &gt; &lt;2&gt;
    (.*)(\d+)$   &lt;I have 2 numbers: 5314&gt; &lt;7&gt;
    (.*?)(\d+)$  &lt;I have 2 numbers: &gt; &lt;53147&gt;
    (.*)\b(\d+)$ &lt;I have 2 numbers: &gt; &lt;53147&gt;
    (.*\D)(\d+)$ &lt;I have 2 numbers: &gt; &lt;53147&gt;

As you see, this can be a bit tricky.  It's important to realize that a
regular expression is merely a set of assertions that gives a definition
of success.  There may be 0, 1, or several different ways that the
definition might succeed against a particular string.  And if there are
multiple ways it might succeed, you need to understand backtracking to
know which variety of success you will achieve.

When using lookahead assertions and negations, this can all get even
trickier.  Imagine you'd like to find a sequence of non-digits not
followed by &quot;123&quot;.  You might try to write that as

    $_ = &quot;ABC123&quot;;
    if ( /^\D*(?!123)/ ) {                # Wrong!
        print &quot;Yup, no 123 in $_\n&quot;;
    }

But that isn't going to match; at least, not the way you're hoping.  It
claims that there is no 123 in the string.  Here's a clearer picture of
why that pattern matches, contrary to popular expectations:

    $x = 'ABC123';
    $y = 'ABC445';

    print &quot;1: got $1\n&quot; if $x =~ /^(ABC)(?!123)/;
    print &quot;2: got $1\n&quot; if $y =~ /^(ABC)(?!123)/;

    print &quot;3: got $1\n&quot; if $x =~ /^(\D*)(?!123)/;
    print &quot;4: got $1\n&quot; if $y =~ /^(\D*)(?!123)/;

This prints

    2: got ABC
    3: got AB
    4: got ABC

You might have expected test 3 to fail because it seems to a more
general purpose version of test 1.  The important difference between
them is that test 3 contains a quantifier (C&lt;\D*&gt;) and so can use
backtracking, whereas test 1 will not.  What's happening is
that you've asked &quot;Is it true that at the start of C&lt;$x&gt;, following 0 or more
non-digits, you have something that's not 123?&quot;  If the pattern matcher had
let C&lt;\D*&gt; expand to &quot;ABC&quot;, this would have caused the whole pattern to
fail.

The search engine will initially match C&lt;\D*&gt; with &quot;ABC&quot;.  Then it will
try to match C&lt;(?!123)&gt; with &quot;123&quot;, which fails.  But because
a quantifier (C&lt;\D*&gt;) has been used in the regular expression, the
search engine can backtrack and retry the match differently
in the hope of matching the complete regular expression.

The pattern really, I&lt;really&gt; wants to succeed, so it uses the
standard pattern back-off-and-retry and lets C&lt;\D*&gt; expand to just &quot;AB&quot; this
time.  Now there's indeed something following &quot;AB&quot; that is not
&quot;123&quot;.  It's &quot;C123&quot;, which suffices.

We can deal with this by using both an assertion and a negation.
We'll say that the first part in C&lt;$1&gt; must be followed both by a digit
and by something that's not &quot;123&quot;.  Remember that the lookaheads
are zero-width expressions--they only look, but don't consume any
of the string in their match.  So rewriting this way produces what
you'd expect; that is, case 5 will fail, but case 6 succeeds:

    print &quot;5: got $1\n&quot; if $x =~ /^(\D*)(?=\d)(?!123)/;
    print &quot;6: got $1\n&quot; if $y =~ /^(\D*)(?=\d)(?!123)/;

    6: got ABC

In other words, the two zero-width assertions next to each other work as though
they're ANDed together, just as you'd use any built-in assertions:  C&lt;/^$/&gt;
matches only if you're at the beginning of the line AND the end of the
line simultaneously.  The deeper underlying truth is that juxtaposition in
regular expressions always means AND, except when you write an explicit OR
using the vertical bar.  C&lt;/ab/&gt; means match &quot;a&quot; AND (then) match &quot;b&quot;,
although the attempted matches are made at different positions because &quot;a&quot;
is not a zero-width assertion, but a one-width assertion.

B&lt;WARNING&gt;: Particularly complicated regular expressions can take
exponential time to solve because of the immense number of possible
ways they can use backtracking to try for a match.  For example, without
internal optimizations done by the regular expression engine, this will
take a painfully long time to run:

    'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/

And if you used C&lt;&quot;*&quot;&gt;'s in the internal groups instead of limiting them
to 0 through 5 matches, then it would take forever--or until you ran
out of stack space.  Moreover, these internal optimizations are not
always applicable.  For example, if you put C&lt;{0,5}&gt; instead of C&lt;&quot;*&quot;&gt;
on the external group, no current optimization is applicable, and the
match takes a long time to finish.

A powerful tool for optimizing such beasts is what is known as an
&quot;independent group&quot;,
which does not backtrack (see L&lt;/C&lt;&lt; (?&gt;pattern) &gt;&gt;&gt;).  Note also that
zero-length lookahead/lookbehind assertions will not backtrack to make
the tail match, since they are in &quot;logical&quot; context: only
whether they match is considered relevant.  For an example
where side-effects of lookahead I&lt;might&gt; have influenced the
following match, see L&lt;/C&lt;&lt; (?&gt;pattern) &gt;&gt;&gt;.

=head2 Special Backtracking Control Verbs

These special patterns are generally of the form C&lt;(*I&lt;VERB&gt;:I&lt;ARG&gt;)&gt;. Unless
otherwise stated the I&lt;ARG&gt; argument is optional; in some cases, it is
mandatory.

Any pattern containing a special backtracking verb that allows an argument
has the special behaviour that when executed it sets the current package's
C&lt;$REGERROR&gt; and C&lt;$REGMARK&gt; variables. When doing so the following
rules apply:

On failure, the C&lt;$REGERROR&gt; variable will be set to the I&lt;ARG&gt; value of the
verb pattern, if the verb was involved in the failure of the match. If the
I&lt;ARG&gt; part of the pattern was omitted, then C&lt;$REGERROR&gt; will be set to the
name of the last C&lt;(*MARK:NAME)&gt; pattern executed, or to TRUE if there was
none. Also, the C&lt;$REGMARK&gt; variable will be set to FALSE.

On a successful match, the C&lt;$REGERROR&gt; variable will be set to FALSE, and
the C&lt;$REGMARK&gt; variable will be set to the name of the last
C&lt;(*MARK:NAME)&gt; pattern executed.  See the explanation for the
C&lt;(*MARK:NAME)&gt; verb below for more details.

B&lt;NOTE:&gt; C&lt;$REGERROR&gt; and C&lt;$REGMARK&gt; are not magic variables like C&lt;$1&gt;
and most other regex-related variables. They are not local to a scope, nor
readonly, but instead are volatile package variables similar to C&lt;$AUTOLOAD&gt;.
They are set in the package containing the code that I&lt;executed&gt; the regex
(rather than the one that compiled it, where those differ).  If necessary, you
can use C&lt;local&gt; to localize changes to these variables to a specific scope
before executing a regex.

If a pattern does not contain a special backtracking verb that allows an
argument, then C&lt;$REGERROR&gt; and C&lt;$REGMARK&gt; are not touched at all.

=over 3

=item Verbs

=over 4

=item C&lt;(*PRUNE)&gt; C&lt;(*PRUNE:NAME)&gt;
X&lt;(*PRUNE)&gt; X&lt;(*PRUNE:NAME)&gt;

This zero-width pattern prunes the backtracking tree at the current point
when backtracked into on failure. Consider the pattern C&lt;/I&lt;A&gt; (*PRUNE) I&lt;B&gt;/&gt;,
where I&lt;A&gt; and I&lt;B&gt; are complex patterns. Until the C&lt;(*PRUNE)&gt; verb is reached,
I&lt;A&gt; may backtrack as necessary to match. Once it is reached, matching
continues in I&lt;B&gt;, which may also backtrack as necessary; however, should B
not match, then no further backtracking will take place, and the pattern
will fail outright at the current starting position.

The following example counts all the possible matching strings in a
pattern (without actually matching any of them).

    'aaab' =~ /a+b?(?{print &quot;$&amp;\n&quot;; $count++})(*FAIL)/;
    print &quot;Count=$count\n&quot;;

which produces:

    aaab
    aaa
    aa
    a
    aab
    aa
    a
    ab
    a
    Count=9

If we add a C&lt;(*PRUNE)&gt; before the count like the following

    'aaab' =~ /a+b?(*PRUNE)(?{print &quot;$&amp;\n&quot;; $count++})(*FAIL)/;
    print &quot;Count=$count\n&quot;;

we prevent backtracking and find the count of the longest matching string
at each matching starting point like so:

    aaab
    aab
    ab
    Count=3

Any number of C&lt;(*PRUNE)&gt; assertions may be used in a pattern.

See also C&lt;&lt;&lt; L&lt;&lt; /(?&gt;pattern) &gt;&gt; &gt;&gt;&gt; and possessive quantifiers for
other ways to
control backtracking. In some cases, the use of C&lt;(*PRUNE)&gt; can be
replaced with a C&lt;&lt; (?&gt;pattern) &gt;&gt; with no functional difference; however,
C&lt;(*PRUNE)&gt; can be used to handle cases that cannot be expressed using a
C&lt;&lt; (?&gt;pattern) &gt;&gt; alone.

=item C&lt;(*SKIP)&gt; C&lt;(*SKIP:NAME)&gt;
X&lt;(*SKIP)&gt;

This zero-width pattern is similar to C&lt;(*PRUNE)&gt;, except that on
failure it also signifies that whatever text that was matched leading up
to the C&lt;(*SKIP)&gt; pattern being executed cannot be part of I&lt;any&gt; match
of this pattern. This effectively means that the regex engine &quot;skips&quot; forward
to this position on failure and tries to match again, (assuming that
there is sufficient room to match).

The name of the C&lt;(*SKIP:NAME)&gt; pattern has special significance. If a
C&lt;(*MARK:NAME)&gt; was encountered while matching, then it is that position
which is used as the &quot;skip point&quot;. If no C&lt;(*MARK)&gt; of that name was
encountered, then the C&lt;(*SKIP)&gt; operator has no effect. When used
without a name the &quot;skip point&quot; is where the match point was when
executing the C&lt;(*SKIP)&gt; pattern.

Compare the following to the examples in C&lt;(*PRUNE)&gt;; note the string
is twice as long:

 'aaabaaab' =~ /a+b?(*SKIP)(?{print &quot;$&amp;\n&quot;; $count++})(*FAIL)/;
 print &quot;Count=$count\n&quot;;

outputs

    aaab
    aaab
    Count=2

Once the 'aaab' at the start of the string has matched, and the C&lt;(*SKIP)&gt;
executed, the next starting point will be where the cursor was when the
C&lt;(*SKIP)&gt; was executed.

=item C&lt;(*MARK:NAME)&gt; C&lt;(*:NAME)&gt;
X&lt;(*MARK)&gt; X&lt;(*MARK:NAME)&gt; X&lt;(*:NAME)&gt;

This zero-width pattern can be used to mark the point reached in a string
when a certain part of the pattern has been successfully matched. This
mark may be given a name. A later C&lt;(*SKIP)&gt; pattern will then skip
forward to that point if backtracked into on failure. Any number of
C&lt;(*MARK)&gt; patterns are allowed, and the I&lt;NAME&gt; portion may be duplicated.

In addition to interacting with the C&lt;(*SKIP)&gt; pattern, C&lt;(*MARK:NAME)&gt;
can be used to &quot;label&quot; a pattern branch, so that after matching, the
program can determine which branches of the pattern were involved in the
match.

When a match is successful, the C&lt;$REGMARK&gt; variable will be set to the
name of the most recently executed C&lt;(*MARK:NAME)&gt; that was involved
in the match.

This can be used to determine which branch of a pattern was matched
without using a separate capture group for each branch, which in turn
can result in a performance improvement, as perl cannot optimize
C&lt;/(?:(x)|(y)|(z))/&gt; as efficiently as something like
C&lt;/(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/&gt;.

When a match has failed, and unless another verb has been involved in
failing the match and has provided its own name to use, the C&lt;$REGERROR&gt;
variable will be set to the name of the most recently executed
C&lt;(*MARK:NAME)&gt;.

See L&lt;/(*SKIP)&gt; for more details.

As a shortcut C&lt;(*MARK:NAME)&gt; can be written C&lt;(*:NAME)&gt;.

=item C&lt;(*THEN)&gt; C&lt;(*THEN:NAME)&gt;

This is similar to the &quot;cut group&quot; operator C&lt;::&gt; from Perl 6.  Like
C&lt;(*PRUNE)&gt;, this verb always matches, and when backtracked into on
failure, it causes the regex engine to try the next alternation in the
innermost enclosing group (capturing or otherwise) that has alternations.
The two branches of a C&lt;(?(condition)yes-pattern|no-pattern)&gt; do not
count as an alternation, as far as C&lt;(*THEN)&gt; is concerned.

Its name comes from the observation that this operation combined with the
alternation operator (C&lt;&quot;|&quot;&gt;) can be used to create what is essentially a
pattern-based if/then/else block:

  ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )

Note that if this operator is used and NOT inside of an alternation then
it acts exactly like the C&lt;(*PRUNE)&gt; operator.

  / A (*PRUNE) B /

is the same as

  / A (*THEN) B /

but

  / ( A (*THEN) B | C ) /

is not the same as

  / ( A (*PRUNE) B | C ) /

as after matching the I&lt;A&gt; but failing on the I&lt;B&gt; the C&lt;(*THEN)&gt; verb will
backtrack and try I&lt;C&gt;; but the C&lt;(*PRUNE)&gt; verb will simply fail.

=item C&lt;(*COMMIT)&gt; C&lt;(*COMMIT:args)&gt;
X&lt;(*COMMIT)&gt;

This is the Perl 6 &quot;commit pattern&quot; C&lt;&lt; &lt;commit&gt; &gt;&gt; or C&lt;:::&gt;. It's a
zero-width pattern similar to C&lt;(*SKIP)&gt;, except that when backtracked
into on failure it causes the match to fail outright. No further attempts
to find a valid match by advancing the start pointer will occur again.
For example,

 'aaabaaab' =~ /a+b?(*COMMIT)(?{print &quot;$&amp;\n&quot;; $count++})(*FAIL)/;
 print &quot;Count=$count\n&quot;;

outputs

    aaab
    Count=1

In other words, once the C&lt;(*COMMIT)&gt; has been entered, and if the pattern
does not match, the regex engine will not try any further matching on the
rest of the string.

=item C&lt;(*FAIL)&gt; C&lt;(*F)&gt; C&lt;(*FAIL:arg)&gt;
X&lt;(*FAIL)&gt; X&lt;(*F)&gt;

This pattern matches nothing and always fails. It can be used to force the
engine to backtrack. It is equivalent to C&lt;(?!)&gt;, but easier to read. In
fact, C&lt;(?!)&gt; gets optimised into C&lt;(*FAIL)&gt; internally. You can provide
an argument so that if the match fails because of this C&lt;FAIL&gt; directive
the argument can be obtained from C&lt;$REGERROR&gt;.

It is probably useful only when combined with C&lt;(?{})&gt; or C&lt;(??{})&gt;.

=item C&lt;(*ACCEPT)&gt; C&lt;(*ACCEPT:arg)&gt;
X&lt;(*ACCEPT)&gt;

This pattern matches nothing and causes the end of successful matching at
the point at which the C&lt;(*ACCEPT)&gt; pattern was encountered, regardless of
whether there is actually more to match in the string. When inside of a
nested pattern, such as recursion, or in a subpattern dynamically generated
via C&lt;(??{})&gt;, only the innermost pattern is ended immediately.

If the C&lt;(*ACCEPT)&gt; is inside of capturing groups then the groups are
marked as ended at the point at which the C&lt;(*ACCEPT)&gt; was encountered.
For instance:

  'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;

will match, and C&lt;$1&gt; will be C&lt;AB&gt; and C&lt;$2&gt; will be C&lt;&quot;B&quot;&gt;, C&lt;$3&gt; will not
be set. If another branch in the inner parentheses was matched, such as in the
string 'ACDE', then the C&lt;&quot;D&quot;&gt; and C&lt;&quot;E&quot;&gt; would have to be matched as well.

You can provide an argument, which will be available in the var
C&lt;$REGMARK&gt; after the match completes.

=back

=back

=head2 Warning on C&lt;\1&gt; Instead of C&lt;$1&gt;

Some people get too used to writing things like:

    $pattern =~ s/(\W)/\\\1/g;

This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
shocking the
B&lt;sed&gt; addicts, but it's a dirty habit to get into.  That's because in
PerlThink, the righthand side of an C&lt;s///&gt; is a double-quoted string.  C&lt;\1&gt; in
the usual double-quoted string means a control-A.  The customary Unix
meaning of C&lt;\1&gt; is kludged in for C&lt;s///&gt;.  However, if you get into the habit
of doing that, you get yourself into trouble if you then add an C&lt;/e&gt;
modifier.

    s/(\d+)/ \1 + 1 /eg;            # causes warning under -w

Or if you try to do

    s/(\d+)/\1000/;

You can't disambiguate that by saying C&lt;\{1}000&gt;, whereas you can fix it with
C&lt;${1}000&gt;.  The operation of interpolation should not be confused
with the operation of matching a backreference.  Certainly they mean two
different things on the I&lt;left&gt; side of the C&lt;s///&gt;.

=head2 Repeated Patterns Matching a Zero-length Substring

B&lt;WARNING&gt;: Difficult material (and prose) ahead.  This section needs a rewrite.

Regular expressions provide a terse and powerful programming language.  As
with most other power tools, power comes together with the ability
to wreak havoc.

A common abuse of this power stems from the ability to make infinite
loops using regular expressions, with something as innocuous as:

    'foo' =~ m{ ( o? )* }x;

The C&lt;o?&gt; matches at the beginning of &quot;C&lt;foo&gt;&quot;, and since the position
in the string is not moved by the match, C&lt;o?&gt; would match again and again
because of the C&lt;&quot;*&quot;&gt; quantifier.  Another common way to create a similar cycle
is with the looping modifier C&lt;/g&gt;:

    @matches = ( 'foo' =~ m{ o? }xg );

or

    print &quot;match: &lt;$&amp;&gt;\n&quot; while 'foo' =~ m{ o? }xg;

or the loop implied by C&lt;split()&gt;.

However, long experience has shown that many programming tasks may
be significantly simplified by using repeated subexpressions that
may match zero-length substrings.  Here's a simple example being:

    @chars = split //, $string;           # // is not magic in split
    ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /

Thus Perl allows such constructs, by I&lt;forcefully breaking
the infinite loop&gt;.  The rules for this are different for lower-level
loops given by the greedy quantifiers C&lt;*+{}&gt;, and for higher-level
ones like the C&lt;/g&gt; modifier or C&lt;split()&gt; operator.

The lower-level loops are I&lt;interrupted&gt; (that is, the loop is
broken) when Perl detects that a repeated expression matched a
zero-length substring.   Thus

   m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;

is made equivalent to

   m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;

For example, this program

   #!perl -l
   &quot;aaaaab&quot; =~ /
     (?:
        a                 # non-zero
        |                 # or
       (?{print &quot;hello&quot;}) # print hello whenever this
                          #    branch is tried
       (?=(b))            # zero-width assertion
     )*  # any number of times
    /x;
   print $&amp;;
   print $1;

prints

   hello
   aaaaa
   b

Notice that &quot;hello&quot; is only printed once, as when Perl sees that the sixth
iteration of the outermost C&lt;(?:)*&gt; matches a zero-length string, it stops
the C&lt;&quot;*&quot;&gt;.

The higher-level loops preserve an additional state between iterations:
whether the last match was zero-length.  To break the loop, the following
match after a zero-length match is prohibited to have a length of zero.
This prohibition interacts with backtracking (see L&lt;/&quot;Backtracking&quot;&gt;),
and so the I&lt;second best&gt; match is chosen if the I&lt;best&gt; match is of
zero length.

For example:

    $_ = 'bar';
    s/\w??/&lt;$&amp;&gt;/g;

results in C&lt;&lt; &lt;&gt;&lt;b&gt;&lt;&gt;&lt;a&gt;&lt;&gt;&lt;r&gt;&lt;&gt; &gt;&gt;.  At each position of the string the best
match given by non-greedy C&lt;??&gt; is the zero-length match, and the I&lt;second
best&gt; match is what is matched by C&lt;\w&gt;.  Thus zero-length matches
alternate with one-character-long matches.

Similarly, for repeated C&lt;m/()/g&gt; the second-best match is the match at the
position one notch further in the string.

The additional state of being I&lt;matched with zero-length&gt; is associated with
the matched string, and is reset by each assignment to C&lt;pos()&gt;.
Zero-length matches at the end of the previous match are ignored
during C&lt;split&gt;.

=head2 Combining RE Pieces

Each of the elementary pieces of regular expressions which were described
before (such as C&lt;ab&gt; or C&lt;\Z&gt;) could match at most one substring
at the given position of the input string.  However, in a typical regular
expression these elementary pieces are combined into more complicated
patterns using combining operators C&lt;ST&gt;, C&lt;S|T&gt;, C&lt;S*&gt; I&lt;etc&gt;.
(in these examples C&lt;&quot;S&quot;&gt; and C&lt;&quot;T&quot;&gt; are regular subexpressions).

Such combinations can include alternatives, leading to a problem of choice:
if we match a regular expression C&lt;a|ab&gt; against C&lt;&quot;abc&quot;&gt;, will it match
substring C&lt;&quot;a&quot;&gt; or C&lt;&quot;ab&quot;&gt;?  One way to describe which substring is
actually matched is the concept of backtracking (see L&lt;/&quot;Backtracking&quot;&gt;).
However, this description is too low-level and makes you think
in terms of a particular implementation.

Another description starts with notions of &quot;better&quot;/&quot;worse&quot;.  All the
substrings which may be matched by the given regular expression can be
sorted from the &quot;best&quot; match to the &quot;worst&quot; match, and it is the &quot;best&quot;
match which is chosen.  This substitutes the question of &quot;what is chosen?&quot;
by the question of &quot;which matches are better, and which are worse?&quot;.

Again, for elementary pieces there is no such question, since at most
one match at a given position is possible.  This section describes the
notion of better/worse for combining operators.  In the description
below C&lt;&quot;S&quot;&gt; and C&lt;&quot;T&quot;&gt; are regular subexpressions.

=over 4

=item C&lt;ST&gt;

Consider two possible matches, C&lt;AB&gt; and C&lt;A'B'&gt;, C&lt;&quot;A&quot;&gt; and C&lt;A'&gt; are
substrings which can be matched by C&lt;&quot;S&quot;&gt;, C&lt;&quot;B&quot;&gt; and C&lt;B'&gt; are substrings
which can be matched by C&lt;&quot;T&quot;&gt;.

If C&lt;&quot;A&quot;&gt; is a better match for C&lt;&quot;S&quot;&gt; than C&lt;A'&gt;, C&lt;AB&gt; is a better
match than C&lt;A'B'&gt;.

If C&lt;&quot;A&quot;&gt; and C&lt;A'&gt; coincide: C&lt;AB&gt; is a better match than C&lt;AB'&gt; if
C&lt;&quot;B&quot;&gt; is a better match for C&lt;&quot;T&quot;&gt; than C&lt;B'&gt;.

=item C&lt;S|T&gt;

When C&lt;&quot;S&quot;&gt; can match, it is a better match than when only C&lt;&quot;T&quot;&gt; can match.

Ordering of two matches for C&lt;&quot;S&quot;&gt; is the same as for C&lt;&quot;S&quot;&gt;.  Similar for
two matches for C&lt;&quot;T&quot;&gt;.

=item C&lt;S{REPEAT_COUNT}&gt;

Matches as C&lt;SSS...S&gt; (repeated as many times as necessary).

=item C&lt;S{min,max}&gt;

Matches as C&lt;S{max}|S{max-1}|...|S{min+1}|S{min}&gt;.

=item C&lt;S{min,max}?&gt;

Matches as C&lt;S{min}|S{min+1}|...|S{max-1}|S{max}&gt;.

=item C&lt;S?&gt;, C&lt;S*&gt;, C&lt;S+&gt;

Same as C&lt;S{0,1}&gt;, C&lt;S{0,BIG_NUMBER}&gt;, C&lt;S{1,BIG_NUMBER}&gt; respectively.

=item C&lt;S??&gt;, C&lt;S*?&gt;, C&lt;S+?&gt;

Same as C&lt;S{0,1}?&gt;, C&lt;S{0,BIG_NUMBER}?&gt;, C&lt;S{1,BIG_NUMBER}?&gt; respectively.

=item C&lt;&lt; (?&gt;S) &gt;&gt;

Matches the best match for C&lt;&quot;S&quot;&gt; and only that.

=item C&lt;(?=S)&gt;, C&lt;(?&lt;=S)&gt;

Only the best match for C&lt;&quot;S&quot;&gt; is considered.  (This is important only if
C&lt;&quot;S&quot;&gt; has capturing parentheses, and backreferences are used somewhere
else in the whole regular expression.)

=item C&lt;(?!S)&gt;, C&lt;(?&lt;!S)&gt;

For this grouping operator there is no need to describe the ordering, since
only whether or not C&lt;&quot;S&quot;&gt; can match is important.

=item C&lt;(??{ EXPR })&gt;, C&lt;(?I&lt;PARNO&gt;)&gt;

The ordering is the same as for the regular expression which is
the result of EXPR, or the pattern contained by capture group I&lt;PARNO&gt;.

=item C&lt;(?(condition)yes-pattern|no-pattern)&gt;

Recall that which of C&lt;yes-pattern&gt; or C&lt;no-pattern&gt; actually matches is
already determined.  The ordering of the matches is the same as for the
chosen subexpression.

=back

The above recipes describe the ordering of matches I&lt;at a given position&gt;.
One more rule is needed to understand how a match is determined for the
whole regular expression: a match at an earlier position is always better
than a match at a later position.

=head2 Creating Custom RE Engines

As of Perl 5.10.0, one can create custom regular expression engines.  This
is not for the faint of heart, as they have to plug in at the C level.  See
L&lt;perlreapi&gt; for more details.

As an alternative, overloaded constants (see L&lt;overload&gt;) provide a simple
way to extend the functionality of the RE engine, by substituting one
pattern for another.

Suppose that we want to enable a new RE escape-sequence C&lt;\Y|&gt; which
matches at a boundary between whitespace characters and non-whitespace
characters.  Note that C&lt;(?=\S)(?&lt;!\S)|(?!\S)(?&lt;=\S)&gt; matches exactly
at these positions, so we want to have each C&lt;\Y|&gt; in the place of the
more complicated version.  We can create a module C&lt;customre&gt; to do
this:

    package customre;
    use overload;

    sub import {
      shift;
      die &quot;No argument to customre::import allowed&quot; if @_;
      overload::constant 'qr' =&gt; \&amp;convert;
    }

    sub invalid { die &quot;/$_[0]/: invalid escape '\\$_[1]'&quot;}

    # We must also take care of not escaping the legitimate \\Y|
    # sequence, hence the presence of '\\' in the conversion rules.
    my %rules = ( '\\' =&gt; '\\\\',
                  'Y|' =&gt; qr/(?=\S)(?&lt;!\S)|(?!\S)(?&lt;=\S)/ );
    sub convert {
      my $re = shift;
      $re =~ s{
                \\ ( \\ | Y . )
              }
              { $rules{$1} or invalid($re,$1) }sgex;
      return $re;
    }

Now C&lt;use customre&gt; enables the new escape in constant regular
expressions, I&lt;i.e.&gt;, those without any runtime variable interpolations.
As documented in L&lt;overload&gt;, this conversion will work only over
literal parts of regular expressions.  For C&lt;\Y|$re\Y|&gt; the variable
part of this regular expression needs to be converted explicitly
(but only if the special meaning of C&lt;\Y|&gt; should be enabled inside C&lt;$re&gt;):

    use customre;
    $re = &lt;&gt;;
    chomp $re;
    $re = customre::convert $re;
    /\Y|$re\Y|/;

=head2 Embedded Code Execution Frequency

The exact rules for how often C&lt;(??{})&gt; and C&lt;(?{})&gt; are executed in a pattern
are unspecified.  In the case of a successful match you can assume that
they DWIM and will be executed in left to right order the appropriate
number of times in the accepting path of the pattern as would any other
meta-pattern.  How non-accepting pathways and match failures affect the
number of times a pattern is executed is specifically unspecified and
may vary depending on what optimizations can be applied to the pattern
and is likely to change from version to version.

For instance in

  &quot;aaabcdeeeee&quot;=~/a(?{print &quot;a&quot;})b(?{print &quot;b&quot;})cde/;

the exact number of times &quot;a&quot; or &quot;b&quot; are printed out is unspecified for
failure, but you may assume they will be printed at least once during
a successful match, additionally you may assume that if &quot;b&quot; is printed,
it will be preceded by at least one &quot;a&quot;.

In the case of branching constructs like the following:

  /a(b|(?{ print &quot;a&quot; }))c(?{ print &quot;c&quot; })/;

you can assume that the input &quot;ac&quot; will output &quot;ac&quot;, and that &quot;abc&quot;
will output only &quot;c&quot;.

When embedded code is quantified, successful matches will call the
code once for each matched iteration of the quantifier.  For
example:

  &quot;good&quot; =~ /g(?:o(?{print &quot;o&quot;}))*d/;

will output &quot;o&quot; twice.

=head2 PCRE/Python Support

As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
to the regex syntax. While Perl programmers are encouraged to use the
Perl-specific syntax, the following are also accepted:

=over 4

=item C&lt;&lt; (?PE&lt;lt&gt;NAMEE&lt;gt&gt;pattern) &gt;&gt;

Define a named capture group. Equivalent to C&lt;&lt; (?&lt;NAME&gt;pattern) &gt;&gt;.

=item C&lt;&lt; (?P=NAME) &gt;&gt;

Backreference to a named capture group. Equivalent to C&lt;&lt; \g{NAME} &gt;&gt;.

=item C&lt;&lt; (?P&gt;NAME) &gt;&gt;

Subroutine call to a named capture group. Equivalent to C&lt;&lt; (?&amp;NAME) &gt;&gt;.

=back

=head1 BUGS

There are a number of issues with regard to case-insensitive matching
in Unicode rules.  See C&lt;&quot;i&quot;&gt; under L&lt;/Modifiers&gt; above.

This document varies from difficult to understand to completely
and utterly opaque.  The wandering prose riddled with jargon is
hard to fathom in several places.

This document needs a rewrite that separates the tutorial content
from the reference content.

=head1 SEE ALSO

The syntax of patterns used in Perl pattern matching evolved from those
supplied in the Bell Labs Research Unix 8th Edition (Version 8) regex
routines.  (The code is actually derived (distantly) from Henry
Spencer's freely redistributable reimplementation of those V8 routines.)

L&lt;perlrequick&gt;.

L&lt;perlretut&gt;.

L&lt;perlop/&quot;Regexp Quote-Like Operators&quot;&gt;.

L&lt;perlop/&quot;Gory details of parsing quoted constructs&quot;&gt;.

L&lt;perlfaq6&gt;.

L&lt;perlfunc/pos&gt;.

L&lt;perllocale&gt;.

L&lt;perlebcdic&gt;.

I&lt;Mastering Regular Expressions&gt; by Jeffrey Friedl, published
by O'Reilly and Associates.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>