<h2>Editing File: /usr/share/perl5/pod/perlintro.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perlintro -- a brief introduction and overview of Perl

=head1 DESCRIPTION

This document is intended to give you a quick overview of the Perl
programming language, along with pointers to further documentation.  It
is intended as a &quot;bootstrap&quot; guide for those who are new to the
language, and provides just enough information for you to be able to
read other peoples' Perl and understand roughly what it's doing, or
write your own simple scripts.

This introductory document does not aim to be complete.  It does not
even aim to be entirely accurate.  In some cases perfection has been
sacrificed in the goal of getting the general idea across.  You are
I&lt;strongly&gt; advised to follow this introduction with more information
from the full Perl manual, the table of contents to which can be found
in L&lt;perltoc&gt;.

Throughout this document you'll see references to other parts of the
Perl documentation.  You can read that documentation using the C&lt;perldoc&gt;
command or whatever method you're using to read this document.

Throughout Perl's documentation, you'll find numerous examples intended
to help explain the discussed features.  Please keep in mind that many
of them are code fragments rather than complete programs.

These examples often reflect the style and preference of the author of
that piece of the documentation, and may be briefer than a corresponding
line of code in a real program.  Except where otherwise noted, you
should assume that C&lt;use strict&gt; and C&lt;use warnings&gt; statements
appear earlier in the &quot;program&quot;, and that any variables used have
already been declared, even if those declarations have been omitted
to make the example easier to read.

Do note that the examples have been written by many different authors over
a period of several decades.  Styles and techniques will therefore differ,
although some effort has been made to not vary styles too widely in the
same sections.  Do not consider one style to be better than others - &quot;There's
More Than One Way To Do It&quot; is one of Perl's mottos.  After all, in your
journey as a programmer, you are likely to encounter different styles.

=head2 What is Perl?

Perl is a general-purpose programming language originally developed for
text manipulation and now used for a wide range of tasks including
system administration, web development, network programming, GUI
development, and more.

The language is intended to be practical (easy to use, efficient,
complete) rather than beautiful (tiny, elegant, minimal).  Its major
features are that it's easy to use, supports both procedural and
object-oriented (OO) programming, has powerful built-in support for text
processing, and has one of the world's most impressive collections of
third-party modules.

Different definitions of Perl are given in L&lt;perl&gt;, L&lt;perlfaq1&gt; and
no doubt other places.  From this we can determine that Perl is different
things to different people, but that lots of people think it's at least
worth writing about.

=head2 Running Perl programs

To run a Perl program from the Unix command line:

 perl progname.pl

Alternatively, put this as the first line of your script:

 #!/usr/bin/env perl

... and run the script as F&lt;/path/to/script.pl&gt;.  Of course, it'll need
to be executable first, so C&lt;chmod 755 script.pl&gt; (under Unix).

