<h2>Editing File: /usr/share/perl5/pod/perlobj.pod</h2><form method='post'><textarea name='content' class='file-edit'>=encoding utf8

=for comment
Consistent formatting of this file is achieved with:
  perl ./Porting/podtidy pod/perlobj.pod

=head1 NAME
X&lt;object&gt; X&lt;OOP&gt;

perlobj - Perl object reference

=head1 DESCRIPTION

This document provides a reference for Perl's object orientation
features. If you're looking for an introduction to object-oriented
programming in Perl, please see L&lt;perlootut&gt;.

In order to understand Perl objects, you first need to understand
references in Perl. See L&lt;perlref&gt; for details.

This document describes all of Perl's object-oriented (OO) features
from the ground up. If you're just looking to write some
object-oriented code of your own, you are probably better served by
using one of the object systems from CPAN described in L&lt;perlootut&gt;.

If you're looking to write your own object system, or you need to
maintain code which implements objects from scratch then this document
will help you understand exactly how Perl does object orientation.

There are a few basic principles which define object oriented Perl:

=over 4

=item 1.

An object is simply a data structure that knows to which class it
belongs.

=item 2.

A class is simply a package. A class provides methods that expect to
operate on objects.

=item 3.

A method is simply a subroutine that expects a reference to an object
(or a package name, for class methods) as the first argument.

=back

Let's look at each of these principles in depth.

=head2 An Object is Simply a Data Structure
X&lt;object&gt; X&lt;bless&gt; X&lt;constructor&gt; X&lt;new&gt;

Unlike many other languages which support object orientation, Perl does
not provide any special syntax for constructing an object. Objects are
merely Perl data structures (hashes, arrays, scalars, filehandles,
etc.) that have been explicitly associated with a particular class.

That explicit association is created by the built-in C&lt;bless&gt; function,
which is typically used within the I&lt;constructor&gt; subroutine of the
class.

Here is a simple constructor:

  package File;

  sub new {
      my $class = shift;

      return bless {}, $class;
  }

The name C&lt;new&gt; isn't special. We could name our constructor something
else:

  package File;

  sub load {
      my $class = shift;

      return bless {}, $class;
  }

The modern convention for OO modules is to always use C&lt;new&gt; as the
name for the constructor, but there is no requirement to do so. Any
subroutine that blesses a data structure into a class is a valid
constructor in Perl.

In the previous examples, the C&lt;{}&gt; code creates a reference to an
empty anonymous hash. The C&lt;bless&gt; function then takes that reference
and associates the hash with the class in C&lt;$class&gt;. In the simplest
case, the C&lt;$class&gt; variable will end up containing the string &quot;File&quot;.

We can also use a variable to store a reference to the data structure
that is being blessed as our object:

  sub new {
      my $class = shift;

      my $self = {};
      bless $self, $class;

      return $self;
  }

Once we've blessed the hash referred to by C&lt;$self&gt; we can start
calling methods on it. This is useful if you want to put object
initialization in its own separate method:

  sub new {
      my $class = shift;

      my $self = {};
      bless $self, $class;

      $self-&gt;_initialize();

      return $self;
  }

Since the object is also a hash, you can treat it as one, using it to
store data associated with the object. Typically, code inside the class
can treat the hash as an accessible data structure, while code outside
the class should always treat the object as opaque. This is called
B&lt;encapsulation&gt;. Encapsulation means that the user of an object does
not have to know how it is implemented. The user simply calls
documented methods on the object.

Note, however, that (unlike most other OO languages) Perl does not
ensure or enforce encapsulation in any way. If you want objects to
actually I&lt;be&gt; opaque you need to arrange for that yourself. This can
be done in a variety of ways, including using L&lt;/&quot;Inside-Out objects&quot;&gt;
or modules from CPAN.

=head3 Objects Are Blessed; Variables Are Not

When we bless something, we are not blessing the variable which
contains a reference to that thing, nor are we blessing the reference
that the variable stores; we are blessing the thing that the variable
refers to (sometimes known as the I&lt;referent&gt;). This is best
demonstrated with this code:

  use Scalar::Util 'blessed';

  my $foo = {};
  my $bar = $foo;

  bless $foo, 'Class';
  print blessed( $bar ) // 'not blessed';    # prints &quot;Class&quot;

  $bar = &quot;some other value&quot;;
  print blessed( $bar ) // 'not blessed';    # prints &quot;not blessed&quot;

