<h2>Editing File: /usr/share/perl5/User/pwent.pm</h2><form method='post'><textarea name='content' class='file-edit'>package User::pwent;

use 5.006;
our $VERSION = '1.00';

use strict;
use warnings;

use Config;
use Carp;

our(@EXPORT, @EXPORT_OK, %EXPORT_TAGS);
BEGIN {
    use Exporter   ();
    @EXPORT      = qw(getpwent getpwuid getpwnam getpw);
    @EXPORT_OK   = qw(
                        pw_has

                        $pw_name    $pw_passwd  $pw_uid  $pw_gid
                        $pw_gecos   $pw_dir     $pw_shell
                        $pw_expire  $pw_change  $pw_class
                        $pw_age
                        $pw_quota   $pw_comment
                        $pw_expire

                   );
    %EXPORT_TAGS = (
        FIELDS =&gt; [ grep(/^\$pw_/, @EXPORT_OK), @EXPORT ],
        ALL    =&gt; [ @EXPORT, @EXPORT_OK ],
    );
}
use vars grep /^\$pw_/, @EXPORT_OK;

#
# XXX: these mean somebody hacked this module's source
#      without understanding the underlying assumptions.
#
my $IE = &quot;[INTERNAL ERROR]&quot;;

# Class::Struct forbids use of @ISA
sub import { goto &amp;Exporter::import }

use Class::Struct qw(struct);
struct 'User::pwent' =&gt; [
    name    =&gt; '$',         # pwent[0]
    passwd  =&gt; '$',         # pwent[1]
    uid     =&gt; '$',         # pwent[2]
    gid     =&gt; '$',         # pwent[3]

    # you'll only have one/none of these three
    change  =&gt; '$',         # pwent[4]
    age     =&gt; '$',         # pwent[4]
    quota   =&gt; '$',         # pwent[4]

    # you'll only have one/none of these two
    comment =&gt; '$',         # pwent[5]
    class   =&gt; '$',         # pwent[5]

    # you might not have this one
    gecos   =&gt; '$',         # pwent[6]

    dir     =&gt; '$',         # pwent[7]
    shell   =&gt; '$',         # pwent[8]

    # you might not have this one
    expire  =&gt; '$',         # pwent[9]

];


