<h2>Editing File: /usr/share/perl5/pod/perlmod.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perlmod - Perl modules (packages and symbol tables)

=head1 DESCRIPTION

=head2 Is this the document you were after?

There are other documents which might contain the information that you're
looking for:

=over 2

=item This doc

Perl's packages, namespaces, and some info on classes.

=item L&lt;perlnewmod&gt;

Tutorial on making a new module.

=item L&lt;perlmodstyle&gt;

Best practices for making a new module.

=back

=head2 Packages
X&lt;package&gt; X&lt;namespace&gt; X&lt;variable, global&gt; X&lt;global variable&gt; X&lt;global&gt;

Unlike Perl 4, in which all the variables were dynamic and shared one
global name space, causing maintainability problems, Perl 5 provides two
mechanisms for protecting code from having its variables stomped on by
other code: lexically scoped variables created with C&lt;my&gt; or C&lt;state&gt; and
namespaced global variables, which are exposed via the C&lt;vars&gt; pragma,
or the C&lt;our&gt; keyword. Any global variable is considered to
be part of a namespace and can be accessed via a &quot;fully qualified form&quot;.
Conversely, any lexically scoped variable is considered to be part of
that lexical-scope, and does not have a &quot;fully qualified form&quot;.

In perl namespaces are called &quot;packages&quot; and
the C&lt;package&gt; declaration tells the compiler which
namespace to prefix to C&lt;our&gt; variables and unqualified dynamic names.
This both protects
against accidental stomping and provides an interface for deliberately
clobbering global dynamic variables declared and used in other scopes or
packages, when that is what you want to do.

The scope of the C&lt;package&gt; declaration is from the
declaration itself through the end of the enclosing block, C&lt;eval&gt;,
or file, whichever comes first (the same scope as the my(), our(), state(), and
local() operators, and also the effect
of the experimental &quot;reference aliasing,&quot; which may change), or until
the next C&lt;package&gt; declaration.  Unqualified dynamic identifiers will be in
this namespace, except for those few identifiers that, if unqualified,
default to the main package instead of the current one as described
below.  A C&lt;package&gt; statement affects only dynamic global
symbols, including subroutine names, and variables you've used local()
on, but I&lt;not&gt; lexical variables created with my(), our() or state().

Typically, a C&lt;package&gt; statement is the first declaration in a file
included in a program by one of the C&lt;do&gt;, C&lt;require&gt;, or C&lt;use&gt; operators.  You can
switch into a package in more than one place: C&lt;package&gt; has no
effect beyond specifying which symbol table the compiler will use for
dynamic symbols for the rest of that block or until the next C&lt;package&gt; statement.
You can refer to variables and filehandles in other packages
by prefixing the identifier with the package name and a double
colon: C&lt;$Package::Variable&gt;.  If the package name is null, the
C&lt;main&gt; package is assumed.  That is, C&lt;$::sail&gt; is equivalent to
C&lt;$main::sail&gt;.

The old package delimiter was a single quote, but double colon is now the
preferred delimiter, in part because it's more readable to humans, and
in part because it's more readable to B&lt;emacs&gt; macros.  It also makes C++
programmers feel like they know what's going on--as opposed to using the
single quote as separator, which was there to make Ada programmers feel
like they knew what was going on.  Because the old-fashioned syntax is still
supported for backwards compatibility, if you try to use a string like
C&lt;&quot;This is $owner's house&quot;&gt;, you'll be accessing C&lt;$owner::s&gt;; that is,
the $s variable in package C&lt;owner&gt;, which is probably not what you meant.
Use braces to disambiguate, as in C&lt;&quot;This is ${owner}'s house&quot;&gt;.
X&lt;::&gt; X&lt;'&gt;

Packages may themselves contain package separators, as in
C&lt;$OUTER::INNER::var&gt;.  This implies nothing about the order of
name lookups, however.  There are no relative packages: all symbols
are either local to the current package, or must be fully qualified
from the outer package name down.  For instance, there is nowhere
within package C&lt;OUTER&gt; that C&lt;$INNER::var&gt; refers to
C&lt;$OUTER::INNER::var&gt;.  C&lt;INNER&gt; refers to a totally
separate global package. The custom of treating package names as a
hierarchy is very strong, but the language in no way enforces it.

