<h2>Editing File: /usr/share/perl5/pod/perlootut.pod</h2><form method='post'><textarea name='content' class='file-edit'>=encoding utf8

=for comment
Consistent formatting of this file is achieved with:
  perl ./Porting/podtidy pod/perlootut.pod

=head1 NAME

perlootut - Object-Oriented Programming in Perl Tutorial

=head1 DATE

This document was created in February, 2011, and the last major
revision was in February, 2013.

If you are reading this in the future then it's possible that the state
of the art has changed. We recommend you start by reading the perlootut
document in the latest stable release of Perl, rather than this
version.

=head1 DESCRIPTION

This document provides an introduction to object-oriented programming
in Perl. It begins with a brief overview of the concepts behind object
oriented design. Then it introduces several different OO systems from
L&lt;CPAN|http://search.cpan.org&gt; which build on top of what Perl
provides.

By default, Perl's built-in OO system is very minimal, leaving you to
do most of the work. This minimalism made a lot of sense in 1994, but
in the years since Perl 5.0 we've seen a number of common patterns
emerge in Perl OO. Fortunately, Perl's flexibility has allowed a rich
ecosystem of Perl OO systems to flourish.

If you want to know how Perl OO works under the hood, the L&lt;perlobj&gt;
document explains the nitty gritty details.

This document assumes that you already understand the basics of Perl
syntax, variable types, operators, and subroutine calls. If you don't
understand these concepts yet, please read L&lt;perlintro&gt; first. You
should also read the L&lt;perlsyn&gt;, L&lt;perlop&gt;, and L&lt;perlsub&gt; documents.

=head1 OBJECT-ORIENTED FUNDAMENTALS

Most object systems share a number of common concepts. You've probably
heard terms like &quot;class&quot;, &quot;object, &quot;method&quot;, and &quot;attribute&quot; before.
Understanding the concepts will make it much easier to read and write
object-oriented code. If you're already familiar with these terms, you
should still skim this section, since it explains each concept in terms
of Perl's OO implementation.

Perl's OO system is class-based. Class-based OO is fairly common. It's
used by Java, C++, C#, Python, Ruby, and many other languages. There
are other object orientation paradigms as well. JavaScript is the most
popular language to use another paradigm. JavaScript's OO system is
prototype-based.

=head2 Object

An B&lt;object&gt; is a data structure that bundles together data and
subroutines which operate on that data. An object's data is called
B&lt;attributes&gt;, and its subroutines are called B&lt;methods&gt;. An object can
be thought of as a noun (a person, a web service, a computer).

An object represents a single discrete thing. For example, an object
might represent a file. The attributes for a file object might include
its path, content, and last modification time. If we created an object
to represent F&lt;/etc/hostname&gt; on a machine named &quot;foo.example.com&quot;,
that object's path would be &quot;/etc/hostname&quot;, its content would be
&quot;foo\n&quot;, and it's last modification time would be 1304974868 seconds
since the beginning of the epoch.

The methods associated with a file might include C&lt;rename()&gt; and
C&lt;write()&gt;.

In Perl most objects are hashes, but the OO systems we recommend keep
you from having to worry about this. In practice, it's best to consider
an object's internal data structure opaque.

=head2 Class

A B&lt;class&gt; defines the behavior of a category of objects. A class is a
name for a category (like &quot;File&quot;), and a class also defines the
behavior of objects in that category.

All objects belong to a specific class. For example, our
F&lt;/etc/hostname&gt; object belongs to the C&lt;File&gt; class. When we want to
create a specific object, we start with its class, and B&lt;construct&gt; or
B&lt;instantiate&gt; an object. A specific object is often referred to as an
B&lt;instance&gt; of a class.

In Perl, any package can be a class. The difference between a package
which is a class and one which isn't is based on how the package is
used. Here's our &quot;class declaration&quot; for the C&lt;File&gt; class:

  package File;

In Perl, there is no special keyword for constructing an object.
However, most OO modules on CPAN use a method named C&lt;new()&gt; to
construct a new object:

  my $hostname = File-&gt;new(
      path          =&gt; '/etc/hostname',
      content       =&gt; &quot;foo\n&quot;,
      last_mod_time =&gt; 1304974868,
  );

