<h2>Editing File: /usr/share/perl5/Tie/RefHash.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Tie::RefHash;

use vars qw/$VERSION/;

$VERSION = &quot;1.39&quot;;

use 5.005;

=head1 NAME

Tie::RefHash - use references as hash keys

=head1 SYNOPSIS

    require 5.004;
    use Tie::RefHash;
    tie HASHVARIABLE, 'Tie::RefHash', LIST;
    tie HASHVARIABLE, 'Tie::RefHash::Nestable', LIST;

    untie HASHVARIABLE;

=head1 DESCRIPTION

This module provides the ability to use references as hash keys if you
first C&lt;tie&gt; the hash variable to this module.  Normally, only the
keys of the tied hash itself are preserved as references; to use
references as keys in hashes-of-hashes, use Tie::RefHash::Nestable,
included as part of Tie::RefHash.

It is implemented using the standard perl TIEHASH interface.  Please
see the C&lt;tie&gt; entry in perlfunc(1) and perltie(1) for more information.

The Nestable version works by looking for hash references being stored
and converting them to tied hashes so that they too can have
references as keys.  This will happen without warning whenever you
store a reference to one of your own hashes in the tied hash.

=head1 EXAMPLE

    use Tie::RefHash;
    tie %h, 'Tie::RefHash';
    $a = [];
    $b = {};
    $c = \*main;
    $d = \&quot;gunk&quot;;
    $e = sub { 'foo' };
    %h = ($a =&gt; 1, $b =&gt; 2, $c =&gt; 3, $d =&gt; 4, $e =&gt; 5);
    $a-&gt;[0] = 'foo';
    $b-&gt;{foo} = 'bar';
    for (keys %h) {
       print ref($_), &quot;\n&quot;;
    }

    tie %h, 'Tie::RefHash::Nestable';
    $h{$a}-&gt;{$b} = 1;
    for (keys %h, keys %{$h{$a}}) {
       print ref($_), &quot;\n&quot;;
    }

=head1 THREAD SUPPORT

L&lt;Tie::RefHash&gt; fully supports threading using the C&lt;CLONE&gt; method.

=head1 STORABLE SUPPORT

L&lt;Storable&gt; hooks are provided for semantically correct serialization and
cloning of tied refhashes.

=head1 RELIC SUPPORT

This version of Tie::RefHash seems to no longer work with 5.004. This has not
been throughly investigated. Patches welcome ;-)

=head1 LICENSE

This program is free software; you can redistribute it and/or modify it under
the same terms as Perl itself

=head1 MAINTAINER

Yuval Kogman E&lt;lt&gt;nothingmuch@woobling.orgE&lt;gt&gt;

=head1 AUTHOR

Gurusamy Sarathy        gsar@activestate.com

'Nestable' by Ed Avis   ed@membled.com

=head1 SEE ALSO

perl(1), perlfunc(1), perltie(1)

=cut

use Tie::Hash;
use vars '@ISA';
@ISA = qw(Tie::Hash);
use strict;
use Carp qw/croak/;

BEGIN {
  local $@;
  # determine whether we need to take care of threads
  use Config ();
  my $usethreads = $Config::Config{usethreads}; # &amp;&amp; exists $INC{&quot;threads.pm&quot;}
  *_HAS_THREADS = $usethreads ? sub () { 1 } : sub () { 0 };
  *_HAS_SCALAR_UTIL = eval { require Scalar::Util; 1 } ? sub () { 1 } : sub () { 0 };
  *_HAS_WEAKEN = defined(&amp;Scalar::Util::weaken) ? sub () { 1 } : sub () { 0 };
}

BEGIN {
  # create a refaddr function

  local $@;

  if ( _HAS_SCALAR_UTIL ) {
    Scalar::Util-&gt;import(&quot;refaddr&quot;);
  } else {
    require overload;

    *refaddr = sub {
      if ( overload::StrVal($_[0]) =~ /\( 0x ([a-zA-Z0-9]+) \)$/x) {
          return $1;
      } else {
        die &quot;couldn't parse StrVal: &quot; . overload::StrVal($_[0]);
      }
    };
  }
}

my (@thread_object_registry, $count); # used by the CLONE method to rehash the keys after their refaddr changed

