<h2>Editing File: /usr/share/perl5/less.pm</h2><form method='post'><textarea name='content' class='file-edit'>package less;
use strict;
use warnings;

our $VERSION = '0.03';

sub _pack_tags {
    return join ' ', @_;
}

sub _unpack_tags {
    return grep { defined and length }
        map  { split ' ' }
        grep {defined} @_;
}

sub stash_name { $_[0] }

sub of {
    my $class = shift @_;

    # If no one wants the result, don't bother computing it.
    return unless defined wantarray;

    my $hinthash = ( caller 0 )[10];
    my %tags;
    @tags{ _unpack_tags( $hinthash-&gt;{ $class-&gt;stash_name } ) } = ();

    if (@_) {
        exists $tags{$_} and return !!1 for @_;
        return;
    }
    else {
        return keys %tags;
    }
}

sub import {
    my $class = shift @_;
    my $stash = $class-&gt;stash_name;

    @_ = 'please' if not @_;
    my %tags;
    @tags{ _unpack_tags( @_, $^H{ $stash } ) } = ();

    $^H{$stash} = _pack_tags( keys %tags );
    return;
}

sub unimport {
    my $class = shift @_;

    if (@_) {
        my %tags;
        @tags{ _unpack_tags( $^H{$class} ) } = ();
        delete @tags{ _unpack_tags(@_) };
        my $new = _pack_tags( keys %tags );

        if ( not length $new ) {
            delete $^H{ $class-&gt;stash_name };
        }
        else {
            $^H{ $class-&gt;stash_name } = $new;
        }
    }
    else {
        delete $^H{ $class-&gt;stash_name };
    }

    return;
}

1;

__END__

=head1 NAME

less - perl pragma to request less of something

=head1 SYNOPSIS

    use less 'CPU';

=head1 DESCRIPTION

This is a user-pragma. If you're very lucky some code you're using
will know that you asked for less CPU usage or ram or fat or... we
just can't know. Consult your documentation on everything you're
currently using.

For general suggestions, try requesting C&lt;CPU&gt; or C&lt;memory&gt;.

    use less 'memory';
    use less 'CPU';
    use less 'fat';

If you ask for nothing in particular, you'll be asking for C&lt;less
'please'&gt;.

    use less 'please';

=head1 FOR MODULE AUTHORS

L&lt;less&gt; has been in the core as a &quot;joke&quot; module for ages now and it
hasn't had any real way to communicating any information to
anything. Thanks to Nicholas Clark we have user pragmas (see
L&lt;perlpragma&gt;) and now C&lt;less&gt; can do something.

You can probably expect your users to be able to guess that they can
request less CPU or memory or just &quot;less&quot; overall.

If the user didn't specify anything, it's interpreted as having used
the C&lt;please&gt; tag. It's up to you to make this useful.

  # equivalent
  use less;
  use less 'please';

=head2 C&lt;&lt; BOOLEAN = less-&gt;of( FEATURE ) &gt;&gt;

The class method C&lt;&lt; less-&gt;of( NAME ) &gt;&gt; returns a boolean to tell you
whether your user requested less of something.

  if ( less-&gt;of( 'CPU' ) ) {
      ...
  }
  elsif ( less-&gt;of( 'memory' ) ) {

  }

=head2 C&lt;&lt; FEATURES = less-&gt;of() &gt;&gt;

If you don't ask for any feature, you get the list of features that
the user requested you to be nice to. This has the nice side effect
that if you don't respect anything in particular then you can just ask
for it and use it like a boolean.

  if ( less-&gt;of ) {
      ...
  }
  else {
      ...
  }

=head1 CAVEATS

=over

=item This probably does nothing.

=item This works only on 5.10+

At least it's backwards compatible in not doing much.

=back

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5'>Back to Directory</a>