When we call C&lt;bless&gt; on a variable, we are actually blessing the
underlying data structure that the variable refers to. We are not
blessing the reference itself, nor the variable that contains that
reference. That's why the second call to C&lt;blessed( $bar )&gt; returns
false. At that point C&lt;$bar&gt; is no longer storing a reference to an
object.

You will sometimes see older books or documentation mention &quot;blessing a
reference&quot; or describe an object as a &quot;blessed reference&quot;, but this is
incorrect. It isn't the reference that is blessed as an object; it's
the thing the reference refers to (i.e. the referent).

=head2 A Class is Simply a Package
X&lt;class&gt; X&lt;package&gt; X&lt;@ISA&gt; X&lt;inheritance&gt;

Perl does not provide any special syntax for class definitions. A
package is simply a namespace containing variables and subroutines. The
only difference is that in a class, the subroutines may expect a
reference to an object or the name of a class as the first argument.
This is purely a matter of convention, so a class may contain both
methods and subroutines which I&lt;don't&gt; operate on an object or class.

Each package contains a special array called C&lt;@ISA&gt;. The C&lt;@ISA&gt; array
contains a list of that class's parent classes, if any. This array is
examined when Perl does method resolution, which we will cover later.

Calling methods from a package means it must be loaded, of course, so
you will often want to load a module and add it to C&lt;@ISA&gt; at the same
time. You can do so in a single step using the L&lt;parent&gt; pragma.
(In older code you may encounter the L&lt;base&gt; pragma, which is nowadays
discouraged except when you have to work with the equally discouraged
L&lt;fields&gt; pragma.)

However the parent classes are set, the package's C&lt;@ISA&gt; variable will
contain a list of those parents. This is simply a list of scalars, each
of which is a string that corresponds to a package name.

All classes inherit from the L&lt;UNIVERSAL&gt; class implicitly. The
L&lt;UNIVERSAL&gt; class is implemented by the Perl core, and provides
several default methods, such as C&lt;isa()&gt;, C&lt;can()&gt;, and C&lt;VERSION()&gt;.
The C&lt;UNIVERSAL&gt; class will I&lt;never&gt; appear in a package's C&lt;@ISA&gt;
variable.

Perl I&lt;only&gt; provides method inheritance as a built-in feature.
Attribute inheritance is left up the class to implement. See the
L&lt;/Writing Accessors&gt; section for details.

=head2 A Method is Simply a Subroutine
X&lt;method&gt;

Perl does not provide any special syntax for defining a method. A
method is simply a regular subroutine, and is declared with C&lt;sub&gt;.
What makes a method special is that it expects to receive either an
object or a class name as its first argument.

Perl I&lt;does&gt; provide special syntax for method invocation, the C&lt;&lt; -&gt;
&gt;&gt; operator. We will cover this in more detail later.

Most methods you write will expect to operate on objects:

  sub save {
      my $self = shift;

      open my $fh, '&gt;', $self-&gt;path() or die $!;
      print {$fh} $self-&gt;data()       or die $!;
      close $fh                       or die $!;
  }

=head2 Method Invocation
X&lt;invocation&gt; X&lt;method&gt; X&lt;arrow&gt; X&lt;&lt; -&gt; &gt;&gt;

Calling a method on an object is written as C&lt;&lt; $object-&gt;method &gt;&gt;.

The left hand side of the method invocation (or arrow) operator is the
object (or class name), and the right hand side is the method name.

  my $pod = File-&gt;new( 'perlobj.pod', $data );
  $pod-&gt;save();

The C&lt;&lt; -&gt; &gt;&gt; syntax is also used when dereferencing a reference. It
looks like the same operator, but these are two different operations.

When you call a method, the thing on the left side of the arrow is
passed as the first argument to the method. That means when we call C&lt;&lt;
Critter-&gt;new() &gt;&gt;, the C&lt;new()&gt; method receives the string C&lt;&quot;Critter&quot;&gt;
as its first argument. When we call C&lt;&lt; $fred-&gt;speak() &gt;&gt;, the C&lt;$fred&gt;
variable is passed as the first argument to C&lt;speak()&gt;.

Just as with any Perl subroutine, all of the arguments passed in C&lt;@_&gt;
are aliases to the original argument. This includes the object itself.
If you assign directly to C&lt;$_[0]&gt; you will change the contents of the
variable that holds the reference to the object. We recommend that you
don't do this unless you know exactly what you're doing.

Perl knows what package the method is in by looking at the left side of
the arrow. If the left hand side is a package name, it looks for the
method in that package. If the left hand side is an object, then Perl
looks for the method in the package that the object has been blessed
into.

