<h2>Editing File: /usr/share/perl5/Net/Ping.pm</h2><form method='post'><textarea name='content' class='file-edit'>package Net::Ping;

require 5.002;
require Exporter;

use strict;
use vars qw(@ISA @EXPORT @EXPORT_OK $VERSION
            $def_timeout $def_proto $def_factor $def_family
            $max_datasize $pingstring $hires $source_verify $syn_forking);
use Fcntl qw( F_GETFL F_SETFL O_NONBLOCK );
use Socket qw( SOCK_DGRAM SOCK_STREAM SOCK_RAW AF_INET PF_INET IPPROTO_TCP
	       SOL_SOCKET SO_ERROR SO_BROADCAST
               IPPROTO_IP IP_TOS IP_TTL
               inet_ntoa inet_aton getnameinfo NI_NUMERICHOST sockaddr_in );
use POSIX qw( ENOTCONN ECONNREFUSED ECONNRESET EINPROGRESS EWOULDBLOCK EAGAIN
	      WNOHANG );
use FileHandle;
use Carp;
use Time::HiRes;

@ISA = qw(Exporter);
@EXPORT = qw(pingecho);
@EXPORT_OK = qw(wakeonlan);
$VERSION = &quot;2.55&quot;;

# Globals

$def_timeout = 5;           # Default timeout to wait for a reply
$def_proto = &quot;tcp&quot;;         # Default protocol to use for pinging
$def_factor = 1.2;          # Default exponential backoff rate.
$def_family = AF_INET;      # Default family.
$max_datasize = 1024;       # Maximum data bytes in a packet
# The data we exchange with the server for the stream protocol
$pingstring = &quot;pingschwingping!\n&quot;;
$source_verify = 1;         # Default is to verify source endpoint
$syn_forking = 0;

# Constants

my $AF_INET6  = eval { Socket::AF_INET6() };
my $AF_UNSPEC = eval { Socket::AF_UNSPEC() };
my $AI_NUMERICHOST = eval { Socket::AI_NUMERICHOST() };
my $NI_NUMERICHOST = eval { Socket::NI_NUMERICHOST() };
my $IPPROTO_IPV6   = eval { Socket::IPPROTO_IPV6() };
#my $IPV6_HOPLIMIT  = eval { Socket::IPV6_HOPLIMIT() };  # ping6 -h 0-255
my $qr_family = qr/^(?:(?:(:?ip)?v?(?:4|6))|${\AF_INET}|$AF_INET6)$/;
my $qr_family4 = qr/^(?:(?:(:?ip)?v?4)|${\AF_INET})$/;

if ($^O =~ /Win32/i) {
  # Hack to avoid this Win32 spewage:
  # Your vendor has not defined POSIX macro ECONNREFUSED
  my @pairs = (ECONNREFUSED =&gt; 10061, # &quot;Unknown Error&quot; Special Win32 Response?
	       ENOTCONN     =&gt; 10057,
	       ECONNRESET   =&gt; 10054,
	       EINPROGRESS  =&gt; 10036,
	       EWOULDBLOCK  =&gt; 10035,
	  );
  while (my $name = shift @pairs) {
    my $value = shift @pairs;
    # When defined, these all are non-zero
    unless (eval $name) {
      no strict 'refs';
      *{$name} = defined prototype \&amp;{$name} ? sub () {$value} : sub {$value};
    }
  }
#  $syn_forking = 1;    # XXX possibly useful in &lt; Win2K ?
};

# Description:  The pingecho() subroutine is provided for backward
# compatibility with the original Net::Ping.  It accepts a host
# name/IP and an optional timeout in seconds.  Create a tcp ping
# object and try pinging the host.  The result of the ping is returned.

sub pingecho
{
  my ($host,              # Name or IP number of host to ping
      $timeout            # Optional timeout in seconds
      ) = @_;
  my ($p);                # A ping object

  $p = Net::Ping-&gt;new(&quot;tcp&quot;, $timeout);
  $p-&gt;ping($host);        # Going out of scope closes the connection
}

# Description:  The new() method creates a new ping object.  Optional
# parameters may be specified for the protocol to use, the timeout in
# seconds and the size in bytes of additional data which should be
# included in the packet.
#   After the optional parameters are checked, the data is constructed
# and a socket is opened if appropriate.  The object is returned.