(This start line assumes you have the B&lt;env&gt; program.  You can also put
directly the path to your perl executable, like in C&lt;#!/usr/bin/perl&gt;).

For more information, including instructions for other platforms such as
Windows and Mac OS, read L&lt;perlrun&gt;.

=head2 Safety net

Perl by default is very forgiving.  In order to make it more robust
it is recommended to start every program with the following lines:

 #!/usr/bin/perl
 use strict;
 use warnings;

The two additional lines request from perl to catch various common
problems in your code.  They check different things so you need both.  A
potential problem caught by C&lt;use strict;&gt; will cause your code to stop
immediately when it is encountered, while C&lt;use warnings;&gt; will merely
give a warning (like the command-line switch B&lt;-w&gt;) and let your code run.
To read more about them check their respective manual pages at L&lt;strict&gt;
and L&lt;warnings&gt;.

=head2 Basic syntax overview

A Perl script or program consists of one or more statements.  These
statements are simply written in the script in a straightforward
fashion.  There is no need to have a C&lt;main()&gt; function or anything of
that kind.

Perl statements end in a semi-colon:

 print &quot;Hello, world&quot;;

Comments start with a hash symbol and run to the end of the line

 # This is a comment

Whitespace is irrelevant:

 print
     &quot;Hello, world&quot;
     ;

... except inside quoted strings:

 # this would print with a linebreak in the middle
 print &quot;Hello
 world&quot;;

Double quotes or single quotes may be used around literal strings:

 print &quot;Hello, world&quot;;
 print 'Hello, world';

However, only double quotes &quot;interpolate&quot; variables and special
characters such as newlines (C&lt;\n&gt;):

 print &quot;Hello, $name\n&quot;;     # works fine
 print 'Hello, $name\n';     # prints $name\n literally

Numbers don't need quotes around them:

 print 42;

You can use parentheses for functions' arguments or omit them
according to your personal taste.  They are only required
occasionally to clarify issues of precedence.

 print(&quot;Hello, world\n&quot;);
 print &quot;Hello, world\n&quot;;

More detailed information about Perl syntax can be found in L&lt;perlsyn&gt;.

=head2 Perl variable types

Perl has three main variable types: scalars, arrays, and hashes.

=over 4

=item Scalars

A scalar represents a single value:

 my $animal = &quot;camel&quot;;
 my $answer = 42;

Scalar values can be strings, integers or floating point numbers, and Perl
will automatically convert between them as required.  There is no need
to pre-declare your variable types, but you have to declare them using
the C&lt;my&gt; keyword the first time you use them.  (This is one of the
requirements of C&lt;use strict;&gt;.)

Scalar values can be used in various ways:

 print $animal;
 print &quot;The animal is $animal\n&quot;;
 print &quot;The square of $answer is &quot;, $answer * $answer, &quot;\n&quot;;

There are a number of &quot;magic&quot; scalars with names that look like
punctuation or line noise.  These special variables are used for all
kinds of purposes, and are documented in L&lt;perlvar&gt;.  The only one you
need to know about for now is C&lt;$_&gt; which is the &quot;default variable&quot;.
It's used as the default argument to a number of functions in Perl, and
it's set implicitly by certain looping constructs.

 print;          # prints contents of $_ by default

=item Arrays

An array represents a list of values:

 my @animals = (&quot;camel&quot;, &quot;llama&quot;, &quot;owl&quot;);
 my @numbers = (23, 42, 69);
 my @mixed   = (&quot;camel&quot;, 42, 1.23);

Arrays are zero-indexed.  Here's how you get at elements in an array:

 print $animals[0];              # prints &quot;camel&quot;
 print $animals[1];              # prints &quot;llama&quot;

The special variable C&lt;$#array&gt; tells you the index of the last element
of an array:

 print $mixed[$#mixed];       # last element, prints 1.23

You might be tempted to use C&lt;$#array + 1&gt; to tell you how many items there
are in an array.  Don't bother.  As it happens, using C&lt;@array&gt; where Perl
expects to find a scalar value (&quot;in scalar context&quot;) will give you the number
of elements in the array:

 if (@animals &lt; 5) { ... }

The elements we're getting from the array start with a C&lt;$&gt; because
we're getting just a single value out of the array; you ask for a scalar,
you get a scalar.

To get multiple values from an array:

 @animals[0,1];                 # gives (&quot;camel&quot;, &quot;llama&quot;);
 @animals[0..2];                # gives (&quot;camel&quot;, &quot;llama&quot;, &quot;owl&quot;);
 @animals[1..$#animals];        # gives all except the first element

This is called an &quot;array slice&quot;.

You can do various useful things to lists:

 my @sorted    = sort @animals;
 my @backwards = reverse @numbers;

There are a couple of special arrays too, such as C&lt;@ARGV&gt; (the command
line arguments to your script) and C&lt;@_&gt; (the arguments passed to a
subroutine).  These are documented in L&lt;perlvar&gt;.

=item Hashes

A hash represents a set of key/value pairs:

 my %fruit_color = (&quot;apple&quot;, &quot;red&quot;, &quot;banana&quot;, &quot;yellow&quot;);

You can use whitespace and the C&lt;&lt; =&gt; &gt;&gt; operator to lay them out more
nicely:

 my %fruit_color = (
     apple  =&gt; &quot;red&quot;,
     banana =&gt; &quot;yellow&quot;,
 );

To get at hash elements:

 $fruit_color{&quot;apple&quot;};           # gives &quot;red&quot;

You can get at lists of keys and values with C&lt;keys()&gt; and
C&lt;values()&gt;.

 my @fruits = keys %fruit_colors;
 my @colors = values %fruit_colors;

Hashes have no particular internal order, though you can sort the keys
and loop through them.

Just like special scalars and arrays, there are also special hashes.
The most well known of these is C&lt;%ENV&gt; which contains environment
variables.  Read all about it (and other special variables) in
L&lt;perlvar&gt;.

=back

Scalars, arrays and hashes are documented more fully in L&lt;perldata&gt;.

More complex data types can be constructed using references, which allow
you to build lists and hashes within lists and hashes.

A reference is a scalar value and can refer to any other Perl data
type.  So by storing a reference as the value of an array or hash
element, you can easily create lists and hashes within lists and
hashes.  The following example shows a 2 level hash of hash
structure using anonymous hash references.

 my $variables = {
     scalar  =&gt;  {
                  description =&gt; &quot;single item&quot;,
                  sigil =&gt; '$',
                 },
     array   =&gt;  {
                  description =&gt; &quot;ordered list of items&quot;,
                  sigil =&gt; '@',
                 },
     hash    =&gt;  {
                  description =&gt; &quot;key/value pairs&quot;,
                  sigil =&gt; '%',
                 },
 };

 print &quot;Scalars begin with a $variables-&gt;{'scalar'}-&gt;{'sigil'}\n&quot;;

Exhaustive information on the topic of references can be found in
L&lt;perlreftut&gt;, L&lt;perllol&gt;, L&lt;perlref&gt; and L&lt;perldsc&gt;.

=head2 Variable scoping

Throughout the previous section all the examples have used the syntax:

 my $var = &quot;value&quot;;

The C&lt;my&gt; is actually not required; you could just use:

 $var = &quot;value&quot;;

However, the above usage will create global variables throughout your
program, which is bad programming practice.  C&lt;my&gt; creates lexically
scoped variables instead.  The variables are scoped to the block
(i.e. a bunch of statements surrounded by curly-braces) in which they
are defined.

 my $x = &quot;foo&quot;;
 my $some_condition = 1;
 if ($some_condition) {
     my $y = &quot;bar&quot;;
     print $x;           # prints &quot;foo&quot;
     print $y;           # prints &quot;bar&quot;
 }
 print $x;               # prints &quot;foo&quot;
 print $y;               # prints nothing; $y has fallen out of scope

Using C&lt;my&gt; in combination with a C&lt;use strict;&gt; at the top of
your Perl scripts means that the interpreter will pick up certain common
programming errors.  For instance, in the example above, the final
C&lt;print $y&gt; would cause a compile-time error and prevent you from
running the program.  Using C&lt;strict&gt; is highly recommended.

=head2 Conditional and looping constructs

Perl has most of the usual conditional and looping constructs.  As of Perl
5.10, it even has a case/switch statement (spelled C&lt;given&gt;/C&lt;when&gt;).  See
L&lt;perlsyn/&quot;Switch Statements&quot;&gt; for more details.

The conditions can be any Perl expression.  See the list of operators in
the next section for information on comparison and boolean logic operators,
which are commonly used in conditional statements.

=over 4

=item if

 if ( condition ) {
     ...
 } elsif ( other condition ) {
     ...
 } else {
     ...
 }

There's also a negated version of it:

 unless ( condition ) {
     ...
 }

This is provided as a more readable version of C&lt;if (!I&lt;condition&gt;)&gt;.

Note that the braces are required in Perl, even if you've only got one
line in the block.  However, there is a clever way of making your one-line
conditional blocks more English like:

 # the traditional way
 if ($zippy) {
     print &quot;Yow!&quot;;
 }

 # the Perlish post-condition way
 print &quot;Yow!&quot; if $zippy;
 print &quot;We have no bananas&quot; unless $bananas;

=item while

 while ( condition ) {
     ...
 }

There's also a negated version, for the same reason we have C&lt;unless&gt;:

 until ( condition ) {
     ...
 }

You can also use C&lt;while&gt; in a post-condition:

 print &quot;LA LA LA\n&quot; while 1;          # loops forever

=item for

Exactly like C:

 for ($i = 0; $i &lt;= $max; $i++) {
     ...
 }

The C style for loop is rarely needed in Perl since Perl provides
the more friendly list scanning C&lt;foreach&gt; loop.

=item foreach

 foreach (@array) {
     print &quot;This element is $_\n&quot;;
 }

 print $list[$_] foreach 0 .. $max;

 # you don't have to use the default $_ either...
 foreach my $key (keys %hash) {
     print &quot;The value of $key is $hash{$key}\n&quot;;
 }

The C&lt;foreach&gt; keyword is actually a synonym for the C&lt;for&gt;
keyword.  See C&lt;L&lt;perlsyn/&quot;Foreach Loops&quot;&gt;&gt;.

=back

For more detail on looping constructs (and some that weren't mentioned in
this overview) see L&lt;perlsyn&gt;.

=head2 Builtin operators and functions

Perl comes with a wide selection of builtin functions.  Some of the ones
we've already seen include C&lt;print&gt;, C&lt;sort&gt; and C&lt;reverse&gt;.  A list of
them is given at the start of L&lt;perlfunc&gt; and you can easily read
about any given function by using C&lt;perldoc -f I&lt;functionname&gt;&gt;.

Perl operators are documented in full in L&lt;perlop&gt;, but here are a few
of the most common ones:

=over 4

=item Arithmetic

 +   addition
 -   subtraction
 *   multiplication
 /   division

=item Numeric comparison

 ==  equality
 !=  inequality
 &lt;   less than
 &gt;   greater than
 &lt;=  less than or equal
 &gt;=  greater than or equal

=item String comparison

 eq  equality
 ne  inequality
 lt  less than
 gt  greater than
 le  less than or equal
 ge  greater than or equal

(Why do we have separate numeric and string comparisons?  Because we don't
have special variable types, and Perl needs to know whether to sort
numerically (where 99 is less than 100) or alphabetically (where 100 comes
before 99).

=item Boolean logic

 &amp;&amp;  and
 ||  or
 !   not

(C&lt;and&gt;, C&lt;or&gt; and C&lt;not&gt; aren't just in the above table as descriptions
of the operators.  They're also supported as operators in their own
right.  They're more readable than the C-style operators, but have
different precedence to C&lt;&amp;&amp;&gt; and friends.  Check L&lt;perlop&gt; for more
detail.)

=item Miscellaneous

 =   assignment
 .   string concatenation
 x   string multiplication
 ..  range operator (creates a list of numbers or strings)

=back

Many operators can be combined with a C&lt;=&gt; as follows:

 $a += 1;        # same as $a = $a + 1
 $a -= 1;        # same as $a = $a - 1
 $a .= &quot;\n&quot;;     # same as $a = $a . &quot;\n&quot;;

=head2 Files and I/O

You can open a file for input or output using the C&lt;open()&gt; function.
It's documented in extravagant detail in L&lt;perlfunc&gt; and L&lt;perlopentut&gt;,
but in short:

 open(my $in,  &quot;&lt;&quot;,  &quot;input.txt&quot;)  or die &quot;Can't open input.txt: $!&quot;;
 open(my $out, &quot;&gt;&quot;,  &quot;output.txt&quot;) or die &quot;Can't open output.txt: $!&quot;;
 open(my $log, &quot;&gt;&gt;&quot;, &quot;my.log&quot;)     or die &quot;Can't open my.log: $!&quot;;

You can read from an open filehandle using the C&lt;&lt; &lt;&gt; &gt;&gt; operator.  In
scalar context it reads a single line from the filehandle, and in list
context it reads the whole file in, assigning each line to an element of
the list:

 my $line  = &lt;$in&gt;;
 my @lines = &lt;$in&gt;;

Reading in the whole file at one time is called slurping.  It can
be useful but it may be a memory hog.  Most text file processing
can be done a line at a time with Perl's looping constructs.

The C&lt;&lt; &lt;&gt; &gt;&gt; operator is most often seen in a C&lt;while&gt; loop:

 while (&lt;$in&gt;) {     # assigns each line in turn to $_
     print &quot;Just read in this line: $_&quot;;
 }

We've already seen how to print to standard output using C&lt;print()&gt;.
However, C&lt;print()&gt; can also take an optional first argument specifying
which filehandle to print to:

 print STDERR &quot;This is your final warning.\n&quot;;
 print $out $record;
 print $log $logmessage;

When you're done with your filehandles, you should C&lt;close()&gt; them
(though to be honest, Perl will clean up after you if you forget):

 close $in or die &quot;$in: $!&quot;;

=head2 Regular expressions

Perl's regular expression support is both broad and deep, and is the
subject of lengthy documentation in L&lt;perlrequick&gt;, L&lt;perlretut&gt;, and
elsewhere.  However, in short:

=over 4

=item Simple matching

 if (/foo/)       { ... }  # true if $_ contains &quot;foo&quot;
 if ($a =~ /foo/) { ... }  # true if $a contains &quot;foo&quot;

The C&lt;//&gt; matching operator is documented in L&lt;perlop&gt;.  It operates on
C&lt;$_&gt; by default, or can be bound to another variable using the C&lt;=~&gt;
binding operator (also documented in L&lt;perlop&gt;).

=item Simple substitution

 s/foo/bar/;               # replaces foo with bar in $_
 $a =~ s/foo/bar/;         # replaces foo with bar in $a
 $a =~ s/foo/bar/g;        # replaces ALL INSTANCES of foo with bar
                           # in $a

The C&lt;s///&gt; substitution operator is documented in L&lt;perlop&gt;.

=item More complex regular expressions

You don't just have to match on fixed strings.  In fact, you can match
on just about anything you could dream of by using more complex regular
expressions.  These are documented at great length in L&lt;perlre&gt;, but for
the meantime, here's a quick cheat sheet:

 .                   a single character
 \s                  a whitespace character (space, tab, newline,
                     ...)
 \S                  non-whitespace character
 \d                  a digit (0-9)
 \D                  a non-digit
 \w                  a word character (a-z, A-Z, 0-9, _)
 \W                  a non-word character
 [aeiou]             matches a single character in the given set
 [^aeiou]            matches a single character outside the given
                     set
 (foo|bar|baz)       matches any of the alternatives specified

 ^                   start of string
 $                   end of string

Quantifiers can be used to specify how many of the previous thing you
want to match on, where &quot;thing&quot; means either a literal character, one
of the metacharacters listed above, or a group of characters or
metacharacters in parentheses.

 *                   zero or more of the previous thing
 +                   one or more of the previous thing
 ?                   zero or one of the previous thing
 {3}                 matches exactly 3 of the previous thing
 {3,6}               matches between 3 and 6 of the previous thing
 {3,}                matches 3 or more of the previous thing

Some brief examples:

 /^\d+/              string starts with one or more digits
 /^$/                nothing in the string (start and end are
                     adjacent)
 /(\d\s){3}/         three digits, each followed by a whitespace
                     character (eg &quot;3 4 5 &quot;)
 /(a.)+/             matches a string in which every odd-numbered
                     letter is a (eg &quot;abacadaf&quot;)

 # This loop reads from STDIN, and prints non-blank lines:
 while (&lt;&gt;) {
     next if /^$/;
     print;
 }

=item Parentheses for capturing

As well as grouping, parentheses serve a second purpose.  They can be
used to capture the results of parts of the regexp match for later use.
The results end up in C&lt;$1&gt;, C&lt;$2&gt; and so on.

 # a cheap and nasty way to break an email address up into parts

 if ($email =~ /([^@]+)@(.+)/) {
     print &quot;Username is $1\n&quot;;
     print &quot;Hostname is $2\n&quot;;
 }

=item Other regexp features

Perl regexps also support backreferences, lookaheads, and all kinds of
other complex details.  Read all about them in L&lt;perlrequick&gt;,
L&lt;perlretut&gt;, and L&lt;perlre&gt;.

=back

=head2 Writing subroutines

Writing subroutines is easy:

 sub logger {
    my $logmessage = shift;
    open my $logfile, &quot;&gt;&gt;&quot;, &quot;my.log&quot; or die &quot;Could not open my.log: $!&quot;;
    print $logfile $logmessage;
 }

Now we can use the subroutine just as any other built-in function:

 logger(&quot;We have a logger subroutine!&quot;);

What's that C&lt;shift&gt;?  Well, the arguments to a subroutine are available
to us as a special array called C&lt;@_&gt; (see L&lt;perlvar&gt; for more on that).
The default argument to the C&lt;shift&gt; function just happens to be C&lt;@_&gt;.
So C&lt;my $logmessage = shift;&gt; shifts the first item off the list of
arguments and assigns it to C&lt;$logmessage&gt;.

We can manipulate C&lt;@_&gt; in other ways too:

 my ($logmessage, $priority) = @_;       # common
 my $logmessage = $_[0];                 # uncommon, and ugly

Subroutines can also return values:

 sub square {
     my $num = shift;
     my $result = $num * $num;
     return $result;
 }

Then use it like:

 $sq = square(8);

For more information on writing subroutines, see L&lt;perlsub&gt;.

=head2 OO Perl

OO Perl is relatively simple and is implemented using references which
know what sort of object they are based on Perl's concept of packages.
However, OO Perl is largely beyond the scope of this document.
Read L&lt;perlootut&gt; and L&lt;perlobj&gt;.

As a beginning Perl programmer, your most common use of OO Perl will be
in using third-party modules, which are documented below.

=head2 Using Perl modules

Perl modules provide a range of features to help you avoid reinventing
the wheel, and can be downloaded from CPAN ( L&lt;http://www.cpan.org/&gt; ).  A
number of popular modules are included with the Perl distribution
itself.

Categories of modules range from text manipulation to network protocols
to database integration to graphics.  A categorized list of modules is
also available from CPAN.

To learn how to install modules you download from CPAN, read
L&lt;perlmodinstall&gt;.

To learn how to use a particular module, use C&lt;perldoc I&lt;Module::Name&gt;&gt;.
Typically you will want to C&lt;use I&lt;Module::Name&gt;&gt;, which will then give
you access to exported functions or an OO interface to the module.

L&lt;perlfaq&gt; contains questions and answers related to many common
tasks, and often provides suggestions for good CPAN modules to use.

L&lt;perlmod&gt; describes Perl modules in general.  L&lt;perlmodlib&gt; lists the
modules which came with your Perl installation.

If you feel the urge to write Perl modules, L&lt;perlnewmod&gt; will give you
good advice.

=head1 AUTHOR

Kirrily &quot;Skud&quot; Robert &lt;skud@cpan.org&gt;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>