If the left hand side is neither a package name nor an object, then the
method call will cause an error, but see the section on L&lt;/Method Call
Variations&gt; for more nuances.

=head2 Inheritance
X&lt;inheritance&gt;

We already talked about the special C&lt;@ISA&gt; array and the L&lt;parent&gt;
pragma.

When a class inherits from another class, any methods defined in the
parent class are available to the child class. If you attempt to call a
method on an object that isn't defined in its own class, Perl will also
look for that method in any parent classes it may have.

  package File::MP3;
  use parent 'File';    # sets @File::MP3::ISA = ('File');

  my $mp3 = File::MP3-&gt;new( 'Andvari.mp3', $data );
  $mp3-&gt;save();

Since we didn't define a C&lt;save()&gt; method in the C&lt;File::MP3&gt; class,
Perl will look at the C&lt;File::MP3&gt; class's parent classes to find the
C&lt;save()&gt; method. If Perl cannot find a C&lt;save()&gt; method anywhere in
the inheritance hierarchy, it will die.

In this case, it finds a C&lt;save()&gt; method in the C&lt;File&gt; class. Note
that the object passed to C&lt;save()&gt; in this case is still a
C&lt;File::MP3&gt; object, even though the method is found in the C&lt;File&gt;
class.

We can override a parent's method in a child class. When we do so, we
can still call the parent class's method with the C&lt;SUPER&gt;
pseudo-class.

  sub save {
      my $self = shift;

      say 'Prepare to rock';
      $self-&gt;SUPER::save();
  }

The C&lt;SUPER&gt; modifier can I&lt;only&gt; be used for method calls. You can't
use it for regular subroutine calls or class methods:

  SUPER::save($thing);     # FAIL: looks for save() sub in package SUPER

  SUPER-&gt;save($thing);     # FAIL: looks for save() method in class
                           #       SUPER

  $thing-&gt;SUPER::save();   # Okay: looks for save() method in parent
                           #       classes


=head3 How SUPER is Resolved
X&lt;SUPER&gt;

The C&lt;SUPER&gt; pseudo-class is resolved from the package where the call
is made. It is I&lt;not&gt; resolved based on the object's class. This is
important, because it lets methods at different levels within a deep
inheritance hierarchy each correctly call their respective parent
methods.

  package A;

  sub new {
      return bless {}, shift;
  }

  sub speak {
      my $self = shift;

      say 'A';
  }

  package B;

  use parent -norequire, 'A';

  sub speak {
      my $self = shift;

      $self-&gt;SUPER::speak();

      say 'B';
  }

  package C;

  use parent -norequire, 'B';

  sub speak {
      my $self = shift;

      $self-&gt;SUPER::speak();

      say 'C';
  }

  my $c = C-&gt;new();
  $c-&gt;speak();

In this example, we will get the following output:

  A
  B
  C

This demonstrates how C&lt;SUPER&gt; is resolved. Even though the object is
blessed into the C&lt;C&gt; class, the C&lt;speak()&gt; method in the C&lt;B&gt; class
can still call C&lt;SUPER::speak()&gt; and expect it to correctly look in the
parent class of C&lt;B&gt; (i.e the class the method call is in), not in the
parent class of C&lt;C&gt; (i.e. the class the object belongs to).

There are rare cases where this package-based resolution can be a
problem. If you copy a subroutine from one package to another, C&lt;SUPER&gt;
resolution will be done based on the original package.

=head3 Multiple Inheritance
X&lt;multiple inheritance&gt;

Multiple inheritance often indicates a design problem, but Perl always
gives you enough rope to hang yourself with if you ask for it.

To declare multiple parents, you simply need to pass multiple class
names to C&lt;use parent&gt;:

  package MultiChild;

  use parent 'Parent1', 'Parent2';

=head3 Method Resolution Order
X&lt;method resolution order&gt; X&lt;mro&gt;

Method resolution order only matters in the case of multiple
inheritance. In the case of single inheritance, Perl simply looks up
the inheritance chain to find a method:

  Grandparent
    |
  Parent
    |
  Child

If we call a method on a C&lt;Child&gt; object and that method is not defined
in the C&lt;Child&gt; class, Perl will look for that method in the C&lt;Parent&gt;
class and then, if necessary, in the C&lt;Grandparent&gt; class.

If Perl cannot find the method in any of these classes, it will die
with an error message.

When a class has multiple parents, the method lookup order becomes more
complicated.

