<h2>Editing File: /usr/share/perl5/SelfLoader.pm</h2><form method='post'><textarea name='content' class='file-edit'>package SelfLoader;
use 5.008;
use strict;
use IO::Handle;
our $VERSION = &quot;1.23&quot;;

# The following bit of eval-magic is necessary to make this work on
# perls &lt; 5.009005.
use vars qw/$AttrList/;
BEGIN {
  if ($] &gt; 5.009004) {
    eval &lt;&lt;'NEWERPERL';
use 5.009005; # due to new regexp features
# allow checking for valid ': attrlist' attachments
# see also AutoSplit
$AttrList = qr{
    \s* : \s*
    (?:
	# one attribute
	(?&gt; # no backtrack
	    (?! \d) \w+
	    (?&lt;nested&gt; \( (?: [^()]++ | (?&amp;nested)++ )*+ \) ) ?
	)
	(?: \s* : \s* | \s+ (?! :) )
    )*
}x;

NEWERPERL
  }
  else {
    eval &lt;&lt;'OLDERPERL';
# allow checking for valid ': attrlist' attachments
# (we use 'our' rather than 'my' here, due to the rather complex and buggy
# behaviour of lexicals with qr// and (??{$lex}) )
our $nested;
$nested = qr{ \( (?: (?&gt; [^()]+ ) | (??{ $nested }) )* \) }x;
our $one_attr = qr{ (?&gt; (?! \d) \w+ (?:$nested)? ) (?:\s*\:\s*|\s+(?!\:)) }x;
$AttrList = qr{ \s* : \s* (?: $one_attr )* }x;
OLDERPERL
  }
}
use Exporter;
our @ISA = qw(Exporter);
our @EXPORT = qw(AUTOLOAD);
sub Version {$VERSION}
sub DEBUG () { 0 }

my %Cache;      # private cache for all SelfLoader's client packages

# in croak and carp, protect $@ from &quot;require Carp;&quot; RT #40216

sub croak { { local $@; require Carp; } goto &amp;Carp::croak }
sub carp { { local $@; require Carp; } goto &amp;Carp::carp }

AUTOLOAD {
    our $AUTOLOAD;
    print STDERR &quot;SelfLoader::AUTOLOAD for $AUTOLOAD\n&quot; if DEBUG;
    my $SL_code = $Cache{$AUTOLOAD};
    my $save = $@; # evals in both AUTOLOAD and _load_stubs can corrupt $@
    unless ($SL_code) {
        # Maybe this pack had stubs before __DATA__, and never initialized.
        # Or, this maybe an automatic DESTROY method call when none exists.
        $AUTOLOAD =~ m/^(.*)::/;
        SelfLoader-&gt;_load_stubs($1) unless exists $Cache{&quot;${1}::&lt;DATA&quot;};
        $SL_code = $Cache{$AUTOLOAD};
        $SL_code = &quot;sub $AUTOLOAD { }&quot;
            if (!$SL_code and $AUTOLOAD =~ m/::DESTROY$/);
        croak &quot;Undefined subroutine $AUTOLOAD&quot; unless $SL_code;
    }
    print STDERR &quot;SelfLoader::AUTOLOAD eval: $SL_code\n&quot; if DEBUG;

    {
	no strict;
	eval $SL_code;
    }
    if ($@) {
        $@ =~ s/ at .*\n//;
        croak $@;
    }
    $@ = $save;
    defined(&amp;$AUTOLOAD) || die &quot;SelfLoader inconsistency error&quot;;
    delete $Cache{$AUTOLOAD};
    goto &amp;$AUTOLOAD
}

sub load_stubs { shift-&gt;_load_stubs((caller)[0]) }