Only identifiers starting with letters (or underscore) are stored
in a package's symbol table.  All other symbols are kept in package
C&lt;main&gt;, including all punctuation variables, like $_.  In addition,
when unqualified, the identifiers STDIN, STDOUT, STDERR, ARGV,
ARGVOUT, ENV, INC, and SIG are forced to be in package C&lt;main&gt;,
even when used for other purposes than their built-in ones.  If you
have a package called C&lt;m&gt;, C&lt;s&gt;, or C&lt;y&gt;, then you can't use the
qualified form of an identifier because it would be instead interpreted
as a pattern match, a substitution, or a transliteration.
X&lt;variable, punctuation&gt; 

Variables beginning with underscore used to be forced into package
main, but we decided it was more useful for package writers to be able
to use leading underscore to indicate private variables and method names.
However, variables and functions named with a single C&lt;_&gt;, such as
$_ and C&lt;sub _&gt;, are still forced into the package C&lt;main&gt;.  See also
L&lt;perlvar/&quot;The Syntax of Variable Names&quot;&gt;.

C&lt;eval&gt;ed strings are compiled in the package in which the eval() was
compiled.  (Assignments to C&lt;$SIG{}&gt;, however, assume the signal
handler specified is in the C&lt;main&gt; package.  Qualify the signal handler
name if you wish to have a signal handler in a package.)  For an
example, examine F&lt;perldb.pl&gt; in the Perl library.  It initially switches
to the C&lt;DB&gt; package so that the debugger doesn't interfere with variables
in the program you are trying to debug.  At various points, however, it
temporarily switches back to the C&lt;main&gt; package to evaluate various
expressions in the context of the C&lt;main&gt; package (or wherever you came
from).  See L&lt;perldebug&gt;.

The special symbol C&lt;__PACKAGE__&gt; contains the current package, but cannot
(easily) be used to construct variable names. After C&lt;my($foo)&gt; has hidden
package variable C&lt;$foo&gt;, it can still be accessed, without knowing what
package you are in, as C&lt;${__PACKAGE__.'::foo'}&gt;.

See L&lt;perlsub&gt; for other scoping issues related to my() and local(),
and L&lt;perlref&gt; regarding closures.

=head2 Symbol Tables
X&lt;symbol table&gt; X&lt;stash&gt; X&lt;%::&gt; X&lt;%main::&gt; X&lt;typeglob&gt; X&lt;glob&gt; X&lt;alias&gt;

The symbol table for a package happens to be stored in the hash of that
name with two colons appended.  The main symbol table's name is thus
C&lt;%main::&gt;, or C&lt;%::&gt; for short.  Likewise the symbol table for the nested
package mentioned earlier is named C&lt;%OUTER::INNER::&gt;.

The value in each entry of the hash is what you are referring to when you
use the C&lt;*name&gt; typeglob notation.

    local *main::foo    = *main::bar;

You can use this to print out all the variables in a package, for
instance.  The standard but antiquated F&lt;dumpvar.pl&gt; library and
the CPAN module Devel::Symdump make use of this.

The results of creating new symbol table entries directly or modifying any
entries that are not already typeglobs are undefined and subject to change
between releases of perl.

Assignment to a typeglob performs an aliasing operation, i.e.,

    *dick = *richard;

causes variables, subroutines, formats, and file and directory handles
accessible via the identifier C&lt;richard&gt; also to be accessible via the
identifier C&lt;dick&gt;.  If you want to alias only a particular variable or
subroutine, assign a reference instead:

    *dick = \$richard;

Which makes $richard and $dick the same variable, but leaves
@richard and @dick as separate arrays.  Tricky, eh?

There is one subtle difference between the following statements:

    *foo = *bar;
    *foo = \$bar;