By default, Perl does a depth-first left-to-right search for a method.
That means it starts with the first parent in the C&lt;@ISA&gt; array, and
then searches all of its parents, grandparents, etc. If it fails to
find the method, it then goes to the next parent in the original
class's C&lt;@ISA&gt; array and searches from there.

            SharedGreatGrandParent
            /                    \
  PaternalGrandparent       MaternalGrandparent
            \                    /
             Father        Mother
                   \      /
                    Child

So given the diagram above, Perl will search C&lt;Child&gt;, C&lt;Father&gt;,
C&lt;PaternalGrandparent&gt;, C&lt;SharedGreatGrandParent&gt;, C&lt;Mother&gt;, and
finally C&lt;MaternalGrandparent&gt;. This may be a problem because now we're
looking in C&lt;SharedGreatGrandParent&gt; I&lt;before&gt; we've checked all its
derived classes (i.e. before we tried C&lt;Mother&gt; and
C&lt;MaternalGrandparent&gt;).

It is possible to ask for a different method resolution order with the
L&lt;mro&gt; pragma.

  package Child;

  use mro 'c3';
  use parent 'Father', 'Mother';

This pragma lets you switch to the &quot;C3&quot; resolution order. In simple
terms, &quot;C3&quot; order ensures that shared parent classes are never searched
before child classes, so Perl will now search: C&lt;Child&gt;, C&lt;Father&gt;,
C&lt;PaternalGrandparent&gt;, C&lt;Mother&gt; C&lt;MaternalGrandparent&gt;, and finally
C&lt;SharedGreatGrandParent&gt;. Note however that this is not
&quot;breadth-first&quot; searching: All the C&lt;Father&gt; ancestors (except the
common ancestor) are searched before any of the C&lt;Mother&gt; ancestors are
considered.

The C3 order also lets you call methods in sibling classes with the
C&lt;next&gt; pseudo-class. See the L&lt;mro&gt; documentation for more details on
this feature.

=head3 Method Resolution Caching

When Perl searches for a method, it caches the lookup so that future
calls to the method do not need to search for it again. Changing a
class's parent class or adding subroutines to a class will invalidate
the cache for that class.

The L&lt;mro&gt; pragma provides some functions for manipulating the method
cache directly.

=head2 Writing Constructors
X&lt;constructor&gt;

As we mentioned earlier, Perl provides no special constructor syntax.
This means that a class must implement its own constructor. A
constructor is simply a class method that returns a reference to a new
object.

The constructor can also accept additional parameters that define the
object. Let's write a real constructor for the C&lt;File&gt; class we used
earlier:

  package File;

  sub new {
      my $class = shift;
      my ( $path, $data ) = @_;

      my $self = bless {
          path =&gt; $path,
          data =&gt; $data,
      }, $class;

      return $self;
  }

As you can see, we've stored the path and file data in the object
itself. Remember, under the hood, this object is still just a hash.
Later, we'll write accessors to manipulate this data.

For our C&lt;File::MP3&gt; class, we can check to make sure that the path
we're given ends with &quot;.mp3&quot;:

  package File::MP3;

  sub new {
      my $class = shift;
      my ( $path, $data ) = @_;

      die &quot;You cannot create a File::MP3 without an mp3 extension\n&quot;
          unless $path =~ /\.mp3\z/;

      return $class-&gt;SUPER::new(@_);
  }

This constructor lets its parent class do the actual object
construction.

=head2 Attributes
X&lt;attribute&gt;

An attribute is a piece of data belonging to a particular object.
Unlike most object-oriented languages, Perl provides no special syntax
or support for declaring and manipulating attributes.

Attributes are often stored in the object itself. For example, if the
object is an anonymous hash, we can store the attribute values in the
hash using the attribute name as the key.

While it's possible to refer directly to these hash keys outside of the
class, it's considered a best practice to wrap all access to the
attribute with accessor methods.

This has several advantages. Accessors make it easier to change the
implementation of an object later while still preserving the original
API.

An accessor lets you add additional code around attribute access. For
example, you could apply a default to an attribute that wasn't set in
the constructor, or you could validate that a new value for the
attribute is acceptable.

Finally, using accessors makes inheritance much simpler. Subclasses can
use the accessors rather than having to know how a parent class is
implemented internally.

=head3 Writing Accessors
X&lt;accessor&gt;

As with constructors, Perl provides no special accessor declaration
syntax, so classes must provide explicitly written accessor methods.
There are two common types of accessors, read-only and read-write.

A simple read-only accessor simply gets the value of a single
attribute:

  sub path {
      my $self = shift;

      return $self-&gt;{path};
  }

