<h2>Editing File: /usr/share/perl5/locale.pm</h2><form method='post'><textarea name='content' class='file-edit'>package locale;

our $VERSION = '1.09';
use Config;

$Carp::Internal{ (__PACKAGE__) } = 1;

=head1 NAME

locale - Perl pragma to use or avoid POSIX locales for built-in operations

=head1 WARNING

DO NOT USE this pragma in scripts that have multiple
L&lt;threads|threads&gt; active.  The locale is not local to a single thread.
Another thread may change the locale at any time, which could cause at a
minimum that a given thread is operating in a locale it isn't expecting
to be in.  On some platforms, segfaults can also occur.  The locale
change need not be explicit; some operations cause perl to change the
locale itself.  You are vulnerable simply by having done a C&lt;&quot;use
locale&quot;&gt;.

=head1 SYNOPSIS

    @x = sort @y;      # Native-platform/Unicode code point sort order
    {
        use locale;
        @x = sort @y;  # Locale-defined sort order
    }
    @x = sort @y;      # Native-platform/Unicode code point sort order
                       # again

=head1 DESCRIPTION

This pragma tells the compiler to enable (or disable) the use of POSIX
locales for built-in operations (for example, LC_CTYPE for regular
expressions, LC_COLLATE for string comparison, and LC_NUMERIC for number
formatting).  Each &quot;use locale&quot; or &quot;no locale&quot;
affects statements to the end of the enclosing BLOCK.

See L&lt;perllocale&gt; for more detailed information on how Perl supports
locales.

On systems that don't have locales, this pragma will cause your operations
to behave as if in the &quot;C&quot; locale; attempts to change the locale will fail.

=cut

# A separate bit is used for each of the two forms of the pragma, to save
# having to look at %^H for the normal case of a plain 'use locale' without an
# argument.

$locale::hint_bits = 0x4;
$locale::partial_hint_bits = 0x10;  # If pragma has an argument

# The pseudo-category :characters consists of 2 real ones; but it also is
# given its own number, -1, because in the complement form it also has the
# side effect of &quot;use feature 'unicode_strings'&quot;

sub import {
    shift;  # should be 'locale'; not checked

    $^H{locale} = 0 unless defined $^H{locale};
    if (! @_) { # If no parameter, use the plain form that changes all categories
        $^H |= $locale::hint_bits;

    }
    else {
        my @categories = ( qw(:ctype :collate :messages
                              :numeric :monetary :time) );
        for (my $i = 0; $i &lt; @_; $i++) {
            my $arg = $_[$i];
            $complement = $arg =~ s/ : ( ! | not_ ) /:/x;
            if (! grep { $arg eq $_ } @categories, &quot;:characters&quot;) {
                require Carp;
                Carp::croak(&quot;Unknown parameter '$_[$i]' to 'use locale'&quot;);
            }

            if ($complement) {
                if ($i != 0 || $i &lt; @_ - 1)  {
                    require Carp;
                    Carp::croak(&quot;Only one argument to 'use locale' allowed&quot;
                                . &quot;if is $complement&quot;);
                }

                if ($arg eq ':characters') {
                    push @_, grep { $_ ne ':ctype' &amp;&amp; $_ ne ':collate' }
                                  @categories;
                    # We add 1 to the category number;  This category number
                    # is -1
                    $^H{locale} |= (1 &lt;&lt; 0);
                }
                else {
                    push @_, grep { $_ ne $arg } @categories;
                }
                next;
            }
            elsif ($arg eq ':characters') {
                push @_, ':ctype', ':collate';
                next;
            }

            $^H |= $locale::partial_hint_bits;

            # This form of the pragma overrides the other
            $^H &amp;= ~$locale::hint_bits;

            $arg =~ s/^://;

            eval { require POSIX; import POSIX 'locale_h'; };

            # Map our names to the ones defined by POSIX
            my $LC = &quot;LC_&quot; . uc($arg);

            my $bit = eval &quot;&amp;POSIX::$LC&quot;;
            if (defined $bit) { # XXX Should we warn that this category isn't
                                # supported on this platform, or make it
                                # always be the C locale?

                # Verify our assumption.
                if (! ($bit &gt;= 0 &amp;&amp; $bit &lt; 31)) {
                    require Carp;
                    Carp::croak(&quot;Cannot have ':$arg' parameter to 'use locale'&quot;
                              . &quot; on this platform.  Use the 'perlbug' utility&quot;
                              . &quot; to report this problem, or send email to&quot;
                              . &quot; 'perlbug\@perl.org'.  $LC=$bit&quot;);
                }

                # 1 is added so that the pseudo-category :characters, which is
                # -1, comes out 0.
                $^H{locale} |= 1 &lt;&lt; ($bit + 1);
            }
        }
    }

}

sub unimport {
    $^H &amp;= ~($locale::hint_bits|$locale::partial_hint_bits);
    $^H{locale} = 0;
}

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5'>Back to Directory</a>