<h2>Editing File: /usr/share/perl5/Test.pm</h2><form method='post'><textarea name='content' class='file-edit'>
require 5.004;
package Test;

use strict;

use Carp;
use vars (qw($VERSION @ISA @EXPORT @EXPORT_OK $ntest $TestLevel), #public-ish
          qw($TESTOUT $TESTERR %Program_Lines $told_about_diff
             $ONFAIL %todo %history $planned @FAILDETAIL) #private-ish
         );

# In case a test is run in a persistent environment.
sub _reset_globals {
    %todo       = ();
    %history    = ();
    @FAILDETAIL = ();
    $ntest      = 1;
    $TestLevel  = 0;		# how many extra stack frames to skip
    $planned    = 0;
}

$VERSION = '1.30';
require Exporter;
@ISA=('Exporter');

@EXPORT    = qw(&amp;plan &amp;ok &amp;skip);
@EXPORT_OK = qw($ntest $TESTOUT $TESTERR);

$|=1;
$TESTOUT = *STDOUT{IO};
$TESTERR = *STDERR{IO};

# Use of this variable is strongly discouraged.  It is set mainly to
# help test coverage analyzers know which test is running.
$ENV{REGRESSION_TEST} = $0;


=head1 NAME

Test - provides a simple framework for writing test scripts

=head1 SYNOPSIS

  use strict;
  use Test;

  # use a BEGIN block so we print our plan before MyModule is loaded
  BEGIN { plan tests =&gt; 14, todo =&gt; [3,4] }

  # load your module...
  use MyModule;

  # Helpful notes.  All note-lines must start with a &quot;#&quot;.
  print &quot;# I'm testing MyModule version $MyModule::VERSION\n&quot;;

  ok(0); # failure
  ok(1); # success

  ok(0); # ok, expected failure (see todo list, above)
  ok(1); # surprise success!

  ok(0,1);             # failure: '0' ne '1'
  ok('broke','fixed'); # failure: 'broke' ne 'fixed'
  ok('fixed','fixed'); # success: 'fixed' eq 'fixed'
  ok('fixed',qr/x/);   # success: 'fixed' =~ qr/x/

  ok(sub { 1+1 }, 2);  # success: '2' eq '2'
  ok(sub { 1+1 }, 3);  # failure: '2' ne '3'

  my @list = (0,0);
  ok @list, 3, &quot;\@list=&quot;.join(',',@list);      #extra notes
  ok 'segmentation fault', '/(?i)success/';    #regex match

  skip(
    $^O =~ m/MSWin/ ? &quot;Skip if MSWin&quot; : 0,  # whether to skip
    $foo, $bar  # arguments just like for ok(...)
  );
  skip(
    $^O =~ m/MSWin/ ? 0 : &quot;Skip unless MSWin&quot;,  # whether to skip
    $foo, $bar  # arguments just like for ok(...)
  );

=head1 DESCRIPTION

This module simplifies the task of writing test files for Perl modules,
such that their output is in the format that
L&lt;Test::Harness|Test::Harness&gt; expects to see.

=head1 QUICK START GUIDE

To write a test for your new (and probably not even done) module, create
a new file called F&lt;t/test.t&gt; (in a new F&lt;t&gt; directory). If you have
multiple test files, to test the &quot;foo&quot;, &quot;bar&quot;, and &quot;baz&quot; feature sets,
then feel free to call your files F&lt;t/foo.t&gt;, F&lt;t/bar.t&gt;, and
F&lt;t/baz.t&gt;

=head2 Functions

This module defines three public functions, C&lt;plan(...)&gt;, C&lt;ok(...)&gt;,
and C&lt;skip(...)&gt;.  By default, all three are exported by
the C&lt;use Test;&gt; statement.

=over 4

=item C&lt;plan(...)&gt;

     BEGIN { plan %theplan; }

This should be the first thing you call in your test script.  It
declares your testing plan, how many there will be, if any of them
should be allowed to fail, and so on.

Typical usage is just:

     use Test;
     BEGIN { plan tests =&gt; 23 }

These are the things that you can put in the parameters to plan:

=over

=item C&lt;tests =E&lt;gt&gt; I&lt;number&gt;&gt;

The number of tests in your script.
This means all ok() and skip() calls.

=item C&lt;todo =E&lt;gt&gt; [I&lt;1,5,14&gt;]&gt;

A reference to a list of tests which are allowed to fail.
See L&lt;/TODO TESTS&gt;.

=item C&lt;onfail =E&lt;gt&gt; sub { ... }&gt;

=item C&lt;onfail =E&lt;gt&gt; \&amp;some_sub&gt;

A subroutine reference to be run at the end of the test script, if
any of the tests fail.  See L&lt;/ONFAIL&gt;.