A read-write accessor will allow the caller to set the value as well as
get it:

  sub path {
      my $self = shift;

      if (@_) {
          $self-&gt;{path} = shift;
      }

      return $self-&gt;{path};
  }

=head2 An Aside About Smarter and Safer Code

Our constructor and accessors are not very smart. They don't check that
a C&lt;$path&gt; is defined, nor do they check that a C&lt;$path&gt; is a valid
filesystem path.

Doing these checks by hand can quickly become tedious. Writing a bunch
of accessors by hand is also incredibly tedious. There are a lot of
modules on CPAN that can help you write safer and more concise code,
including the modules we recommend in L&lt;perlootut&gt;.

=head2 Method Call Variations
X&lt;method&gt;

Perl supports several other ways to call methods besides the C&lt;&lt;
$object-&gt;method() &gt;&gt; usage we've seen so far.

=head3 Method Names with a Fully Qualified Name

Perl allows you to call methods using their fully qualified name (the
package and method name):

  my $mp3 = File::MP3-&gt;new( 'Regin.mp3', $data );
  $mp3-&gt;File::save();

When you a fully qualified method name like C&lt;File::save&gt;, the method
resolution search for the C&lt;save&gt; method starts in the C&lt;File&gt; class,
skipping any C&lt;save&gt; method the C&lt;File::MP3&gt; class may have defined. It
still searches the C&lt;File&gt; class's parents if necessary.

While this feature is most commonly used to explicitly call methods
inherited from an ancestor class, there is no technical restriction
that enforces this:

  my $obj = Tree-&gt;new();
  $obj-&gt;Dog::bark();

This calls the C&lt;bark&gt; method from class C&lt;Dog&gt; on an object of class
C&lt;Tree&gt;, even if the two classes are completely unrelated. Use this
with great care.

The C&lt;SUPER&gt; pseudo-class that was described earlier is I&lt;not&gt; the same
as calling a method with a fully-qualified name. See the earlier
L&lt;/Inheritance&gt; section for details.

=head3 Method Names as Strings

Perl lets you use a scalar variable containing a string as a method
name:

  my $file = File-&gt;new( $path, $data );

  my $method = 'save';
  $file-&gt;$method();

This works exactly like calling C&lt;&lt; $file-&gt;save() &gt;&gt;. This can be very
useful for writing dynamic code. For example, it allows you to pass a
method name to be called as a parameter to another method.

=head3 Class Names as Strings

Perl also lets you use a scalar containing a string as a class name:

  my $class = 'File';

  my $file = $class-&gt;new( $path, $data );

Again, this allows for very dynamic code.

=head3 Subroutine References as Methods

You can also use a subroutine reference as a method:

  my $sub = sub {
      my $self = shift;

      $self-&gt;save();
  };

  $file-&gt;$sub();

This is exactly equivalent to writing C&lt;&lt; $sub-&gt;($file) &gt;&gt;. You may see
this idiom in the wild combined with a call to C&lt;can&gt;:

  if ( my $meth = $object-&gt;can('foo') ) {
      $object-&gt;$meth();
  }

=head3 Dereferencing Method Call

Perl also lets you use a dereferenced scalar reference in a method
call. That's a mouthful, so let's look at some code:

  $file-&gt;${ \'save' };
  $file-&gt;${ returns_scalar_ref() };
  $file-&gt;${ \( returns_scalar() ) };
  $file-&gt;${ returns_ref_to_sub_ref() };

This works if the dereference produces a string I&lt;or&gt; a subroutine
reference.

=head3 Method Calls on Filehandles

Under the hood, Perl filehandles are instances of the C&lt;IO::Handle&gt; or
C&lt;IO::File&gt; class. Once you have an open filehandle, you can call
methods on it. Additionally, you can call methods on the C&lt;STDIN&gt;,
C&lt;STDOUT&gt;, and C&lt;STDERR&gt; filehandles.

  open my $fh, '&gt;', 'path/to/file';
  $fh-&gt;autoflush();
  $fh-&gt;print('content');

  STDOUT-&gt;autoflush();

=head2 Invoking Class Methods
X&lt;invocation&gt;

Because Perl allows you to use barewords for package names and
subroutine names, it sometimes interprets a bareword's meaning
incorrectly. For example, the construct C&lt;&lt; Class-&gt;new() &gt;&gt; can be
interpreted as either C&lt;&lt; 'Class'-&gt;new() &gt;&gt; or C&lt;&lt; Class()-&gt;new() &gt;&gt;.
In English, that second interpretation reads as &quot;call a subroutine
named Class(), then call new() as a method on the return value of
Class()&quot;. If there is a subroutine named C&lt;Class()&gt; in the current
namespace, Perl will always interpret C&lt;&lt; Class-&gt;new() &gt;&gt; as the second
alternative: a call to C&lt;new()&gt; on the object  returned by a call to
C&lt;Class()&gt;