C&lt;*foo = *bar&gt; makes the typeglobs themselves synonymous while
C&lt;*foo = \$bar&gt; makes the SCALAR portions of two distinct typeglobs
refer to the same scalar value. This means that the following code:

    $bar = 1;
    *foo = \$bar;       # Make $foo an alias for $bar

    {
        local $bar = 2; # Restrict changes to block
        print $foo;     # Prints '1'!
    }

Would print '1', because C&lt;$foo&gt; holds a reference to the I&lt;original&gt;
C&lt;$bar&gt;. The one that was stuffed away by C&lt;local()&gt; and which will be
restored when the block ends. Because variables are accessed through the
typeglob, you can use C&lt;*foo = *bar&gt; to create an alias which can be
localized. (But be aware that this means you can't have a separate
C&lt;@foo&gt; and C&lt;@bar&gt;, etc.)

What makes all of this important is that the Exporter module uses glob
aliasing as the import/export mechanism. Whether or not you can properly
localize a variable that has been exported from a module depends on how
it was exported:

    @EXPORT = qw($FOO); # Usual form, can't be localized
    @EXPORT = qw(*FOO); # Can be localized

You can work around the first case by using the fully qualified name
(C&lt;$Package::FOO&gt;) where you need a local value, or by overriding it
by saying C&lt;*FOO = *Package::FOO&gt; in your script.

The C&lt;*x = \$y&gt; mechanism may be used to pass and return cheap references
into or from subroutines if you don't want to copy the whole
thing.  It only works when assigning to dynamic variables, not
lexicals.

    %some_hash = ();			# can't be my()
    *some_hash = fn( \%another_hash );
    sub fn {
	local *hashsym = shift;
	# now use %hashsym normally, and you
	# will affect the caller's %another_hash
	my %nhash = (); # do what you want
	return \%nhash;
    }

On return, the reference will overwrite the hash slot in the
symbol table specified by the *some_hash typeglob.  This
is a somewhat tricky way of passing around references cheaply
when you don't want to have to remember to dereference variables
explicitly.

Another use of symbol tables is for making &quot;constant&quot; scalars.
X&lt;constant&gt; X&lt;scalar, constant&gt;

    *PI = \3.14159265358979;

Now you cannot alter C&lt;$PI&gt;, which is probably a good thing all in all.
This isn't the same as a constant subroutine, which is subject to
optimization at compile-time.  A constant subroutine is one prototyped
to take no arguments and to return a constant expression.  See
L&lt;perlsub&gt; for details on these.  The C&lt;use constant&gt; pragma is a
convenient shorthand for these.

You can say C&lt;*foo{PACKAGE}&gt; and C&lt;*foo{NAME}&gt; to find out what name and
package the *foo symbol table entry comes from.  This may be useful
in a subroutine that gets passed typeglobs as arguments:

    sub identify_typeglob {
        my $glob = shift;
        print 'You gave me ', *{$glob}{PACKAGE},
            '::', *{$glob}{NAME}, &quot;\n&quot;;
    }
    identify_typeglob *foo;
    identify_typeglob *bar::baz;

This prints

    You gave me main::foo
    You gave me bar::baz

The C&lt;*foo{THING}&gt; notation can also be used to obtain references to the
individual elements of *foo.  See L&lt;perlref&gt;.

Subroutine definitions (and declarations, for that matter) need
not necessarily be situated in the package whose symbol table they
occupy.  You can define a subroutine outside its package by
explicitly qualifying the name of the subroutine:

    package main;
    sub Some_package::foo { ... }   # &amp;foo defined in Some_package

This is just a shorthand for a typeglob assignment at compile time:

    BEGIN { *Some_package::foo = sub { ... } }

and is I&lt;not&gt; the same as writing:

    {
	package Some_package;
	sub foo { ... }
    }

In the first two versions, the body of the subroutine is
lexically in the main package, I&lt;not&gt; in Some_package. So
something like this:

    package main;

    $Some_package::name = &quot;fred&quot;;
    $main::name = &quot;barney&quot;;

    sub Some_package::foo {
	print &quot;in &quot;, __PACKAGE__, &quot;: \$name is '$name'\n&quot;;
    }

    Some_package::foo();