sub new
{
  my ($this,
      $proto,             # Optional protocol to use for pinging
      $timeout,           # Optional timeout in seconds
      $data_size,         # Optional additional bytes of data
      $device,            # Optional device to use
      $tos,               # Optional ToS to set
      $ttl,               # Optional TTL to set
      $family,            # Optional address family (AF_INET)
      ) = @_;
  my  $class = ref($this) || $this;
  my  $self = {};
  my ($cnt,               # Count through data bytes
      $min_datasize       # Minimum data bytes required
      );

  bless($self, $class);
  if (ref $proto eq 'HASH') { # support named args
    for my $k (qw(proto timeout data_size device tos ttl family
                  gateway host port bind retrans pingstring source_verify
                  econnrefused dontfrag
                  IPV6_USE_MIN_MTU IPV6_RECVPATHMTU IPV6_HOPLIMIT))
    {
      if (exists $proto-&gt;{$k}) {
        $self-&gt;{$k} = $proto-&gt;{$k};
        # some are still globals
        if ($k eq 'pingstring') { $pingstring = $proto-&gt;{$k} }
        if ($k eq 'source_verify') { $source_verify = $proto-&gt;{$k} }
        delete $proto-&gt;{$k};
      }
    }
    if (%$proto) {
      croak(&quot;Invalid named argument: &quot;,join(&quot; &quot;,keys (%$proto)));
    }
    $proto = $self-&gt;{'proto'};
  }

  $proto = $def_proto unless $proto;          # Determine the protocol
  croak('Protocol for ping must be &quot;icmp&quot;, &quot;icmpv6&quot;, &quot;udp&quot;, &quot;tcp&quot;, &quot;syn&quot;, &quot;stream&quot; or &quot;external&quot;')
    unless $proto =~ m/^(icmp|icmpv6|udp|tcp|syn|stream|external)$/;
  $self-&gt;{proto} = $proto;

  $timeout = $def_timeout unless $timeout;    # Determine the timeout
  croak(&quot;Default timeout for ping must be greater than 0 seconds&quot;)
    if $timeout &lt;= 0;
  $self-&gt;{timeout} = $timeout;

  $self-&gt;{device} = $device;

  $self-&gt;{tos} = $tos;

  if ($self-&gt;{'host'}) {
    my $host = $self-&gt;{'host'};
    my $ip = _resolv($host)
      or carp(&quot;could not resolve host $host&quot;);
    $self-&gt;{host} = $ip;
    $self-&gt;{family} = $ip-&gt;{family};
  }

  if ($self-&gt;{bind}) {
    my $addr = $self-&gt;{bind};
    my $ip = _resolv($addr)
      or carp(&quot;could not resolve local addr $addr&quot;);
    $self-&gt;{local_addr} = $ip;
  } else {
    $self-&gt;{local_addr} = undef;              # Don't bind by default
  }

  if ($self-&gt;{proto} eq 'icmp') {
    croak('TTL must be from 0 to 255')
      if ($ttl &amp;&amp; ($ttl &lt; 0 || $ttl &gt; 255));
    $self-&gt;{ttl} = $ttl;
  }

  if ($family) {
    if ($family =~ $qr_family) {
      if ($family =~ $qr_family4) {
        $self-&gt;{family} = AF_INET;
      } else {
        $self-&gt;{family} = $AF_INET6;
      }
    } else {
      croak('Family must be &quot;ipv4&quot; or &quot;ipv6&quot;')
    }
  } else {
    $self-&gt;{family} = $def_family;
  }

  $min_datasize = ($proto eq &quot;udp&quot;) ? 1 : 0;  # Determine data size
  $data_size = $min_datasize unless defined($data_size) &amp;&amp; $proto ne &quot;tcp&quot;;
  croak(&quot;Data for ping must be from $min_datasize to $max_datasize bytes&quot;)
    if ($data_size &lt; $min_datasize) || ($data_size &gt; $max_datasize);
  $data_size-- if $self-&gt;{proto} eq &quot;udp&quot;;  # We provide the first byte
  $self-&gt;{data_size} = $data_size;

  $self-&gt;{data} = &quot;&quot;;                       # Construct data bytes
  for ($cnt = 0; $cnt &lt; $self-&gt;{data_size}; $cnt++)
  {
    $self-&gt;{data} .= chr($cnt % 256);
  }

  # Default exponential backoff rate
  $self-&gt;{retrans} = $def_factor unless exists $self-&gt;{retrans};
  # Default Connection refused behavior
  $self-&gt;{econnrefused} = undef unless exists $self-&gt;{econnrefused};

  $self-&gt;{seq} = 0;                         # For counting packets
  if ($self-&gt;{proto} eq &quot;udp&quot;)              # Open a socket
  {
    $self-&gt;{proto_num} = eval { (getprotobyname('udp'))[2] } ||
      croak(&quot;Can't udp protocol by name&quot;);
    $self-&gt;{port_num} = $self-&gt;{port}
      || (getservbyname('echo', 'udp'))[2]
      || croak(&quot;Can't get udp echo port by name&quot;);
    $self-&gt;{fh} = FileHandle-&gt;new();
    socket($self-&gt;{fh}, PF_INET, SOCK_DGRAM,
           $self-&gt;{proto_num}) ||
             croak(&quot;udp socket error - $!&quot;);
    $self-&gt;_setopts();
  }
  elsif ($self-&gt;{proto} eq &quot;icmp&quot;)
  {
    croak(&quot;icmp ping requires root privilege&quot;) if !_isroot();
    $self-&gt;{proto_num} = eval { (getprotobyname('icmp'))[2] } ||
      croak(&quot;Can't get icmp protocol by name&quot;);
    $self-&gt;{pid} = $$ &amp; 0xffff;           # Save lower 16 bits of pid
    $self-&gt;{fh} = FileHandle-&gt;new();
    socket($self-&gt;{fh}, PF_INET, SOCK_RAW, $self-&gt;{proto_num}) ||
      croak(&quot;icmp socket error - $!&quot;);
    $self-&gt;_setopts();
    if ($self-&gt;{'ttl'}) {
      setsockopt($self-&gt;{fh}, IPPROTO_IP, IP_TTL, pack(&quot;I*&quot;, $self-&gt;{'ttl'}))
        or croak &quot;error configuring ttl to $self-&gt;{'ttl'} $!&quot;;
    }
  }
  elsif ($self-&gt;{proto} eq &quot;icmpv6&quot;)
  {
    croak(&quot;icmpv6 ping requires root privilege&quot;) if !_isroot();
    croak(&quot;Wrong family $self-&gt;{family} for icmpv6 protocol&quot;)
      if $self-&gt;{family} and $self-&gt;{family} != $AF_INET6;
    $self-&gt;{family} = $AF_INET6;
    $self-&gt;{proto_num} = eval { (getprotobyname('ipv6-icmp'))[2] } ||
      croak(&quot;Can't get ipv6-icmp protocol by name&quot;); # 58
    $self-&gt;{pid} = $$ &amp; 0xffff;           # Save lower 16 bits of pid
    $self-&gt;{fh} = FileHandle-&gt;new();
    socket($self-&gt;{fh}, $AF_INET6, SOCK_RAW, $self-&gt;{proto_num}) ||
      croak(&quot;icmp socket error - $!&quot;);
    $self-&gt;_setopts();
    if ($self-&gt;{'gateway'}) {
      my $g = $self-&gt;{gateway};
      my $ip = _resolv($g)
        or croak(&quot;nonexistent gateway $g&quot;);
      $self-&gt;{family} eq $AF_INET6
        or croak(&quot;gateway requires the AF_INET6 family&quot;);
      $ip-&gt;{family} eq $AF_INET6
        or croak(&quot;gateway address needs to be IPv6&quot;);
      my $IPV6_NEXTHOP = eval { Socket::IPV6_NEXTHOP() } || 48; # IPV6_3542NEXTHOP, or 21
      setsockopt($self-&gt;{fh}, $IPPROTO_IPV6, $IPV6_NEXTHOP, _pack_sockaddr_in($ip))
        or croak &quot;error configuring gateway to $g NEXTHOP $!&quot;;
    }
    if (exists $self-&gt;{IPV6_USE_MIN_MTU}) {
      my $IPV6_USE_MIN_MTU = eval { Socket::IPV6_USE_MIN_MTU() } || 42;
      setsockopt($self-&gt;{fh}, $IPPROTO_IPV6, $IPV6_USE_MIN_MTU,
                 pack(&quot;I*&quot;, $self-&gt;{'IPV6_USE_MIN_MT'}))
        or croak &quot;error configuring IPV6_USE_MIN_MT} $!&quot;;
    }
    if (exists $self-&gt;{IPV6_RECVPATHMTU}) {
      my $IPV6_RECVPATHMTU = eval { Socket::IPV6_RECVPATHMTU() } || 43;
      setsockopt($self-&gt;{fh}, $IPPROTO_IPV6, $IPV6_RECVPATHMTU,
                 pack(&quot;I*&quot;, $self-&gt;{'RECVPATHMTU'}))
        or croak &quot;error configuring IPV6_RECVPATHMTU $!&quot;;
    }
    if ($self-&gt;{'tos'}) {
      my $proto = $self-&gt;{family} == AF_INET ? IPPROTO_IP : $IPPROTO_IPV6;
      setsockopt($self-&gt;{fh}, $proto, IP_TOS, pack(&quot;I*&quot;, $self-&gt;{'tos'}))
        or croak &quot;error configuring tos to $self-&gt;{'tos'} $!&quot;;
    }
    if ($self-&gt;{'ttl'}) {
      my $proto = $self-&gt;{family} == AF_INET ? IPPROTO_IP : $IPPROTO_IPV6;
      setsockopt($self-&gt;{fh}, $proto, IP_TTL, pack(&quot;I*&quot;, $self-&gt;{'ttl'}))
        or croak &quot;error configuring ttl to $self-&gt;{'ttl'} $!&quot;;
    }
  }
  elsif ($self-&gt;{proto} eq &quot;tcp&quot; || $self-&gt;{proto} eq &quot;stream&quot;)
  {
    $self-&gt;{proto_num} = eval { (getprotobyname('tcp'))[2] } ||
      croak(&quot;Can't get tcp protocol by name&quot;);
    $self-&gt;{port_num} = $self-&gt;{port}
      || (getservbyname('echo', 'tcp'))[2]
      ||  croak(&quot;Can't get tcp echo port by name&quot;);
    $self-&gt;{fh} = FileHandle-&gt;new();
  }
  elsif ($self-&gt;{proto} eq &quot;syn&quot;)
  {
    $self-&gt;{proto_num} = eval { (getprotobyname('tcp'))[2] } ||
      croak(&quot;Can't get tcp protocol by name&quot;);
    $self-&gt;{port_num} = (getservbyname('echo', 'tcp'))[2] ||
      croak(&quot;Can't get tcp echo port by name&quot;);
    if ($syn_forking) {
      $self-&gt;{fork_rd} = FileHandle-&gt;new();
      $self-&gt;{fork_wr} = FileHandle-&gt;new();
      pipe($self-&gt;{fork_rd}, $self-&gt;{fork_wr});
      $self-&gt;{fh} = FileHandle-&gt;new();
      $self-&gt;{good} = {};
      $self-&gt;{bad} = {};
    } else {
      $self-&gt;{wbits} = &quot;&quot;;
      $self-&gt;{bad} = {};
    }
    $self-&gt;{syn} = {};
    $self-&gt;{stop_time} = 0;
  }

  return($self);
}

# Description: Set the local IP address from which pings will be sent.
# For ICMP, UDP and TCP pings, just saves the address to be used when 
# the socket is opened.  Returns non-zero if successful; croaks on error.
sub bind
{
  my ($self,
      $local_addr         # Name or IP number of local interface
      ) = @_;
  my ($ip,                # Hash of addr (string), addr_in (packed), family
      $h		  # resolved hash
      );

  croak(&quot;Usage: \$p-&gt;bind(\$local_addr)&quot;) unless @_ == 2;
  croak(&quot;already bound&quot;) if defined($self-&gt;{local_addr}) &amp;&amp;
    ($self-&gt;{proto} eq &quot;udp&quot; || $self-&gt;{proto} eq &quot;icmp&quot;);

  $ip = $self-&gt;_resolv($local_addr);
  carp(&quot;nonexistent local address $local_addr&quot;) unless defined($ip);
  $self-&gt;{local_addr} = $ip;

  if (($self-&gt;{proto} ne &quot;udp&quot;) &amp;&amp; 
      ($self-&gt;{proto} ne &quot;icmp&quot;) &amp;&amp; 
      ($self-&gt;{proto} ne &quot;tcp&quot;) &amp;&amp; 
      ($self-&gt;{proto} ne &quot;syn&quot;))
  {
    croak(&quot;Unknown protocol \&quot;$self-&gt;{proto}\&quot; in bind()&quot;);
  }

  return 1;
}

# Description: A select() wrapper that compensates for platform
# peculiarities.
sub mselect
{
    if ($_[3] &gt; 0 and $^O eq 'MSWin32') {
	# On windows, select() doesn't process the message loop,
	# but sleep() will, allowing alarm() to interrupt the latter.
	# So we chop up the timeout into smaller pieces and interleave
	# select() and sleep() calls.
	my $t = $_[3];
	my $gran = 0.5;  # polling granularity in seconds
	my @args = @_;
	while (1) {
	    $gran = $t if $gran &gt; $t;
	    my $nfound = select($_[0], $_[1], $_[2], $gran);
	    undef $nfound if $nfound == -1;
	    $t -= $gran;
	    return $nfound if $nfound or !defined($nfound) or $t &lt;= 0;

	    sleep(0);
	    ($_[0], $_[1], $_[2]) = @args;
	}
    }
    else {
	my $nfound = select($_[0], $_[1], $_[2], $_[3]);
	undef $nfound if $nfound == -1;
	return $nfound;
    }
}

# Description: Allow UDP source endpoint comparison to be
#              skipped for those remote interfaces that do
#              not response from the same endpoint.

sub source_verify
{
  my $self = shift;
  $source_verify = 1 unless defined
    ($source_verify = ((defined $self) &amp;&amp; (ref $self)) ? shift() : $self);
}

# Description: Set whether or not the connect
# behavior should enforce remote service
# availability as well as reachability.

sub service_check
{
  my $self = shift;
  $self-&gt;{econnrefused} = 1 unless defined
    ($self-&gt;{econnrefused} = shift());
}

sub tcp_service_check
{
  service_check(@_);
}

# Description: Set exponential backoff for retransmission.
# Should be &gt; 1 to retain exponential properties.
# If set to 0, retransmissions are disabled.

sub retrans
{
  my $self = shift;
  $self-&gt;{retrans} = shift;
}

sub _IsAdminUser {
  return unless $^O eq 'MSWin32' or $^O eq &quot;cygwin&quot;;
  return unless eval { require Win32 };
  return unless defined &amp;Win32::IsAdminUser;
  return Win32::IsAdminUser();
}

sub _isroot {
  if (($&gt; and $^O ne 'VMS' and $^O ne 'cygwin')
    or (($^O eq 'MSWin32' or $^O eq 'cygwin')
        and !_IsAdminUser())
    or ($^O eq 'VMS'
        and (`write sys\$output f\$privilege(&quot;SYSPRV&quot;)` =~ m/FALSE/))) {
      return 0;
  }
  else {
    return 1;
  }
}

# Description: Sets ipv6 reachability
# REACHCONF was removed in RFC3542, ping6 -R supports it. requires root.

sub IPV6_REACHCONF
{
  my $self = shift;
  my $on = shift;
  if ($on) {
    my $reachconf = eval { Socket::IPV6_REACHCONF() };
    if (!$reachconf) {
      carp &quot;IPV6_REACHCONF not supported on this platform&quot;;
      return 0;
    }
    if (!_isroot()) {
      carp &quot;IPV6_REACHCONF requires root permissions&quot;;
      return 0;
    }
    $self-&gt;{IPV6_REACHCONF} = 1;
  }
  else {
    return $self-&gt;{IPV6_REACHCONF};
  }
}

# Description: set it on or off.

sub IPV6_USE_MIN_MTU
{
  my $self = shift;
  my $on = shift;
  if (defined $on) {
    my $IPV6_USE_MIN_MTU = eval { Socket::IPV6_USE_MIN_MTU() } || 43;
    #if (!$IPV6_USE_MIN_MTU) {
    #  carp &quot;IPV6_USE_MIN_MTU not supported on this platform&quot;;
    #  return 0;
    #}
    $self-&gt;{IPV6_USE_MIN_MTU} = $on ? 1 : 0;
    setsockopt($self-&gt;{fh}, $IPPROTO_IPV6, $IPV6_USE_MIN_MTU,
               pack(&quot;I*&quot;, $self-&gt;{'IPV6_USE_MIN_MT'}))
      or croak &quot;error configuring IPV6_USE_MIN_MT} $!&quot;;
  }
  else {
    return $self-&gt;{IPV6_USE_MIN_MTU};
  }
}

# Description: notify an according MTU

sub IPV6_RECVPATHMTU
{
  my $self = shift;
  my $on = shift;
  if ($on) {
    my $IPV6_RECVPATHMTU = eval { Socket::IPV6_RECVPATHMTU() } || 43;
    #if (!$RECVPATHMTU) {
    #  carp &quot;IPV6_RECVPATHMTU not supported on this platform&quot;;
    #  return 0;
    #}
    $self-&gt;{IPV6_RECVPATHMTU} = 1;
    setsockopt($self-&gt;{fh}, $IPPROTO_IPV6, $IPV6_RECVPATHMTU,
               pack(&quot;I*&quot;, $self-&gt;{'IPV6_RECVPATHMTU'}))
      or croak &quot;error configuring IPV6_RECVPATHMTU} $!&quot;;
  }
  else {
    return $self-&gt;{IPV6_RECVPATHMTU};
  }
}

# Description: allows the module to use milliseconds as returned by
# the Time::HiRes module

$hires = 1;
sub hires
{
  my $self = shift;
  $hires = 1 unless defined
    ($hires = ((defined $self) &amp;&amp; (ref $self)) ? shift() : $self);
}

sub time
{
  return $hires ? Time::HiRes::time() : CORE::time();
}

# Description: Sets or clears the O_NONBLOCK flag on a file handle.
sub socket_blocking_mode
{
  my ($self,
      $fh,              # the file handle whose flags are to be modified
      $block) = @_;     # if true then set the blocking
                        # mode (clear O_NONBLOCK), otherwise
                        # set the non-blocking mode (set O_NONBLOCK)

  my $flags;
  if ($^O eq 'MSWin32' || $^O eq 'VMS') {
      # FIONBIO enables non-blocking sockets on windows and vms.
      # FIONBIO is (0x80000000|(4&lt;&lt;16)|(ord('f')&lt;&lt;8)|126), as per winsock.h, ioctl.h
      my $f = 0x8004667e;
      my $v = pack(&quot;L&quot;, $block ? 0 : 1);
      ioctl($fh, $f, $v) or croak(&quot;ioctl failed: $!&quot;);
      return;
  }
  if ($flags = fcntl($fh, F_GETFL, 0)) {
    $flags = $block ? ($flags &amp; ~O_NONBLOCK) : ($flags | O_NONBLOCK);
    if (!fcntl($fh, F_SETFL, $flags)) {
      croak(&quot;fcntl F_SETFL: $!&quot;);
    }
  } else {
    croak(&quot;fcntl F_GETFL: $!&quot;);
  }
}

# Description: Ping a host name or IP number with an optional timeout.
# First lookup the host, and return undef if it is not found.  Otherwise
# perform the specific ping method based on the protocol.  Return the
# result of the ping.

sub ping
{
  my ($self,
      $host,              # Name or IP number of host to ping
      $timeout,           # Seconds after which ping times out
      $family,            # Address family
      ) = @_;
  my ($ip,                # Hash of addr (string), addr_in (packed), family
      $ret,               # The return value
      $ping_time,         # When ping began
      );

  $host = $self-&gt;{host} if !defined $host and $self-&gt;{host};
  croak(&quot;Usage: \$p-&gt;ping([ \$host [, \$timeout [, \$family]]])&quot;) if @_ &gt; 4 or !$host;
  $timeout = $self-&gt;{timeout} unless $timeout;
  croak(&quot;Timeout must be greater than 0 seconds&quot;) if $timeout &lt;= 0;

  if ($family) {
    if ($family =~ $qr_family) {
      if ($family =~ $qr_family4) {
        $self-&gt;{family_local} = AF_INET;
      } else {
        $self-&gt;{family_local} = $AF_INET6;
      }
    } else {
      croak('Family must be &quot;ipv4&quot; or &quot;ipv6&quot;')
    }
  } else {
    $self-&gt;{family_local} = $self-&gt;{family};
  }
  
  $ip = $self-&gt;_resolv($host);
  return () unless defined($ip);      # Does host exist?

  # Dispatch to the appropriate routine.
  $ping_time = &amp;time();
  if ($self-&gt;{proto} eq &quot;external&quot;) {
    $ret = $self-&gt;ping_external($ip, $timeout);
  }
  elsif ($self-&gt;{proto} eq &quot;udp&quot;) {
    $ret = $self-&gt;ping_udp($ip, $timeout);
  }
  elsif ($self-&gt;{proto} eq &quot;icmp&quot;) {
    $ret = $self-&gt;ping_icmp($ip, $timeout);
  }
  elsif ($self-&gt;{proto} eq &quot;icmpv6&quot;) {
    $ret = $self-&gt;ping_icmpv6($ip, $timeout);
  }
  elsif ($self-&gt;{proto} eq &quot;tcp&quot;) {
    $ret = $self-&gt;ping_tcp($ip, $timeout);
  }
  elsif ($self-&gt;{proto} eq &quot;stream&quot;) {
    $ret = $self-&gt;ping_stream($ip, $timeout);
  }
  elsif ($self-&gt;{proto} eq &quot;syn&quot;) {
    $ret = $self-&gt;ping_syn($host, $ip, $ping_time, $ping_time+$timeout);
  } else {
    croak(&quot;Unknown protocol \&quot;$self-&gt;{proto}\&quot; in ping()&quot;);
  }

  return wantarray ? ($ret, &amp;time() - $ping_time, $self-&gt;ntop($ip)) : $ret;
}

# Uses Net::Ping::External to do an external ping.
sub ping_external {
  my ($self,
      $ip,                # Hash of addr (string), addr_in (packed), family
      $timeout,           # Seconds after which ping times out
      $family
     ) = @_;

  $ip = $self-&gt;{host} if !defined $ip and $self-&gt;{host};
  $timeout = $self-&gt;{timeout} if !defined $timeout and $self-&gt;{timeout};
  my @addr = exists $ip-&gt;{addr_in}
    ? ('ip' =&gt; $ip-&gt;{addr_in})
    : ('host' =&gt; $ip-&gt;{host});

  eval { require Net::Ping::External; }
    or croak('Protocol &quot;external&quot; not supported on your system: Net::Ping::External not found');
  return Net::Ping::External::ping(@addr, timeout =&gt; $timeout,
                                   family =&gt; $family);
}

# h2ph &quot;asm/socket.h&quot;
# require &quot;asm/socket.ph&quot;;
use constant SO_BINDTODEVICE  =&gt; 25;
use constant ICMP_ECHOREPLY   =&gt; 0; # ICMP packet types
use constant ICMPv6_ECHOREPLY =&gt; 129; # ICMP packet types
use constant ICMP_UNREACHABLE =&gt; 3; # ICMP packet types
use constant ICMPv6_UNREACHABLE =&gt; 1; # ICMP packet types
use constant ICMP_ECHO        =&gt; 8;
use constant ICMPv6_ECHO      =&gt; 128;
use constant ICMP_TIME_EXCEEDED =&gt; 11; # ICMP packet types
use constant ICMP_PARAMETER_PROBLEM =&gt; 12; # ICMP packet types
use constant ICMP_STRUCT      =&gt; &quot;C2 n3 A&quot;; # Structure of a minimal ICMP packet
use constant SUBCODE          =&gt; 0; # No ICMP subcode for ECHO and ECHOREPLY
use constant ICMP_FLAGS       =&gt; 0; # No special flags for send or recv
use constant ICMP_PORT        =&gt; 0; # No port with ICMP
use constant IP_MTU_DISCOVER  =&gt; 10; # linux only

sub ping_icmp
{
  my ($self,
      $ip,                # Hash of addr (string), addr_in (packed), family
      $timeout            # Seconds after which ping times out
      ) = @_;

  my ($saddr,             # sockaddr_in with port and ip
      $checksum,          # Checksum of ICMP packet
      $msg,               # ICMP packet to send
      $len_msg,           # Length of $msg
      $rbits,             # Read bits, filehandles for reading
      $nfound,            # Number of ready filehandles found
      $finish_time,       # Time ping should be finished
      $done,              # set to 1 when we are done
      $ret,               # Return value
      $recv_msg,          # Received message including IP header
      $from_saddr,        # sockaddr_in of sender
      $from_port,         # Port packet was sent from
      $from_ip,           # Packed IP of sender
      $from_type,         # ICMP type
      $from_subcode,      # ICMP subcode
      $from_chk,          # ICMP packet checksum
      $from_pid,          # ICMP packet id
      $from_seq,          # ICMP packet sequence
      $from_msg           # ICMP message
      );

  $ip = $self-&gt;{host} if !defined $ip and $self-&gt;{host};
  $timeout = $self-&gt;{timeout} if !defined $timeout and $self-&gt;{timeout};

  socket($self-&gt;{fh}, $ip-&gt;{family}, SOCK_RAW, $self-&gt;{proto_num}) ||
    croak(&quot;icmp socket error - $!&quot;);

  if (defined $self-&gt;{local_addr} &amp;&amp;
      !CORE::bind($self-&gt;{fh}, _pack_sockaddr_in(0, $self-&gt;{local_addr}))) {
    croak(&quot;icmp bind error - $!&quot;);
  }
  $self-&gt;_setopts();

  $self-&gt;{seq} = ($self-&gt;{seq} + 1) % 65536; # Increment sequence
  $checksum = 0;                          # No checksum for starters
  if ($ip-&gt;{family} == AF_INET) {
    $msg = pack(ICMP_STRUCT . $self-&gt;{data_size}, ICMP_ECHO, SUBCODE,
                $checksum, $self-&gt;{pid}, $self-&gt;{seq}, $self-&gt;{data});
  } else {
                                          # how to get SRC
    my $pseudo_header = pack('a16a16Nnn', $ip-&gt;{addr_in}, $ip-&gt;{addr_in}, 8+length($self-&gt;{data}), &quot;\0&quot;, 0x003a);
    $msg = pack(ICMP_STRUCT . $self-&gt;{data_size}, ICMPv6_ECHO, SUBCODE,
                $checksum, $self-&gt;{pid}, $self-&gt;{seq}, $self-&gt;{data});
    $msg = $pseudo_header.$msg
  }
  $checksum = Net::Ping-&gt;checksum($msg);
  if ($ip-&gt;{family} == AF_INET) {
    $msg = pack(ICMP_STRUCT . $self-&gt;{data_size}, ICMP_ECHO, SUBCODE,
                $checksum, $self-&gt;{pid}, $self-&gt;{seq}, $self-&gt;{data});
  } else {
    $msg = pack(ICMP_STRUCT . $self-&gt;{data_size}, ICMPv6_ECHO, SUBCODE,
                $checksum, $self-&gt;{pid}, $self-&gt;{seq}, $self-&gt;{data});
  }
  $len_msg = length($msg);
  $saddr = _pack_sockaddr_in(ICMP_PORT, $ip);
  $self-&gt;{from_ip} = undef;
  $self-&gt;{from_type} = undef;
  $self-&gt;{from_subcode} = undef;
  send($self-&gt;{fh}, $msg, ICMP_FLAGS, $saddr); # Send the message

  $rbits = &quot;&quot;;
  vec($rbits, $self-&gt;{fh}-&gt;fileno(), 1) = 1;
  $ret = 0;
  $done = 0;
  $finish_time = &amp;time() + $timeout;      # Must be done by this time
  while (!$done &amp;&amp; $timeout &gt; 0)          # Keep trying if we have time
  {
    $nfound = mselect((my $rout=$rbits), undef, undef, $timeout); # Wait for packet
    $timeout = $finish_time - &amp;time();    # Get remaining time
    if (!defined($nfound))                # Hmm, a strange error
    {
      $ret = undef;
      $done = 1;
    }
    elsif ($nfound)                     # Got a packet from somewhere
    {
      $recv_msg = &quot;&quot;;
      $from_pid = -1;
      $from_seq = -1;
      $from_saddr = recv($self-&gt;{fh}, $recv_msg, 1500, ICMP_FLAGS);
      ($from_port, $from_ip) = _unpack_sockaddr_in($from_saddr, $ip-&gt;{family});
      ($from_type, $from_subcode) = unpack(&quot;C2&quot;, substr($recv_msg, 20, 2));
      if ($from_type == ICMP_ECHOREPLY) {
        ($from_pid, $from_seq) = unpack(&quot;n3&quot;, substr($recv_msg, 24, 4))
          if length $recv_msg &gt;= 28;
      } elsif ($from_type == ICMPv6_ECHOREPLY) {
        ($from_pid, $from_seq) = unpack(&quot;n3&quot;, substr($recv_msg, 24, 4))
          if length $recv_msg &gt;= 28;
      } else {
        ($from_pid, $from_seq) = unpack(&quot;n3&quot;, substr($recv_msg, 52, 4))
          if length $recv_msg &gt;= 56;
      }
      $self-&gt;{from_ip} = $from_ip;
      $self-&gt;{from_type} = $from_type;
      $self-&gt;{from_subcode} = $from_subcode;
      next if ($from_pid != $self-&gt;{pid});
      next if ($from_seq != $self-&gt;{seq});
      if (! $source_verify || ($self-&gt;ntop($from_ip) eq $self-&gt;ntop($ip))) { # Does the packet check out?
        if (($from_type == ICMP_ECHOREPLY) || ($from_type == ICMPv6_ECHOREPLY)) {
          $ret = 1;
          $done = 1;
        } elsif (($from_type == ICMP_UNREACHABLE) || ($from_type == ICMPv6_UNREACHABLE)) {
          $done = 1;
        } elsif ($from_type == ICMP_TIME_EXCEEDED) {
          $ret = 0;
          $done = 1;
        }
      }
    } else {     # Oops, timed out
      $done = 1;
    }
  }
  return $ret;
}

sub ping_icmpv6
{
  shift-&gt;ping_icmp(@_);
}

sub icmp_result {
  my ($self) = @_;
  my $addr = $self-&gt;{from_ip} || &quot;&quot;;
  $addr = &quot;\0\0\0\0&quot; unless 4 == length $addr;
  return ($self-&gt;ntop($addr),($self-&gt;{from_type} || 0), ($self-&gt;{from_subcode} || 0));
}

# Description:  Do a checksum on the message.  Basically sum all of
# the short words and fold the high order bits into the low order bits.

sub checksum
{
  my ($class,
      $msg            # The message to checksum
      ) = @_;
  my ($len_msg,       # Length of the message
      $num_short,     # The number of short words in the message
      $short,         # One short word
      $chk            # The checksum
      );

  $len_msg = length($msg);
  $num_short = int($len_msg / 2);
  $chk = 0;
  foreach $short (unpack(&quot;n$num_short&quot;, $msg))
  {
    $chk += $short;
  }                                           # Add the odd byte in
  $chk += (unpack(&quot;C&quot;, substr($msg, $len_msg - 1, 1)) &lt;&lt; 8) if $len_msg % 2;
  $chk = ($chk &gt;&gt; 16) + ($chk &amp; 0xffff);      # Fold high into low
  return(~(($chk &gt;&gt; 16) + $chk) &amp; 0xffff);    # Again and complement
}


# Description:  Perform a tcp echo ping.  Since a tcp connection is
# host specific, we have to open and close each connection here.  We
# can't just leave a socket open.  Because of the robust nature of
# tcp, it will take a while before it gives up trying to establish a
# connection.  Therefore, we use select() on a non-blocking socket to
# check against our timeout.  No data bytes are actually
# sent since the successful establishment of a connection is proof
# enough of the reachability of the remote host.  Also, tcp is
# expensive and doesn't need our help to add to the overhead.

sub ping_tcp
{
  my ($self,
      $ip,                # Hash of addr (string), addr_in (packed), family
      $timeout            # Seconds after which ping times out
      ) = @_;
  my ($ret                # The return value
      );

  $ip = $self-&gt;{host} if !defined $ip and $self-&gt;{host};
  $timeout = $self-&gt;{timeout} if !defined $timeout and $self-&gt;{timeout};

  $! = 0;
  $ret = $self -&gt; tcp_connect( $ip, $timeout);
  if (!$self-&gt;{econnrefused} &amp;&amp;
      $! == ECONNREFUSED) {
    $ret = 1;  # &quot;Connection refused&quot; means reachable
  }
  $self-&gt;{fh}-&gt;close();
  return $ret;
}

sub tcp_connect
{
  my ($self,
      $ip,                # Hash of addr (string), addr_in (packed), family
      $timeout            # Seconds after which connect times out
      ) = @_;
  my ($saddr);            # Packed IP and Port

  $ip = $self-&gt;{host} if !defined $ip and $self-&gt;{host};
  $timeout = $self-&gt;{timeout} if !defined $timeout and $self-&gt;{timeout};

  $saddr = _pack_sockaddr_in($self-&gt;{port_num}, $ip);

  my $ret = 0;            # Default to unreachable

  my $do_socket = sub {
    socket($self-&gt;{fh}, $ip-&gt;{family}, SOCK_STREAM, $self-&gt;{proto_num}) ||
      croak(&quot;tcp socket error - $!&quot;);
    if (defined $self-&gt;{local_addr} &amp;&amp;
        !CORE::bind($self-&gt;{fh}, _pack_sockaddr_in(0, $self-&gt;{local_addr}))) {
      croak(&quot;tcp bind error - $!&quot;);
    }
    $self-&gt;_setopts();
  };
  my $do_connect = sub {
    $self-&gt;{ip} = $ip-&gt;{addr_in};
    # ECONNREFUSED is 10061 on MSWin32. If we pass it as child error through $?,
    # we'll get (10061 &amp; 255) = 77, so we cannot check it in the parent process.
    return ($ret = connect($self-&gt;{fh}, $saddr) || ($! == ECONNREFUSED &amp;&amp; !$self-&gt;{econnrefused}));
  };
  my $do_connect_nb = sub {
    # Set O_NONBLOCK property on filehandle
    $self-&gt;socket_blocking_mode($self-&gt;{fh}, 0);

    # start the connection attempt
    if (!connect($self-&gt;{fh}, $saddr)) {
      if ($! == ECONNREFUSED) {
        $ret = 1 unless $self-&gt;{econnrefused};
      } elsif ($! != EINPROGRESS &amp;&amp; ($^O ne 'MSWin32' || $! != EWOULDBLOCK)) {
        # EINPROGRESS is the expected error code after a connect()
        # on a non-blocking socket.  But if the kernel immediately
        # determined that this connect() will never work,
        # Simply respond with &quot;unreachable&quot; status.
        # (This can occur on some platforms with errno
        # EHOSTUNREACH or ENETUNREACH.)
        return 0;
      } else {
        # Got the expected EINPROGRESS.
        # Just wait for connection completion...
        my ($wbits, $wout, $wexc);
        $wout = $wexc = $wbits = &quot;&quot;;
        vec($wbits, $self-&gt;{fh}-&gt;fileno, 1) = 1;

        my $nfound = mselect(undef,
			    ($wout = $wbits),
			    ($^O eq 'MSWin32' ? ($wexc = $wbits) : undef),
			    $timeout);
        warn(&quot;select: $!&quot;) unless defined $nfound;

        if ($nfound &amp;&amp; vec($wout, $self-&gt;{fh}-&gt;fileno, 1)) {
          # the socket is ready for writing so the connection
          # attempt completed. test whether the connection
          # attempt was successful or not

          if (getpeername($self-&gt;{fh})) {
            # Connection established to remote host
            $ret = 1;
          } else {
            # TCP ACK will never come from this host
            # because there was an error connecting.

            # This should set $! to the correct error.
            my $char;
            sysread($self-&gt;{fh},$char,1);
            $! = ECONNREFUSED if ($! == EAGAIN &amp;&amp; $^O =~ /cygwin/i);

            $ret = 1 if (!$self-&gt;{econnrefused}
                         &amp;&amp; $! == ECONNREFUSED);
          }
        } else {
          # the connection attempt timed out (or there were connect
	  # errors on Windows)
	  if ($^O =~ 'MSWin32') {
	      # If the connect will fail on a non-blocking socket,
	      # winsock reports ECONNREFUSED as an exception, and we
	      # need to fetch the socket-level error code via getsockopt()
	      # instead of using the thread-level error code that is in $!.
	      if ($nfound &amp;&amp; vec($wexc, $self-&gt;{fh}-&gt;fileno, 1)) {
		  $! = unpack(&quot;i&quot;, getsockopt($self-&gt;{fh}, SOL_SOCKET,
			                      SO_ERROR));
	      }
	  }
        }
      }
    } else {
      # Connection established to remote host
      $ret = 1;
    }

    # Unset O_NONBLOCK property on filehandle
    $self-&gt;socket_blocking_mode($self-&gt;{fh}, 1);
    $self-&gt;{ip} = $ip-&gt;{addr_in};
    return $ret;
  };

  if ($syn_forking) {
    # Buggy Winsock API doesn't allow nonblocking connect.
    # Hence, if our OS is Windows, we need to create a separate
    # process to do the blocking connect attempt.
    # XXX Above comments are not true at least for Win2K, where
    # nonblocking connect works.

    $| = 1; # Clear buffer prior to fork to prevent duplicate flushing.
    $self-&gt;{'tcp_chld'} = fork;
    if (!$self-&gt;{'tcp_chld'}) {
      if (!defined $self-&gt;{'tcp_chld'}) {
        # Fork did not work
        warn &quot;Fork error: $!&quot;;
        return 0;
      }
      &amp;{ $do_socket }();

      # Try a slow blocking connect() call
      # and report the status to the parent.
      if ( &amp;{ $do_connect }() ) {
        $self-&gt;{fh}-&gt;close();
        # No error
        exit 0;
      } else {
        # Pass the error status to the parent
        # Make sure that $! &lt;= 255
        exit($! &lt;= 255 ? $! : 255);
      }
    }

    &amp;{ $do_socket }();

    my $patience = &amp;time() + $timeout;

    my ($child, $child_errno);
    $? = 0; $child_errno = 0;
    # Wait up to the timeout
    # And clean off the zombie
    do {
      $child = waitpid($self-&gt;{'tcp_chld'}, &amp;WNOHANG());
      $child_errno = $? &gt;&gt; 8;
      select(undef, undef, undef, 0.1);
    } while &amp;time() &lt; $patience &amp;&amp; $child != $self-&gt;{'tcp_chld'};

    if ($child == $self-&gt;{'tcp_chld'}) {
      if ($self-&gt;{proto} eq &quot;stream&quot;) {
        # We need the socket connected here, in parent
        # Should be safe to connect because the child finished
        # within the timeout
        &amp;{ $do_connect }();
      }
      # $ret cannot be set by the child process
      $ret = !$child_errno;
    } else {
      # Time must have run out.
      # Put that choking client out of its misery
      kill &quot;KILL&quot;, $self-&gt;{'tcp_chld'};
      # Clean off the zombie
      waitpid($self-&gt;{'tcp_chld'}, 0);
      $ret = 0;
    }
    delete $self-&gt;{'tcp_chld'};
    $! = $child_errno;
  } else {
    # Otherwise don't waste the resources to fork

    &amp;{ $do_socket }();

    &amp;{ $do_connect_nb }();
  }

  return $ret;
}

sub DESTROY {
  my $self = shift;
  if ($self-&gt;{'proto'} eq 'tcp' &amp;&amp;
      $self-&gt;{'tcp_chld'}) {
    # Put that choking client out of its misery
    kill &quot;KILL&quot;, $self-&gt;{'tcp_chld'};
    # Clean off the zombie
    waitpid($self-&gt;{'tcp_chld'}, 0);
  }
}

# This writes the given string to the socket and then reads it
# back.  It returns 1 on success, 0 on failure.
sub tcp_echo
{
  my ($self, $timeout, $pingstring) = @_;

  $timeout = $self-&gt;{timeout} if !defined $timeout and $self-&gt;{timeout};
  $pingstring = $self-&gt;{pingstring} if !defined $pingstring and $self-&gt;{pingstring};

  my $ret = undef;
  my $time = &amp;time();
  my $wrstr = $pingstring;
  my $rdstr = &quot;&quot;;

  eval &lt;&lt;'EOM';
    do {
      my $rin = &quot;&quot;;
      vec($rin, $self-&gt;{fh}-&gt;fileno(), 1) = 1;

      my $rout = undef;
      if($wrstr) {
        $rout = &quot;&quot;;
        vec($rout, $self-&gt;{fh}-&gt;fileno(), 1) = 1;
      }

      if(mselect($rin, $rout, undef, ($time + $timeout) - &amp;time())) {

        if($rout &amp;&amp; vec($rout,$self-&gt;{fh}-&gt;fileno(),1)) {
          my $num = syswrite($self-&gt;{fh}, $wrstr, length $wrstr);
          if($num) {
            # If it was a partial write, update and try again.
            $wrstr = substr($wrstr,$num);
          } else {
            # There was an error.
            $ret = 0;
          }
        }

        if(vec($rin,$self-&gt;{fh}-&gt;fileno(),1)) {
          my $reply;
          if(sysread($self-&gt;{fh},$reply,length($pingstring)-length($rdstr))) {
            $rdstr .= $reply;
            $ret = 1 if $rdstr eq $pingstring;
          } else {
            # There was an error.
            $ret = 0;
          }
        }

      }
    } until &amp;time() &gt; ($time + $timeout) || defined($ret);
EOM

  return $ret;
}

# Description: Perform a stream ping.  If the tcp connection isn't
# already open, it opens it.  It then sends some data and waits for
# a reply.  It leaves the stream open on exit.

sub ping_stream
{
  my ($self,
      $ip,                # Hash of addr (string), addr_in (packed), family
      $timeout            # Seconds after which ping times out
      ) = @_;

  # Open the stream if it's not already open
  if(!defined $self-&gt;{fh}-&gt;fileno()) {
    $self-&gt;tcp_connect($ip, $timeout) or return 0;
  }

  croak &quot;tried to switch servers while stream pinging&quot;
    if $self-&gt;{ip} ne $ip-&gt;{addr_in};

  return $self-&gt;tcp_echo($timeout, $pingstring);
}

# Description: opens the stream.  You would do this if you want to
# separate the overhead of opening the stream from the first ping.

sub open
{
  my ($self,
      $host,              # Host or IP address
      $timeout,           # Seconds after which open times out
      $family
      ) = @_;
  my $ip;                 # Hash of addr (string), addr_in (packed), family
  $host = $self-&gt;{host} unless defined $host;

  if ($family) {
    if ($family =~ $qr_family) {
      if ($family =~ $qr_family4) {
        $self-&gt;{family_local} = AF_INET;
      } else {
        $self-&gt;{family_local} = $AF_INET6;
      }
    } else {
      croak('Family must be &quot;ipv4&quot; or &quot;ipv6&quot;')
    }
  } else {
    $self-&gt;{family_local} = $self-&gt;{family};
  }

  $timeout = $self-&gt;{timeout} unless $timeout;
  $ip = $self-&gt;_resolv($host);

  if ($self-&gt;{proto} eq &quot;stream&quot;) {
    if (defined($self-&gt;{fh}-&gt;fileno())) {
      croak(&quot;socket is already open&quot;);
    } else {
      return () unless $ip;
      $self-&gt;tcp_connect($ip, $timeout);
    }
  }
}

sub _dontfrag {
  my $self = shift;
  # bsd solaris
  my $IP_DONTFRAG = eval { Socket::IP_DONTFRAG() };
  if ($IP_DONTFRAG) {
    my $i = 1;
    setsockopt($self-&gt;{fh}, IPPROTO_IP, $IP_DONTFRAG, pack(&quot;I*&quot;, $i))
      or croak &quot;error configuring IP_DONTFRAG $!&quot;;
    # Linux needs more: Path MTU Discovery as defined in RFC 1191
    # For non SOCK_STREAM sockets it is the user's responsibility to packetize
    # the data in MTU sized chunks and to do the retransmits if necessary.
    # The kernel will reject packets that are bigger than the known path
    # MTU if this flag is set (with EMSGSIZE).
    if ($^O eq 'linux') {
      my $i = 2; # IP_PMTUDISC_DO
      setsockopt($self-&gt;{fh}, IPPROTO_IP, IP_MTU_DISCOVER, pack(&quot;I*&quot;, $i))
        or croak &quot;error configuring IP_MTU_DISCOVER $!&quot;;
    }
  }
}

# SO_BINDTODEVICE + IP_TOS
sub _setopts {
  my $self = shift;
  if ($self-&gt;{'device'}) {
    setsockopt($self-&gt;{fh}, SOL_SOCKET, SO_BINDTODEVICE, pack(&quot;Z*&quot;, $self-&gt;{'device'}))
      or croak &quot;error binding to device $self-&gt;{'device'} $!&quot;;
  }
  if ($self-&gt;{'tos'}) { # need to re-apply ToS (RT #6706)
    setsockopt($self-&gt;{fh}, IPPROTO_IP, IP_TOS, pack(&quot;I*&quot;, $self-&gt;{'tos'}))
      or croak &quot;error applying tos to $self-&gt;{'tos'} $!&quot;;
  }
  if ($self-&gt;{'dontfrag'}) {
    $self-&gt;_dontfrag;
  }
}  


# Description:  Perform a udp echo ping.  Construct a message of
# at least the one-byte sequence number and any additional data bytes.
# Send the message out and wait for a message to come back.  If we
# get a message, make sure all of its parts match.  If they do, we are
# done.  Otherwise go back and wait for the message until we run out
# of time.  Return the result of our efforts.

use constant UDP_FLAGS =&gt; 0; # Nothing special on send or recv
sub ping_udp
{
  my ($self,
      $ip,                # Hash of addr (string), addr_in (packed), family
      $timeout            # Seconds after which ping times out
      ) = @_;

  my ($saddr,             # sockaddr_in with port and ip
      $ret,               # The return value
      $msg,               # Message to be echoed
      $finish_time,       # Time ping should be finished
      $flush,             # Whether socket needs to be disconnected
      $connect,           # Whether socket needs to be connected
      $done,              # Set to 1 when we are done pinging
      $rbits,             # Read bits, filehandles for reading
      $nfound,            # Number of ready filehandles found
      $from_saddr,        # sockaddr_in of sender
      $from_msg,          # Characters echoed by $host
      $from_port,         # Port message was echoed from
      $from_ip            # Packed IP number of sender
      );

  $saddr = _pack_sockaddr_in($self-&gt;{port_num}, $ip);
  $self-&gt;{seq} = ($self-&gt;{seq} + 1) % 256;    # Increment sequence
  $msg = chr($self-&gt;{seq}) . $self-&gt;{data};   # Add data if any

  socket($self-&gt;{fh}, $ip-&gt;{family}, SOCK_DGRAM,
         $self-&gt;{proto_num}) ||
           croak(&quot;udp socket error - $!&quot;);

  if (defined $self-&gt;{local_addr} &amp;&amp;
      !CORE::bind($self-&gt;{fh}, _pack_sockaddr_in(0, $self-&gt;{local_addr}))) {
    croak(&quot;udp bind error - $!&quot;);
  }

  $self-&gt;_setopts();

  if ($self-&gt;{connected}) {
    if ($self-&gt;{connected} ne $saddr) {
      # Still connected to wrong destination.
      # Need to flush out the old one.
      $flush = 1;
    }
  } else {
    # Not connected yet.
    # Need to connect() before send()
    $connect = 1;
  }

  # Have to connect() and send() instead of sendto()
  # in order to pick up on the ECONNREFUSED setting
  # from recv() or double send() errno as utilized in
  # the concept by rdw @ perlmonks.  See:
  # http://perlmonks.thepen.com/42898.html
  if ($flush) {
    # Need to socket() again to flush the descriptor
    # This will disconnect from the old saddr.
    socket($self-&gt;{fh}, $ip-&gt;{family}, SOCK_DGRAM,
           $self-&gt;{proto_num});
    $self-&gt;_setopts();
  }
  # Connect the socket if it isn't already connected
  # to the right destination.
  if ($flush || $connect) {
    connect($self-&gt;{fh}, $saddr);               # Tie destination to socket
    $self-&gt;{connected} = $saddr;
  }
  send($self-&gt;{fh}, $msg, UDP_FLAGS);           # Send it

  $rbits = &quot;&quot;;
  vec($rbits, $self-&gt;{fh}-&gt;fileno(), 1) = 1;
  $ret = 0;                   # Default to unreachable
  $done = 0;
  my $retrans = 0.01;
  my $factor = $self-&gt;{retrans};
  $finish_time = &amp;time() + $timeout;       # Ping needs to be done by then
  while (!$done &amp;&amp; $timeout &gt; 0)
  {
    if ($factor &gt; 1)
    {
      $timeout = $retrans if $timeout &gt; $retrans;
      $retrans*= $factor; # Exponential backoff
    }
    $nfound  = mselect((my $rout=$rbits), undef, undef, $timeout); # Wait for response
    my $why = $!;
    $timeout = $finish_time - &amp;time();   # Get remaining time

    if (!defined($nfound))  # Hmm, a strange error
    {
      $ret = undef;
      $done = 1;
    }
    elsif ($nfound)         # A packet is waiting
    {
      $from_msg = &quot;&quot;;
      $from_saddr = recv($self-&gt;{fh}, $from_msg, 1500, UDP_FLAGS);
      if (!$from_saddr) {
        # For example an unreachable host will make recv() fail.
        if (!$self-&gt;{econnrefused} &amp;&amp;
            ($! == ECONNREFUSED ||
             $! == ECONNRESET)) {
          # &quot;Connection refused&quot; means reachable
          # Good, continue
          $ret = 1;
        }
        $done = 1;
      } else {
        ($from_port, $from_ip) = _unpack_sockaddr_in($from_saddr, $ip-&gt;{family});
        if (!$source_verify ||
            (($from_ip eq $ip) &amp;&amp;        # Does the packet check out?
             ($from_port == $self-&gt;{port_num}) &amp;&amp;
             ($from_msg eq $msg)))
        {
          $ret = 1;       # It's a winner
          $done = 1;
        }
      }
    }
    elsif ($timeout &lt;= 0)              # Oops, timed out
    {
      $done = 1;
    }
    else
    {
      # Send another in case the last one dropped
      if (send($self-&gt;{fh}, $msg, UDP_FLAGS)) {
        # Another send worked?  The previous udp packet
        # must have gotten lost or is still in transit.
        # Hopefully this new packet will arrive safely.
      } else {
        if (!$self-&gt;{econnrefused} &amp;&amp;
            $! == ECONNREFUSED) {
          # &quot;Connection refused&quot; means reachable
          # Good, continue
          $ret = 1;
        }
        $done = 1;
      }
    }
  }
  return $ret;
}

# Description: Send a TCP SYN packet to host specified.
sub ping_syn
{
  my $self = shift;
  my $host = shift;
  my $ip = shift;
  my $start_time = shift;
  my $stop_time = shift;

  if ($syn_forking) {
    return $self-&gt;ping_syn_fork($host, $ip, $start_time, $stop_time);
  }

  my $fh = FileHandle-&gt;new();
  my $saddr = _pack_sockaddr_in($self-&gt;{port_num}, $ip);

  # Create TCP socket
  if (!socket ($fh, $ip-&gt;{family}, SOCK_STREAM, $self-&gt;{proto_num})) {
    croak(&quot;tcp socket error - $!&quot;);
  }

  if (defined $self-&gt;{local_addr} &amp;&amp;
      !CORE::bind($fh, _pack_sockaddr_in(0, $self-&gt;{local_addr}))) {
    croak(&quot;tcp bind error - $!&quot;);
  }

  $self-&gt;_setopts();
  # Set O_NONBLOCK property on filehandle
  $self-&gt;socket_blocking_mode($fh, 0);

  # Attempt the non-blocking connect
  # by just sending the TCP SYN packet
  if (connect($fh, $saddr)) {
    # Non-blocking, yet still connected?
    # Must have connected very quickly,
    # or else it wasn't very non-blocking.
    #warn &quot;WARNING: Nonblocking connect connected anyway? ($^O)&quot;;
  } else {
    # Error occurred connecting.
    if ($! == EINPROGRESS || ($^O eq 'MSWin32' &amp;&amp; $! == EWOULDBLOCK)) {
      # The connection is just still in progress.
      # This is the expected condition.
    } else {
      # Just save the error and continue on.
      # The ack() can check the status later.
      $self-&gt;{bad}-&gt;{$host} = $!;
    }
  }

  my $entry = [ $host, $ip, $fh, $start_time, $stop_time ];
  $self-&gt;{syn}-&gt;{$fh-&gt;fileno} = $entry;
  if ($self-&gt;{stop_time} &lt; $stop_time) {
    $self-&gt;{stop_time} = $stop_time;
  }
  vec($self-&gt;{wbits}, $fh-&gt;fileno, 1) = 1;

  return 1;
}

sub ping_syn_fork {
  my ($self, $host, $ip, $start_time, $stop_time) = @_;

  # Buggy Winsock API doesn't allow nonblocking connect.
  # Hence, if our OS is Windows, we need to create a separate
  # process to do the blocking connect attempt.
  my $pid = fork();
  if (defined $pid) {
    if ($pid) {
      # Parent process
      my $entry = [ $host, $ip, $pid, $start_time, $stop_time ];
      $self-&gt;{syn}-&gt;{$pid} = $entry;
      if ($self-&gt;{stop_time} &lt; $stop_time) {
        $self-&gt;{stop_time} = $stop_time;
      }
    } else {
      # Child process
      my $saddr = _pack_sockaddr_in($self-&gt;{port_num}, $ip);

      # Create TCP socket
      if (!socket ($self-&gt;{fh}, $ip-&gt;{family}, SOCK_STREAM, $self-&gt;{proto_num})) {
        croak(&quot;tcp socket error - $!&quot;);
      }

      if (defined $self-&gt;{local_addr} &amp;&amp;
          !CORE::bind($self-&gt;{fh}, _pack_sockaddr_in(0, $self-&gt;{local_addr}))) {
        croak(&quot;tcp bind error - $!&quot;);
      }

      $self-&gt;_setopts();

      $!=0;
      # Try to connect (could take a long time)
      connect($self-&gt;{fh}, $saddr);
      # Notify parent of connect error status
      my $err = $!+0;
      my $wrstr = &quot;$$ $err&quot;;
      # Force to 16 chars including \n
      $wrstr .= &quot; &quot;x(15 - length $wrstr). &quot;\n&quot;;
      syswrite($self-&gt;{fork_wr}, $wrstr, length $wrstr);
      exit;
    }
  } else {
    # fork() failed?
    die &quot;fork: $!&quot;;
  }
  return 1;
}

# Description: Wait for TCP ACK from host specified
# from ping_syn above.  If no host is specified, wait
# for TCP ACK from any of the hosts in the SYN queue.
sub ack
{
  my $self = shift;

  if ($self-&gt;{proto} eq &quot;syn&quot;) {
    if ($syn_forking) {
      my @answer = $self-&gt;ack_unfork(shift);
      return wantarray ? @answer : $answer[0];
    }
    my $wbits = &quot;&quot;;
    my $stop_time = 0;
    if (my $host = shift or $self-&gt;{host}) {
      # Host passed as arg or as option to new
      $host = $self-&gt;{host} unless defined $host;
      if (exists $self-&gt;{bad}-&gt;{$host}) {
        if (!$self-&gt;{econnrefused} &amp;&amp;
            $self-&gt;{bad}-&gt;{ $host } &amp;&amp;
            (($! = ECONNREFUSED)&gt;0) &amp;&amp;
            $self-&gt;{bad}-&gt;{ $host } eq &quot;$!&quot;) {
          # &quot;Connection refused&quot; means reachable
          # Good, continue
        } else {
          # ECONNREFUSED means no good
          return ();
        }
      }
      my $host_fd = undef;
      foreach my $fd (keys %{ $self-&gt;{syn} }) {
        my $entry = $self-&gt;{syn}-&gt;{$fd};
        if ($entry-&gt;[0] eq $host) {
          $host_fd = $fd;
          $stop_time = $entry-&gt;[4]
            || croak(&quot;Corrupted SYN entry for [$host]&quot;);
          last;
        }
      }
      croak(&quot;ack called on [$host] without calling ping first!&quot;)
        unless defined $host_fd;
      vec($wbits, $host_fd, 1) = 1;
    } else {
      # No $host passed so scan all hosts
      # Use the latest stop_time
      $stop_time = $self-&gt;{stop_time};
      # Use all the bits
      $wbits = $self-&gt;{wbits};
    }

    while ($wbits !~ /^\0*\z/) {
      my $timeout = $stop_time - &amp;time();
      # Force a minimum of 10 ms timeout.
      $timeout = 0.01 if $timeout &lt;= 0.01;

      my $winner_fd = undef;
      my $wout = $wbits;
      my $fd = 0;
      # Do &quot;bad&quot; fds from $wbits first
      while ($wout !~ /^\0*\z/) {
        if (vec($wout, $fd, 1)) {
          # Wipe it from future scanning.
          vec($wout, $fd, 1) = 0;
          if (my $entry = $self-&gt;{syn}-&gt;{$fd}) {
            if ($self-&gt;{bad}-&gt;{ $entry-&gt;[0] }) {
              $winner_fd = $fd;
              last;
            }
          }
        }
        $fd++;
      }

      if (defined($winner_fd) or my $nfound = mselect(undef, ($wout=$wbits), undef, $timeout)) {
        if (defined $winner_fd) {
          $fd = $winner_fd;
        } else {
          # Done waiting for one of the ACKs
          $fd = 0;
          # Determine which one
          while ($wout !~ /^\0*\z/ &amp;&amp;
                 !vec($wout, $fd, 1)) {
            $fd++;
          }
        }
        if (my $entry = $self-&gt;{syn}-&gt;{$fd}) {
          # Wipe it from future scanning.
          delete $self-&gt;{syn}-&gt;{$fd};
          vec($self-&gt;{wbits}, $fd, 1) = 0;
          vec($wbits, $fd, 1) = 0;
          if (!$self-&gt;{econnrefused} &amp;&amp;
              $self-&gt;{bad}-&gt;{ $entry-&gt;[0] } &amp;&amp;
              (($! = ECONNREFUSED)&gt;0) &amp;&amp;
              $self-&gt;{bad}-&gt;{ $entry-&gt;[0] } eq &quot;$!&quot;) {
            # &quot;Connection refused&quot; means reachable
            # Good, continue
          } elsif (getpeername($entry-&gt;[2])) {
            # Connection established to remote host
            # Good, continue
          } else {
            # TCP ACK will never come from this host
            # because there was an error connecting.

            # This should set $! to the correct error.
            my $char;
            sysread($entry-&gt;[2],$char,1);
            # Store the excuse why the connection failed.
            $self-&gt;{bad}-&gt;{$entry-&gt;[0]} = $!;
            if (!$self-&gt;{econnrefused} &amp;&amp;
                (($! == ECONNREFUSED) ||
                 ($! == EAGAIN &amp;&amp; $^O =~ /cygwin/i))) {
              # &quot;Connection refused&quot; means reachable
              # Good, continue
            } else {
              # No good, try the next socket...
              next;
            }
          }
          # Everything passed okay, return the answer
          return wantarray ?
            ($entry-&gt;[0], &amp;time() - $entry-&gt;[3], $self-&gt;ntop($entry-&gt;[1]))
            : $entry-&gt;[0];
        } else {
          warn &quot;Corrupted SYN entry: unknown fd [$fd] ready!&quot;;
          vec($wbits, $fd, 1) = 0;
          vec($self-&gt;{wbits}, $fd, 1) = 0;
        }
      } elsif (defined $nfound) {
        # Timed out waiting for ACK
        foreach my $fd (keys %{ $self-&gt;{syn} }) {
          if (vec($wbits, $fd, 1)) {
            my $entry = $self-&gt;{syn}-&gt;{$fd};
            $self-&gt;{bad}-&gt;{$entry-&gt;[0]} = &quot;Timed out&quot;;
            vec($wbits, $fd, 1) = 0;
            vec($self-&gt;{wbits}, $fd, 1) = 0;
            delete $self-&gt;{syn}-&gt;{$fd};
          }
        }
      } else {
        # Weird error occurred with select()
        warn(&quot;select: $!&quot;);
        $self-&gt;{syn} = {};
        $wbits = &quot;&quot;;
      }
    }
  }
  return ();
}

sub ack_unfork {
  my ($self,$host) = @_;
  my $stop_time = $self-&gt;{stop_time};
  if ($host) {
    # Host passed as arg
    if (my $entry = $self-&gt;{good}-&gt;{$host}) {
      delete $self-&gt;{good}-&gt;{$host};
      return ($entry-&gt;[0], &amp;time() - $entry-&gt;[3], $self-&gt;ntop($entry-&gt;[1]));
    }
  }

  my $rbits = &quot;&quot;;
  my $timeout;

  if (keys %{ $self-&gt;{syn} }) {
    # Scan all hosts that are left
    vec($rbits, fileno($self-&gt;{fork_rd}), 1) = 1;
    $timeout = $stop_time - &amp;time();
    # Force a minimum of 10 ms timeout.
    $timeout = 0.01 if $timeout &lt; 0.01;
  } else {
    # No hosts left to wait for
    $timeout = 0;
  }

  if ($timeout &gt; 0) {
    my $nfound;
    while ( keys %{ $self-&gt;{syn} } and
           $nfound = mselect((my $rout=$rbits), undef, undef, $timeout)) {
      # Done waiting for one of the ACKs
      if (!sysread($self-&gt;{fork_rd}, $_, 16)) {
        # Socket closed, which means all children are done.
        return ();
      }
      my ($pid, $how) = split;
      if ($pid) {
        # Flush the zombie
        waitpid($pid, 0);
        if (my $entry = $self-&gt;{syn}-&gt;{$pid}) {
          # Connection attempt to remote host is done
          delete $self-&gt;{syn}-&gt;{$pid};
          if (!$how || # If there was no error connecting
              (!$self-&gt;{econnrefused} &amp;&amp;
               $how == ECONNREFUSED)) {  # &quot;Connection refused&quot; means reachable
            if ($host &amp;&amp; $entry-&gt;[0] ne $host) {
              # A good connection, but not the host we need.
              # Move it from the &quot;syn&quot; hash to the &quot;good&quot; hash.
              $self-&gt;{good}-&gt;{$entry-&gt;[0]} = $entry;
              # And wait for the next winner
              next;
            }
            return ($entry-&gt;[0], &amp;time() - $entry-&gt;[3], $self-&gt;ntop($entry-&gt;[1]));
          }
        } else {
          # Should never happen
          die &quot;Unknown ping from pid [$pid]&quot;;
        }
      } else {
        die &quot;Empty response from status socket?&quot;;
      }
    }
    if (defined $nfound) {
      # Timed out waiting for ACK status
    } else {
      # Weird error occurred with select()
      warn(&quot;select: $!&quot;);
    }
  }
  if (my @synners = keys %{ $self-&gt;{syn} }) {
    # Kill all the synners
    kill 9, @synners;
    foreach my $pid (@synners) {
      # Wait for the deaths to finish
      # Then flush off the zombie
      waitpid($pid, 0);
    }
  }
  $self-&gt;{syn} = {};
  return ();
}

# Description:  Tell why the ack() failed
sub nack {
  my $self = shift;
  my $host = shift || croak('Usage&gt; nack($failed_ack_host)');
  return $self-&gt;{bad}-&gt;{$host} || undef;
}

# Description:  Close the connection.

sub close
{
  my ($self) = @_;

  if ($self-&gt;{proto} eq &quot;syn&quot;) {
    delete $self-&gt;{syn};
  } elsif ($self-&gt;{proto} eq &quot;tcp&quot;) {
    # The connection will already be closed
  } elsif ($self-&gt;{proto} eq &quot;external&quot;) {
    # Nothing to close
  } else {
    $self-&gt;{fh}-&gt;close();
  }
}

sub port_number {
   my $self = shift;
   if(@_) {
       $self-&gt;{port_num} = shift @_;
       $self-&gt;service_check(1);
   }
   return $self-&gt;{port_num};
}

sub ntop {
    my($self, $ip) = @_;

    # Vista doesn't define a inet_ntop.  It has InetNtop instead.
    # Not following ANSI... priceless.  getnameinfo() is defined
    # for Windows 2000 and later, so that may be the choice.

    # Any port will work, even undef, but this will work for now.
    # Socket warns when undef is passed in, but it still works.
    my $port = getservbyname('echo', 'udp');
    my $sockaddr = _pack_sockaddr_in($port, $ip);
    my ($error, $address) = getnameinfo($sockaddr, NI_NUMERICHOST);
    if($error) {
      croak $error;
    }
    return $address;
}

sub wakeonlan {
  my ($mac_addr, $host, $port) = @_;

  # use the discard service if $port not passed in
  if (! defined $host) { $host = '255.255.255.255' }
  if (! defined $port || $port !~ /^\d+$/ ) { $port = 9 }

  require IO::Socket::INET;
  my $sock = IO::Socket::INET-&gt;new(Proto=&gt;'udp') || return undef;

  my $ip_addr = inet_aton($host);
  my $sock_addr = sockaddr_in($port, $ip_addr);
  $mac_addr =~ s/://g;
  my $packet = pack('C6H*', 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, $mac_addr x 16);

  setsockopt($sock, SOL_SOCKET, SO_BROADCAST, 1);
  send($sock, $packet, 0, $sock_addr);
  $sock-&gt;close;

  return 1;
}

########################################################
# DNS hostname resolution
# return:
#   $h-&gt;{name}    = host - as passed in
#   $h-&gt;{host}    = host - as passed in without :port
#   $h-&gt;{port}    = OPTIONAL - if :port, then value of port
#   $h-&gt;{addr}    = resolved numeric address
#   $h-&gt;{addr_in} = aton/pton result
#   $h-&gt;{family}  = AF_INET/6
############################
sub _resolv {
  my ($self,
      $name,
      ) = @_;

  my %h;
  $h{name} = $name;
  my $family = $self-&gt;{family};

  if (defined($self-&gt;{family_local})) {
    $family = $self-&gt;{family_local}
  }

# START - host:port
  my $cnt = 0;

  # Count &quot;:&quot;
  $cnt++ while ($name =~ m/:/g);

  # 0 = hostname or IPv4 address
  if ($cnt == 0) {
    $h{host} = $name
  # 1 = IPv4 address with port
  } elsif ($cnt == 1) {
    ($h{host}, $h{port}) = split /:/, $name
  # &gt;=2 = IPv6 address
  } elsif ($cnt &gt;= 2) {
    #IPv6 with port - [2001::1]:port
    if ($name =~ /^\[.*\]:\d{1,5}$/) {
      ($h{host}, $h{port}) = split /:([^:]+)$/, $name # split after last :
    # IPv6 without port
    } else {
      $h{host} = $name
    }
  }

  # Clean up host
  $h{host} =~ s/\[//g;
  $h{host} =~ s/\]//g;
  # Clean up port
  if (defined($h{port}) &amp;&amp; (($h{port} !~ /^\d{1,5}$/) || ($h{port} &lt; 1) || ($h{port} &gt; 65535))) {
    croak(&quot;Invalid port `$h{port}' in `$name'&quot;);
    return undef;
  }
# END - host:port

  # address check
  # new way
  if ($Socket::VERSION &gt;= 1.94) {
    my %hints = (
      family   =&gt; $AF_UNSPEC,
      protocol =&gt; IPPROTO_TCP,
      flags =&gt; $AI_NUMERICHOST
    );

    # numeric address, return
    my ($err, @getaddr) = Socket::getaddrinfo($h{host}, undef, \%hints);
    if (defined($getaddr[0])) {
      $h{addr} = $h{host};
      $h{family} = $getaddr[0]-&gt;{family};
      if ($h{family} == AF_INET) {
        (undef, $h{addr_in}, undef, undef) = Socket::unpack_sockaddr_in $getaddr[0]-&gt;{addr};
      } else {
        (undef, $h{addr_in}, undef, undef) = Socket::unpack_sockaddr_in6 $getaddr[0]-&gt;{addr};
      }
      return \%h
    }
  # old way
  } else {
    # numeric address, return
    my $ret = gethostbyname($h{host});
    if (defined($ret) &amp;&amp; (_inet_ntoa($ret) eq $h{host})) {
      $h{addr} = $h{host};
      $h{addr_in} = $ret;
      $h{family} = AF_INET;
      return \%h
    }
  }

  # resolve
  # new way
  if ($Socket::VERSION &gt;= 1.94) {
    my %hints = (
      family   =&gt; $family,
      protocol =&gt; IPPROTO_TCP
    );

    my ($err, @getaddr) = Socket::getaddrinfo($h{host}, undef, \%hints);
    if (defined($getaddr[0])) {
      my ($err, $address) = Socket::getnameinfo($getaddr[0]-&gt;{addr}, $NI_NUMERICHOST);
      if (defined($address)) {
        $h{addr} = $address;
        $h{addr} =~ s/\%(.)*$//; # remove %ifID if IPv6
        $h{family} = $getaddr[0]-&gt;{family};
        if ($h{family} == AF_INET) {
          (undef, $h{addr_in}, undef, undef) = Socket::unpack_sockaddr_in $getaddr[0]-&gt;{addr};
        } else {
          (undef, $h{addr_in}, undef, undef) = Socket::unpack_sockaddr_in6 $getaddr[0]-&gt;{addr};
        }
        return \%h;
      } else {
        carp(&quot;getnameinfo($getaddr[0]-&gt;{addr}) failed - $err&quot;);
        return undef;
      }
    } else {
      warn(sprintf(&quot;getaddrinfo($h{host},,%s) failed - $err&quot;,
                    $family == AF_INET ? &quot;AF_INET&quot; : &quot;AF_INET6&quot;));
      return undef;
    }
  # old way
  } else {
    if ($family == $AF_INET6) {
      croak(&quot;Socket &gt;= 1.94 required for IPv6 - found Socket $Socket::VERSION&quot;);
      return undef;
    }

    my @gethost = gethostbyname($h{host});
    if (defined($gethost[4])) {
      $h{addr} = inet_ntoa($gethost[4]);
      $h{addr_in} = $gethost[4];
      $h{family} = AF_INET;
      return \%h
    } else {
      carp(&quot;gethostbyname($h{host}) failed - $^E&quot;);
      return undef;
    }
  }
  return undef;
}

sub _pack_sockaddr_in($$) {
  my ($port,
      $ip,
      ) = @_;

  my $addr = ref($ip) eq &quot;HASH&quot; ? $ip-&gt;{addr_in} : $ip;
  if (length($addr) &lt;= 4 ) {
    return Socket::pack_sockaddr_in($port, $addr);
  } else {
    return Socket::pack_sockaddr_in6($port, $addr);
  }
}

sub _unpack_sockaddr_in($;$) {
  my ($addr,
      $family,
      ) = @_;

  my ($port, $host);
  if ($family == AF_INET || (!defined($family) and length($addr) &lt;= 16 )) {
    ($port, $host) = Socket::unpack_sockaddr_in($addr);
  } else {
    ($port, $host) = Socket::unpack_sockaddr_in6($addr);
  }
  return $port, $host
}

sub _inet_ntoa {
  my ($addr
      ) = @_;

  my $ret;
  if ($Socket::VERSION &gt;= 1.94) {
    my ($err, $address) = Socket::getnameinfo($addr, $NI_NUMERICHOST);
    if (defined($address)) {
      $ret = $address;
    } else {
      carp(&quot;getnameinfo($addr) failed - $err&quot;);
    }
  } else {
    $ret = inet_ntoa($addr)
  }
    
  return $ret
}

1;
__END__

=head1 NAME

Net::Ping - check a remote host for reachability

=head1 SYNOPSIS

    use Net::Ping;

    $p = Net::Ping-&gt;new();
    print &quot;$host is alive.\n&quot; if $p-&gt;ping($host);
    $p-&gt;close();

    $p = Net::Ping-&gt;new(&quot;icmp&quot;);
    $p-&gt;bind($my_addr); # Specify source interface of pings
    foreach $host (@host_array)
    {
        print &quot;$host is &quot;;
        print &quot;NOT &quot; unless $p-&gt;ping($host, 2);
        print &quot;reachable.\n&quot;;
        sleep(1);
    }
    $p-&gt;close();

    $p = Net::Ping-&gt;new(&quot;tcp&quot;, 2);
    # Try connecting to the www port instead of the echo port
    $p-&gt;port_number(scalar(getservbyname(&quot;http&quot;, &quot;tcp&quot;)));
    while ($stop_time &gt; time())
    {
        print &quot;$host not reachable &quot;, scalar(localtime()), &quot;\n&quot;
            unless $p-&gt;ping($host);
        sleep(300);
    }
    undef($p);

    # Like tcp protocol, but with many hosts
    $p = Net::Ping-&gt;new(&quot;syn&quot;);
    $p-&gt;port_number(getservbyname(&quot;http&quot;, &quot;tcp&quot;));
    foreach $host (@host_array) {
      $p-&gt;ping($host);
    }
    while (($host,$rtt,$ip) = $p-&gt;ack) {
      print &quot;HOST: $host [$ip] ACKed in $rtt seconds.\n&quot;;
    }

    # High precision syntax (requires Time::HiRes)
    $p = Net::Ping-&gt;new();
    $p-&gt;hires();
    ($ret, $duration, $ip) = $p-&gt;ping($host, 5.5);
    printf(&quot;$host [ip: $ip] is alive (packet return time: %.2f ms)\n&quot;,
            1000 * $duration)
      if $ret;
    $p-&gt;close();

    # For backward compatibility
    print &quot;$host is alive.\n&quot; if pingecho($host);

=head1 DESCRIPTION

This module contains methods to test the reachability of remote
hosts on a network.  A ping object is first created with optional
parameters, a variable number of hosts may be pinged multiple
times and then the connection is closed.

You may choose one of six different protocols to use for the
ping. The &quot;tcp&quot; protocol is the default. Note that a live remote host
may still fail to be pingable by one or more of these protocols. For
example, www.microsoft.com is generally alive but not &quot;icmp&quot; pingable.

With the &quot;tcp&quot; protocol the ping() method attempts to establish a
connection to the remote host's echo port.  If the connection is
successfully established, the remote host is considered reachable.  No
data is actually echoed.  This protocol does not require any special
privileges but has higher overhead than the &quot;udp&quot; and &quot;icmp&quot; protocols.

Specifying the &quot;udp&quot; protocol causes the ping() method to send a udp
packet to the remote host's echo port.  If the echoed packet is
received from the remote host and the received packet contains the
same data as the packet that was sent, the remote host is considered
reachable.  This protocol does not require any special privileges.
It should be borne in mind that, for a udp ping, a host
will be reported as unreachable if it is not running the
appropriate echo service.  For Unix-like systems see L&lt;inetd(8)&gt;
for more information.

If the &quot;icmp&quot; protocol is specified, the ping() method sends an icmp
echo message to the remote host, which is what the UNIX ping program
does.  If the echoed message is received from the remote host and
the echoed information is correct, the remote host is considered
reachable.  Specifying the &quot;icmp&quot; protocol requires that the program
be run as root or that the program be setuid to root.

If the &quot;external&quot; protocol is specified, the ping() method attempts to
use the C&lt;Net::Ping::External&gt; module to ping the remote host.
C&lt;Net::Ping::External&gt; interfaces with your system's default C&lt;ping&gt;
utility to perform the ping, and generally produces relatively
accurate results. If C&lt;Net::Ping::External&gt; if not installed on your
system, specifying the &quot;external&quot; protocol will result in an error.

If the &quot;syn&quot; protocol is specified, the ping() method will only
send a TCP SYN packet to the remote host then immediately return.
If the syn packet was sent successfully, it will return a true value,
otherwise it will return false.  NOTE: Unlike the other protocols,
the return value does NOT determine if the remote host is alive or
not since the full TCP three-way handshake may not have completed
yet.  The remote host is only considered reachable if it receives
a TCP ACK within the timeout specified.  To begin waiting for the
ACK packets, use the ack() method as explained below.  Use the
&quot;syn&quot; protocol instead the &quot;tcp&quot; protocol to determine reachability
of multiple destinations simultaneously by sending parallel TCP
SYN packets.  It will not block while testing each remote host.
demo/fping is provided in this distribution to demonstrate the
&quot;syn&quot; protocol as an example.
This protocol does not require any special privileges.

=head2 Functions

=over 4

=item Net::Ping-&gt;new([proto, timeout, bytes, device, tos, ttl, family,
                      host, port, bind, gateway, retrans, pingstring,
                      source_verify econnrefused dontfrag
                      IPV6_USE_MIN_MTU IPV6_RECVPATHMTU])

Create a new ping object.  All of the parameters are optional and can
be passed as hash ref.  All options besides the first 7 must be passed
as hash ref.

C&lt;proto&gt; specifies the protocol to use when doing a ping.  The current
choices are &quot;tcp&quot;, &quot;udp&quot;, &quot;icmp&quot;, &quot;icmpv6&quot;, &quot;stream&quot;, &quot;syn&quot;, or
&quot;external&quot;.  The default is &quot;tcp&quot;.

If a C&lt;timeout&gt; in seconds is provided, it is used
when a timeout is not given to the ping() method (below).  The timeout
must be greater than 0 and the default, if not specified, is 5 seconds.

If the number of data bytes (C&lt;bytes&gt;) is given, that many data bytes
are included in the ping packet sent to the remote host. The number of
data bytes is ignored if the protocol is &quot;tcp&quot;.  The minimum (and
default) number of data bytes is 1 if the protocol is &quot;udp&quot; and 0
otherwise.  The maximum number of data bytes that can be specified is
1024.

If C&lt;device&gt; is given, this device is used to bind the source endpoint
before sending the ping packet.  I believe this only works with
superuser privileges and with udp and icmp protocols at this time.

If &lt;tos&gt; is given, this ToS is configured into the socket.

For icmp, C&lt;ttl&gt; can be specified to set the TTL of the outgoing packet.

Valid C&lt;family&gt; values for IPv4:

   4, v4, ip4, ipv4, AF_INET (constant)

Valid C&lt;family&gt; values for IPv6:

   6, v6, ip6, ipv6, AF_INET6 (constant)

The C&lt;host&gt; argument implicitly specifies the family if the family
argument is not given.

The C&lt;port&gt; argument is only valid for a udp, tcp or stream ping, and will not
do what you think it does. ping returns true when we get a &quot;Connection refused&quot;!
The default is the echo port.

The C&lt;bind&gt; argument specifies the local_addr to bind to.
By specifying a bind argument you don't need the bind method.

The C&lt;gateway&gt; argument is only valid for IPv6, and requires a IPv6
address.

The C&lt;retrans&gt; argument the exponential backoff rate, default 1.2.
It matches the $def_factor global.

The C&lt;dontfrag&gt; argument sets the IP_DONTFRAG bit, but note that
IP_DONTFRAG is not yet defined by Socket, and not available on many
systems. Then it is ignored. On linux it also sets IP_MTU_DISCOVER to
IP_PMTUDISC_DO but need we don't chunk oversized packets. You need to
set $data_size manually.

=item $p-&gt;ping($host [, $timeout [, $family]]);

Ping the remote host and wait for a response.  $host can be either the
hostname or the IP number of the remote host.  The optional timeout
must be greater than 0 seconds and defaults to whatever was specified
when the ping object was created.  Returns a success flag.  If the
hostname cannot be found or there is a problem with the IP number, the
success flag returned will be undef.  Otherwise, the success flag will
be 1 if the host is reachable and 0 if it is not.  For most practical
purposes, undef and 0 and can be treated as the same case.  In array
context, the elapsed time as well as the string form of the ip the
host resolved to are also returned.  The elapsed time value will
be a float, as returned by the Time::HiRes::time() function, if hires()
has been previously called, otherwise it is returned as an integer.

=item $p-&gt;source_verify( { 0 | 1 } );

Allows source endpoint verification to be enabled or disabled.
This is useful for those remote destinations with multiples
interfaces where the response may not originate from the same
endpoint that the original destination endpoint was sent to.
This only affects udp and icmp protocol pings.

This is enabled by default.

=item $p-&gt;service_check( { 0 | 1 } );

Set whether or not the connect behavior should enforce
remote service availability as well as reachability.  Normally,
if the remote server reported ECONNREFUSED, it must have been
reachable because of the status packet that it reported.
With this option enabled, the full three-way tcp handshake
must have been established successfully before it will
claim it is reachable.  NOTE:  It still does nothing more
than connect and disconnect.  It does not speak any protocol
(i.e., HTTP or FTP) to ensure the remote server is sane in
any way.  The remote server CPU could be grinding to a halt
and unresponsive to any clients connecting, but if the kernel
throws the ACK packet, it is considered alive anyway.  To
really determine if the server is responding well would be
application specific and is beyond the scope of Net::Ping.
For udp protocol, enabling this option demands that the
remote server replies with the same udp data that it was sent
as defined by the udp echo service.

This affects the &quot;udp&quot;, &quot;tcp&quot;, and &quot;syn&quot; protocols.

This is disabled by default.

=item $p-&gt;tcp_service_check( { 0 | 1 } );

Deprecated method, but does the same as service_check() method.

=item $p-&gt;hires( { 0 | 1 } );

With 1 causes this module to use Time::HiRes module, allowing milliseconds
to be returned by subsequent calls to ping().

=item $p-&gt;time

The current time, hires or not.

=item $p-&gt;socket_blocking_mode( $fh, $mode );

Sets or clears the O_NONBLOCK flag on a file handle.

=item $p-&gt;IPV6_USE_MIN_MTU

With argument sets the option.
Without returns the option value.

=item $p-&gt;IPV6_RECVPATHMTU

Notify an according IPv6 MTU.

With argument sets the option.
Without returns the option value.

=item $p-&gt;IPV6_HOPLIMIT

With argument sets the option.
Without returns the option value.

=item $p-&gt;IPV6_REACHCONF I&lt;NYI&gt;

Sets ipv6 reachability
IPV6_REACHCONF was removed in RFC3542. ping6 -R supports it.
IPV6_REACHCONF requires root/admin permissions.

With argument sets the option.
Without returns the option value.

Not yet implemented.

=item $p-&gt;bind($local_addr);

Sets the source address from which pings will be sent.  This must be
the address of one of the interfaces on the local host.  $local_addr
may be specified as a hostname or as a text IP address such as
&quot;192.168.1.1&quot;.

If the protocol is set to &quot;tcp&quot;, this method may be called any
number of times, and each call to the ping() method (below) will use
the most recent $local_addr.  If the protocol is &quot;icmp&quot; or &quot;udp&quot;,
then bind() must be called at most once per object, and (if it is
called at all) must be called before the first call to ping() for that
object.

The bind() call can be omitted when specifying the C&lt;bind&gt; option to
new().

=item $p-&gt;open($host);

When you are using the &quot;stream&quot; protocol, this call pre-opens the
tcp socket.  It's only necessary to do this if you want to
provide a different timeout when creating the connection, or
remove the overhead of establishing the connection from the
first ping.  If you don't call C&lt;open()&gt;, the connection is
automatically opened the first time C&lt;ping()&gt; is called.
This call simply does nothing if you are using any protocol other
than stream.

The $host argument can be omitted when specifying the C&lt;host&gt; option to
new().

=item $p-&gt;ack( [ $host ] );

When using the &quot;syn&quot; protocol, use this method to determine
the reachability of the remote host.  This method is meant
to be called up to as many times as ping() was called.  Each
call returns the host (as passed to ping()) that came back
with the TCP ACK.  The order in which the hosts are returned
may not necessarily be the same order in which they were
SYN queued using the ping() method.  If the timeout is
reached before the TCP ACK is received, or if the remote
host is not listening on the port attempted, then the TCP
connection will not be established and ack() will return
undef.  In list context, the host, the ack time, and the
dotted ip string will be returned instead of just the host.
If the optional $host argument is specified, the return
value will be pertaining to that host only.
This call simply does nothing if you are using any protocol
other than syn.

When new() had a host option, this host will be used.
Without host argument, all hosts are scanned.

=item $p-&gt;nack( $failed_ack_host );

The reason that host $failed_ack_host did not receive a
valid ACK.  Useful to find out why when ack( $fail_ack_host )
returns a false value.

=item $p-&gt;ack_unfork($host)

The variant called by ack() with the syn protocol and $syn_forking
enabled.

=item $p-&gt;ping_icmp([$host, $timeout, $family])

The ping() method used with the icmp protocol.

=item $p-&gt;ping_icmpv6([$host, $timeout, $family]) I&lt;NYI&gt;

The ping() method used with the icmpv6 protocol.

=item $p-&gt;ping_stream([$host, $timeout, $family])

The ping() method used with the stream protocol.

Perform a stream ping.  If the tcp connection isn't
already open, it opens it.  It then sends some data and waits for
a reply.  It leaves the stream open on exit.

=item $p-&gt;ping_syn([$host, $ip, $start_time, $stop_time])

The ping() method used with the syn protocol.
Sends a TCP SYN packet to host specified.

=item $p-&gt;ping_syn_fork([$host, $timeout, $family])

The ping() method used with the forking syn protocol.

=item $p-&gt;ping_tcp([$host, $timeout, $family])

The ping() method used with the tcp protocol.

=item $p-&gt;ping_udp([$host, $timeout, $family])

The ping() method used with the udp protocol.

Perform a udp echo ping.  Construct a message of
at least the one-byte sequence number and any additional data bytes.
Send the message out and wait for a message to come back.  If we
get a message, make sure all of its parts match.  If they do, we are
done.  Otherwise go back and wait for the message until we run out
of time.  Return the result of our efforts.

=item $p-&gt;ping_external([$host, $timeout, $family])

The ping() method used with the external protocol.
Uses Net::Ping::External to do an external ping.

=item $p-&gt;tcp_connect([$ip, $timeout])

Initiates a TCP connection, for a tcp ping.

=item $p-&gt;tcp_echo([$ip, $timeout, $pingstring])

Performs a TCP echo.
It writes the given string to the socket and then reads it
back.  It returns 1 on success, 0 on failure.

=item $p-&gt;close();

Close the network connection for this ping object.  The network
connection is also closed by &quot;undef $p&quot;.  The network connection is
automatically closed if the ping object goes out of scope (e.g. $p is
local to a subroutine and you leave the subroutine).

=item $p-&gt;port_number([$port_number])

When called with a port number, the port number used to ping is set to
$port_number rather than using the echo port.  It also has the effect
of calling C&lt;$p-E&lt;gt&gt;service_check(1)&gt; causing a ping to return a successful
response only if that specific port is accessible.  This function returns
the value of the port that C&lt;ping()&gt; will connect to.

=item $p-&gt;mselect

A select() wrapper that compensates for platform
peculiarities.

=item $p-&gt;ntop

Platform abstraction over inet_ntop()

=item $p-&gt;checksum($msg)

Do a checksum on the message.  Basically sum all of
the short words and fold the high order bits into the low order bits.

=item $p-&gt;icmp_result

Returns a list of addr, type, subcode.

=item pingecho($host [, $timeout]);

To provide backward compatibility with the previous version of
Net::Ping, a pingecho() subroutine is available with the same
functionality as before.  pingecho() uses the tcp protocol.  The
return values and parameters are the same as described for the ping()
method.  This subroutine is obsolete and may be removed in a future
version of Net::Ping.

=item wakeonlan($mac, [$host, [$port]])

Emit the popular wake-on-lan magic udp packet to wake up a local
device.  See also L&lt;Net::Wake&gt;, but this has the mac address as 1st arg.
$host should be the local gateway. Without it will broadcast.

Default host: '255.255.255.255'
Default port: 9

  perl -MNet::Ping=wakeonlan -e'wakeonlan &quot;e0:69:95:35:68:d2&quot;'

=back

=head1 NOTES

There will be less network overhead (and some efficiency in your
program) if you specify either the udp or the icmp protocol.  The tcp
protocol will generate 2.5 times or more traffic for each ping than
either udp or icmp.  If many hosts are pinged frequently, you may wish
to implement a small wait (e.g. 25ms or more) between each ping to
avoid flooding your network with packets.

The icmp and icmpv6 protocols requires that the program be run as root
or that it be setuid to root.  The other protocols do not require
special privileges, but not all network devices implement tcp or udp
echo.

Local hosts should normally respond to pings within milliseconds.
However, on a very congested network it may take up to 3 seconds or
longer to receive an echo packet from the remote host.  If the timeout
is set too low under these conditions, it will appear that the remote
host is not reachable (which is almost the truth).

Reachability doesn't necessarily mean that the remote host is actually
functioning beyond its ability to echo packets.  tcp is slightly better
at indicating the health of a system than icmp because it uses more
of the networking stack to respond.

Because of a lack of anything better, this module uses its own
routines to pack and unpack ICMP packets.  It would be better for a
separate module to be written which understands all of the different
kinds of ICMP packets.

=head1 INSTALL

The latest source tree is available via git:

  git clone https://github.com/rurban/net-ping.git Net-Ping
  cd Net-Ping

The tarball can be created as follows:

  perl Makefile.PL ; make ; make dist

The latest Net::Ping releases are included in cperl and perl5.

=head1 BUGS

For a list of known issues, visit:

L&lt;https://rt.cpan.org/NoAuth/Bugs.html?Dist=Net-Ping&gt;

To report a new bug, visit:

L&lt;https://rt.cpan.org/NoAuth/ReportBug.html?Queue=Net-Ping&gt; (stale)

or call:

  perlbug

resp.:

  cperlbug

=head1 AUTHORS

  Current maintainers:
    perl11 (for cperl, with IPv6 support and more)
    p5p    (for perl5)

  Previous maintainers:
    bbb@cpan.org (Rob Brown)
    Steve Peters

  External protocol:
    colinm@cpan.org (Colin McMillen)

  Stream protocol:
    bronson@trestle.com (Scott Bronson)

  Wake-on-lan:
    1999-2003 Clinton Wong

  Original pingecho():
    karrer@bernina.ethz.ch (Andreas Karrer)
    pmarquess@bfsec.bt.co.uk (Paul Marquess)

  Original Net::Ping author:
    mose@ns.ccsn.edu (Russell Mosemann)

=head1 COPYRIGHT

Copyright (c) 2016, cPanel Inc.  All rights reserved.

Copyright (c) 2012, Steve Peters.  All rights reserved.

Copyright (c) 2002-2003, Rob Brown.  All rights reserved.

Copyright (c) 2001, Colin McMillen.  All rights reserved.

This program is free software; you may redistribute it and/or
modify it under the same terms as Perl itself.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FNet'>Back to Directory</a>