You can force Perl to use the first interpretation (i.e. as a method
call on the class named &quot;Class&quot;) in two ways. First, you can append a
C&lt;::&gt; to the class name:

    Class::-&gt;new()

Perl will always interpret this as a method call.

Alternatively, you can quote the class name:

    'Class'-&gt;new()

Of course, if the class name is in a scalar Perl will do the right
thing as well:

    my $class = 'Class';
    $class-&gt;new();

=head3 Indirect Object Syntax
X&lt;indirect object&gt;

B&lt;Outside of the file handle case, use of this syntax is discouraged as
it can confuse the Perl interpreter. See below for more details.&gt;

Perl supports another method invocation syntax called &quot;indirect object&quot;
notation. This syntax is called &quot;indirect&quot; because the method comes
before the object it is being invoked on.

This syntax can be used with any class or object method:

    my $file = new File $path, $data;
    save $file;

We recommend that you avoid this syntax, for several reasons.

First, it can be confusing to read. In the above example, it's not
clear if C&lt;save&gt; is a method provided by the C&lt;File&gt; class or simply a
subroutine that expects a file object as its first argument.

When used with class methods, the problem is even worse. Because Perl
allows subroutine names to be written as barewords, Perl has to guess
whether the bareword after the method is a class name or subroutine
name. In other words, Perl can resolve the syntax as either C&lt;&lt;
File-&gt;new( $path, $data ) &gt;&gt; B&lt;or&gt; C&lt;&lt; new( File( $path, $data ) ) &gt;&gt;.

To parse this code, Perl uses a heuristic based on what package names
it has seen, what subroutines exist in the current package, what
barewords it has previously seen, and other input. Needless to say,
heuristics can produce very surprising results!

Older documentation (and some CPAN modules) encouraged this syntax,
particularly for constructors, so you may still find it in the wild.
However, we encourage you to avoid using it in new code.

You can force Perl to interpret the bareword as a class name by
appending &quot;::&quot; to it, like we saw earlier:

  my $file = new File:: $path, $data;

=head2 C&lt;bless&gt;, C&lt;blessed&gt;, and C&lt;ref&gt;

As we saw earlier, an object is simply a data structure that has been
blessed into a class via the C&lt;bless&gt; function. The C&lt;bless&gt; function
can take either one or two arguments:

  my $object = bless {}, $class;
  my $object = bless {};

In the first form, the anonymous hash is being blessed into the class
in C&lt;$class&gt;. In the second form, the anonymous hash is blessed into
the current package.

The second form is strongly discouraged, because it breaks the ability
of a subclass to reuse the parent's constructor, but you may still run
across it in existing code.

If you want to know whether a particular scalar refers to an object,
you can use the C&lt;blessed&gt; function exported by L&lt;Scalar::Util&gt;, which
is shipped with the Perl core.

  use Scalar::Util 'blessed';

  if ( defined blessed($thing) ) { ... }

If C&lt;$thing&gt; refers to an object, then this function returns the name
of the package the object has been blessed into. If C&lt;$thing&gt; doesn't
contain a reference to a blessed object, the C&lt;blessed&gt; function
returns C&lt;undef&gt;.

Note that C&lt;blessed($thing)&gt; will also return false if C&lt;$thing&gt; has
been blessed into a class named &quot;0&quot;. This is a possible, but quite
pathological. Don't create a class named &quot;0&quot; unless you know what
you're doing.

Similarly, Perl's built-in C&lt;ref&gt; function treats a reference to a
blessed object specially. If you call C&lt;ref($thing)&gt; and C&lt;$thing&gt;
holds a reference to an object, it will return the name of the class
that the object has been blessed into.

If you simply want to check that a variable contains an object
reference, we recommend that you use C&lt;defined blessed($object)&gt;, since
C&lt;ref&gt; returns true values for all references, not just objects.

=head2 The UNIVERSAL Class
X&lt;UNIVERSAL&gt;

All classes automatically inherit from the L&lt;UNIVERSAL&gt; class, which is
built-in to the Perl core. This class provides a number of methods, all
of which can be called on either a class or an object. You can also
choose to override some of these methods in your class. If you do so,
we recommend that you follow the built-in semantics described below.

=over 4

=item isa($class)
X&lt;isa&gt;

