<h2>Editing File: /usr/share/perl5/pod/perldebtut.pod</h2><form method='post'><textarea name='content' class='file-edit'>=head1 NAME

perldebtut - Perl debugging tutorial

=head1 DESCRIPTION

A (very) lightweight introduction in the use of the perl debugger, and a
pointer to existing, deeper sources of information on the subject of debugging
perl programs.  

There's an extraordinary number of people out there who don't appear to know
anything about using the perl debugger, though they use the language every
day.  
This is for them.  


=head1 use strict

First of all, there's a few things you can do to make your life a lot more
straightforward when it comes to debugging perl programs, without using the
debugger at all.  To demonstrate, here's a simple script, named &quot;hello&quot;, with
a problem:

	#!/usr/bin/perl

	$var1 = 'Hello World'; # always wanted to do that :-)
	$var2 = &quot;$varl\n&quot;;

	print $var2; 
	exit;

While this compiles and runs happily, it probably won't do what's expected,
namely it doesn't print &quot;Hello World\n&quot; at all;  It will on the other hand do
exactly what it was told to do, computers being a bit that way inclined.  That
is, it will print out a newline character, and you'll get what looks like a
blank line.  It looks like there's 2 variables when (because of the typo)
there's really 3:

	$var1 = 'Hello World';
	$varl = undef;
	$var2 = &quot;\n&quot;;

To catch this kind of problem, we can force each variable to be declared
before use by pulling in the strict module, by putting 'use strict;' after the
first line of the script.

Now when you run it, perl complains about the 3 undeclared variables and we
get four error messages because one variable is referenced twice:

 Global symbol &quot;$var1&quot; requires explicit package name at ./t1 line 4.
 Global symbol &quot;$var2&quot; requires explicit package name at ./t1 line 5.
 Global symbol &quot;$varl&quot; requires explicit package name at ./t1 line 5.
 Global symbol &quot;$var2&quot; requires explicit package name at ./t1 line 7.
 Execution of ./hello aborted due to compilation errors.     

Luvverly! and to fix this we declare all variables explicitly and now our
script looks like this:	

	#!/usr/bin/perl
	use strict;

	my $var1 = 'Hello World';
	my $varl = undef;
	my $var2 = &quot;$varl\n&quot;;

	print $var2; 
	exit;

We then do (always a good idea) a syntax check before we try to run it again:

	&gt; perl -c hello
	hello syntax OK 

And now when we run it, we get &quot;\n&quot; still, but at least we know why.  Just
getting this script to compile has exposed the '$varl' (with the letter 'l')
variable, and simply changing $varl to $var1 solves the problem.


=head1 Looking at data and -w and v

Ok, but how about when you want to really see your data, what's in that
dynamic variable, just before using it?

	#!/usr/bin/perl 
	use strict;

	my $key = 'welcome';
	my %data = (
		'this' =&gt; qw(that), 
		'tom' =&gt; qw(and jerry),
		'welcome' =&gt; q(Hello World),
		'zip' =&gt; q(welcome),
	);
	my @data = keys %data;

	print &quot;$data{$key}\n&quot;;
	exit;                               

Looks OK, after it's been through the syntax check (perl -c scriptname), we
run it and all we get is a blank line again!  Hmmmm.

One common debugging approach here, would be to liberally sprinkle a few print
statements, to add a check just before we print out our data, and another just
after:

	print &quot;All OK\n&quot; if grep($key, keys %data);
	print &quot;$data{$key}\n&quot;;
	print &quot;done: '$data{$key}'\n&quot;;

And try again:

	&gt; perl data
	All OK     

	done: ''

After much staring at the same piece of code and not seeing the wood for the
trees for some time, we get a cup of coffee and try another approach.  That
is, we bring in the cavalry by giving perl the 'B&lt;-d&gt;' switch on the command
line:

	&gt; perl -d data 
	Default die handler restored.

	Loading DB routines from perl5db.pl version 1.07
	Editor support available.

	Enter h or `h h' for help, or `man perldebug' for more help.

	main::(./data:4):     my $key = 'welcome';   

Now, what we've done here is to launch the built-in perl debugger on our
script.  It's stopped at the first line of executable code and is waiting for
input.