(Don't worry about that C&lt;&lt; -&gt; &gt;&gt; operator, it will be explained
later.)

=head3 Blessing

As we said earlier, most Perl objects are hashes, but an object can be
an instance of any Perl data type (scalar, array, etc.). Turning a
plain data structure into an object is done by B&lt;blessing&gt; that data
structure using Perl's C&lt;bless&gt; function.

While we strongly suggest you don't build your objects from scratch,
you should know the term B&lt;bless&gt;. A B&lt;blessed&gt; data structure (aka &quot;a
referent&quot;) is an object. We sometimes say that an object has been
&quot;blessed into a class&quot;.

Once a referent has been blessed, the C&lt;blessed&gt; function from the
L&lt;Scalar::Util&gt; core module can tell us its class name. This subroutine
returns an object's class when passed an object, and false otherwise.

  use Scalar::Util 'blessed';

  print blessed($hash);      # undef
  print blessed($hostname);  # File

=head3 Constructor

A B&lt;constructor&gt; creates a new object. In Perl, a class's constructor
is just another method, unlike some other languages, which provide
syntax for constructors. Most Perl classes use C&lt;new&gt; as the name for
their constructor:

  my $file = File-&gt;new(...);

=head2 Methods

You already learned that a B&lt;method&gt; is a subroutine that operates on
an object. You can think of a method as the things that an object can
I&lt;do&gt;. If an object is a noun, then methods are its verbs (save, print,
open).

In Perl, methods are simply subroutines that live in a class's package.
Methods are always written to receive the object as their first
argument:

  sub print_info {
      my $self = shift;

      print &quot;This file is at &quot;, $self-&gt;path, &quot;\n&quot;;
  }

  $file-&gt;print_info;
  # The file is at /etc/hostname

What makes a method special is I&lt;how it's called&gt;. The arrow operator
(C&lt;&lt; -&gt; &gt;&gt;) tells Perl that we are calling a method.

When we make a method call, Perl arranges for the method's B&lt;invocant&gt;
to be passed as the first argument. B&lt;Invocant&gt; is a fancy name for the
thing on the left side of the arrow. The invocant can either be a class
name or an object. We can also pass additional arguments to the method:

  sub print_info {
      my $self   = shift;
      my $prefix = shift // &quot;This file is at &quot;;

      print $prefix, &quot;, &quot;, $self-&gt;path, &quot;\n&quot;;
  }

  $file-&gt;print_info(&quot;The file is located at &quot;);
  # The file is located at /etc/hostname

=head2 Attributes

Each class can define its B&lt;attributes&gt;. When we instantiate an object,
we assign values to those attributes. For example, every C&lt;File&gt; object
has a path. Attributes are sometimes called B&lt;properties&gt;.

Perl has no special syntax for attributes. Under the hood, attributes
are often stored as keys in the object's underlying hash, but don't
worry about this.

We recommend that you only access attributes via B&lt;accessor&gt; methods.
These are methods that can get or set the value of each attribute. We
saw this earlier in the C&lt;print_info()&gt; example, which calls C&lt;&lt;
$self-&gt;path &gt;&gt;.

You might also see the terms B&lt;getter&gt; and B&lt;setter&gt;. These are two
types of accessors. A getter gets the attribute's value, while a setter
sets it. Another term for a setter is B&lt;mutator&gt;

Attributes are typically defined as read-only or read-write. Read-only
attributes can only be set when the object is first created, while
read-write attributes can be altered at any time.

The value of an attribute may itself be another object. For example,
instead of returning its last mod time as a number, the C&lt;File&gt; class
could return a L&lt;DateTime&gt; object representing that value.

It's possible to have a class that does not expose any publicly
settable attributes. Not every class has attributes and methods.

=head2 Polymorphism

B&lt;Polymorphism&gt; is a fancy way of saying that objects from two
different classes share an API. For example, we could have C&lt;File&gt; and
C&lt;WebPage&gt; classes which both have a C&lt;print_content()&gt; method. This
method might produce different output for each class, but they share a
common interface.

