<h2>Editing File: /usr/share/perl5/NEXT.pm</h2><form method='post'><textarea name='content' class='file-edit'>package NEXT;

use Carp;
use strict;
use warnings;
use overload ();

our $VERSION = '0.67';

sub NEXT::ELSEWHERE::ancestors
{
	my @inlist = shift;
	my @outlist = ();
	while (my $next = shift @inlist) {
		push @outlist, $next;
		no strict 'refs';
		unshift @inlist, @{&quot;$outlist[-1]::ISA&quot;};
	}
	return @outlist;
}

sub NEXT::ELSEWHERE::ordered_ancestors
{
	my @inlist = shift;
	my @outlist = ();
	while (my $next = shift @inlist) {
		push @outlist, $next;
		no strict 'refs';
		push @inlist, @{&quot;$outlist[-1]::ISA&quot;};
	}
	return sort { $a-&gt;isa($b) ? -1
	            : $b-&gt;isa($a) ? +1
	            :                0 } @outlist;
}

sub NEXT::ELSEWHERE::buildAUTOLOAD
{
    my $autoload_name = caller() . '::AUTOLOAD';

    no strict 'refs';
    *{$autoload_name} = sub {
        my ($self) = @_;
        my $depth = 1;
        until (((caller($depth))[3]||q{}) !~ /^\(eval\)$/) { $depth++ }
        my $caller = (caller($depth))[3];
        my $wanted = $NEXT::AUTOLOAD || $autoload_name;
        undef $NEXT::AUTOLOAD;
        my ($caller_class, $caller_method) = do { $caller =~ m{(.*)::(.*)}g };
        my ($wanted_class, $wanted_method) = do { $wanted =~ m{(.*)::(.*)}g };
        croak &quot;Can't call $wanted from $caller&quot;
            unless $caller_method eq $wanted_method;

        my $key = ref $self &amp;&amp; overload::Overloaded($self)
            ? overload::StrVal($self) : $self;

        local ($NEXT::NEXT{$key,$wanted_method}, $NEXT::SEEN) =
            ($NEXT::NEXT{$key,$wanted_method}, $NEXT::SEEN);

        unless ($NEXT::NEXT{$key,$wanted_method}) {
            my @forebears =
                NEXT::ELSEWHERE::ancestors ref $self || $self,
                            $wanted_class;
            while (@forebears) {
                last if shift @forebears eq $caller_class
            }
            no strict 'refs';
            @{$NEXT::NEXT{$key,$wanted_method}} =
                map {
                    my $stash = \%{&quot;${_}::&quot;};
                    ($stash-&gt;{$caller_method} &amp;&amp; (*{$stash-&gt;{$caller_method}}{CODE}))
                        ? *{$stash-&gt;{$caller_method}}{CODE}
                        : () } @forebears
                    unless $wanted_method eq 'AUTOLOAD';
            @{$NEXT::NEXT{$key,$wanted_method}} =
                map {
                    my $stash = \%{&quot;${_}::&quot;};
                    ($stash-&gt;{AUTOLOAD} &amp;&amp; (*{$stash-&gt;{AUTOLOAD}}{CODE}))
                        ? &quot;${_}::AUTOLOAD&quot;
                        : () } @forebears
                    unless @{$NEXT::NEXT{$key,$wanted_method}||[]};
            $NEXT::SEEN-&gt;{$key,*{$caller}{CODE}}++;
        }
        my $call_method = shift @{$NEXT::NEXT{$key,$wanted_method}};
        while (do { $wanted_class =~ /^NEXT\b.*\b(UNSEEN|DISTINCT)\b/ }
            &amp;&amp; defined $call_method
            &amp;&amp; $NEXT::SEEN-&gt;{$key,$call_method}++) {
            $call_method = shift @{$NEXT::NEXT{$key,$wanted_method}};
        }
        unless (defined $call_method) {
            return unless do { $wanted_class =~ /^NEXT:.*:ACTUAL/ };
            (local $Carp::CarpLevel)++;
            croak qq(Can't locate object method &quot;$wanted_method&quot; ),
                qq(via package &quot;$caller_class&quot;);
        };
        return $self-&gt;$call_method(@_[1..$#_]) if ref $call_method eq 'CODE';
        no strict 'refs';
        do { ($wanted_method=${$caller_class.&quot;::AUTOLOAD&quot;}) =~ s/.*::// }
            if $wanted_method eq 'AUTOLOAD';
        $$call_method = $caller_class.&quot;::NEXT::&quot;.$wanted_method;
        return $call_method-&gt;(@_);
    };
}

no strict 'vars';
package NEXT;                                  NEXT::ELSEWHERE::buildAUTOLOAD();
package NEXT::UNSEEN;		@ISA = 'NEXT';     NEXT::ELSEWHERE::buildAUTOLOAD();
package NEXT::DISTINCT;		@ISA = 'NEXT';     NEXT::ELSEWHERE::buildAUTOLOAD();
package NEXT::ACTUAL;		@ISA = 'NEXT';     NEXT::ELSEWHERE::buildAUTOLOAD();
package NEXT::ACTUAL::UNSEEN;	@ISA = 'NEXT'; NEXT::ELSEWHERE::buildAUTOLOAD();
package NEXT::ACTUAL::DISTINCT;	@ISA = 'NEXT'; NEXT::ELSEWHERE::buildAUTOLOAD();
package NEXT::UNSEEN::ACTUAL;	@ISA = 'NEXT'; NEXT::ELSEWHERE::buildAUTOLOAD();
package NEXT::DISTINCT::ACTUAL;	@ISA = 'NEXT'; NEXT::ELSEWHERE::buildAUTOLOAD();

package
    EVERY;

sub EVERY::ELSEWHERE::buildAUTOLOAD {
    my $autoload_name = caller() . '::AUTOLOAD';

    no strict 'refs';
    *{$autoload_name} = sub {
        my ($self) = @_;
        my $depth = 1;
        until (((caller($depth))[3]||q{}) !~ /^\(eval\)$/) { $depth++ }
        my $caller = (caller($depth))[3];
        my $wanted = $EVERY::AUTOLOAD || $autoload_name;
        undef $EVERY::AUTOLOAD;
        my ($wanted_class, $wanted_method) = do { $wanted =~ m{(.*)::(.*)}g };

        my $key = ref($self) &amp;&amp; overload::Overloaded($self)
            ? overload::StrVal($self) : $self;

        local $NEXT::ALREADY_IN_EVERY{$key,$wanted_method} =
            $NEXT::ALREADY_IN_EVERY{$key,$wanted_method};

        return if $NEXT::ALREADY_IN_EVERY{$key,$wanted_method}++;

        my @forebears = NEXT::ELSEWHERE::ordered_ancestors ref $self || $self,
                                        $wanted_class;
        @forebears = reverse @forebears if do { $wanted_class =~ /\bLAST\b/ };
        no strict 'refs';
        my %seen;
        my @every = map { my $sub = &quot;${_}::$wanted_method&quot;;
                    !*{$sub}{CODE} || $seen{$sub}++ ? () : $sub
                    } @forebears
                    unless $wanted_method eq 'AUTOLOAD';

        my $want = wantarray;
        if (@every) {
            if ($want) {
                return map {($_, [$self-&gt;$_(@_[1..$#_])])} @every;
            }
            elsif (defined $want) {
                return { map {($_, scalar($self-&gt;$_(@_[1..$#_])))}
                        @every
                    };
            }
            else {
                $self-&gt;$_(@_[1..$#_]) for @every;
                return;
            }
        }

        @every = map { my $sub = &quot;${_}::AUTOLOAD&quot;;
                !*{$sub}{CODE} || $seen{$sub}++ ? () : &quot;${_}::AUTOLOAD&quot;
                } @forebears;
        if ($want) {
            return map { $$_ = ref($self).&quot;::EVERY::&quot;.$wanted_method;
                    ($_, [$self-&gt;$_(@_[1..$#_])]);
                } @every;
        }
        elsif (defined $want) {
            return { map { $$_ = ref($self).&quot;::EVERY::&quot;.$wanted_method;
                    ($_, scalar($self-&gt;$_(@_[1..$#_])))
                    } @every
                };
        }
        else {
            for (@every) {
                $$_ = ref($self).&quot;::EVERY::&quot;.$wanted_method;
                $self-&gt;$_(@_[1..$#_]);
            }
            return;
        }
    };
}

package EVERY::LAST;   @ISA = 'EVERY';   EVERY::ELSEWHERE::buildAUTOLOAD();
package
    EVERY;             @ISA = 'NEXT';    EVERY::ELSEWHERE::buildAUTOLOAD();

1;

__END__

=head1 NAME

NEXT - Provide a pseudo-class NEXT (et al) that allows method redispatch

=head1 SYNOPSIS

    use NEXT;

    package P;
    sub P::method   { print &quot;$_[0]: P method\n&quot;;   $_[0]-&gt;NEXT::method() }
    sub P::DESTROY  { print &quot;$_[0]: P dtor\n&quot;;     $_[0]-&gt;NEXT::DESTROY() }

    package Q;
    use base qw( P );
    sub Q::AUTOLOAD { print &quot;$_[0]: Q AUTOLOAD\n&quot;; $_[0]-&gt;NEXT::AUTOLOAD() }
    sub Q::DESTROY  { print &quot;$_[0]: Q dtor\n&quot;;     $_[0]-&gt;NEXT::DESTROY() }

    package R;
    sub R::method   { print &quot;$_[0]: R method\n&quot;;   $_[0]-&gt;NEXT::method() }
    sub R::AUTOLOAD { print &quot;$_[0]: R AUTOLOAD\n&quot;; $_[0]-&gt;NEXT::AUTOLOAD() }
    sub R::DESTROY  { print &quot;$_[0]: R dtor\n&quot;;     $_[0]-&gt;NEXT::DESTROY() }

    package S;
    use base qw( Q R );
    sub S::method   { print &quot;$_[0]: S method\n&quot;;   $_[0]-&gt;NEXT::method() }
    sub S::AUTOLOAD { print &quot;$_[0]: S AUTOLOAD\n&quot;; $_[0]-&gt;NEXT::AUTOLOAD() }
    sub S::DESTROY  { print &quot;$_[0]: S dtor\n&quot;;     $_[0]-&gt;NEXT::DESTROY() }

    package main;

    my $obj = bless {}, &quot;S&quot;;

    $obj-&gt;method();		# Calls S::method, P::method, R::method
    $obj-&gt;missing_method(); # Calls S::AUTOLOAD, Q::AUTOLOAD, R::AUTOLOAD

    # Clean-up calls S::DESTROY, Q::DESTROY, P::DESTROY, R::DESTROY


=head1 DESCRIPTION

The C&lt;NEXT&gt; module adds a pseudoclass named C&lt;NEXT&gt; to any program
that uses it. If a method C&lt;m&gt; calls C&lt;$self-E&lt;gt&gt;NEXT::m()&gt;, the call to
C&lt;m&gt; is redispatched as if the calling method had not originally been found.

B&lt;Note:&gt; before using this module,
you should look at L&lt;next::method|https://metacpan.org/pod/mro#next::method&gt;
in the core L&lt;mro&gt; module.
C&lt;mro&gt; has been a core module since Perl 5.9.5.

In other words, a call to C&lt;$self-E&lt;gt&gt;NEXT::m()&gt; resumes the depth-first,
left-to-right search of C&lt;$self&gt;'s class hierarchy that resulted in the
original call to C&lt;m&gt;.

Note that this is not the same thing as C&lt;$self-E&lt;gt&gt;SUPER::m()&gt;, which
begins a new dispatch that is restricted to searching the ancestors
of the current class. C&lt;$self-E&lt;gt&gt;NEXT::m()&gt; can backtrack
past the current class -- to look for a suitable method in other
ancestors of C&lt;$self&gt; -- whereas C&lt;$self-E&lt;gt&gt;SUPER::m()&gt; cannot.

A typical use would be in the destructors of a class hierarchy,
as illustrated in the SYNOPSIS above. Each class in the hierarchy
has a DESTROY method that performs some class-specific action
and then redispatches the call up the hierarchy. As a result,
when an object of class S is destroyed, the destructors of I&lt;all&gt;
its parent classes are called (in depth-first, left-to-right order).

Another typical use of redispatch would be in C&lt;AUTOLOAD&gt;'ed methods.
If such a method determined that it was not able to handle a
particular call, it might choose to redispatch that call, in the
hope that some other C&lt;AUTOLOAD&gt; (above it, or to its left) might
do better.

By default, if a redispatch attempt fails to find another method
elsewhere in the objects class hierarchy, it quietly gives up and does
nothing (but see L&lt;&quot;Enforcing redispatch&quot;&gt;). This gracious acquiescence
is also unlike the (generally annoying) behaviour of C&lt;SUPER&gt;, which
throws an exception if it cannot redispatch.

Note that it is a fatal error for any method (including C&lt;AUTOLOAD&gt;)
to attempt to redispatch any method that does not have the
same name. For example:

        sub S::oops { print &quot;oops!\n&quot;; $_[0]-&gt;NEXT::other_method() }


=head2 Enforcing redispatch

It is possible to make C&lt;NEXT&gt; redispatch more demandingly (i.e. like
C&lt;SUPER&gt; does), so that the redispatch throws an exception if it cannot
find a &quot;next&quot; method to call.

To do this, simple invoke the redispatch as:

	$self-&gt;NEXT::ACTUAL::method();

rather than:

	$self-&gt;NEXT::method();

The C&lt;ACTUAL&gt; tells C&lt;NEXT&gt; that there must actually be a next method to call,
or it should throw an exception.

C&lt;NEXT::ACTUAL&gt; is most commonly used in C&lt;AUTOLOAD&gt; methods, as a means to
decline an C&lt;AUTOLOAD&gt; request, but preserve the normal exception-on-failure 
semantics:

	sub AUTOLOAD {
		if ($AUTOLOAD =~ /foo|bar/) {
			# handle here
		}
		else {  # try elsewhere
			shift()-&gt;NEXT::ACTUAL::AUTOLOAD(@_);
		}
	}

By using C&lt;NEXT::ACTUAL&gt;, if there is no other C&lt;AUTOLOAD&gt; to handle the
method call, an exception will be thrown (as usually happens in the absence of
a suitable C&lt;AUTOLOAD&gt;).


=head2 Avoiding repetitions

If C&lt;NEXT&gt; redispatching is used in the methods of a &quot;diamond&quot; class hierarchy:

	#     A   B
	#    / \ /
	#   C   D
	#    \ /
	#     E

	use NEXT;

	package A;                 
	sub foo { print &quot;called A::foo\n&quot;; shift-&gt;NEXT::foo() }

	package B;                 
	sub foo { print &quot;called B::foo\n&quot;; shift-&gt;NEXT::foo() }

	package C; @ISA = qw( A );
	sub foo { print &quot;called C::foo\n&quot;; shift-&gt;NEXT::foo() }

	package D; @ISA = qw(A B);
	sub foo { print &quot;called D::foo\n&quot;; shift-&gt;NEXT::foo() }

	package E; @ISA = qw(C D);
	sub foo { print &quot;called E::foo\n&quot;; shift-&gt;NEXT::foo() }

	E-&gt;foo();

then derived classes may (re-)inherit base-class methods through two or
more distinct paths (e.g. in the way C&lt;E&gt; inherits C&lt;A::foo&gt; twice --
through C&lt;C&gt; and C&lt;D&gt;). In such cases, a sequence of C&lt;NEXT&gt; redispatches
will invoke the multiply inherited method as many times as it is
inherited. For example, the above code prints:

        called E::foo
        called C::foo
        called A::foo
        called D::foo
        called A::foo
        called B::foo

(i.e. C&lt;A::foo&gt; is called twice).

In some cases this I&lt;may&gt; be the desired effect within a diamond hierarchy,
but in others (e.g. for destructors) it may be more appropriate to 
call each method only once during a sequence of redispatches.

To cover such cases, you can redispatch methods via:

        $self-&gt;NEXT::DISTINCT::method();

rather than:

        $self-&gt;NEXT::method();

This causes the redispatcher to only visit each distinct C&lt;method&gt; method
once. That is, to skip any classes in the hierarchy that it has
already visited during redispatch. So, for example, if the
previous example were rewritten:

        package A;                 
        sub foo { print &quot;called A::foo\n&quot;; shift-&gt;NEXT::DISTINCT::foo() }

        package B;                 
        sub foo { print &quot;called B::foo\n&quot;; shift-&gt;NEXT::DISTINCT::foo() }

        package C; @ISA = qw( A );
        sub foo { print &quot;called C::foo\n&quot;; shift-&gt;NEXT::DISTINCT::foo() }

        package D; @ISA = qw(A B);
        sub foo { print &quot;called D::foo\n&quot;; shift-&gt;NEXT::DISTINCT::foo() }

        package E; @ISA = qw(C D);
        sub foo { print &quot;called E::foo\n&quot;; shift-&gt;NEXT::DISTINCT::foo() }

        E-&gt;foo();

then it would print:

        called E::foo
        called C::foo
        called A::foo
        called D::foo
        called B::foo

and omit the second call to C&lt;A::foo&gt; (since it would not be distinct
from the first call to C&lt;A::foo&gt;).

Note that you can also use:

        $self-&gt;NEXT::DISTINCT::ACTUAL::method();

or:

        $self-&gt;NEXT::ACTUAL::DISTINCT::method();

to get both unique invocation I&lt;and&gt; exception-on-failure.

Note that, for historical compatibility, you can also use
C&lt;NEXT::UNSEEN&gt; instead of C&lt;NEXT::DISTINCT&gt;.


=head2 Invoking all versions of a method with a single call

Yet another pseudo-class that C&lt;NEXT&gt; provides is C&lt;EVERY&gt;.
Its behaviour is considerably simpler than that of the C&lt;NEXT&gt; family.
A call to:

	$obj-&gt;EVERY::foo();

calls I&lt;every&gt; method named C&lt;foo&gt; that the object in C&lt;$obj&gt; has inherited.
That is:

	use NEXT;

	package A; @ISA = qw(B D X);
	sub foo { print &quot;A::foo &quot; }

	package B; @ISA = qw(D X);
	sub foo { print &quot;B::foo &quot; }

	package X; @ISA = qw(D);
	sub foo { print &quot;X::foo &quot; }

	package D;
	sub foo { print &quot;D::foo &quot; }

	package main;

	my $obj = bless {}, 'A';
	$obj-&gt;EVERY::foo();        # prints&quot; A::foo B::foo X::foo D::foo

Prefixing a method call with C&lt;EVERY::&gt; causes every method in the
object's hierarchy with that name to be invoked. As the above example
illustrates, they are not called in Perl's usual &quot;left-most-depth-first&quot;
order. Instead, they are called &quot;breadth-first-dependency-wise&quot;.

That means that the inheritance tree of the object is traversed breadth-first
and the resulting order of classes is used as the sequence in which methods
are called. However, that sequence is modified by imposing a rule that the
appropriate method of a derived class must be called before the same method of
any ancestral class. That's why, in the above example, C&lt;X::foo&gt; is called
before C&lt;D::foo&gt;, even though C&lt;D&gt; comes before C&lt;X&gt; in C&lt;@B::ISA&gt;.

In general, there's no need to worry about the order of calls. They will be
left-to-right, breadth-first, most-derived-first. This works perfectly for
most inherited methods (including destructors), but is inappropriate for
some kinds of methods (such as constructors, cloners, debuggers, and
initializers) where it's more appropriate that the least-derived methods be
called first (as more-derived methods may rely on the behaviour of their
&quot;ancestors&quot;). In that case, instead of using the C&lt;EVERY&gt; pseudo-class:

	$obj-&gt;EVERY::foo();        # prints&quot; A::foo B::foo X::foo D::foo      

you can use the C&lt;EVERY::LAST&gt; pseudo-class:

	$obj-&gt;EVERY::LAST::foo();  # prints&quot; D::foo X::foo B::foo A::foo      

which reverses the order of method call.

Whichever version is used, the actual methods are called in the same
context (list, scalar, or void) as the original call via C&lt;EVERY&gt;, and return:

=over

=item *

A hash of array references in list context. Each entry of the hash has the
fully qualified method name as its key and a reference to an array containing
the method's list-context return values as its value.

=item *

A reference to a hash of scalar values in scalar context. Each entry of the hash has the
fully qualified method name as its key and the method's scalar-context return values as its value.

=item *

Nothing in void context (obviously).

=back

=head2 Using C&lt;EVERY&gt; methods

The typical way to use an C&lt;EVERY&gt; call is to wrap it in another base
method, that all classes inherit. For example, to ensure that every
destructor an object inherits is actually called (as opposed to just the
left-most-depth-first-est one):

        package Base;
        sub DESTROY { $_[0]-&gt;EVERY::Destroy }

        package Derived1; 
        use base 'Base';
        sub Destroy {...}

        package Derived2; 
        use base 'Base', 'Derived1';
        sub Destroy {...}

et cetera. Every derived class than needs its own clean-up
behaviour simply adds its own C&lt;Destroy&gt; method (I&lt;not&gt; a C&lt;DESTROY&gt; method),
which the call to C&lt;EVERY::LAST::Destroy&gt; in the inherited destructor
then correctly picks up.

Likewise, to create a class hierarchy in which every initializer inherited by
a new object is invoked:

        package Base;
        sub new {
		my ($class, %args) = @_;
		my $obj = bless {}, $class;
		$obj-&gt;EVERY::LAST::Init(\%args);
	}

        package Derived1; 
        use base 'Base';
        sub Init {
		my ($argsref) = @_;
		...
	}

        package Derived2; 
        use base 'Base', 'Derived1';
        sub Init {
		my ($argsref) = @_;
		...
	}

et cetera. Every derived class than needs some additional initialization
behaviour simply adds its own C&lt;Init&gt; method (I&lt;not&gt; a C&lt;new&gt; method),
which the call to C&lt;EVERY::LAST::Init&gt; in the inherited constructor
then correctly picks up.

=head1 SEE ALSO

L&lt;mro&gt;
(in particular L&lt;next::method|https://metacpan.org/pod/mro#next::method&gt;),
which has been a core module since Perl 5.9.5.

=head1 AUTHOR

Damian Conway (damian@conway.org)

=head1 BUGS AND IRRITATIONS

Because it's a module, not an integral part of the interpreter, C&lt;NEXT&gt;
has to guess where the surrounding call was found in the method
look-up sequence. In the presence of diamond inheritance patterns
it occasionally guesses wrong.

It's also too slow (despite caching).

Comment, suggestions, and patches welcome.

=head1 COPYRIGHT

 Copyright (c) 2000-2001, Damian Conway. All Rights Reserved.
 This module is free software. It may be used, redistributed
    and/or modified under the same terms as Perl itself.
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5'>Back to Directory</a>