<h2>Editing File: /usr/share/perl5/fields.pm</h2><form method='post'><textarea name='content' class='file-edit'>use 5.008;
package fields;

require 5.005;
use strict;
no strict 'refs';
unless( eval q{require warnings::register; warnings::register-&gt;import; 1} ) {
    *warnings::warnif = sub { 
        require Carp;
        Carp::carp(@_);
    }
}
use vars qw(%attr $VERSION);

$VERSION = '2.23';
$VERSION =~ tr/_//d;

# constant.pm is slow
sub PUBLIC     () { 2**0  }
sub PRIVATE    () { 2**1  }
sub INHERITED  () { 2**2  }
sub PROTECTED  () { 2**3  }


# The %attr hash holds the attributes of the currently assigned fields
# per class.  The hash is indexed by class names and the hash value is
# an array reference.  The first element in the array is the lowest field
# number not belonging to a base class.  The remaining elements' indices
# are the field numbers.  The values are integer bit masks, or undef
# in the case of base class private fields (which occupy a slot but are
# otherwise irrelevant to the class).

sub import {
    my $class = shift;
    return unless @_;
    my $package = caller(0);
    # avoid possible typo warnings
    %{&quot;$package\::FIELDS&quot;} = () unless %{&quot;$package\::FIELDS&quot;};
    my $fields = \%{&quot;$package\::FIELDS&quot;};
    my $fattr = ($attr{$package} ||= [1]);
    my $next = @$fattr;

    # Quiet pseudo-hash deprecation warning for uses of fields::new.
    bless \%{&quot;$package\::FIELDS&quot;}, 'pseudohash';

    if ($next &gt; $fattr-&gt;[0]
        and ($fields-&gt;{$_[0]} || 0) &gt;= $fattr-&gt;[0])
    {
        # There are already fields not belonging to base classes.
        # Looks like a possible module reload...
        $next = $fattr-&gt;[0];
    }
    foreach my $f (@_) {
        my $fno = $fields-&gt;{$f};

        # Allow the module to be reloaded so long as field positions
        # have not changed.
        if ($fno and $fno != $next) {
            require Carp;
            if ($fno &lt; $fattr-&gt;[0]) {
              if ($] &lt; 5.006001) {
                warn(&quot;Hides field '$f' in base class&quot;) if $^W;
              } else {
                warnings::warnif(&quot;Hides field '$f' in base class&quot;) ;
              }
            } else {
                Carp::croak(&quot;Field name '$f' already in use&quot;);
            }
        }
        $fields-&gt;{$f} = $next;
        $fattr-&gt;[$next] = ($f =~ /^_/) ? PRIVATE : PUBLIC;
        $next += 1;
    }
    if (@$fattr &gt; $next) {
        # Well, we gave them the benefit of the doubt by guessing the
        # module was reloaded, but they appear to be declaring fields
        # in more than one place.  We can't be sure (without some extra
        # bookkeeping) that the rest of the fields will be declared or
        # have the same positions, so punt.
        require Carp;
        Carp::croak (&quot;Reloaded module must declare all fields at once&quot;);
    }
}

sub inherit {
    require base;
    goto &amp;base::inherit_fields;
}

sub _dump  # sometimes useful for debugging
{
    for my $pkg (sort keys %attr) {
        print &quot;\n$pkg&quot;;
        if (@{&quot;$pkg\::ISA&quot;}) {
            print &quot; (&quot;, join(&quot;, &quot;, @{&quot;$pkg\::ISA&quot;}), &quot;)&quot;;
        }
        print &quot;\n&quot;;
        my $fields = \%{&quot;$pkg\::FIELDS&quot;};
        for my $f (sort {$fields-&gt;{$a} &lt;=&gt; $fields-&gt;{$b}} keys %$fields) {
            my $no = $fields-&gt;{$f};
            print &quot;   $no: $f&quot;;
            my $fattr = $attr{$pkg}[$no];
            if (defined $fattr) {
                my @a;
                push(@a, &quot;public&quot;)    if $fattr &amp; PUBLIC;
                push(@a, &quot;private&quot;)   if $fattr &amp; PRIVATE;
                push(@a, &quot;inherited&quot;) if $fattr &amp; INHERITED;
                print &quot;\t(&quot;, join(&quot;, &quot;, @a), &quot;)&quot;;
            }
            print &quot;\n&quot;;
        }
    }
}

if ($] &lt; 5.009) {
  *new = sub {
    my $class = shift;
    $class = ref $class if ref $class;
    return bless [\%{$class . &quot;::FIELDS&quot;}], $class;
  }
} else {
  *new = sub {
    my $class = shift;
    $class = ref $class if ref $class;
    require Hash::Util;
    my $self = bless {}, $class;

    # The lock_keys() prototype won't work since we require Hash::Util :(
    &amp;Hash::Util::lock_keys(\%$self, _accessible_keys($class));
    return $self;
  }
}

sub _accessible_keys {
    my ($class) = @_;
    return (
        keys %{$class.'::FIELDS'},
        map(_accessible_keys($_), @{$class.'::ISA'}),
    );
}