=back

You must call C&lt;plan(...)&gt; once and only once.  You should call it
in a C&lt;BEGIN {...}&gt; block, like so:

     BEGIN { plan tests =&gt; 23 }

=cut

sub plan {
    croak &quot;Test::plan(%args): odd number of arguments&quot; if @_ &amp; 1;
    croak &quot;Test::plan(): should not be called more than once&quot; if $planned;

    local($\, $,);   # guard against -l and other things that screw with
                     # print

    _reset_globals();

    _read_program( (caller)[1] );

    my $max=0;
    while (@_) {
	my ($k,$v) = splice(@_, 0, 2);
	if ($k =~ /^test(s)?$/) { $max = $v; }
	elsif ($k eq 'todo' or
	       $k eq 'failok') { for (@$v) { $todo{$_}=1; }; }
	elsif ($k eq 'onfail') {
	    ref $v eq 'CODE' or croak &quot;Test::plan(onfail =&gt; $v): must be CODE&quot;;
	    $ONFAIL = $v;
	}
	else { carp &quot;Test::plan(): skipping unrecognized directive '$k'&quot; }
    }
    my @todo = sort { $a &lt;=&gt; $b } keys %todo;
    if (@todo) {
	print $TESTOUT &quot;1..$max todo &quot;.join(' ', @todo).&quot;;\n&quot;;
    } else {
	print $TESTOUT &quot;1..$max\n&quot;;
    }
    ++$planned;
    print $TESTOUT &quot;# Running under perl version $] for $^O&quot;,
      (chr(65) eq 'A') ? &quot;\n&quot; : &quot; in a non-ASCII world\n&quot;;

    print $TESTOUT &quot;# Win32::BuildNumber &quot;, &amp;Win32::BuildNumber(), &quot;\n&quot;
      if defined(&amp;Win32::BuildNumber) and defined &amp;Win32::BuildNumber();

    print $TESTOUT &quot;# MacPerl version $MacPerl::Version\n&quot;
      if defined $MacPerl::Version;

    printf $TESTOUT
      &quot;# Current time local: %s\n# Current time GMT:   %s\n&quot;,
      scalar(localtime($^T)), scalar(gmtime($^T));

    print $TESTOUT &quot;# Using Test.pm version $VERSION\n&quot;;

    # Retval never used:
    return undef;
}

