<h2>Editing File: /usr/share/perl5/Net/servent.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Net::servent;
use strict;

use 5.006_001;
our $VERSION = '1.01';
our(@EXPORT, @EXPORT_OK, %EXPORT_TAGS);
BEGIN {
    use Exporter   ();
    @EXPORT      = qw(getservbyname getservbyport getservent getserv);
    @EXPORT_OK   = qw( $s_name @s_aliases $s_port $s_proto );
    %EXPORT_TAGS = ( FIELDS =&gt; [ @EXPORT_OK, @EXPORT ] );
}
use vars      @EXPORT_OK;

# Class::Struct forbids use of @ISA
sub import { goto &amp;Exporter::import }

use Class::Struct qw(struct);
struct 'Net::servent' =&gt; [
   name		=&gt; '$',
   aliases	=&gt; '@',
   port		=&gt; '$',
   proto	=&gt; '$',
];

sub populate (@) {
    return unless @_;
    my $sob = new();
    $s_name 	 =    $sob-&gt;[0]     	     = $_[0];
    @s_aliases	 = @{ $sob-&gt;[1] } = split ' ', $_[1];
    $s_port	 =    $sob-&gt;[2] 	     = $_[2];
    $s_proto	 =    $sob-&gt;[3] 	     = $_[3];
    return $sob;
}

sub getservent    (   ) { populate(CORE::getservent()) }
sub getservbyname ($;$) { populate(CORE::getservbyname(shift,shift||'tcp')) }
sub getservbyport ($;$) { populate(CORE::getservbyport(shift,shift||'tcp')) }

sub getserv ($;$) {
    no strict 'refs';
    return &amp;{'getservby' . ($_[0]=~/^\d+$/ ? 'port' : 'name')}(@_);
}

1;

__END__

=head1 NAME

Net::servent - by-name interface to Perl's built-in getserv*() functions

=head1 SYNOPSIS

 use Net::servent;
 $s = getservbyname(shift || 'ftp') || die &quot;no service&quot;;
 printf &quot;port for %s is %s, aliases are %s\n&quot;,
    $s-&gt;name, $s-&gt;port, &quot;@{$s-&gt;aliases}&quot;;

 use Net::servent qw(:FIELDS);
 getservbyname(shift || 'ftp') || die &quot;no service&quot;;
 print &quot;port for $s_name is $s_port, aliases are @s_aliases\n&quot;;

=head1 DESCRIPTION

This module's default exports override the core getservent(),
getservbyname(), and
getnetbyport() functions, replacing them with versions that return
&quot;Net::servent&quot; objects.  They take default second arguments of &quot;tcp&quot;.  This object has methods that return the similarly
named structure field name from the C's servent structure from F&lt;netdb.h&gt;;
namely name, aliases, port, and proto.  The aliases
method returns an array reference, the rest scalars.

You may also import all the structure fields directly into your namespace
as regular variables using the :FIELDS import tag.  (Note that this still
overrides your core functions.)  Access these fields as variables named
with a preceding C&lt;s_&gt;.  Thus, C&lt;$serv_obj-E&lt;gt&gt;name()&gt; corresponds to
$s_name if you import the fields.  Array references are available as
regular array variables, so for example C&lt;@{ $serv_obj-E&lt;gt&gt;aliases()}&gt;
would be simply @s_aliases.

The getserv() function is a simple front-end that forwards a numeric
argument to getservbyport(), and the rest to getservbyname().

To access this functionality without the core overrides,
pass the C&lt;use&gt; an empty import list, and then access
function functions with their full qualified names.
On the other hand, the built-ins are still available
via the C&lt;CORE::&gt; pseudo-package.

=head1 EXAMPLES

 use Net::servent qw(:FIELDS);

 while (@ARGV) {
     my ($service, $proto) = ((split m!/!, shift), 'tcp');
     my $valet = getserv($service, $proto);
     unless ($valet) {
         warn &quot;$0: No service: $service/$proto\n&quot;
         next;
     }
     printf &quot;service $service/$proto is port %d\n&quot;, $valet-&gt;port;
     print &quot;alias are @s_aliases\n&quot; if @s_aliases;
 }

=head1 NOTE

While this class is currently implemented using the Class::Struct
module to build a struct-like class, you shouldn't rely upon this.

=head1 AUTHOR

Tom Christiansen
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FNet'>Back to Directory</a>