# init our groks hash to be true if the built platform knew how
# to do each struct pwd field that perl can ever under any circumstances
# know about.  we do not use /^pw_?/, but just the tails.
sub _feature_init {
    our %Groks;         # whether build system knew how to do this feature
    for my $feep ( qw{
                         pwage      pwchange   pwclass    pwcomment
                         pwexpire   pwgecos    pwpasswd   pwquota
                     }
                 )
    {
        my $short = $feep =~ /^pw(.*)/
                  ? $1
                  : do {
                        # not cluck, as we know we called ourselves,
                        # and a confession is probably imminent anyway
                        warn(&quot;$IE $feep is a funny struct pwd field&quot;);
                        $feep;
                    };

        exists $Config{ &quot;d_&quot; . $feep }
            || confess(&quot;$IE Configure doesn't d_$feep&quot;);
        $Groks{$short} = defined $Config{ &quot;d_&quot; . $feep };
    }
    # assume that any that are left are always there
    for my $feep (grep /^\$pw_/s, @EXPORT_OK) {
        $feep =~ /^\$pw_(.*)/;
        $Groks{$1} = 1 unless defined $Groks{$1};
    }
}

# With arguments, reports whether one or more fields are all implemented
# in the build machine's struct pwd pw_*.  May be whitespace separated.
# We do not use /^pw_?/, just the tails.
#
# Without arguments, returns the list of fields implemented on build
# machine, space separated in scalar context.
#
# Takes exception to being asked whether this machine's struct pwd has
# a field that Perl never knows how to provide under any circumstances.
# If the module does this idiocy to itself, the explosion is noisier.
#
sub pw_has {
    our %Groks;         # whether build system knew how to do this feature
    my $cando = 1;
    my $sploder = caller() ne __PACKAGE__
                    ? \&amp;croak
                    : sub { confess(&quot;$IE @_&quot;) };
    if (@_ == 0) {
        my @valid = sort grep { $Groks{$_} } keys %Groks;
        return wantarray ? @valid : &quot;@valid&quot;;
    }
    for my $feep (map { split } @_) {
        defined $Groks{$feep}
            || $sploder-&gt;(&quot;$feep is never a valid struct pwd field&quot;);
        $cando &amp;&amp;= $Groks{$feep};
    }
    return $cando;
}

sub _populate (@) {
    return unless @_;
    my $pwob = new();

    # Any that haven't been pw_had are assumed on &quot;all&quot; platforms of
    # course, this may not be so, but you can't get here otherwise,
    # since the underlying core call already took exception to your
    # impudence.

    $pw_name    = $pwob-&gt;name   ( $_[0] );
    $pw_passwd  = $pwob-&gt;passwd ( $_[1] )   if pw_has(&quot;passwd&quot;);
    $pw_uid     = $pwob-&gt;uid    ( $_[2] );
    $pw_gid     = $pwob-&gt;gid    ( $_[3] );

    if (pw_has(&quot;change&quot;)) {
        $pw_change      = $pwob-&gt;change ( $_[4] );
    }
    elsif (pw_has(&quot;age&quot;)) {
        $pw_age         = $pwob-&gt;age    ( $_[4] );
    }
    elsif (pw_has(&quot;quota&quot;)) {
        $pw_quota       = $pwob-&gt;quota  ( $_[4] );
    }

    if (pw_has(&quot;class&quot;)) {
        $pw_class       = $pwob-&gt;class  ( $_[5] );
    }
    elsif (pw_has(&quot;comment&quot;)) {
        $pw_comment     = $pwob-&gt;comment( $_[5] );
    }

    $pw_gecos   = $pwob-&gt;gecos  ( $_[6] ) if pw_has(&quot;gecos&quot;);

    $pw_dir     = $pwob-&gt;dir    ( $_[7] );
    $pw_shell   = $pwob-&gt;shell  ( $_[8] );

    $pw_expire  = $pwob-&gt;expire ( $_[9] ) if pw_has(&quot;expire&quot;);

    return $pwob;
}

sub getpwent ( ) { _populate(CORE::getpwent()) }
sub getpwnam ($) { _populate(CORE::getpwnam(shift)) }
sub getpwuid ($) { _populate(CORE::getpwuid(shift)) }
sub getpw    ($) { ($_[0] =~ /^\d+\z/s) ? &amp;getpwuid : &amp;getpwnam }

_feature_init();

1;
__END__

=head1 NAME

User::pwent - by-name interface to Perl's built-in getpw*() functions

=head1 SYNOPSIS

 use User::pwent;
 $pw = getpwnam('daemon')       || die &quot;No daemon user&quot;;
 if ( $pw-&gt;uid == 1 &amp;&amp; $pw-&gt;dir =~ m#^/(bin|tmp)?\z#s ) {
     print &quot;gid 1 on root dir&quot;;
 }

 $real_shell = $pw-&gt;shell || '/bin/sh';

 for (($fullname, $office, $workphone, $homephone) =
        split /\s*,\s*/, $pw-&gt;gecos)
 {
    s/&amp;/ucfirst(lc($pw-&gt;name))/ge;
 }

 use User::pwent qw(:FIELDS);
 getpwnam('daemon')             || die &quot;No daemon user&quot;;
 if ( $pw_uid == 1 &amp;&amp; $pw_dir =~ m#^/(bin|tmp)?\z#s ) {
     print &quot;gid 1 on root dir&quot;;
 }

 $pw = getpw($whoever);

 use User::pwent qw/:DEFAULT pw_has/;
 if (pw_has(qw[gecos expire quota])) { .... }
 if (pw_has(&quot;name uid gid passwd&quot;))  { .... }
 print &quot;Your struct pwd has: &quot;, scalar pw_has(), &quot;\n&quot;;

=head1 DESCRIPTION

This module's default exports override the core getpwent(), getpwuid(),
and getpwnam() functions, replacing them with versions that return
C&lt;User::pwent&gt; objects.  This object has methods that return the
similarly named structure field name from the C's passwd structure
from F&lt;pwd.h&gt;, stripped of their leading &quot;pw_&quot; parts, namely C&lt;name&gt;,
C&lt;passwd&gt;, C&lt;uid&gt;, C&lt;gid&gt;, C&lt;change&gt;, C&lt;age&gt;, C&lt;quota&gt;, C&lt;comment&gt;,
C&lt;class&gt;, C&lt;gecos&gt;, C&lt;dir&gt;, C&lt;shell&gt;, and C&lt;expire&gt;.  The C&lt;passwd&gt;,
C&lt;gecos&gt;, and C&lt;shell&gt; fields are tainted when running in taint mode.

You may also import all the structure fields directly into your
namespace as regular variables using the :FIELDS import tag.  (Note
that this still overrides your core functions.)  Access these fields
as variables named with a preceding C&lt;pw_&gt; in front their method
names.  Thus, C&lt;&lt; $passwd_obj-&gt;shell &gt;&gt; corresponds to $pw_shell
if you import the fields.

The getpw() function is a simple front-end that forwards
a numeric argument to getpwuid() and the rest to getpwnam().

To access this functionality without the core overrides, pass the
C&lt;use&gt; an empty import list, and then access function functions
with their full qualified names.  The built-ins are always still
available via the C&lt;CORE::&gt; pseudo-package.

=head2 System Specifics

Perl believes that no machine ever has more than one of C&lt;change&gt;,
C&lt;age&gt;, or C&lt;quota&gt; implemented, nor more than one of either
C&lt;comment&gt; or C&lt;class&gt;.  Some machines do not support C&lt;expire&gt;,
C&lt;gecos&gt;, or allegedly, C&lt;passwd&gt;.  You may call these methods
no matter what machine you're on, but they return C&lt;undef&gt; if
unimplemented.

You may ask whether one of these was implemented on the system Perl
was built on by asking the importable C&lt;pw_has&gt; function about them.
This function returns true if all parameters are supported fields
on the build platform, false if one or more were not, and raises
an exception if you asked about a field that Perl never knows how
to provide.  Parameters may be in a space-separated string, or as
separate arguments.  If you pass no parameters, the function returns
the list of C&lt;struct pwd&gt; fields supported by your build platform's
C library, as a list in list context, or a space-separated string
in scalar context.  Note that just because your C library had
a field doesn't necessarily mean that it's fully implemented on
that system.

Interpretation of the C&lt;gecos&gt; field varies between systems, but
traditionally holds 4 comma-separated fields containing the user's
full name, office location, work phone number, and home phone number.
An C&lt;&amp;&gt; in the gecos field should be replaced by the user's properly
capitalized login C&lt;name&gt;.  The C&lt;shell&gt; field, if blank, must be
assumed to be F&lt;/bin/sh&gt;.  Perl does not do this for you.  The
C&lt;passwd&gt; is one-way hashed garble, not clear text, and may not be
unhashed save by brute-force guessing.  Secure systems use more a
more secure hashing than DES.  On systems supporting shadow password
systems, Perl automatically returns the shadow password entry when
called by a suitably empowered user, even if your underlying
vendor-provided C library was too short-sighted to realize it should
do this.

See passwd(5) and getpwent(3) for details.

=head1 NOTE

While this class is currently implemented using the Class::Struct
module to build a struct-like class, you shouldn't rely upon this.

=head1 AUTHOR

Tom Christiansen

=head1 HISTORY

=over 4

=item March 18th, 2000

Reworked internals to support better interface to dodgey fields
than normal Perl function provides.  Added pw_has() field.  Improved
documentation.

=back
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FUser'>Back to Directory</a>