prints:

    in main: $name is 'barney'

rather than:

    in Some_package: $name is 'fred'

This also has implications for the use of the SUPER:: qualifier
(see L&lt;perlobj&gt;).

=head2 BEGIN, UNITCHECK, CHECK, INIT and END
X&lt;BEGIN&gt; X&lt;UNITCHECK&gt; X&lt;CHECK&gt; X&lt;INIT&gt; X&lt;END&gt;

Five specially named code blocks are executed at the beginning and at
the end of a running Perl program.  These are the C&lt;BEGIN&gt;,
C&lt;UNITCHECK&gt;, C&lt;CHECK&gt;, C&lt;INIT&gt;, and C&lt;END&gt; blocks.

These code blocks can be prefixed with C&lt;sub&gt; to give the appearance of a
subroutine (although this is not considered good style).  One should note
that these code blocks don't really exist as named subroutines (despite
their appearance). The thing that gives this away is the fact that you can
have B&lt;more than one&gt; of these code blocks in a program, and they will get
B&lt;all&gt; executed at the appropriate moment.  So you can't execute any of
these code blocks by name.

A C&lt;BEGIN&gt; code block is executed as soon as possible, that is, the moment
it is completely defined, even before the rest of the containing file (or
string) is parsed.  You may have multiple C&lt;BEGIN&gt; blocks within a file (or
eval'ed string); they will execute in order of definition.  Because a C&lt;BEGIN&gt;
code block executes immediately, it can pull in definitions of subroutines
and such from other files in time to be visible to the rest of the compile
and run time.  Once a C&lt;BEGIN&gt; has run, it is immediately undefined and any
code it used is returned to Perl's memory pool.

An C&lt;END&gt; code block is executed as late as possible, that is, after
perl has finished running the program and just before the interpreter
is being exited, even if it is exiting as a result of a die() function.
(But not if it's morphing into another program via C&lt;exec&gt;, or
being blown out of the water by a signal--you have to trap that yourself
(if you can).)  You may have multiple C&lt;END&gt; blocks within a file--they
will execute in reverse order of definition; that is: last in, first
out (LIFO).  C&lt;END&gt; blocks are not executed when you run perl with the
C&lt;-c&gt; switch, or if compilation fails.

Note that C&lt;END&gt; code blocks are B&lt;not&gt; executed at the end of a string
C&lt;eval()&gt;: if any C&lt;END&gt; code blocks are created in a string C&lt;eval()&gt;,
they will be executed just as any other C&lt;END&gt; code block of that package
in LIFO order just before the interpreter is being exited.

Inside an C&lt;END&gt; code block, C&lt;$?&gt; contains the value that the program is
going to pass to C&lt;exit()&gt;.  You can modify C&lt;$?&gt; to change the exit
value of the program.  Beware of changing C&lt;$?&gt; by accident (e.g. by
running something via C&lt;system&gt;).
X&lt;$?&gt;

Inside of a C&lt;END&gt; block, the value of C&lt;${^GLOBAL_PHASE}&gt; will be
C&lt;&quot;END&quot;&gt;.

C&lt;UNITCHECK&gt;, C&lt;CHECK&gt; and C&lt;INIT&gt; code blocks are useful to catch the
transition between the compilation phase and the execution phase of
the main program.

C&lt;UNITCHECK&gt; blocks are run just after the unit which defined them has
been compiled.  The main program file and each module it loads are
compilation units, as are string C&lt;eval&gt;s, run-time code compiled using the
C&lt;(?{ })&gt; construct in a regex, calls to C&lt;do FILE&gt;, C&lt;require FILE&gt;,
and code after the C&lt;-e&gt; switch on the command line.

C&lt;BEGIN&gt; and C&lt;UNITCHECK&gt; blocks are not directly related to the phase of
the interpreter.  They can be created and executed during any phase.

C&lt;CHECK&gt; code blocks are run just after the B&lt;initial&gt; Perl compile phase ends
and before the run time begins, in LIFO order.  C&lt;CHECK&gt; code blocks are used
in the Perl compiler suite to save the compiled state of the program.

Inside of a C&lt;CHECK&gt; block, the value of C&lt;${^GLOBAL_PHASE}&gt; will be
C&lt;&quot;CHECK&quot;&gt;.

C&lt;INIT&gt; blocks are run just before the Perl runtime begins execution, in
&quot;first in, first out&quot; (FIFO) order.

Inside of an C&lt;INIT&gt; block, the value of C&lt;${^GLOBAL_PHASE}&gt; will be C&lt;&quot;INIT&quot;&gt;.

The C&lt;CHECK&gt; and C&lt;INIT&gt; blocks in code compiled by C&lt;require&gt;, string C&lt;do&gt;,
or string C&lt;eval&gt; will not be executed if they occur after the end of the
main compilation phase; that can be a problem in mod_perl and other persistent
environments which use those functions to load code at runtime.

When you use the B&lt;-n&gt; and B&lt;-p&gt; switches to Perl, C&lt;BEGIN&gt; and
C&lt;END&gt; work just as they do in B&lt;awk&gt;, as a degenerate case.
Both C&lt;BEGIN&gt; and C&lt;CHECK&gt; blocks are run when you use the B&lt;-c&gt;
switch for a compile-only syntax check, although your main code
is not.

The B&lt;begincheck&gt; program makes it all clear, eventually:

  #!/usr/bin/perl

  # begincheck

  print         &quot;10. Ordinary code runs at runtime.\n&quot;;

  END { print   &quot;16.   So this is the end of the tale.\n&quot; }
  INIT { print  &quot; 7. INIT blocks run FIFO just before runtime.\n&quot; }
  UNITCHECK {
    print       &quot; 4.   And therefore before any CHECK blocks.\n&quot;
  }
  CHECK { print &quot; 6.   So this is the sixth line.\n&quot; }

  print         &quot;11.   It runs in order, of course.\n&quot;;

  BEGIN { print &quot; 1. BEGIN blocks run FIFO during compilation.\n&quot; }
  END { print   &quot;15.   Read perlmod for the rest of the story.\n&quot; }
  CHECK { print &quot; 5. CHECK blocks run LIFO after all compilation.\n&quot; }
  INIT { print  &quot; 8.   Run this again, using Perl's -c switch.\n&quot; }

  print         &quot;12.   This is anti-obfuscated code.\n&quot;;

  END { print   &quot;14. END blocks run LIFO at quitting time.\n&quot; }
  BEGIN { print &quot; 2.   So this line comes out second.\n&quot; }
  UNITCHECK {
   print &quot; 3. UNITCHECK blocks run LIFO after each file is compiled.\n&quot;
  }
  INIT { print  &quot; 9.   You'll see the difference right away.\n&quot; }

  print         &quot;13.   It only _looks_ like it should be confusing.\n&quot;;

  __END__

=head2 Perl Classes
X&lt;class&gt; X&lt;@ISA&gt;

There is no special class syntax in Perl, but a package may act
as a class if it provides subroutines to act as methods.  Such a
package may also derive some of its methods from another class (package)
by listing the other package name(s) in its global @ISA array (which
must be a package global, not a lexical).

For more on this, see L&lt;perlootut&gt; and L&lt;perlobj&gt;.

=head2 Perl Modules
X&lt;module&gt;

A module is just a set of related functions in a library file, i.e.,
a Perl package with the same name as the file.  It is specifically
designed to be reusable by other modules or programs.  It may do this
by providing a mechanism for exporting some of its symbols into the
symbol table of any package using it, or it may function as a class
definition and make its semantics available implicitly through
method calls on the class and its objects, without explicitly
exporting anything.  Or it can do a little of both.

For example, to start a traditional, non-OO module called Some::Module,
create a file called F&lt;Some/Module.pm&gt; and start with this template:

    package Some::Module;  # assumes Some/Module.pm

    use strict;
    use warnings;

    BEGIN {
        require Exporter;

        # set the version for version checking
        our $VERSION     = 1.00;

        # Inherit from Exporter to export functions and variables
        our @ISA         = qw(Exporter);

        # Functions and variables which are exported by default
        our @EXPORT      = qw(func1 func2);

        # Functions and variables which can be optionally exported
        our @EXPORT_OK   = qw($Var1 %Hashit func3);
    }

    # exported package globals go here
    our $Var1    = '';
    our %Hashit  = ();

    # non-exported package globals go here
    # (they are still accessible as $Some::Module::stuff)
    our @more    = ();
    our $stuff   = '';

    # file-private lexicals go here, before any functions which use them
    my $priv_var    = '';
    my %secret_hash = ();

    # here's a file-private function as a closure,
    # callable as $priv_func-&gt;();
    my $priv_func = sub {
        ...
    };

    # make all your functions, whether exported or not;
    # remember to put something interesting in the {} stubs
    sub func1      { ... }
    sub func2      { ... }

    # this one isn't exported, but could be called directly
    # as Some::Module::func3()
    sub func3      { ... }

    END { ... }       # module clean-up code here (global destructor)

    1;  # don't forget to return a true value from the file

Then go on to declare and use your variables in functions without
any qualifications.  See L&lt;Exporter&gt; and the L&lt;perlmodlib&gt; for
details on mechanics and style issues in module creation.

Perl modules are included into your program by saying

    use Module;

or

    use Module LIST;

This is exactly equivalent to

    BEGIN { require 'Module.pm'; 'Module'-&gt;import; }

or

    BEGIN { require 'Module.pm'; 'Module'-&gt;import( LIST ); }

As a special case

    use Module ();

is exactly equivalent to

    BEGIN { require 'Module.pm'; }

All Perl module files have the extension F&lt;.pm&gt;.  The C&lt;use&gt; operator
assumes this so you don't have to spell out &quot;F&lt;Module.pm&gt;&quot; in quotes.
This also helps to differentiate new modules from old F&lt;.pl&gt; and
F&lt;.ph&gt; files.  Module names are also capitalized unless they're
functioning as pragmas; pragmas are in effect compiler directives,
and are sometimes called &quot;pragmatic modules&quot; (or even &quot;pragmata&quot;
if you're a classicist).

The two statements:

    require SomeModule;
    require &quot;SomeModule.pm&quot;;

differ from each other in two ways.  In the first case, any double
colons in the module name, such as C&lt;Some::Module&gt;, are translated
into your system's directory separator, usually &quot;/&quot;.   The second
case does not, and would have to be specified literally.  The other
difference is that seeing the first C&lt;require&gt; clues in the compiler
that uses of indirect object notation involving &quot;SomeModule&quot;, as
in C&lt;$ob = purge SomeModule&gt;, are method calls, not function calls.
(Yes, this really can make a difference.)

Because the C&lt;use&gt; statement implies a C&lt;BEGIN&gt; block, the importing
of semantics happens as soon as the C&lt;use&gt; statement is compiled,
before the rest of the file is compiled.  This is how it is able
to function as a pragma mechanism, and also how modules are able to
declare subroutines that are then visible as list or unary operators for
the rest of the current file.  This will not work if you use C&lt;require&gt;
instead of C&lt;use&gt;.  With C&lt;require&gt; you can get into this problem:

    require Cwd;		# make Cwd:: accessible
    $here = Cwd::getcwd();

    use Cwd;			# import names from Cwd::
    $here = getcwd();

    require Cwd;	    	# make Cwd:: accessible
    $here = getcwd(); 		# oops! no main::getcwd()

In general, C&lt;use Module ()&gt; is recommended over C&lt;require Module&gt;,
because it determines module availability at compile time, not in the
middle of your program's execution.  An exception would be if two modules
each tried to C&lt;use&gt; each other, and each also called a function from
that other module.  In that case, it's easy to use C&lt;require&gt; instead.

Perl packages may be nested inside other package names, so we can have
package names containing C&lt;::&gt;.  But if we used that package name
directly as a filename it would make for unwieldy or impossible
filenames on some systems.  Therefore, if a module's name is, say,
C&lt;Text::Soundex&gt;, then its definition is actually found in the library
file F&lt;Text/Soundex.pm&gt;.

Perl modules always have a F&lt;.pm&gt; file, but there may also be
dynamically linked executables (often ending in F&lt;.so&gt;) or autoloaded
subroutine definitions (often ending in F&lt;.al&gt;) associated with the
module.  If so, these will be entirely transparent to the user of
the module.  It is the responsibility of the F&lt;.pm&gt; file to load
(or arrange to autoload) any additional functionality.  For example,
although the POSIX module happens to do both dynamic loading and
autoloading, the user can say just C&lt;use POSIX&gt; to get it all.

=head2 Making your module threadsafe
X&lt;threadsafe&gt; X&lt;thread safe&gt;
X&lt;module, threadsafe&gt; X&lt;module, thread safe&gt;
X&lt;CLONE&gt; X&lt;CLONE_SKIP&gt; X&lt;thread&gt; X&lt;threads&gt; X&lt;ithread&gt;

Perl supports a type of threads called interpreter threads (ithreads).
These threads can be used explicitly and implicitly.

Ithreads work by cloning the data tree so that no data is shared
between different threads. These threads can be used by using the C&lt;threads&gt;
module or by doing fork() on win32 (fake fork() support). When a
thread is cloned all Perl data is cloned, however non-Perl data cannot
be cloned automatically.  Perl after 5.8.0 has support for the C&lt;CLONE&gt;
special subroutine.  In C&lt;CLONE&gt; you can do whatever
you need to do,
like for example handle the cloning of non-Perl data, if necessary.
C&lt;CLONE&gt; will be called once as a class method for every package that has it
defined (or inherits it).  It will be called in the context of the new thread,
so all modifications are made in the new area.  Currently CLONE is called with
no parameters other than the invocant package name, but code should not assume
that this will remain unchanged, as it is likely that in future extra parameters
will be passed in to give more information about the state of cloning.

If you want to CLONE all objects you will need to keep track of them per
package. This is simply done using a hash and Scalar::Util::weaken().

Perl after 5.8.7 has support for the C&lt;CLONE_SKIP&gt; special subroutine.
Like C&lt;CLONE&gt;, C&lt;CLONE_SKIP&gt; is called once per package; however, it is
called just before cloning starts, and in the context of the parent
thread. If it returns a true value, then no objects of that class will
be cloned; or rather, they will be copied as unblessed, undef values.
For example: if in the parent there are two references to a single blessed
hash, then in the child there will be two references to a single undefined
scalar value instead.
This provides a simple mechanism for making a module threadsafe; just add
C&lt;sub CLONE_SKIP { 1 }&gt; at the top of the class, and C&lt;DESTROY()&gt; will
now only be called once per object. Of course, if the child thread needs
to make use of the objects, then a more sophisticated approach is
needed.

Like C&lt;CLONE&gt;, C&lt;CLONE_SKIP&gt; is currently called with no parameters other
than the invocant package name, although that may change. Similarly, to
allow for future expansion, the return value should be a single C&lt;0&gt; or
C&lt;1&gt; value.

=head1 SEE ALSO

See L&lt;perlmodlib&gt; for general style issues related to building Perl
modules and classes, as well as descriptions of the standard library
and CPAN, L&lt;Exporter&gt; for how Perl's standard import/export mechanism
works, L&lt;perlootut&gt; and L&lt;perlobj&gt; for in-depth information on
creating classes, L&lt;perlobj&gt; for a hard-core reference document on
objects, L&lt;perlsub&gt; for an explanation of functions and scoping,
and L&lt;perlxstut&gt; and L&lt;perlguts&gt; for more information on writing
extension modules.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>