sub phash {
    die &quot;Pseudo-hashes have been removed from Perl&quot; if $] &gt;= 5.009;
    my $h;
    my $v;
    if (@_) {
       if (ref $_[0] eq 'ARRAY') {
           my $a = shift;
           @$h{@$a} = 1 .. @$a;
           if (@_) {
               $v = shift;
               unless (! @_ and ref $v eq 'ARRAY') {
                   require Carp;
                   Carp::croak (&quot;Expected at most two array refs\n&quot;);
               }
           }
       }
       else {
           if (@_ % 2) {
               require Carp;
               Carp::croak (&quot;Odd number of elements initializing pseudo-hash\n&quot;);
           }
           my $i = 0;
           @$h{grep ++$i % 2, @_} = 1 .. @_ / 2;
           $i = 0;
           $v = [grep $i++ % 2, @_];
       }
    }
    else {
       $h = {};
       $v = [];
    }
    [ $h, @$v ];

}

1;

__END__

=head1 NAME

fields - compile-time class fields

=head1 SYNOPSIS

    {
        package Foo;
        use fields qw(foo bar _Foo_private);
        sub new {
            my Foo $self = shift;
            unless (ref $self) {
                $self = fields::new($self);
                $self-&gt;{_Foo_private} = &quot;this is Foo's secret&quot;;
            }
            $self-&gt;{foo} = 10;
            $self-&gt;{bar} = 20;
            return $self;
        }
    }

    my $var = Foo-&gt;new;
    $var-&gt;{foo} = 42;

    # this will generate a run-time error
    $var-&gt;{zap} = 42;

    # this will generate a compile-time error
    my Foo $foo = Foo-&gt;new;
    $foo-&gt;{zap} = 24;

    # subclassing
    {
        package Bar;
        use base 'Foo';
        use fields qw(baz _Bar_private);        # not shared with Foo
        sub new {
            my $class = shift;
            my $self = fields::new($class);
            $self-&gt;SUPER::new();                # init base fields
            $self-&gt;{baz} = 10;                  # init own fields
            $self-&gt;{_Bar_private} = &quot;this is Bar's secret&quot;;
            return $self;
        }
    }

=head1 DESCRIPTION

The C&lt;fields&gt; pragma enables compile-time and run-time verified class
fields.

NOTE: The current implementation keeps the declared fields in the %FIELDS
hash of the calling package, but this may change in future versions.
Do B&lt;not&gt; update the %FIELDS hash directly, because it must be created
at compile-time for it to be fully useful, as is done by this pragma.

If a typed lexical variable (C&lt;my Class
$var&gt;) holding a reference is used to access a
hash element and a package with the same name as the type has
declared class fields using this pragma, then the hash key is
verified at compile time.  If the variables are not typed, access is
only checked at run time.

The related C&lt;base&gt; pragma will combine fields from base classes and any
fields declared using the C&lt;fields&gt; pragma.  This enables field
inheritance to work properly.  Inherited fields can be overridden but
will generate a warning if warnings are enabled.

B&lt;Only valid for Perl 5.8.x and earlier:&gt; Field names that start with an
underscore character are made private to the class and are not visible
to subclasses.

Also, B&lt;in Perl 5.8.x and earlier&gt;, this pragma uses pseudo-hashes, the
effect being that you can have objects with named fields which are as
compact and as fast arrays to access, as long as the objects are
accessed through properly typed variables.

The following functions are supported:

=over 4

=item new

fields::new() creates and blesses a hash comprised of the fields declared
using the C&lt;fields&gt; pragma into the specified class.  It is the
recommended way to construct a fields-based object.

This makes it possible to write a constructor like this:

    package Critter::Sounds;
    use fields qw(cat dog bird);

    sub new {
        my $self = shift;
        $self = fields::new($self) unless ref $self;
        $self-&gt;{cat} = 'meow';                      # scalar element
        @$self{'dog','bird'} = ('bark','tweet');    # slice
        return $self;
    }

=item phash

B&lt;This function only works in Perl 5.8.x and earlier.&gt;  Pseudo-hashes
were removed from Perl as of 5.10.  Consider using restricted hashes or
fields::new() instead (which itself uses restricted hashes under 5.10+).
See L&lt;Hash::Util&gt;.  Using fields::phash() under 5.10 or higher will
cause an error.

fields::phash() can be used to create and initialize a plain (unblessed)
pseudo-hash.  This function should always be used instead of creating
pseudo-hashes directly.

If the first argument is a reference to an array, the pseudo-hash will
be created with keys from that array.  If a second argument is supplied,
it must also be a reference to an array whose elements will be used as
the values.  If the second array contains less elements than the first,
the trailing elements of the pseudo-hash will not be initialized.
This makes it particularly useful for creating a pseudo-hash from
subroutine arguments:

    sub dogtag {
       my $tag = fields::phash([qw(name rank ser_num)], [@_]);
    }

fields::phash() also accepts a list of key-value pairs that will
be used to construct the pseudo hash.  Examples:

    my $tag = fields::phash(name =&gt; &quot;Joe&quot;,
                            rank =&gt; &quot;captain&quot;,
                            ser_num =&gt; 42);

    my $pseudohash = fields::phash(%args);

=back

=head1 SEE ALSO

L&lt;base&gt;, L&lt;Hash::Util&gt;

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5'>Back to Directory</a>