While the two classes may differ in many ways, when it comes to the
C&lt;print_content()&gt; method, they are the same. This means that we can
try to call the C&lt;print_content()&gt; method on an object of either class,
and B&lt;we don't have to know what class the object belongs to!&gt;

Polymorphism is one of the key concepts of object-oriented design.

=head2 Inheritance

B&lt;Inheritance&gt; lets you create a specialized version of an existing
class. Inheritance lets the new class reuse the methods and attributes
of another class.

For example, we could create an C&lt;File::MP3&gt; class which B&lt;inherits&gt;
from C&lt;File&gt;. An C&lt;File::MP3&gt; B&lt;is-a&gt; I&lt;more specific&gt; type of C&lt;File&gt;.
All mp3 files are files, but not all files are mp3 files.

We often refer to inheritance relationships as B&lt;parent-child&gt; or
C&lt;superclass&gt;/C&lt;subclass&gt; relationships. Sometimes we say that the
child has an B&lt;is-a&gt; relationship with its parent class.

C&lt;File&gt; is a B&lt;superclass&gt; of C&lt;File::MP3&gt;, and C&lt;File::MP3&gt; is a
B&lt;subclass&gt; of C&lt;File&gt;.

  package File::MP3;

  use parent 'File';

The L&lt;parent&gt; module is one of several ways that Perl lets you define
inheritance relationships.

Perl allows multiple inheritance, which means that a class can inherit
from multiple parents. While this is possible, we strongly recommend
against it. Generally, you can use B&lt;roles&gt; to do everything you can do
with multiple inheritance, but in a cleaner way.

Note that there's nothing wrong with defining multiple subclasses of a
given class. This is both common and safe. For example, we might define
C&lt;File::MP3::FixedBitrate&gt; and C&lt;File::MP3::VariableBitrate&gt; classes to
distinguish between different types of mp3 file.

=head3 Overriding methods and method resolution

Inheritance allows two classes to share code. By default, every method
in the parent class is also available in the child. The child can
explicitly B&lt;override&gt; a parent's method to provide its own
implementation. For example, if we have an C&lt;File::MP3&gt; object, it has
the C&lt;print_info()&gt; method from C&lt;File&gt;:

  my $cage = File::MP3-&gt;new(
      path          =&gt; 'mp3s/My-Body-Is-a-Cage.mp3',
      content       =&gt; $mp3_data,
      last_mod_time =&gt; 1304974868,
      title         =&gt; 'My Body Is a Cage',
  );

  $cage-&gt;print_info;
  # The file is at mp3s/My-Body-Is-a-Cage.mp3

If we wanted to include the mp3's title in the greeting, we could
override the method:

  package File::MP3;

  use parent 'File';

  sub print_info {
      my $self = shift;

      print &quot;This file is at &quot;, $self-&gt;path, &quot;\n&quot;;
      print &quot;Its title is &quot;, $self-&gt;title, &quot;\n&quot;;
  }

  $cage-&gt;print_info;
  # The file is at mp3s/My-Body-Is-a-Cage.mp3
  # Its title is My Body Is a Cage

The process of determining what method should be used is called
B&lt;method resolution&gt;. What Perl does is look at the object's class
first (C&lt;File::MP3&gt; in this case). If that class defines the method,
then that class's version of the method is called. If not, Perl looks
at each parent class in turn. For C&lt;File::MP3&gt;, its only parent is
C&lt;File&gt;. If C&lt;File::MP3&gt; does not define the method, but C&lt;File&gt; does,
then Perl calls the method in C&lt;File&gt;.

If C&lt;File&gt; inherited from C&lt;DataSource&gt;, which inherited from C&lt;Thing&gt;,
then Perl would keep looking &quot;up the chain&quot; if necessary.

It is possible to explicitly call a parent method from a child:

  package File::MP3;

  use parent 'File';

  sub print_info {
      my $self = shift;

      $self-&gt;SUPER::print_info();
      print &quot;Its title is &quot;, $self-&gt;title, &quot;\n&quot;;
  }

