<h2>Editing File: /usr/share/perl5/pod/perlpragma.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perlpragma - how to write a user pragma

=head1 DESCRIPTION

A pragma is a module which influences some aspect of the compile time or run
time behaviour of Perl, such as C&lt;strict&gt; or C&lt;warnings&gt;. With Perl 5.10 you
are no longer limited to the built in pragmata; you can now create user
pragmata that modify the behaviour of user functions within a lexical scope.

=head1 A basic example

For example, say you need to create a class implementing overloaded
mathematical operators, and would like to provide your own pragma that
functions much like C&lt;use integer;&gt; You'd like this code

    use MyMaths;

    my $l = MyMaths-&gt;new(1.2);
    my $r = MyMaths-&gt;new(3.4);

    print &quot;A: &quot;, $l + $r, &quot;\n&quot;;

    use myint;
    print &quot;B: &quot;, $l + $r, &quot;\n&quot;;

    {
        no myint;
        print &quot;C: &quot;, $l + $r, &quot;\n&quot;;
    }

    print &quot;D: &quot;, $l + $r, &quot;\n&quot;;

    no myint;
    print &quot;E: &quot;, $l + $r, &quot;\n&quot;;

to give the output

    A: 4.6
    B: 4
    C: 4.6
    D: 4
    E: 4.6

I&lt;i.e.&gt;, where C&lt;use myint;&gt; is in effect, addition operations are forced
to integer, whereas by default they are not, with the default behaviour being
restored via C&lt;no myint;&gt;

The minimal implementation of the package C&lt;MyMaths&gt; would be something like
this:

    package MyMaths;
    use warnings;
    use strict;
    use myint();
    use overload '+' =&gt; sub {
        my ($l, $r) = @_;
	# Pass 1 to check up one call level from here
        if (myint::in_effect(1)) {
            int($$l) + int($$r);
        } else {
            $$l + $$r;
        }
    };

    sub new {
        my ($class, $value) = @_;
        bless \$value, $class;
    }

    1;

Note how we load the user pragma C&lt;myint&gt; with an empty list C&lt;()&gt; to
prevent its C&lt;import&gt; being called.

The interaction with the Perl compilation happens inside package C&lt;myint&gt;:

    package myint;

    use strict;
    use warnings;

    sub import {
        $^H{&quot;myint/in_effect&quot;} = 1;
    }

    sub unimport {
        $^H{&quot;myint/in_effect&quot;} = 0;
    }

    sub in_effect {
        my $level = shift // 0;
        my $hinthash = (caller($level))[10];
        return $hinthash-&gt;{&quot;myint/in_effect&quot;};
    }

    1;

As pragmata are implemented as modules, like any other module, C&lt;use myint;&gt;
becomes

    BEGIN {
        require myint;
        myint-&gt;import();
    }

and C&lt;no myint;&gt; is

    BEGIN {
        require myint;
        myint-&gt;unimport();
    }

Hence the C&lt;import&gt; and C&lt;unimport&gt; routines are called at B&lt;compile time&gt;
for the user's code.

User pragmata store their state by writing to the magical hash C&lt;%^H&gt;,
hence these two routines manipulate it. The state information in C&lt;%^H&gt; is
stored in the optree, and can be retrieved read-only at runtime with C&lt;caller()&gt;,
at index 10 of the list of returned results. In the example pragma, retrieval
is encapsulated into the routine C&lt;in_effect()&gt;, which takes as parameter
the number of call frames to go up to find the value of the pragma in the
user's script. This uses C&lt;caller()&gt; to determine the value of
C&lt;$^H{&quot;myint/in_effect&quot;}&gt; when each line of the user's script was called, and
therefore provide the correct semantics in the subroutine implementing the
overloaded addition.

=head1 Key naming

There is only a single C&lt;%^H&gt;, but arbitrarily many modules that want
to use its scoping semantics.  To avoid stepping on each other's toes,
they need to be sure to use different keys in the hash.  It is therefore
conventional for a module to use only keys that begin with the module's
name (the name of its main package) and a &quot;/&quot; character.  After this
module-identifying prefix, the rest of the key is entirely up to the
module: it may include any characters whatsoever.  For example, a module
C&lt;Foo::Bar&gt; should use keys such as C&lt;Foo::Bar/baz&gt; and C&lt;Foo::Bar/$%/_!&gt;.
Modules following this convention all play nicely with each other.

The Perl core uses a handful of keys in C&lt;%^H&gt; which do not follow this
convention, because they predate it.  Keys that follow the convention
won't conflict with the core's historical keys.

=head1 Implementation details

The optree is shared between threads.  This means there is a possibility that
the optree will outlive the particular thread (and therefore the interpreter
instance) that created it, so true Perl scalars cannot be stored in the
optree.  Instead a compact form is used, which can only store values that are
integers (signed and unsigned), strings or C&lt;undef&gt; - references and
floating point values are stringified.  If you need to store multiple values
or complex structures, you should serialise them, for example with C&lt;pack&gt;.
The deletion of a hash key from C&lt;%^H&gt; is recorded, and as ever can be
distinguished from the existence of a key with value C&lt;undef&gt; with
C&lt;exists&gt;.

B&lt;Don't&gt; attempt to store references to data structures as integers which
are retrieved via C&lt;caller&gt; and converted back, as this will not be threadsafe.
Accesses would be to the structure without locking (which is not safe for
Perl's scalars), and either the structure has to leak, or it has to be
freed when its creating thread terminates, which may be before the optree
referencing it is deleted, if other threads outlive it.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>