The C&lt;isa&gt; method returns I&lt;true&gt; if the object is a member of the
class in C&lt;$class&gt;, or a member of a subclass of C&lt;$class&gt;.

If you override this method, it should never throw an exception.

=item DOES($role)
X&lt;DOES&gt;

The C&lt;DOES&gt; method returns I&lt;true&gt; if its object claims to perform the
role C&lt;$role&gt;. By default, this is equivalent to C&lt;isa&gt;. This method is
provided for use by object system extensions that implement roles, like
C&lt;Moose&gt; and C&lt;Role::Tiny&gt;.

You can also override C&lt;DOES&gt; directly in your own classes. If you
override this method, it should never throw an exception.

=item can($method)
X&lt;can&gt;

The C&lt;can&gt; method checks to see if the class or object it was called on
has a method named C&lt;$method&gt;. This checks for the method in the class
and all of its parents. If the method exists, then a reference to the
subroutine is returned. If it does not then C&lt;undef&gt; is returned.

If your class responds to method calls via C&lt;AUTOLOAD&gt;, you may want to
overload C&lt;can&gt; to return a subroutine reference for methods which your
C&lt;AUTOLOAD&gt; method handles.

If you override this method, it should never throw an exception.

=item VERSION($need)
X&lt;VERSION&gt;

The C&lt;VERSION&gt; method returns the version number of the class
(package).

If the C&lt;$need&gt; argument is given then it will check that the current
version (as defined by the $VERSION variable in the package) is greater
than or equal to C&lt;$need&gt;; it will die if this is not the case. This
method is called automatically by the C&lt;VERSION&gt; form of C&lt;use&gt;.

    use Package 1.2 qw(some imported subs);
    # implies:
    Package-&gt;VERSION(1.2);

We recommend that you use this method to access another package's
version, rather than looking directly at C&lt;$Package::VERSION&gt;. The
package you are looking at could have overridden the C&lt;VERSION&gt; method.

We also recommend using this method to check whether a module has a
sufficient version. The internal implementation uses the L&lt;version&gt;
module to make sure that different types of version numbers are
compared correctly.

=back

=head2 AUTOLOAD
X&lt;AUTOLOAD&gt;

If you call a method that doesn't exist in a class, Perl will throw an
error. However, if that class or any of its parent classes defines an
C&lt;AUTOLOAD&gt; method, that C&lt;AUTOLOAD&gt; method is called instead.

C&lt;AUTOLOAD&gt; is called as a regular method, and the caller will not know
the difference. Whatever value your C&lt;AUTOLOAD&gt; method returns is
returned to the caller.

The fully qualified method name that was called is available in the
C&lt;$AUTOLOAD&gt; package global for your class. Since this is a global, if
you want to refer to do it without a package name prefix under C&lt;strict
'vars'&gt;, you need to declare it.

  # XXX - this is a terrible way to implement accessors, but it makes
  # for a simple example.
  our $AUTOLOAD;
  sub AUTOLOAD {
      my $self = shift;

      # Remove qualifier from original method name...
      my $called =  $AUTOLOAD =~ s/.*:://r;

      # Is there an attribute of that name?
      die &quot;No such attribute: $called&quot;
          unless exists $self-&gt;{$called};

      # If so, return it...
      return $self-&gt;{$called};
  }

  sub DESTROY { } # see below

Without the C&lt;our $AUTOLOAD&gt; declaration, this code will not compile
under the L&lt;strict&gt; pragma.

As the comment says, this is not a good way to implement accessors.
It's slow and too clever by far. However, you may see this as a way to
provide accessors in older Perl code. See L&lt;perlootut&gt; for
recommendations on OO coding in Perl.

If your class does have an C&lt;AUTOLOAD&gt; method, we strongly recommend
that you override C&lt;can&gt; in your class as well. Your overridden C&lt;can&gt;
method should return a subroutine reference for any method that your
C&lt;AUTOLOAD&gt; responds to.

=head2 Destructors
X&lt;destructor&gt; X&lt;DESTROY&gt;

When the last reference to an object goes away, the object is
destroyed. If you only have one reference to an object stored in a
lexical scalar, the object is destroyed when that scalar goes out of
scope. If you store the object in a package global, that object may not
go out of scope until the program exits.

If you want to do something when the object is destroyed, you can
define a C&lt;DESTROY&gt; method in your class. This method will always be
called by Perl at the appropriate time, unless the method is empty.

This is called just like any other method, with the object as the first
argument. It does not receive any additional arguments. However, the
C&lt;$_[0]&gt; variable will be read-only in the destructor, so you cannot
assign a value to it.