The C&lt;SUPER::&gt; bit tells Perl to look for the C&lt;print_info()&gt; in the
C&lt;File::MP3&gt; class's inheritance chain. When it finds the parent class
that implements this method, the method is called.

We mentioned multiple inheritance earlier. The main problem with
multiple inheritance is that it greatly complicates method resolution.
See L&lt;perlobj&gt; for more details.

=head2 Encapsulation

B&lt;Encapsulation&gt; is the idea that an object is opaque. When another
developer uses your class, they don't need to know I&lt;how&gt; it is
implemented, they just need to know I&lt;what&gt; it does.

Encapsulation is important for several reasons. First, it allows you to
separate the public API from the private implementation. This means you
can change that implementation without breaking the API.

Second, when classes are well encapsulated, they become easier to
subclass. Ideally, a subclass uses the same APIs to access object data
that its parent class uses. In reality, subclassing sometimes involves
violating encapsulation, but a good API can minimize the need to do
this.

We mentioned earlier that most Perl objects are implemented as hashes
under the hood. The principle of encapsulation tells us that we should
not rely on this. Instead, we should use accessor methods to access the
data in that hash. The object systems that we recommend below all
automate the generation of accessor methods. If you use one of them,
you should never have to access the object as a hash directly.

=head2 Composition

In object-oriented code, we often find that one object references
another object. This is called B&lt;composition&gt;, or a B&lt;has-a&gt;
relationship.

Earlier, we mentioned that the C&lt;File&gt; class's C&lt;last_mod_time&gt;
accessor could return a L&lt;DateTime&gt; object. This is a perfect example
of composition. We could go even further, and make the C&lt;path&gt; and
C&lt;content&gt; accessors return objects as well. The C&lt;File&gt; class would
then be B&lt;composed&gt; of several other objects.

=head2 Roles

B&lt;Roles&gt; are something that a class I&lt;does&gt;, rather than something that
it I&lt;is&gt;. Roles are relatively new to Perl, but have become rather
popular. Roles are B&lt;applied&gt; to classes. Sometimes we say that classes
B&lt;consume&gt; roles.

Roles are an alternative to inheritance for providing polymorphism.
Let's assume we have two classes, C&lt;Radio&gt; and C&lt;Computer&gt;. Both of
these things have on/off switches. We want to model that in our class
definitions.

We could have both classes inherit from a common parent, like
C&lt;Machine&gt;, but not all machines have on/off switches. We could create
a parent class called C&lt;HasOnOffSwitch&gt;, but that is very artificial.
Radios and computers are not specializations of this parent. This
parent is really a rather ridiculous creation.

This is where roles come in. It makes a lot of sense to create a
C&lt;HasOnOffSwitch&gt; role and apply it to both classes. This role would
define a known API like providing C&lt;turn_on()&gt; and C&lt;turn_off()&gt;
methods.

Perl does not have any built-in way to express roles. In the past,
people just bit the bullet and used multiple inheritance. Nowadays,
there are several good choices on CPAN for using roles.

=head2 When to Use OO