sub TIEHASH {
  my $c = shift;
  my $s = [];
  bless $s, $c;
  while (@_) {
    $s-&gt;STORE(shift, shift);
  }

  if (_HAS_THREADS ) {

    if ( _HAS_WEAKEN ) {
      # remember the object so that we can rekey it on CLONE
      push @thread_object_registry, $s;
      # but make this a weak reference, so that there are no leaks
      Scalar::Util::weaken( $thread_object_registry[-1] );

      if ( ++$count &gt; 1000 ) {
        # this ensures we don't fill up with a huge array dead weakrefs
        @thread_object_registry = grep { defined } @thread_object_registry;
        $count = 0;
      }
    } else {
      $count++; # used in the warning
    }
  }

  return $s;
}

my $storable_format_version = join(&quot;/&quot;, __PACKAGE__, &quot;0.01&quot;);

sub STORABLE_freeze {
  my ( $self, $is_cloning ) = @_;
  my ( $refs, $reg ) = @$self;
  return ( $storable_format_version, [ values %$refs ], $reg || {} );
}

sub STORABLE_thaw {
  my ( $self, $is_cloning, $version, $refs, $reg ) = @_;
  croak &quot;incompatible versions of Tie::RefHash between freeze and thaw&quot;
    unless $version eq $storable_format_version;

  @$self = ( {}, $reg );
  $self-&gt;_reindex_keys( $refs );
}

sub CLONE {
  my $pkg = shift;

  if ( $count and not _HAS_WEAKEN ) {
    warn &quot;Tie::RefHash is not threadsafe without Scalar::Util::weaken&quot;;
  }

  # when the thread has been cloned all the objects need to be updated.
  # dead weakrefs are undefined, so we filter them out
  @thread_object_registry = grep { defined &amp;&amp; do { $_-&gt;_reindex_keys; 1 } } @thread_object_registry;
  $count = 0; # we just cleaned up
}

sub _reindex_keys {
  my ( $self, $extra_keys ) = @_;
  # rehash all the ref keys based on their new StrVal
  %{ $self-&gt;[0] } = map { refaddr($_-&gt;[0]) =&gt; $_ } (values(%{ $self-&gt;[0] }), @{ $extra_keys || [] });
}

sub FETCH {
  my($s, $k) = @_;
  if (ref $k) {
      my $kstr = refaddr($k);
      if (defined $s-&gt;[0]{$kstr}) {
        $s-&gt;[0]{$kstr}[1];
      }
      else {
        undef;
      }
  }
  else {
      $s-&gt;[1]{$k};
  }
}

sub STORE {
  my($s, $k, $v) = @_;
  if (ref $k) {
    $s-&gt;[0]{refaddr($k)} = [$k, $v];
  }
  else {
    $s-&gt;[1]{$k} = $v;
  }
  $v;
}

sub DELETE {
  my($s, $k) = @_;
  (ref $k)
    ? (delete($s-&gt;[0]{refaddr($k)}) || [])-&gt;[1]
    : delete($s-&gt;[1]{$k});
}

sub EXISTS {
  my($s, $k) = @_;
  (ref $k) ? exists($s-&gt;[0]{refaddr($k)}) : exists($s-&gt;[1]{$k});
}

sub FIRSTKEY {
  my $s = shift;
  keys %{$s-&gt;[0]};  # reset iterator
  keys %{$s-&gt;[1]};  # reset iterator
  $s-&gt;[2] = 0;      # flag for iteration, see NEXTKEY
  $s-&gt;NEXTKEY;
}

sub NEXTKEY {
  my $s = shift;
  my ($k, $v);
  if (!$s-&gt;[2]) {
    if (($k, $v) = each %{$s-&gt;[0]}) {
      return $v-&gt;[0];
    }
    else {
      $s-&gt;[2] = 1;
    }
  }
  return each %{$s-&gt;[1]};
}

sub CLEAR {
  my $s = shift;
  $s-&gt;[2] = 0;
  %{$s-&gt;[0]} = ();
  %{$s-&gt;[1]} = ();
}

package Tie::RefHash::Nestable;
use vars '@ISA';
@ISA = 'Tie::RefHash';

sub STORE {
  my($s, $k, $v) = @_;
  if (ref($v) eq 'HASH' and not tied %$v) {
      my @elems = %$v;
      tie %$v, ref($s), @elems;
  }
  $s-&gt;SUPER::STORE($k, $v);
}

1;
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FTie'>Back to Directory</a>