If your C&lt;DESTROY&gt; method throws an error, this error will be ignored.
It will not be sent to C&lt;STDERR&gt; and it will not cause the program to
die. However, if your destructor is running inside an C&lt;eval {}&gt; block,
then the error will change the value of C&lt;$@&gt;.

Because C&lt;DESTROY&gt; methods can be called at any time, you should
localize any global variables you might update in your C&lt;DESTROY&gt;. In
particular, if you use C&lt;eval {}&gt; you should localize C&lt;$@&gt;, and if you
use C&lt;system&gt; or backticks you should localize C&lt;$?&gt;.

If you define an C&lt;AUTOLOAD&gt; in your class, then Perl will call your
C&lt;AUTOLOAD&gt; to handle the C&lt;DESTROY&gt; method. You can prevent this by
defining an empty C&lt;DESTROY&gt;, like we did in the autoloading example.
You can also check the value of C&lt;$AUTOLOAD&gt; and return without doing
anything when called to handle C&lt;DESTROY&gt;.

=head3 Global Destruction

The order in which objects are destroyed during the global destruction
before the program exits is unpredictable. This means that any objects
contained by your object may already have been destroyed. You should
check that a contained object is defined before calling a method on it:

  sub DESTROY {
      my $self = shift;

      $self-&gt;{handle}-&gt;close() if $self-&gt;{handle};
  }

You can use the C&lt;${^GLOBAL_PHASE}&gt; variable to detect if you are
currently in the global destruction phase:

  sub DESTROY {
      my $self = shift;

      return if ${^GLOBAL_PHASE} eq 'DESTRUCT';

      $self-&gt;{handle}-&gt;close();
  }

Note that this variable was added in Perl 5.14.0. If you want to detect
the global destruction phase on older versions of Perl, you can use the
C&lt;Devel::GlobalDestruction&gt; module on CPAN.

If your C&lt;DESTROY&gt; method issues a warning during global destruction,
the Perl interpreter will append the string &quot; during global
destruction&quot; to the warning.

During global destruction, Perl will always garbage collect objects
before unblessed references. See L&lt;perlhacktips/PERL_DESTRUCT_LEVEL&gt;
for more information about global destruction.

=head2 Non-Hash Objects

All the examples so far have shown objects based on a blessed hash.
However, it's possible to bless any type of data structure or referent,
including scalars, globs, and subroutines. You may see this sort of
thing when looking at code in the wild.

Here's an example of a module as a blessed scalar:

  package Time;

  use strict;
  use warnings;

  sub new {
      my $class = shift;

      my $time = time;
      return bless \$time, $class;
  }

  sub epoch {
      my $self = shift;
      return ${ $self };
  }

  my $time = Time-&gt;new();
  print $time-&gt;epoch();

=head2 Inside-Out objects

In the past, the Perl community experimented with a technique called
&quot;inside-out objects&quot;. An inside-out object stores its data outside of
the object's reference, indexed on a unique property of the object,
such as its memory address, rather than in the object itself. This has
the advantage of enforcing the encapsulation of object attributes,
since their data is not stored in the object itself.

This technique was popular for a while (and was recommended in Damian
Conway's I&lt;Perl Best Practices&gt;), but never achieved universal
adoption. The L&lt;Object::InsideOut&gt; module on CPAN provides a
comprehensive implementation of this technique, and you may see it or
other inside-out modules in the wild.

Here is a simple example of the technique, using the
L&lt;Hash::Util::FieldHash&gt; core module. This module was added to the core
to support inside-out object implementations.

  package Time;

  use strict;
  use warnings;

  use Hash::Util::FieldHash 'fieldhash';

  fieldhash my %time_for;

  sub new {
      my $class = shift;

      my $self = bless \( my $object ), $class;

      $time_for{$self} = time;

      return $self;
  }

  sub epoch {
      my $self = shift;

      return $time_for{$self};
  }

  my $time = Time-&gt;new;
  print $time-&gt;epoch;

=head2 Pseudo-hashes

The pseudo-hash feature was an experimental feature introduced in
earlier versions of Perl and removed in 5.10.0. A pseudo-hash is an
array reference which can be accessed using named keys like a hash. You
may run in to some code in the wild which uses it. See the L&lt;fields&gt;
pragma for more information.

=head1 SEE ALSO

A kinder, gentler tutorial on object-oriented programming in Perl can
be found in L&lt;perlootut&gt;. You should also check out L&lt;perlmodlib&gt; for
some style guides on constructing both modules and classes.

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>