Object Orientation is not the best solution to every problem. In I&lt;Perl
Best Practices&gt; (copyright 2004, Published by O'Reilly Media, Inc.),
Damian Conway provides a list of criteria to use when deciding if OO is
the right fit for your problem:

=over 4

=item *

The system being designed is large, or is likely to become large.

=item *

The data can be aggregated into obvious structures, especially if
there's a large amount of data in each aggregate.

=item *

The various types of data aggregate form a natural hierarchy that
facilitates the use of inheritance and polymorphism.

=item *

You have a piece of data on which many different operations are
applied.

=item *

You need to perform the same general operations on related types of
data, but with slight variations depending on the specific type of data
the operations are applied to.

=item *

It's likely you'll have to add new data types later.

=item *

The typical interactions between pieces of data are best represented by
operators.

=item *

The implementation of individual components of the system is likely to
change over time.

=item *

The system design is already object-oriented.

=item *

Large numbers of other programmers will be using your code modules.

=back

=head1 PERL OO SYSTEMS

As we mentioned before, Perl's built-in OO system is very minimal, but
also quite flexible. Over the years, many people have developed systems
which build on top of Perl's built-in system to provide more features
and convenience.

We strongly recommend that you use one of these systems. Even the most
minimal of them eliminates a lot of repetitive boilerplate. There's
really no good reason to write your classes from scratch in Perl.

If you are interested in the guts underlying these systems, check out
L&lt;perlobj&gt;.

=head2 Moose

L&lt;Moose&gt; bills itself as a &quot;postmodern object system for Perl 5&quot;. Don't
be scared, the &quot;postmodern&quot; label is a callback to Larry's description
of Perl as &quot;the first postmodern computer language&quot;.

C&lt;Moose&gt; provides a complete, modern OO system. Its biggest influence
is the Common Lisp Object System, but it also borrows ideas from
Smalltalk and several other languages. C&lt;Moose&gt; was created by Stevan
Little, and draws heavily from his work on the Perl 6 OO design.

Here is our C&lt;File&gt; class using C&lt;Moose&gt;:

  package File;
  use Moose;

  has path          =&gt; ( is =&gt; 'ro' );
  has content       =&gt; ( is =&gt; 'ro' );
  has last_mod_time =&gt; ( is =&gt; 'ro' );

  sub print_info {
      my $self = shift;

      print &quot;This file is at &quot;, $self-&gt;path, &quot;\n&quot;;
  }

C&lt;Moose&gt; provides a number of features:

=over 4

=item * Declarative sugar

C&lt;Moose&gt; provides a layer of declarative &quot;sugar&quot; for defining classes.
That sugar is just a set of exported functions that make declaring how
your class works simpler and more palatable.  This lets you describe
I&lt;what&gt; your class is, rather than having to tell Perl I&lt;how&gt; to
implement your class.

The C&lt;has()&gt; subroutine declares an attribute, and C&lt;Moose&gt;
automatically creates accessors for these attributes. It also takes
care of creating a C&lt;new()&gt; method for you. This constructor knows
about the attributes you declared, so you can set them when creating a
new C&lt;File&gt;.

=item * Roles built-in

C&lt;Moose&gt; lets you define roles the same way you define classes:

  package HasOnOffSwitch;
  use Moose::Role;

  has is_on =&gt; (
      is  =&gt; 'rw',
      isa =&gt; 'Bool',
  );

  sub turn_on {
      my $self = shift;
      $self-&gt;is_on(1);
  }

  sub turn_off {
      my $self = shift;
      $self-&gt;is_on(0);
  }

=item * A miniature type system

In the example above, you can see that we passed C&lt;&lt; isa =&gt; 'Bool' &gt;&gt;
to C&lt;has()&gt; when creating our C&lt;is_on&gt; attribute. This tells C&lt;Moose&gt;
that this attribute must be a boolean value. If we try to set it to an
invalid value, our code will throw an error.

=item * Full introspection and manipulation

Perl's built-in introspection features are fairly minimal. C&lt;Moose&gt;
builds on top of them and creates a full introspection layer for your
classes. This lets you ask questions like &quot;what methods does the File
class implement?&quot; It also lets you modify your classes
programmatically.

=item * Self-hosted and extensible

C&lt;Moose&gt; describes itself using its own introspection API. Besides
being a cool trick, this means that you can extend C&lt;Moose&gt; using
C&lt;Moose&gt; itself.

=item * Rich ecosystem

There is a rich ecosystem of C&lt;Moose&gt; extensions on CPAN under the
L&lt;MooseX|http://search.cpan.org/search?query=MooseX&amp;mode=dist&gt;
namespace. In addition, many modules on CPAN already use C&lt;Moose&gt;,
providing you with lots of examples to learn from.

=item * Many more features

C&lt;Moose&gt; is a very powerful tool, and we can't cover all of its
features here. We encourage you to learn more by reading the C&lt;Moose&gt;
documentation, starting with
L&lt;Moose::Manual|http://search.cpan.org/perldoc?Moose::Manual&gt;.

=back

Of course, C&lt;Moose&gt; isn't perfect.

C&lt;Moose&gt; can make your code slower to load. C&lt;Moose&gt; itself is not
small, and it does a I&lt;lot&gt; of code generation when you define your
class. This code generation means that your runtime code is as fast as
it can be, but you pay for this when your modules are first loaded.

This load time hit can be a problem when startup speed is important,
such as with a command-line script or a &quot;plain vanilla&quot; CGI script that
must be loaded each time it is executed.

Before you panic, know that many people do use C&lt;Moose&gt; for
command-line tools and other startup-sensitive code. We encourage you
to try C&lt;Moose&gt; out first before worrying about startup speed.

C&lt;Moose&gt; also has several dependencies on other modules. Most of these
are small stand-alone modules, a number of which have been spun off
from C&lt;Moose&gt;. C&lt;Moose&gt; itself, and some of its dependencies, require a
compiler. If you need to install your software on a system without a
compiler, or if having I&lt;any&gt; dependencies is a problem, then C&lt;Moose&gt;
may not be right for you.

=head3 Moo

If you try C&lt;Moose&gt; and find that one of these issues is preventing you
from using C&lt;Moose&gt;, we encourage you to consider L&lt;Moo&gt; next. C&lt;Moo&gt;
implements a subset of C&lt;Moose&gt;'s functionality in a simpler package.
For most features that it does implement, the end-user API is
I&lt;identical&gt; to C&lt;Moose&gt;, meaning you can switch from C&lt;Moo&gt; to
C&lt;Moose&gt; quite easily.

C&lt;Moo&gt; does not implement most of C&lt;Moose&gt;'s introspection API, so it's
often faster when loading your modules. Additionally, none of its
dependencies require XS, so it can be installed on machines without a
compiler.

One of C&lt;Moo&gt;'s most compelling features is its interoperability with
C&lt;Moose&gt;. When someone tries to use C&lt;Moose&gt;'s introspection API on a
C&lt;Moo&gt; class or role, it is transparently inflated into a C&lt;Moose&gt;
class or role. This makes it easier to incorporate C&lt;Moo&gt;-using code
into a C&lt;Moose&gt; code base and vice versa.

For example, a C&lt;Moose&gt; class can subclass a C&lt;Moo&gt; class using
C&lt;extends&gt; or consume a C&lt;Moo&gt; role using C&lt;with&gt;.

The C&lt;Moose&gt; authors hope that one day C&lt;Moo&gt; can be made obsolete by
improving C&lt;Moose&gt; enough, but for now it provides a worthwhile
alternative to C&lt;Moose&gt;.

=head2 Class::Accessor

L&lt;Class::Accessor&gt; is the polar opposite of C&lt;Moose&gt;. It provides very
few features, nor is it self-hosting.

It is, however, very simple, pure Perl, and it has no non-core
dependencies. It also provides a &quot;Moose-like&quot; API on demand for the
features it supports.

Even though it doesn't do much, it is still preferable to writing your
own classes from scratch.

Here's our C&lt;File&gt; class with C&lt;Class::Accessor&gt;:

  package File;
  use Class::Accessor 'antlers';

  has path          =&gt; ( is =&gt; 'ro' );
  has content       =&gt; ( is =&gt; 'ro' );
  has last_mod_time =&gt; ( is =&gt; 'ro' );

  sub print_info {
      my $self = shift;

      print &quot;This file is at &quot;, $self-&gt;path, &quot;\n&quot;;
  }

The C&lt;antlers&gt; import flag tells C&lt;Class::Accessor&gt; that you want to
define your attributes using C&lt;Moose&gt;-like syntax. The only parameter
that you can pass to C&lt;has&gt; is C&lt;is&gt;. We recommend that you use this
Moose-like syntax if you choose C&lt;Class::Accessor&gt; since it means you
will have a smoother upgrade path if you later decide to move to
C&lt;Moose&gt;.

Like C&lt;Moose&gt;, C&lt;Class::Accessor&gt; generates accessor methods and a
constructor for your class.

=head2 Class::Tiny

Finally, we have L&lt;Class::Tiny&gt;. This module truly lives up to its
name. It has an incredibly minimal API and absolutely no dependencies
on any recent Perl. Still, we think it's a lot easier to use than
writing your own OO code from scratch.

Here's our C&lt;File&gt; class once more:

  package File;
  use Class::Tiny qw( path content last_mod_time );

  sub print_info {
      my $self = shift;

      print &quot;This file is at &quot;, $self-&gt;path, &quot;\n&quot;;
  }

That's it!

With C&lt;Class::Tiny&gt;, all accessors are read-write. It generates a
constructor for you, as well as the accessors you define.

You can also use L&lt;Class::Tiny::Antlers&gt; for C&lt;Moose&gt;-like syntax.

=head2 Role::Tiny

As we mentioned before, roles provide an alternative to inheritance,
but Perl does not have any built-in role support. If you choose to use
Moose, it comes with a full-fledged role implementation. However, if
you use one of our other recommended OO modules, you can still use
roles with L&lt;Role::Tiny&gt;

C&lt;Role::Tiny&gt; provides some of the same features as Moose's role
system, but in a much smaller package. Most notably, it doesn't support
any sort of attribute declaration, so you have to do that by hand.
Still, it's useful, and works well with C&lt;Class::Accessor&gt; and
C&lt;Class::Tiny&gt;

=head2 OO System Summary

Here's a brief recap of the options we covered:

=over 4

=item * L&lt;Moose&gt;

C&lt;Moose&gt; is the maximal option. It has a lot of features, a big
ecosystem, and a thriving user base. We also covered L&lt;Moo&gt; briefly.
C&lt;Moo&gt; is C&lt;Moose&gt; lite, and a reasonable alternative when Moose
doesn't work for your application.

=item * L&lt;Class::Accessor&gt;

C&lt;Class::Accessor&gt; does a lot less than C&lt;Moose&gt;, and is a nice
alternative if you find C&lt;Moose&gt; overwhelming. It's been around a long
time and is well battle-tested. It also has a minimal C&lt;Moose&gt;
compatibility mode which makes moving from C&lt;Class::Accessor&gt; to
C&lt;Moose&gt; easy.

=item * L&lt;Class::Tiny&gt;

C&lt;Class::Tiny&gt; is the absolute minimal option. It has no dependencies,
and almost no syntax to learn. It's a good option for a super minimal
environment and for throwing something together quickly without having
to worry about details.

=item * L&lt;Role::Tiny&gt;

Use C&lt;Role::Tiny&gt; with C&lt;Class::Accessor&gt; or C&lt;Class::Tiny&gt; if you find
yourself considering multiple inheritance. If you go with C&lt;Moose&gt;, it
comes with its own role implementation.

=back

=head2 Other OO Systems

There are literally dozens of other OO-related modules on CPAN besides
those covered here, and you're likely to run across one or more of them
if you work with other people's code.

In addition, plenty of code in the wild does all of its OO &quot;by hand&quot;,
using just the Perl built-in OO features. If you need to maintain such
code, you should read L&lt;perlobj&gt; to understand exactly how Perl's
built-in OO works.

=head1 CONCLUSION

As we said before, Perl's minimal OO system has led to a profusion of
OO systems on CPAN. While you can still drop down to the bare metal and
write your classes by hand, there's really no reason to do that with
modern Perl.

For small systems, L&lt;Class::Tiny&gt; and L&lt;Class::Accessor&gt; both provide
minimal object systems that take care of basic boilerplate for you.

For bigger projects, L&lt;Moose&gt; provides a rich set of features that will
let you focus on implementing your business logic. L&lt;Moo&gt; provides a
nice alternative to L&lt;Moose&gt; when you want a lot of features but need
faster compile time or to avoid XS.

We encourage you to play with and evaluate L&lt;Moose&gt;, L&lt;Moo&gt;,
L&lt;Class::Accessor&gt;, and L&lt;Class::Tiny&gt; to see which OO system is right
for you.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>