sub _read_program {
  my($file) = shift;
  return unless defined $file and length $file
    and -e $file and -f _ and -r _;
  open(SOURCEFILE, '&lt;', $file) || return;
  $Program_Lines{$file} = [&lt;SOURCEFILE&gt;];
  close(SOURCEFILE);

  foreach my $x (@{$Program_Lines{$file}})
   { $x =~ tr/\cm\cj\n\r//d }

  unshift @{$Program_Lines{$file}}, '';
  return 1;
}

=begin _private

=item B&lt;_to_value&gt;

  my $value = _to_value($input);

Converts an C&lt;ok&gt; parameter to its value.  Typically this just means
running it, if it's a code reference.  You should run all inputted
values through this.

=cut

sub _to_value {
    my ($v) = @_;
    return ref $v eq 'CODE' ? $v-&gt;() : $v;
}

sub _quote {
    my $str = $_[0];
    return &quot;&lt;UNDEF&gt;&quot; unless defined $str;
    $str =~ s/\\/\\\\/g;
    $str =~ s/&quot;/\\&quot;/g;
    $str =~ s/\a/\\a/g;
    $str =~ s/[\b]/\\b/g;
    $str =~ s/\e/\\e/g;
    $str =~ s/\f/\\f/g;
    $str =~ s/\n/\\n/g;
    $str =~ s/\r/\\r/g;
    $str =~ s/\t/\\t/g;
    if (defined $^V &amp;&amp; $^V ge v5.6) {
        $str =~ s/([[:cntrl:]])(?!\d)/sprintf('\\%o',ord($1))/eg;
        $str =~ s/([[:^print:]])/sprintf('\\x%02X',ord($1))/eg;
        $str =~ s/([[:^ascii:]])/sprintf('\\x{%X}',ord($1))/eg;
    }
    elsif (ord(&quot;A&quot;) == 65) {
        $str =~ s/([\0-\037])(?!\d)/sprintf('\\%o',ord($1))/eg;
        $str =~ s/([\0-\037\177-\377])/sprintf('\\x%02X',ord($1))/eg;
        $str =~ s/([^\0-\176])/sprintf('\\x{%X}',ord($1))/eg;
    }
    else { # Assuming EBCDIC on this ancient Perl

        # The controls except for one are 0-\077, so almost all controls on
        # EBCDIC platforms will be expressed in octal, instead of just the C0
        # ones.
        $str =~ s/([\0-\077])(?!\d)/sprintf('\\%o',ord($1))/eg;
        $str =~ s/([\0-\077])/sprintf('\\x%02X',ord($1))/eg;

        $str =~ s/([^\0-\xFF])/sprintf('\\x{%X}',ord($1))/eg;

        # What remains to be escaped are the non-ASCII-range characters,
        # including the one control that isn't in the 0-077 range.
        # (We don't escape further any ASCII printables.)
        $str =~ s&lt;[^ !&quot;\$\%#'()*+,\-./0123456789:;\&lt;=\&gt;?\@ABCDEFGHIJKLMNOPQRSTUVWXYZ\[\\\]^_`abcdefghijklmnopqrstuvwxyz{|}~]&gt;&lt;sprintf('\\x%02X',ord($1))&gt;eg;
    }
    #if( $_[1] ) {
    #  substr( $str , 218-3 ) = &quot;...&quot;
    #   if length($str) &gt;= 218 and !$ENV{PERL_TEST_NO_TRUNC};
    #}
    return qq(&quot;$str&quot;);
}


=end _private

=item C&lt;ok(...)&gt;

  ok(1 + 1 == 2);
  ok($have, $expect);
  ok($have, $expect, $diagnostics);

This function is the reason for C&lt;Test&gt;'s existence.  It's
the basic function that
handles printing &quot;C&lt;ok&gt;&quot; or &quot;C&lt;not ok&gt;&quot;, along with the
current test number.  (That's what C&lt;Test::Harness&gt; wants to see.)

In its most basic usage, C&lt;ok(...)&gt; simply takes a single scalar
expression.  If its value is true, the test passes; if false,
the test fails.  Examples:

    # Examples of ok(scalar)

    ok( 1 + 1 == 2 );           # ok if 1 + 1 == 2
    ok( $foo =~ /bar/ );        # ok if $foo contains 'bar'
    ok( baz($x + $y) eq 'Armondo' );    # ok if baz($x + $y) returns
                                        # 'Armondo'
    ok( @a == @b );             # ok if @a and @b are the same
                                # length

The expression is evaluated in scalar context.  So the following will
work:

    ok( @stuff );                       # ok if @stuff has any
                                        # elements
    ok( !grep !defined $_, @stuff );    # ok if everything in @stuff
                                        # is defined.

A special case is if the expression is a subroutine reference (in either
C&lt;sub {...}&gt; syntax or C&lt;\&amp;foo&gt; syntax).  In
that case, it is executed and its value (true or false) determines if
the test passes or fails.  For example,

    ok( sub {   # See whether sleep works at least passably
      my $start_time = time;
      sleep 5;
      time() - $start_time  &gt;= 4
    });

In its two-argument form, C&lt;ok(I&lt;arg1&gt;, I&lt;arg2&gt;)&gt; compares the two
scalar values to see if they match.  They match if both are undefined,
or if I&lt;arg2&gt; is a regex that matches I&lt;arg1&gt;, or if they compare equal
with C&lt;eq&gt;.

    # Example of ok(scalar, scalar)

    ok( &quot;this&quot;, &quot;that&quot; );               # not ok, 'this' ne 'that'
    ok( &quot;&quot;, undef );                    # not ok, &quot;&quot; is defined

The second argument is considered a regex if it is either a regex
object or a string that looks like a regex.  Regex objects are
constructed with the qr// operator in recent versions of perl.  A
string is considered to look like a regex if its first and last
characters are &quot;/&quot;, or if the first character is &quot;m&quot;
and its second and last characters are both the
same non-alphanumeric non-whitespace character.  These regexp

Regex examples:

    ok( 'JaffO', '/Jaff/' );    # ok, 'JaffO' =~ /Jaff/
    ok( 'JaffO', 'm|Jaff|' );   # ok, 'JaffO' =~ m|Jaff|
    ok( 'JaffO', qr/Jaff/ );    # ok, 'JaffO' =~ qr/Jaff/;
    ok( 'JaffO', '/(?i)jaff/ ); # ok, 'JaffO' =~ /jaff/i;

If either (or both!) is a subroutine reference, it is run and used
as the value for comparing.  For example:

    ok sub {
        open(OUT, '&gt;', 'x.dat') || die $!;
        print OUT &quot;\x{e000}&quot;;
        close OUT;
        my $bytecount = -s 'x.dat';
        unlink 'x.dat' or warn &quot;Can't unlink : $!&quot;;
        return $bytecount;
      },
      4
    ;

The above test passes two values to C&lt;ok(arg1, arg2)&gt; -- the first 
a coderef, and the second is the number 4.  Before C&lt;ok&gt; compares them,
it calls the coderef, and uses its return value as the real value of
this parameter. Assuming that C&lt;$bytecount&gt; returns 4, C&lt;ok&gt; ends up
testing C&lt;4 eq 4&gt;.  Since that's true, this test passes.

Finally, you can append an optional third argument, in
C&lt;ok(I&lt;arg1&gt;,I&lt;arg2&gt;, I&lt;note&gt;)&gt;, where I&lt;note&gt; is a string value that
will be printed if the test fails.  This should be some useful
information about the test, pertaining to why it failed, and/or
a description of the test.  For example:

    ok( grep($_ eq 'something unique', @stuff), 1,
        &quot;Something that should be unique isn't!\n&quot;.
        '@stuff = '.join ', ', @stuff
      );

Unfortunately, a note cannot be used with the single argument
style of C&lt;ok()&gt;.  That is, if you try C&lt;ok(I&lt;arg1&gt;, I&lt;note&gt;)&gt;, then
C&lt;Test&gt; will interpret this as C&lt;ok(I&lt;arg1&gt;, I&lt;arg2&gt;)&gt;, and probably
end up testing C&lt;I&lt;arg1&gt; eq I&lt;arg2&gt;&gt; -- and that's not what you want!

All of the above special cases can occasionally cause some
problems.  See L&lt;/BUGS and CAVEATS&gt;.

=cut

# A past maintainer of this module said:
# &lt;&lt;ok(...)'s special handling of subroutine references is an unfortunate
#   &quot;feature&quot; that can't be removed due to compatibility.&gt;&gt;
#

sub ok ($;$$) {
    croak &quot;ok: plan before you test!&quot; if !$planned;

    local($\,$,);   # guard against -l and other things that screw with
                    # print

    my ($pkg,$file,$line) = caller($TestLevel);
    my $repetition = ++$history{&quot;$file:$line&quot;};
    my $context = (&quot;$file at line $line&quot;.
		   ($repetition &gt; 1 ? &quot; fail \#$repetition&quot; : ''));

    # Are we comparing two values?
    my $compare = 0;

    my $ok=0;
    my $result = _to_value(shift);
    my ($expected, $isregex, $regex);
    if (@_ == 0) {
	$ok = $result;
    } else {
        $compare = 1;
	$expected = _to_value(shift);
	if (!defined $expected) {
	    $ok = !defined $result;
	} elsif (!defined $result) {
	    $ok = 0;
	} elsif (ref($expected) eq 'Regexp') {
	    $ok = $result =~ /$expected/;
            $regex = $expected;
	} elsif (($regex) = ($expected =~ m,^ / (.+) / $,sx) or
	    (undef, $regex) = ($expected =~ m,^ m([^\w\s]) (.+) \1 $,sx)) {
	    $ok = $result =~ /$regex/;
	} else {
	    $ok = $result eq $expected;
	}
    }
    my $todo = $todo{$ntest};
    if ($todo and $ok) {
	$context .= ' TODO?!' if $todo;
	print $TESTOUT &quot;ok $ntest # ($context)\n&quot;;
    } else {
        # Issuing two seperate prints() causes problems on VMS.
        if (!$ok) {
            print $TESTOUT &quot;not ok $ntest\n&quot;;
        }
	else {
            print $TESTOUT &quot;ok $ntest\n&quot;;
        }

        $ok or _complain($result, $expected,
        {
          'repetition' =&gt; $repetition, 'package' =&gt; $pkg,
          'result' =&gt; $result, 'todo' =&gt; $todo,
          'file' =&gt; $file, 'line' =&gt; $line,
          'context' =&gt; $context, 'compare' =&gt; $compare,
          @_ ? ('diagnostic' =&gt;  _to_value(shift)) : (),
        });

    }
    ++ $ntest;
    $ok;
}


sub _complain {
    my($result, $expected, $detail) = @_;
    $$detail{expected} = $expected if defined $expected;

    # Get the user's diagnostic, protecting against multi-line
    # diagnostics.
    my $diag = $$detail{diagnostic};
    $diag =~ s/\n/\n#/g if defined $diag;

    my $out = $$detail{todo} ? $TESTOUT : $TESTERR;
    $$detail{context} .= ' *TODO*' if $$detail{todo};
    if (!$$detail{compare}) {
        if (!$diag) {
            print $out &quot;# Failed test $ntest in $$detail{context}\n&quot;;
        } else {
            print $out &quot;# Failed test $ntest in $$detail{context}: $diag\n&quot;;
        }
    } else {
        my $prefix = &quot;Test $ntest&quot;;

        print $out &quot;# $prefix got: &quot; . _quote($result) .
                       &quot; ($$detail{context})\n&quot;;
        $prefix = ' ' x (length($prefix) - 5);
        my $expected_quoted = (defined $$detail{regex})
         ?  'qr{'.($$detail{regex}).'}'  :  _quote($expected);

        print $out &quot;# $prefix Expected: $expected_quoted&quot;,
           $diag ? &quot; ($diag)&quot; : (), &quot;\n&quot;;

        _diff_complain( $result, $expected, $detail, $prefix )
          if defined($expected) and 2 &lt; ($expected =~ tr/\n//);
    }

    if(defined $Program_Lines{ $$detail{file} }[ $$detail{line} ]) {
        print $out
          &quot;#  $$detail{file} line $$detail{line} is: $Program_Lines{ $$detail{file} }[ $$detail{line} ]\n&quot;
         if $Program_Lines{ $$detail{file} }[ $$detail{line} ]
          =~ m/[^\s\#\(\)\{\}\[\]\;]/;  # Otherwise it's uninformative

        undef $Program_Lines{ $$detail{file} }[ $$detail{line} ];
         # So we won't repeat it.
    }

    push @FAILDETAIL, $detail;
    return;
}


sub _diff_complain {
    my($result, $expected, $detail, $prefix) = @_;
    return _diff_complain_external(@_) if $ENV{PERL_TEST_DIFF};
    return _diff_complain_algdiff(@_)
      if eval {
          local @INC = @INC;
          pop @INC if $INC[-1] eq '.';
          require Algorithm::Diff; Algorithm::Diff-&gt;VERSION(1.15);
          1;
      };

    $told_about_diff++ or print $TESTERR &lt;&lt;&quot;EOT&quot;;
# $prefix   (Install the Algorithm::Diff module to have differences in multiline
# $prefix    output explained.  You might also set the PERL_TEST_DIFF environment
# $prefix    variable to run a diff program on the output.)
EOT
    ;
    return;
}


sub _diff_complain_external {
    my($result, $expected, $detail, $prefix) = @_;
    my $diff = $ENV{PERL_TEST_DIFF} || die &quot;WHAAAA?&quot;;

    require File::Temp;
    my($got_fh, $got_filename) = File::Temp::tempfile(&quot;test-got-XXXXX&quot;);
    my($exp_fh, $exp_filename) = File::Temp::tempfile(&quot;test-exp-XXXXX&quot;);
    unless ($got_fh &amp;&amp; $exp_fh) {
      warn &quot;Can't get tempfiles&quot;;
      return;
    }

    print $got_fh $result;
    print $exp_fh $expected;
    if (close($got_fh) &amp;&amp; close($exp_fh)) {
        my $diff_cmd = &quot;$diff $exp_filename $got_filename&quot;;
        print $TESTERR &quot;#\n# $prefix $diff_cmd\n&quot;;
        if (open(DIFF, '-|', $diff_cmd)) {
            local $_;
            while (&lt;DIFF&gt;) {
                print $TESTERR &quot;# $prefix $_&quot;;
            }
            close(DIFF);
        }
        else {
            warn &quot;Can't run diff: $!&quot;;
        }
    } else {
        warn &quot;Can't write to tempfiles: $!&quot;;
    }
    unlink($got_filename);
    unlink($exp_filename);
    return;
}


sub _diff_complain_algdiff {
    my($result, $expected, $detail, $prefix) = @_;

    my @got = split(/^/, $result);
    my @exp = split(/^/, $expected);

    my $diff_kind;
    my @diff_lines;

    my $diff_flush = sub {
        return unless $diff_kind;

        my $count_lines = @diff_lines;
        my $s = $count_lines == 1 ? &quot;&quot; : &quot;s&quot;;
        my $first_line = $diff_lines[0][0] + 1;

        print $TESTERR &quot;# $prefix &quot;;
        if ($diff_kind eq &quot;GOT&quot;) {
            print $TESTERR &quot;Got $count_lines extra line$s at line $first_line:\n&quot;;
            for my $i (@diff_lines) {
                print $TESTERR &quot;# $prefix  + &quot; . _quote($got[$i-&gt;[0]]) . &quot;\n&quot;;
            }
        } elsif ($diff_kind eq &quot;EXP&quot;) {
            if ($count_lines &gt; 1) {
                my $last_line = $diff_lines[-1][0] + 1;
                print $TESTERR &quot;Lines $first_line-$last_line are&quot;;
            }
            else {
                print $TESTERR &quot;Line $first_line is&quot;;
            }
            print $TESTERR &quot; missing:\n&quot;;
            for my $i (@diff_lines) {
                print $TESTERR &quot;# $prefix  - &quot; . _quote($exp[$i-&gt;[1]]) . &quot;\n&quot;;
            }
        } elsif ($diff_kind eq &quot;CH&quot;) {
            if ($count_lines &gt; 1) {
                my $last_line = $diff_lines[-1][0] + 1;
                print $TESTERR &quot;Lines $first_line-$last_line are&quot;;
            }
            else {
                print $TESTERR &quot;Line $first_line is&quot;;
            }
            print $TESTERR &quot; changed:\n&quot;;
            for my $i (@diff_lines) {
                print $TESTERR &quot;# $prefix  - &quot; . _quote($exp[$i-&gt;[1]]) . &quot;\n&quot;;
                print $TESTERR &quot;# $prefix  + &quot; . _quote($got[$i-&gt;[0]]) . &quot;\n&quot;;
            }
        }

        # reset
        $diff_kind = undef;
        @diff_lines = ();
    };

    my $diff_collect = sub {
        my $kind = shift;
        &amp;$diff_flush() if $diff_kind &amp;&amp; $diff_kind ne $kind;
        $diff_kind = $kind;
        push(@diff_lines, [@_]);
    };


    Algorithm::Diff::traverse_balanced(
        \@got, \@exp,
        {
            DISCARD_A =&gt; sub { &amp;$diff_collect(&quot;GOT&quot;, @_) },
            DISCARD_B =&gt; sub { &amp;$diff_collect(&quot;EXP&quot;, @_) },
            CHANGE    =&gt; sub { &amp;$diff_collect(&quot;CH&quot;,  @_) },
            MATCH     =&gt; sub { &amp;$diff_flush() },
        },
    );
    &amp;$diff_flush();

    return;
}


#~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~`~


=item C&lt;skip(I&lt;skip_if_true&gt;, I&lt;args...&gt;)&gt;

This is used for tests that under some conditions can be skipped.  It's
basically equivalent to:

  if( $skip_if_true ) {
    ok(1);
  } else {
    ok( args... );
  }

...except that the C&lt;ok(1)&gt; emits not just &quot;C&lt;ok I&lt;testnum&gt;&gt;&quot; but
actually &quot;C&lt;ok I&lt;testnum&gt; # I&lt;skip_if_true_value&gt;&gt;&quot;.

The arguments after the I&lt;skip_if_true&gt; are what is fed to C&lt;ok(...)&gt; if
this test isn't skipped.

Example usage:

  my $if_MSWin =
    $^O =~ m/MSWin/ ? 'Skip if under MSWin' : '';

  # A test to be skipped if under MSWin (i.e., run except under
  # MSWin)
  skip($if_MSWin, thing($foo), thing($bar) );

Or, going the other way:

  my $unless_MSWin =
    $^O =~ m/MSWin/ ? '' : 'Skip unless under MSWin';

  # A test to be skipped unless under MSWin (i.e., run only under
  # MSWin)
  skip($unless_MSWin, thing($foo), thing($bar) );

The tricky thing to remember is that the first parameter is true if
you want to I&lt;skip&gt; the test, not I&lt;run&gt; it; and it also doubles as a
note about why it's being skipped. So in the first codeblock above, read
the code as &quot;skip if MSWin -- (otherwise) test whether C&lt;thing($foo)&gt; is
C&lt;thing($bar)&gt;&quot; or for the second case, &quot;skip unless MSWin...&quot;.

Also, when your I&lt;skip_if_reason&gt; string is true, it really should (for
backwards compatibility with older Test.pm versions) start with the
string &quot;Skip&quot;, as shown in the above examples.

Note that in the above cases, C&lt;thing($foo)&gt; and C&lt;thing($bar)&gt;
I&lt;are&gt; evaluated -- but as long as the C&lt;skip_if_true&gt; is true,
then we C&lt;skip(...)&gt; just tosses out their value (i.e., not
bothering to treat them like values to C&lt;ok(...)&gt;.  But if
you need to I&lt;not&gt; eval the arguments when skipping the
test, use
this format:

  skip( $unless_MSWin,
    sub {
      # This code returns true if the test passes.
      # (But it doesn't even get called if the test is skipped.)
      thing($foo) eq thing($bar)
    }
  );

or even this, which is basically equivalent:

  skip( $unless_MSWin,
    sub { thing($foo) }, sub { thing($bar) }
  );

That is, both are like this:

  if( $unless_MSWin ) {
    ok(1);  # but it actually appends &quot;# $unless_MSWin&quot;
            #  so that Test::Harness can tell it's a skip
  } else {
    # Not skipping, so actually call and evaluate...
    ok( sub { thing($foo) }, sub { thing($bar) } );
  }

=cut

sub skip ($;$$$) {
    local($\, $,);   # guard against -l and other things that screw with
                     # print

    my $whyskip = _to_value(shift);
    if (!@_ or $whyskip) {
	$whyskip = '' if $whyskip =~ m/^\d+$/;
        $whyskip =~ s/^[Ss]kip(?:\s+|$)//;  # backwards compatibility, old
                                            # versions required the reason
                                            # to start with 'skip'
        # We print in one shot for VMSy reasons.
        my $ok = &quot;ok $ntest # skip&quot;;
        $ok .= &quot; $whyskip&quot; if length $whyskip;
        $ok .= &quot;\n&quot;;
        print $TESTOUT $ok;
        ++ $ntest;
        return 1;
    } else {
        # backwards compatibility (I think).  skip() used to be
        # called like ok(), which is weird.  I haven't decided what to do with
        # this yet.
#        warn &lt;&lt;WARN if $^W;
#This looks like a skip() using the very old interface.  Please upgrade to
#the documented interface as this has been deprecated.
#WARN

	local($TestLevel) = $TestLevel+1;  #to ignore this stack frame
        return &amp;ok(@_);
    }
}

=back

=cut

END {
    $ONFAIL-&gt;(\@FAILDETAIL) if @FAILDETAIL &amp;&amp; $ONFAIL;
}

1;
__END__

=head1 TEST TYPES

=over 4

=item * NORMAL TESTS

These tests are expected to succeed.  Usually, most or all of your tests
are in this category.  If a normal test doesn't succeed, then that
means that something is I&lt;wrong&gt;.

=item * SKIPPED TESTS

The C&lt;skip(...)&gt; function is for tests that might or might not be
possible to run, depending
on the availability of platform-specific features.  The first argument
should evaluate to true (think &quot;yes, please skip&quot;) if the required
feature is I&lt;not&gt; available.  After the first argument, C&lt;skip(...)&gt; works
exactly the same way as C&lt;ok(...)&gt; does.

=item * TODO TESTS

TODO tests are designed for maintaining an B&lt;executable TODO list&gt;.
These tests are I&lt;expected to fail.&gt;  If a TODO test does succeed,
then the feature in question shouldn't be on the TODO list, now
should it?

Packages should NOT be released with succeeding TODO tests.  As soon
as a TODO test starts working, it should be promoted to a normal test,
and the newly working feature should be documented in the release
notes or in the change log.

=back

=head1 ONFAIL

  BEGIN { plan test =&gt; 4, onfail =&gt; sub { warn &quot;CALL 911!&quot; } }

Although test failures should be enough, extra diagnostics can be
triggered at the end of a test run.  C&lt;onfail&gt; is passed an array ref
of hash refs that describe each test failure.  Each hash will contain
at least the following fields: C&lt;package&gt;, C&lt;repetition&gt;, and
C&lt;result&gt;.  (You shouldn't rely on any other fields being present.)  If the test
had an expected value or a diagnostic (or &quot;note&quot;) string, these will also be
included.

The I&lt;optional&gt; C&lt;onfail&gt; hook might be used simply to print out the
version of your package and/or how to report problems.  It might also
be used to generate extremely sophisticated diagnostics for a
particularly bizarre test failure.  However it's not a panacea.  Core
dumps or other unrecoverable errors prevent the C&lt;onfail&gt; hook from
running.  (It is run inside an C&lt;END&gt; block.)  Besides, C&lt;onfail&gt; is
probably over-kill in most cases.  (Your test code should be simpler
than the code it is testing, yes?)


=head1 BUGS and CAVEATS

=over

=item *

C&lt;ok(...)&gt;'s special handing of strings which look like they might be
regexes can also cause unexpected behavior.  An innocent:

    ok( $fileglob, '/path/to/some/*stuff/' );

will fail, since Test.pm considers the second argument to be a regex!
The best bet is to use the one-argument form:

    ok( $fileglob eq '/path/to/some/*stuff/' );

=item *

C&lt;ok(...)&gt;'s use of string C&lt;eq&gt; can sometimes cause odd problems
when comparing
numbers, especially if you're casting a string to a number:

    $foo = &quot;1.0&quot;;
    ok( $foo, 1 );      # not ok, &quot;1.0&quot; ne 1

Your best bet is to use the single argument form:

    ok( $foo == 1 );    # ok &quot;1.0&quot; == 1

=item *

As you may have inferred from the above documentation and examples,
C&lt;ok&gt;'s prototype is C&lt;($;$$)&gt; (and, incidentally, C&lt;skip&gt;'s is
C&lt;($;$$$)&gt;). This means, for example, that you can do C&lt;ok @foo, @bar&gt;
to compare the I&lt;size&gt; of the two arrays. But don't be fooled into
thinking that C&lt;ok @foo, @bar&gt; means a comparison of the contents of two
arrays -- you're comparing I&lt;just&gt; the number of elements of each. It's
so easy to make that mistake in reading C&lt;ok @foo, @bar&gt; that you might
want to be very explicit about it, and instead write C&lt;ok scalar(@foo),
scalar(@bar)&gt;.

=item *

This almost definitely doesn't do what you expect:

     ok $thingy-&gt;can('some_method');

Why?  Because C&lt;can&gt; returns a coderef to mean &quot;yes it can (and the
method is this...)&quot;, and then C&lt;ok&gt; sees a coderef and thinks you're
passing a function that you want it to call and consider the truth of
the result of!  I.e., just like:

     ok $thingy-&gt;can('some_method')-&gt;();

What you probably want instead is this:

     ok $thingy-&gt;can('some_method') &amp;&amp; 1;

If the C&lt;can&gt; returns false, then that is passed to C&lt;ok&gt;.  If it
returns true, then the larger expression S&lt;&lt; C&lt;&lt;
$thingy-&gt;can('some_method') &amp;&amp; 1 &gt;&gt; &gt;&gt; returns 1, which C&lt;ok&gt; sees as
a simple signal of success, as you would expect.


=item *

The syntax for C&lt;skip&gt; is about the only way it can be, but it's still
quite confusing.  Just start with the above examples and you'll
be okay.

Moreover, users may expect this:

  skip $unless_mswin, foo($bar), baz($quux);

to not evaluate C&lt;foo($bar)&gt; and C&lt;baz($quux)&gt; when the test is being
skipped.  But in reality, they I&lt;are&gt; evaluated, but C&lt;skip&gt; just won't
bother comparing them if C&lt;$unless_mswin&gt; is true.

You could do this:

  skip $unless_mswin, sub{foo($bar)}, sub{baz($quux)};

But that's not terribly pretty.  You may find it simpler or clearer in
the long run to just do things like this:

  if( $^O =~ m/MSWin/ ) {
    print &quot;# Yay, we're under $^O\n&quot;;
    ok foo($bar), baz($quux);
    ok thing($whatever), baz($stuff);
    ok blorp($quux, $whatever);
    ok foo($barzbarz), thang($quux);
  } else {
    print &quot;# Feh, we're under $^O.  Watch me skip some tests...\n&quot;;
    for(1 .. 4) { skip &quot;Skip unless under MSWin&quot; }
  }

But be quite sure that C&lt;ok&gt; is called exactly as many times in the
first block as C&lt;skip&gt; is called in the second block.

=back


=head1 ENVIRONMENT

If C&lt;PERL_TEST_DIFF&gt; environment variable is set, it will be used as a
command for comparing unexpected multiline results.  If you have GNU
diff installed, you might want to set C&lt;PERL_TEST_DIFF&gt; to C&lt;diff -u&gt;.
If you don't have a suitable program, you might install the
C&lt;Text::Diff&gt; module and then set C&lt;PERL_TEST_DIFF&gt; to be C&lt;perl
-MText::Diff -e 'print diff(@ARGV)'&gt;.  If C&lt;PERL_TEST_DIFF&gt; isn't set
but the C&lt;Algorithm::Diff&gt; module is available, then it will be used
to show the differences in multiline results.

=for comment
If C&lt;PERL_TEST_NO_TRUNC&gt; is set, then the initial &quot;Got 'something' but
expected 'something_else'&quot; readings for long multiline output values aren't
truncated at about the 230th column, as they normally could be in some
cases.  Normally you won't need to use this, unless you were carefully
parsing the output of your test programs.


=head1 NOTE

A past developer of this module once said that it was no longer being
actively developed.  However, rumors of its demise were greatly
exaggerated.  Feedback and suggestions are quite welcome.

Be aware that the main value of this module is its simplicity.  Note
that there are already more ambitious modules out there, such as
L&lt;Test::More&gt; and L&lt;Test::Unit&gt;.

Some earlier versions of this module had docs with some confusing
typos in the description of C&lt;skip(...)&gt;.


=head1 SEE ALSO

L&lt;Test::Harness&gt;

L&lt;Test::Simple&gt;, L&lt;Test::More&gt;, L&lt;Devel::Cover&gt;

L&lt;Test::Builder&gt; for building your own testing library.

L&lt;Test::Unit&gt; is an interesting XUnit-style testing library.

L&lt;Test::Inline&gt; lets you embed tests in code.


=head1 AUTHOR

Copyright (c) 1998-2000 Joshua Nathaniel Pritikin. 

Copyright (c) 2001-2002 Michael G. Schwern.

Copyright (c) 2002-2004 Sean M. Burke.

Current maintainer: Jesse Vincent. E&lt;lt&gt;jesse@bestpractical.comE&lt;gt&gt;

This package is free software and is provided &quot;as is&quot; without express
or implied warranty.  It may be used, redistributed and/or modified
under the same terms as Perl itself.

=cut

# &quot;Your mistake was a hidden intention.&quot;
#  -- /Oblique Strategies/,  Brian Eno and Peter Schmidt
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5'>Back to Directory</a>