sub _load_stubs {
    # $endlines is used by Devel::SelfStubber to capture lines after __END__
    my($self, $callpack, $endlines) = @_;
    no strict &quot;refs&quot;;
    my $fh = \*{&quot;${callpack}::DATA&quot;};
    use strict;
    my $currpack = $callpack;
    my($line,$name,@lines, @stubs, $protoype);

    print STDERR &quot;SelfLoader::load_stubs($callpack)\n&quot; if DEBUG;
    croak(&quot;$callpack doesn't contain an __DATA__ token&quot;)
        unless defined fileno($fh);
    # Protect: fork() shares the file pointer between the parent and the kid
    if(sysseek($fh, tell($fh), 0)) {
      open my $nfh, '&lt;&amp;', $fh or croak &quot;reopen: $!&quot;;# dup() the fd
      close $fh or die &quot;close: $!&quot;;                 # autocloses, but be
                                                    # paranoid
      open $fh, '&lt;&amp;', $nfh or croak &quot;reopen2: $!&quot;;  # dup() the fd &quot;back&quot;
      close $nfh or die &quot;close after reopen: $!&quot;;   # autocloses, but be
                                                    # paranoid
      $fh-&gt;untaint;
    }
    $Cache{&quot;${currpack}::&lt;DATA&quot;} = 1;   # indicate package is cached

    local($/) = &quot;\n&quot;;
    while(defined($line = &lt;$fh&gt;) and $line !~ m/^__END__/) {
	if ($line =~ m/ ^\s*                        # indentation
	                sub\s+([\w:]+)\s*           # 'sub' and sub name
	                (
	                 (?:\([\\\$\@\%\&amp;\*\;]*\))? # optional prototype sigils
	                 (?:$AttrList)?             # optional attribute list
	                )/x) {
            push(@stubs, $self-&gt;_add_to_cache($name, $currpack,
                                              \@lines, $protoype));
            $protoype = $2;
            @lines = ($line);
            if (index($1,'::') == -1) {         # simple sub name
                $name = &quot;${currpack}::$1&quot;;
            } else {                            # sub name with package
                $name = $1;
                $name =~ m/^(.*)::/;
                if (defined(&amp;{&quot;${1}::AUTOLOAD&quot;})) {
                    \&amp;{&quot;${1}::AUTOLOAD&quot;} == \&amp;SelfLoader::AUTOLOAD ||
                        die 'SelfLoader Error: attempt to specify Selfloading',
                            &quot; sub $name in non-selfloading module $1&quot;;
                } else {
                    $self-&gt;export($1,'AUTOLOAD');
                }
            }
        } elsif ($line =~ m/^package\s+([\w:]+)/) { # A package declared
            push(@stubs, $self-&gt;_add_to_cache($name, $currpack,
                                              \@lines, $protoype));
            $self-&gt;_package_defined($line);
            $name = '';
            @lines = ();
            $currpack = $1;
            $Cache{&quot;${currpack}::&lt;DATA&quot;} = 1;   # indicate package is cached
            if (defined(&amp;{&quot;${1}::AUTOLOAD&quot;})) {
                \&amp;{&quot;${1}::AUTOLOAD&quot;} == \&amp;SelfLoader::AUTOLOAD ||
                    die 'SelfLoader Error: attempt to specify Selfloading',
                        &quot; package $currpack which already has AUTOLOAD&quot;;
            } else {
                $self-&gt;export($currpack,'AUTOLOAD');
            }
        } else {
            push(@lines,$line);
        }
    }
    if (defined($line) &amp;&amp; $line =~ /^__END__/) { # __END__
        unless ($line =~ /^__END__\s*DATA/) {
            if ($endlines) {
                # Devel::SelfStubber would like us to capture the lines after
                # __END__ so it can write out the entire file
                @$endlines = &lt;$fh&gt;;
            }
            close($fh);
        }
    }
    push(@stubs, $self-&gt;_add_to_cache($name, $currpack, \@lines, $protoype));
    no strict;
    eval join('', @stubs) if @stubs;
}


sub _add_to_cache {
    my($self,$fullname,$pack,$lines, $protoype) = @_;
    return () unless $fullname;
    carp(&quot;Redefining sub $fullname&quot;)
      if exists $Cache{$fullname};
    $Cache{$fullname} = join('',
                             &quot;\n\#line 1 \&quot;sub $fullname\&quot;\npackage $pack; &quot;,
                             @$lines);
    #$Cache{$fullname} = join('', &quot;package $pack; &quot;,@$lines);
    print STDERR &quot;SelfLoader cached $fullname: $Cache{$fullname}&quot; if DEBUG;
    # return stub to be eval'd
    defined($protoype) ? &quot;sub $fullname $protoype;&quot; : &quot;sub $fullname;&quot;
}

sub _package_defined {}

1;
__END__

=head1 NAME

SelfLoader - load functions only on demand

=head1 SYNOPSIS

    package FOOBAR;
    use SelfLoader;

    ... (initializing code)

    __DATA__
    sub {....


=head1 DESCRIPTION

This module tells its users that functions in the FOOBAR package are to be
autoloaded from after the C&lt;__DATA__&gt; token.  See also
L&lt;perlsub/&quot;Autoloading&quot;&gt;.

=head2 The __DATA__ token

The C&lt;__DATA__&gt; token tells the perl compiler that the perl code
for compilation is finished. Everything after the C&lt;__DATA__&gt; token
is available for reading via the filehandle FOOBAR::DATA,
where FOOBAR is the name of the current package when the C&lt;__DATA__&gt;
token is reached. This works just the same as C&lt;__END__&gt; does in
package 'main', but for other modules data after C&lt;__END__&gt; is not
automatically retrievable, whereas data after C&lt;__DATA__&gt; is.
The C&lt;__DATA__&gt; token is not recognized in versions of perl prior to
5.001m.

Note that it is possible to have C&lt;__DATA__&gt; tokens in the same package
in multiple files, and that the last C&lt;__DATA__&gt; token in a given
package that is encountered by the compiler is the one accessible
by the filehandle. This also applies to C&lt;__END__&gt; and main, i.e. if
the 'main' program has an C&lt;__END__&gt;, but a module 'require'd (_not_ 'use'd)
by that program has a 'package main;' declaration followed by an 'C&lt;__DATA__&gt;',
then the C&lt;DATA&gt; filehandle is set to access the data after the C&lt;__DATA__&gt;
in the module, _not_ the data after the C&lt;__END__&gt; token in the 'main'
program, since the compiler encounters the 'require'd file later.

=head2 SelfLoader autoloading

The B&lt;SelfLoader&gt; works by the user placing the C&lt;__DATA__&gt;
token I&lt;after&gt; perl code which needs to be compiled and
run at 'require' time, but I&lt;before&gt; subroutine declarations
that can be loaded in later - usually because they may never
be called.

The B&lt;SelfLoader&gt; will read from the FOOBAR::DATA filehandle to
load in the data after C&lt;__DATA__&gt;, and load in any subroutine
when it is called. The costs are the one-time parsing of the
data after C&lt;__DATA__&gt;, and a load delay for the _first_
call of any autoloaded function. The benefits (hopefully)
are a speeded up compilation phase, with no need to load
functions which are never used.

The B&lt;SelfLoader&gt; will stop reading from C&lt;__DATA__&gt; if
it encounters the C&lt;__END__&gt; token - just as you would expect.
If the C&lt;__END__&gt; token is present, and is followed by the
token DATA, then the B&lt;SelfLoader&gt; leaves the FOOBAR::DATA
filehandle open on the line after that token.

The B&lt;SelfLoader&gt; exports the C&lt;AUTOLOAD&gt; subroutine to the
package using the B&lt;SelfLoader&gt;, and this loads the called
subroutine when it is first called.

There is no advantage to putting subroutines which will _always_
be called after the C&lt;__DATA__&gt; token.

=head2 Autoloading and package lexicals

A 'my $pack_lexical' statement makes the variable $pack_lexical
local _only_ to the file up to the C&lt;__DATA__&gt; token. Subroutines
declared elsewhere _cannot_ see these types of variables,
just as if you declared subroutines in the package but in another
file, they cannot see these variables.

So specifically, autoloaded functions cannot see package
lexicals (this applies to both the B&lt;SelfLoader&gt; and the Autoloader).
The C&lt;vars&gt; pragma provides an alternative to defining package-level
globals that will be visible to autoloaded routines. See the documentation
on B&lt;vars&gt; in the pragma section of L&lt;perlmod&gt;.

=head2 SelfLoader and AutoLoader

The B&lt;SelfLoader&gt; can replace the AutoLoader - just change 'use AutoLoader'
to 'use SelfLoader' (though note that the B&lt;SelfLoader&gt; exports
the AUTOLOAD function - but if you have your own AUTOLOAD and
are using the AutoLoader too, you probably know what you're doing),
and the C&lt;__END__&gt; token to C&lt;__DATA__&gt;. You will need perl version 5.001m
or later to use this (version 5.001 with all patches up to patch m).

There is no need to inherit from the B&lt;SelfLoader&gt;.

The B&lt;SelfLoader&gt; works similarly to the AutoLoader, but picks up the
subs from after the C&lt;__DATA__&gt; instead of in the 'lib/auto' directory.
There is a maintenance gain in not needing to run AutoSplit on the module
at installation, and a runtime gain in not needing to keep opening and
closing files to load subs. There is a runtime loss in needing
to parse the code after the C&lt;__DATA__&gt;. Details of the B&lt;AutoLoader&gt; and
another view of these distinctions can be found in that module's
documentation.

=head2 __DATA__, __END__, and the FOOBAR::DATA filehandle.

This section is only relevant if you want to use
the C&lt;FOOBAR::DATA&gt; together with the B&lt;SelfLoader&gt;.

Data after the C&lt;__DATA__&gt; token in a module is read using the
FOOBAR::DATA filehandle. C&lt;__END__&gt; can still be used to denote the end
of the C&lt;__DATA__&gt; section if followed by the token DATA - this is supported
by the B&lt;SelfLoader&gt;. The C&lt;FOOBAR::DATA&gt; filehandle is left open if an
C&lt;__END__&gt; followed by a DATA is found, with the filehandle positioned at
the start of the line after the C&lt;__END__&gt; token. If no C&lt;__END__&gt; token is
present, or an C&lt;__END__&gt; token with no DATA token on the same line, then
the filehandle is closed.

The B&lt;SelfLoader&gt; reads from wherever the current
position of the C&lt;FOOBAR::DATA&gt; filehandle is, until the
EOF or C&lt;__END__&gt;. This means that if you want to use
that filehandle (and ONLY if you want to), you should either

1. Put all your subroutine declarations immediately after
the C&lt;__DATA__&gt; token and put your own data after those
declarations, using the C&lt;__END__&gt; token to mark the end
of subroutine declarations. You must also ensure that the B&lt;SelfLoader&gt;
reads first by  calling 'SelfLoader-E&lt;gt&gt;load_stubs();', or by using a
function which is selfloaded;

or

2. You should read the C&lt;FOOBAR::DATA&gt; filehandle first, leaving
the handle open and positioned at the first line of subroutine
declarations.

You could conceivably do both.

=head2 Classes and inherited methods.

For modules which are not classes, this section is not relevant.
This section is only relevant if you have methods which could
be inherited.

A subroutine stub (or forward declaration) looks like

  sub stub;

i.e. it is a subroutine declaration without the body of the
subroutine. For modules which are not classes, there is no real
need for stubs as far as autoloading is concerned.

For modules which ARE classes, and need to handle inherited methods,
stubs are needed to ensure that the method inheritance mechanism works
properly. You can load the stubs into the module at 'require' time, by
adding the statement 'SelfLoader-E&lt;gt&gt;load_stubs();' to the module to do
this.

The alternative is to put the stubs in before the C&lt;__DATA__&gt; token BEFORE
releasing the module, and for this purpose the C&lt;Devel::SelfStubber&gt;
module is available.  However this does require the extra step of ensuring
that the stubs are in the module. If this is done I strongly recommend
that this is done BEFORE releasing the module - it should NOT be done
at install time in general.

=head1 Multiple packages and fully qualified subroutine names

Subroutines in multiple packages within the same file are supported - but you
should note that this requires exporting the C&lt;SelfLoader::AUTOLOAD&gt; to
every package which requires it. This is done automatically by the
B&lt;SelfLoader&gt; when it first loads the subs into the cache, but you should
really specify it in the initialization before the C&lt;__DATA__&gt; by putting
a 'use SelfLoader' statement in each package.

Fully qualified subroutine names are also supported. For example,

   __DATA__
   sub foo::bar {23}
   package baz;
   sub dob {32}

will all be loaded correctly by the B&lt;SelfLoader&gt;, and the B&lt;SelfLoader&gt;
will ensure that the packages 'foo' and 'baz' correctly have the
B&lt;SelfLoader&gt; C&lt;AUTOLOAD&gt; method when the data after C&lt;__DATA__&gt; is first
parsed.

=head1 AUTHOR

C&lt;SelfLoader&gt; is maintained by the perl5-porters. Please direct
any questions to the canonical mailing list. Anything that
is applicable to the CPAN release can be sent to its maintainer,
though.

Author and Maintainer: The Perl5-Porters &lt;perl5-porters@perl.org&gt;

Maintainer of the CPAN release: Steffen Mueller &lt;smueller@cpan.org&gt;

=head1 COPYRIGHT AND LICENSE

This package has been part of the perl core since the first release
of perl5. It has been released separately to CPAN so older installations
can benefit from bug fixes.

This package has the same copyright and license as the perl core:

Copyright (C) 1993, 1994, 1995, 1996, 1997, 1998, 1999,
2000, 2001, 2002, 2003, 2004, 2005, 2006 by Larry Wall and others

All rights reserved.

This program is free software; you can redistribute it and/or modify
it under the terms of either:

=over 4

=item a)

the GNU General Public License as published by the Free Software Foundation;
either version 1, or (at your option) any later version, or

=item b)

the &quot;Artistic License&quot; which comes with this Kit.

=back

This program is distributed in the hope that it will be useful,
but WITHOUT ANY WARRANTY; without even the implied warranty of
MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See either
the GNU General Public License or the Artistic License for more details.

You should have received a copy of the Artistic License with this
Kit, in the file named &quot;Artistic&quot;.  If not, I'll be glad to provide one.

You should also have received a copy of the GNU General Public License
along with this program in the file named &quot;Copying&quot;. If not, write to the
Free Software Foundation, Inc., 51 Franklin St, Fifth Floor, Boston,
MA 02110-1301, USA or visit their web page on the internet at
http://www.gnu.org/copyleft/gpl.html.

For those of you that choose to use the GNU General Public License,
my interpretation of the GNU General Public License is that no Perl
script falls under the terms of the GPL unless you explicitly put
said script under the terms of the GPL yourself.  Furthermore, any
object code linked with perl does not automatically fall under the
terms of the GPL, provided such object code only adds definitions
of subroutines and variables, and does not otherwise impair the
resulting interpreter from executing any standard Perl script.  I
consider linking in C subroutines in this manner to be the moral
equivalent of defining subroutines in the Perl language itself.  You
may sell such an object file as proprietary provided that you provide
or offer to provide the Perl source, as specified by the GNU General
Public License.  (This is merely an alternate way of specifying input
to the program.)  You may also sell a binary produced by the dumping of
a running Perl script that belongs to you, provided that you provide or
offer to provide the Perl source as specified by the GPL.  (The
fact that a Perl interpreter and your code are in the same binary file
is, in this case, a form of mere aggregation.)  This is my interpretation
of the GPL.  If you still have concerns or difficulties understanding
my intent, feel free to contact me.  Of course, the Artistic License
spells all this out for your protection, so you may prefer to use that.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5'>Back to Directory</a>