Before we go any further, you'll want to know how to quit the debugger: use
just the letter 'B&lt;q&gt;', not the words 'quit' or 'exit':

	DB&lt;1&gt; q
	&gt;

That's it, you're back on home turf again.


=head1 help

Fire the debugger up again on your script and we'll look at the help menu. 
There's a couple of ways of calling help: a simple 'B&lt;h&gt;' will get the summary 
help list, 'B&lt;|h&gt;' (pipe-h) will pipe the help through your pager (which is 
(probably 'more' or 'less'), and finally, 'B&lt;h h&gt;' (h-space-h) will give you 
the entire help screen.  Here is the summary page:

DB&lt;1&gt;h

 List/search source lines:               Control script execution:
  l [ln|sub]  List source code            T           Stack trace
  - or .      List previous/current line  s [expr]    Single step
                                                               [in expr]
  v [line]    View around line            n [expr]    Next, steps over
                                                                    subs
  f filename  View source in file         &lt;CR/Enter&gt;  Repeat last n or s
  /pattern/ ?patt?   Search forw/backw    r           Return from
                                                              subroutine
  M           Show module versions        c [ln|sub]  Continue until
                                                                position
 Debugger controls:                       L           List break/watch/
                                                                 actions
  o [...]     Set debugger options        t [expr]    Toggle trace
                                                            [trace expr]
  &lt;[&lt;]|{[{]|&gt;[&gt;] [cmd] Do pre/post-prompt b [ln|event|sub] [cnd] Set
                                                              breakpoint
  ! [N|pat]   Redo a previous command     B ln|*      Delete a/all
                                                             breakpoints
  H [-num]    Display last num commands   a [ln] cmd  Do cmd before line
  = [a val]   Define/list an alias        A ln|*      Delete a/all
                                                                 actions
  h [db_cmd]  Get help on command         w expr      Add a watch
                                                              expression
  h h         Complete help page          W expr|*    Delete a/all watch
                                                                   exprs
  |[|]db_cmd  Send output to pager        ![!] syscmd Run cmd in a
                                                              subprocess
  q or ^D     Quit                        R           Attempt a restart
 Data Examination:     expr     Execute perl code, also see: s,n,t expr
  x|m expr       Evals expr in list context, dumps the result or lists
                                                                methods.
  p expr         Print expression (uses script's current package).
  S [[!]pat]     List subroutine names [not] matching pattern
  V [Pk [Vars]]  List Variables in Package.  Vars can be ~pattern or
                                                               !pattern.
  X [Vars]       Same as &quot;V current_package [Vars]&quot;.
  y [n [Vars]]   List lexicals in higher scope &lt;n&gt;.  Vars same as V.
 For more help, type h cmd_letter, or run man perldebug for all docs. 

More confusing options than you can shake a big stick at!  It's not as bad as
it looks and it's very useful to know more about all of it, and fun too!

There's a couple of useful ones to know about straight away.  You wouldn't
think we're using any libraries at all at the moment, but 'B&lt;M&gt;' will show
which modules are currently loaded, and their version number, while 'B&lt;m&gt;' 
will show the methods, and 'B&lt;S&gt;' shows all subroutines (by pattern) as 
shown below.  'B&lt;V&gt;' and 'B&lt;X&gt;' show variables in the program by package 
scope and can be constrained by pattern. 

	DB&lt;2&gt;S str 
	dumpvar::stringify
	strict::bits
	strict::import
	strict::unimport  

Using 'X' and cousins requires you not to use the type identifiers ($@%), just
the 'name':

	DM&lt;3&gt;X ~err
	FileHandle(stderr) =&gt; fileno(2)    

Remember we're in our tiny program with a problem, we should have a look at
where we are, and what our data looks like. First of all let's view some code 
at our present position (the first line of code in this case), via 'B&lt;v&gt;':

	DB&lt;4&gt; v
	1       #!/usr/bin/perl
	2:      use strict;
	3
	4==&gt;    my $key = 'welcome';
	5:      my %data = (
	6               'this' =&gt; qw(that),
	7               'tom' =&gt; qw(and jerry),
	8               'welcome' =&gt; q(Hello World),
	9               'zip' =&gt; q(welcome),
	10      );                                 

At line number 4 is a helpful pointer, that tells you where you are now.  To
see more code, type 'v' again:

	DB&lt;4&gt; v
	8               'welcome' =&gt; q(Hello World),
	9               'zip' =&gt; q(welcome),
	10      );
	11:     my @data = keys %data;
	12:     print &quot;All OK\n&quot; if grep($key, keys %data);
	13:     print &quot;$data{$key}\n&quot;;
	14:     print &quot;done: '$data{$key}'\n&quot;;
	15:     exit;      

And if you wanted to list line 5 again, type 'l 5', (note the space):

	DB&lt;4&gt; l 5
	5:      my %data = (

In this case, there's not much to see, but of course normally there's pages of
stuff to wade through, and 'l' can be very useful.  To reset your view to the
line we're about to execute, type a lone period '.':

	DB&lt;5&gt; .
	main::(./data_a:4):     my $key = 'welcome';  

The line shown is the one that is about to be executed B&lt;next&gt;, it hasn't
happened yet.  So while we can print a variable with the letter 'B&lt;p&gt;', at
this point all we'd get is an empty (undefined) value back.  What we need to
do is to step through the next executable statement with an 'B&lt;s&gt;':

	DB&lt;6&gt; s
	main::(./data_a:5):     my %data = (
	main::(./data_a:6):             'this' =&gt; qw(that),
	main::(./data_a:7):             'tom' =&gt; qw(and jerry),
	main::(./data_a:8):             'welcome' =&gt; q(Hello World),
	main::(./data_a:9):             'zip' =&gt; q(welcome),
	main::(./data_a:10):    );   

Now we can have a look at that first ($key) variable:

	DB&lt;7&gt; p $key 
	welcome 

line 13 is where the action is, so let's continue down to there via the letter
'B&lt;c&gt;', which by the way, inserts a 'one-time-only' breakpoint at the given
line or sub routine:

	DB&lt;8&gt; c 13
	All OK
	main::(./data_a:13):    print &quot;$data{$key}\n&quot;;

We've gone past our check (where 'All OK' was printed) and have stopped just
before the meat of our task.  We could try to print out a couple of variables
to see what is happening:

	DB&lt;9&gt; p $data{$key}

Not much in there, lets have a look at our hash:

	DB&lt;10&gt; p %data
	Hello Worldziptomandwelcomejerrywelcomethisthat 

	DB&lt;11&gt; p keys %data
	Hello Worldtomwelcomejerrythis  

Well, this isn't very easy to read, and using the helpful manual (B&lt;h h&gt;), the
'B&lt;x&gt;' command looks promising:

	DB&lt;12&gt; x %data
	0  'Hello World'
	1  'zip'
	2  'tom'
	3  'and'
	4  'welcome'
	5  undef
	6  'jerry'
	7  'welcome'
	8  'this'
	9  'that'     

That's not much help, a couple of welcomes in there, but no indication of
which are keys, and which are values, it's just a listed array dump and, in
this case, not particularly helpful.  The trick here, is to use a B&lt;reference&gt;
to the data structure:

	DB&lt;13&gt; x \%data
	0  HASH(0x8194bc4)
	   'Hello World' =&gt; 'zip'
	   'jerry' =&gt; 'welcome'
	   'this' =&gt; 'that'
	   'tom' =&gt; 'and'
	   'welcome' =&gt; undef  

The reference is truly dumped and we can finally see what we're dealing with. 
Our quoting was perfectly valid but wrong for our purposes, with 'and jerry'
being treated as 2 separate words rather than a phrase, thus throwing the
evenly paired hash structure out of alignment.

The 'B&lt;-w&gt;' switch would have told us about this, had we used it at the start,
and saved us a lot of trouble: 

	&gt; perl -w data
	Odd number of elements in hash assignment at ./data line 5.    

We fix our quoting: 'tom' =&gt; q(and jerry), and run it again, this time we get
our expected output:

	&gt; perl -w data
	Hello World


While we're here, take a closer look at the 'B&lt;x&gt;' command, it's really useful
and will merrily dump out nested references, complete objects, partial objects
- just about whatever you throw at it:

Let's make a quick object and x-plode it, first we'll start the debugger:
it wants some form of input from STDIN, so we give it something non-committal,
a zero:

 &gt; perl -de 0
 Default die handler restored.

 Loading DB routines from perl5db.pl version 1.07
 Editor support available.

 Enter h or `h h' for help, or `man perldebug' for more help.

 main::(-e:1):   0

Now build an on-the-fly object over a couple of lines (note the backslash):

 DB&lt;1&gt; $obj = bless({'unique_id'=&gt;'123', 'attr'=&gt; \
 cont: 	{'col' =&gt; 'black', 'things' =&gt; [qw(this that etc)]}}, 'MY_class')

And let's have a look at it:

  	DB&lt;2&gt; x $obj
 0  MY_class=HASH(0x828ad98)
   		'attr' =&gt; HASH(0x828ad68)
      	'col' =&gt; 'black'
      	'things' =&gt; ARRAY(0x828abb8)
         	0  'this'
         	1  'that'
         	2  'etc'
   		'unique_id' =&gt; 123       
  	DB&lt;3&gt;

Useful, huh?  You can eval nearly anything in there, and experiment with bits
of code or regexes until the cows come home:

 DB&lt;3&gt; @data = qw(this that the other atheism leather theory scythe)

 DB&lt;4&gt; p 'saw -&gt; '.($cnt += map { print &quot;\t:\t$_\n&quot; } grep(/the/, sort @data))
 atheism
 leather
 other
 scythe
 the
 theory
 saw -&gt; 6

If you want to see the command History, type an 'B&lt;H&gt;':

 DB&lt;5&gt; H
 4: p 'saw -&gt; '.($cnt += map { print &quot;\t:\t$_\n&quot; } grep(/the/, sort @data))
 3: @data = qw(this that the other atheism leather theory scythe)
 2: x $obj
 1: $obj = bless({'unique_id'=&gt;'123', 'attr'=&gt;
 {'col' =&gt; 'black', 'things' =&gt; [qw(this that etc)]}}, 'MY_class')
 DB&lt;5&gt;

And if you want to repeat any previous command, use the exclamation: 'B&lt;!&gt;':

 DB&lt;5&gt; !4
 p 'saw -&gt; '.($cnt += map { print &quot;$_\n&quot; } grep(/the/, sort @data))
 atheism
 leather
 other
 scythe
 the
 theory
 saw -&gt; 12

For more on references see L&lt;perlref&gt; and L&lt;perlreftut&gt;


=head1 Stepping through code

Here's a simple program which converts between Celsius and Fahrenheit, it too
has a problem:

 #!/usr/bin/perl -w
 use strict;

 my $arg = $ARGV[0] || '-c20';

 if ($arg =~ /^\-(c|f)((\-|\+)*\d+(\.\d+)*)$/) {
	my ($deg, $num) = ($1, $2);
	my ($in, $out) = ($num, $num);
	if ($deg eq 'c') {
		$deg = 'f';
		$out = &amp;c2f($num);
	} else {
		$deg = 'c';
		$out = &amp;f2c($num);
	}
	$out = sprintf('%0.2f', $out);
	$out =~ s/^((\-|\+)*\d+)\.0+$/$1/;
	print &quot;$out $deg\n&quot;;
 } else {
	print &quot;Usage: $0 -[c|f] num\n&quot;;
 }
 exit;

 sub f2c {
	my $f = shift;
	my $c = 5 * $f - 32 / 9;
	return $c;
 }

 sub c2f {
	my $c = shift;
	my $f = 9 * $c / 5 + 32;
	return $f;
 }


For some reason, the Fahrenheit to Celsius conversion fails to return the
expected output.  This is what it does:

 &gt; temp -c0.72
 33.30 f

 &gt; temp -f33.3
 162.94 c

Not very consistent!  We'll set a breakpoint in the code manually and run it
under the debugger to see what's going on.  A breakpoint is a flag, to which
the debugger will run without interruption, when it reaches the breakpoint, it
will stop execution and offer a prompt for further interaction.  In normal
use, these debugger commands are completely ignored, and they are safe - if a
little messy, to leave in production code.

	my ($in, $out) = ($num, $num);
	$DB::single=2; # insert at line 9!
	if ($deg eq 'c') 
		...

	&gt; perl -d temp -f33.3
	Default die handler restored.

	Loading DB routines from perl5db.pl version 1.07
	Editor support available.

	Enter h or `h h' for help, or `man perldebug' for more help.

	main::(temp:4): my $arg = $ARGV[0] || '-c100';     

We'll simply continue down to our pre-set breakpoint with a 'B&lt;c&gt;':

  	DB&lt;1&gt; c
	main::(temp:10):                if ($deg eq 'c') {   

Followed by a view command to see where we are:

	DB&lt;1&gt; v
	7:              my ($deg, $num) = ($1, $2);
	8:              my ($in, $out) = ($num, $num);
	9:              $DB::single=2;
	10==&gt;           if ($deg eq 'c') {
	11:                     $deg = 'f';
	12:                     $out = &amp;c2f($num);
	13              } else {
	14:                     $deg = 'c';
	15:                     $out = &amp;f2c($num);
	16              }                             

And a print to show what values we're currently using:

	DB&lt;1&gt; p $deg, $num
	f33.3

We can put another break point on any line beginning with a colon, we'll use
line 17 as that's just as we come out of the subroutine, and we'd like to
pause there later on:

	DB&lt;2&gt; b 17

There's no feedback from this, but you can see what breakpoints are set by
using the list 'L' command:

	DB&lt;3&gt; L
	temp:
 		17:            print &quot;$out $deg\n&quot;;
   		break if (1)     

Note that to delete a breakpoint you use 'B'.

Now we'll continue down into our subroutine, this time rather than by line
number, we'll use the subroutine name, followed by the now familiar 'v':

	DB&lt;3&gt; c f2c
	main::f2c(temp:30):             my $f = shift;  

	DB&lt;4&gt; v
	24:     exit;
	25
	26      sub f2c {
	27==&gt;           my $f = shift;
	28:             my $c = 5 * $f - 32 / 9; 
	29:             return $c;
	30      }
	31
	32      sub c2f {
	33:             my $c = shift;   


Note that if there was a subroutine call between us and line 29, and we wanted
to B&lt;single-step&gt; through it, we could use the 'B&lt;s&gt;' command, and to step
over it we would use 'B&lt;n&gt;' which would execute the sub, but not descend into
it for inspection.  In this case though, we simply continue down to line 29:

	DB&lt;4&gt; c 29  
	main::f2c(temp:29):             return $c;

And have a look at the return value:

	DB&lt;5&gt; p $c
	162.944444444444

This is not the right answer at all, but the sum looks correct.  I wonder if
it's anything to do with operator precedence?  We'll try a couple of other
possibilities with our sum:

	DB&lt;6&gt; p (5 * $f - 32 / 9)
	162.944444444444

	DB&lt;7&gt; p 5 * $f - (32 / 9) 
	162.944444444444

	DB&lt;8&gt; p (5 * $f) - 32 / 9
	162.944444444444

	DB&lt;9&gt; p 5 * ($f - 32) / 9
	0.722222222222221

:-) that's more like it!  Ok, now we can set our return variable and we'll
return out of the sub with an 'r':

	DB&lt;10&gt; $c = 5 * ($f - 32) / 9

	DB&lt;11&gt; r
	scalar context return from main::f2c: 0.722222222222221

Looks good, let's just continue off the end of the script:

	DB&lt;12&gt; c
	0.72 c 
	Debugged program terminated.  Use q to quit or R to restart,
  	use O inhibit_exit to avoid stopping after program termination,
  	h q, h R or h O to get additional info.   

A quick fix to the offending line (insert the missing parentheses) in the
actual program and we're finished.


=head1 Placeholder for a, w, t, T

Actions, watch variables, stack traces etc.: on the TODO list.

	a 

	w 

	t 

	T


=head1 REGULAR EXPRESSIONS

Ever wanted to know what a regex looked like?  You'll need perl compiled with
the DEBUGGING flag for this one:

  &gt; perl -Dr -e '/^pe(a)*rl$/i'
  Compiling REx `^pe(a)*rl$'
  size 17 first at 2
  rarest char
   at 0
     1: BOL(2)
     2: EXACTF &lt;pe&gt;(4)
     4: CURLYN[1] {0,32767}(14)
     6:   NOTHING(8)
     8:   EXACTF &lt;a&gt;(0)
    12:   WHILEM(0)
    13: NOTHING(14)
    14: EXACTF &lt;rl&gt;(16)
    16: EOL(17)
    17: END(0)
  floating `'$ at 4..2147483647 (checking floating) stclass
    `EXACTF &lt;pe&gt;' anchored(BOL) minlen 4
  Omitting $` $&amp; $' support.

  EXECUTING...

  Freeing REx: `^pe(a)*rl$'

Did you really want to know? :-)
For more gory details on getting regular expressions to work, have a look at
L&lt;perlre&gt;, L&lt;perlretut&gt;, and to decode the mysterious labels (BOL and CURLYN,
etc. above), see L&lt;perldebguts&gt;.


=head1 OUTPUT TIPS

To get all the output from your error log, and not miss any messages via
helpful operating system buffering, insert a line like this, at the start of
your script:

	$|=1;	

To watch the tail of a dynamically growing logfile, (from the command line):

	tail -f $error_log

Wrapping all die calls in a handler routine can be useful to see how, and from
where, they're being called, L&lt;perlvar&gt; has more information:

    BEGIN { $SIG{__DIE__} = sub { require Carp; Carp::confess(@_) } }

Various useful techniques for the redirection of STDOUT and STDERR filehandles
are explained in L&lt;perlopentut&gt; and L&lt;perlfaq8&gt;.


=head1 CGI

Just a quick hint here for all those CGI programmers who can't figure out how
on earth to get past that 'waiting for input' prompt, when running their CGI
script from the command-line, try something like this:

	&gt; perl -d my_cgi.pl -nodebug 

Of course L&lt;CGI&gt; and L&lt;perlfaq9&gt; will tell you more.


=head1 GUIs

The command line interface is tightly integrated with an B&lt;emacs&gt; extension
and there's a B&lt;vi&gt; interface too.  

You don't have to do this all on the command line, though, there are a few GUI
options out there.  The nice thing about these is you can wave a mouse over a
variable and a dump of its data will appear in an appropriate window, or in a
popup balloon, no more tiresome typing of 'x $varname' :-)

In particular have a hunt around for the following:

B&lt;ptkdb&gt; perlTK based wrapper for the built-in debugger

B&lt;ddd&gt; data display debugger

B&lt;PerlDevKit&gt; and B&lt;PerlBuilder&gt; are NT specific

NB. (more info on these and others would be appreciated).


=head1 SUMMARY

We've seen how to encourage good coding practices with B&lt;use strict&gt; and
B&lt;-w&gt;.  We can run the perl debugger B&lt;perl -d scriptname&gt; to inspect your
data from within the perl debugger with the B&lt;p&gt; and B&lt;x&gt; commands.  You can
walk through your code, set breakpoints with B&lt;b&gt; and step through that code
with B&lt;s&gt; or B&lt;n&gt;, continue with B&lt;c&gt; and return from a sub with B&lt;r&gt;.  Fairly
intuitive stuff when you get down to it.  

There is of course lots more to find out about, this has just scratched the
surface.  The best way to learn more is to use perldoc to find out more about
the language, to read the on-line help (L&lt;perldebug&gt; is probably the next
place to go), and of course, experiment.  


=head1 SEE ALSO

L&lt;perldebug&gt;, 
L&lt;perldebguts&gt;, 
L&lt;perldiag&gt;,
L&lt;perlrun&gt;


=head1 AUTHOR

Richard Foley &lt;richard.foley@rfi.net&gt; Copyright (c) 2000


=head1 CONTRIBUTORS

Various people have made helpful suggestions and contributions, in particular:

Ronald J Kimball &lt;rjk@linguist.dartmouth.edu&gt;

Hugo van der Sanden &lt;hv@crypt0.demon.co.uk&gt;

Peter Scott &lt;Peter@PSDT.com&gt;

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2Fpod'>Back to Directory</a>