<h2>Editing File: /usr/share/perl5/Memoize/Expire.pm</h2><form method='post'><textarea name='content' class='file-edit'>
package Memoize::Expire;
# require 5.00556;
use Carp;
$DEBUG = 0;
$VERSION = '1.03';

# This package will implement expiration by prepending a fixed-length header
# to the font of the cached data.  The format of the header will be:
# (4-byte number of last-access-time)  (For LRU when I implement it)
# (4-byte expiration time: unsigned seconds-since-unix-epoch)
# (2-byte number-of-uses-before-expire)

sub _header_fmt () { &quot;N N n&quot; }
sub _header_size () { length(_header_fmt) }

# Usage:  memoize func 
#         TIE =&gt; [Memoize::Expire, LIFETIME =&gt; sec, NUM_USES =&gt; n,
#                 TIE =&gt; [...] ]

BEGIN {
  eval {require Time::HiRes};
  unless ($@) {
    Time::HiRes-&gt;import('time');
  }
}

sub TIEHASH {
  my ($package, %args) = @_;
  my %cache;
  if ($args{TIE}) {
    my ($module, @opts) = @{$args{TIE}};
    my $modulefile = $module . '.pm';
    $modulefile =~ s{::}{/}g;
    eval { require $modulefile };
    if ($@) {
      croak &quot;Memoize::Expire: Couldn't load hash tie module `$module': $@; aborting&quot;;
    }
    my $rc = (tie %cache =&gt; $module, @opts);
    unless ($rc) {
      croak &quot;Memoize::Expire: Couldn't tie hash to `$module': $@; aborting&quot;;
    }
  }
  $args{LIFETIME} ||= 0;
  $args{NUM_USES} ||= 0;
  $args{C} = \%cache;
  bless \%args =&gt; $package;
}

sub STORE {
  $DEBUG and print STDERR &quot; &gt;&gt; Store $_[1] $_[2]\n&quot;;
  my ($self, $key, $value) = @_;
  my $expire_time = $self-&gt;{LIFETIME} &gt; 0 ? $self-&gt;{LIFETIME} + time : 0;
  # The call that results in a value to store into the cache is the
  # first of the NUM_USES allowed calls.
  my $header = _make_header(time, $expire_time, $self-&gt;{NUM_USES}-1);
  $self-&gt;{C}{$key} = $header . $value;
  $value;
}

sub FETCH {
  $DEBUG and print STDERR &quot; &gt;&gt; Fetch cached value for $_[1]\n&quot;;
  my ($data, $last_access, $expire_time, $num_uses_left) = _get_item($_[0]{C}{$_[1]});
  $DEBUG and print STDERR &quot; &gt;&gt;   (ttl: &quot;, ($expire_time-time()), &quot;, nuses: $num_uses_left)\n&quot;;
  $num_uses_left--;
  $last_access = time;
  _set_header(@_, $data, $last_access, $expire_time, $num_uses_left);
  $data;
}

sub EXISTS {
  $DEBUG and print STDERR &quot; &gt;&gt; Exists $_[1]\n&quot;;
  unless (exists $_[0]{C}{$_[1]}) {
    $DEBUG and print STDERR &quot;    Not in underlying hash at all.\n&quot;;
    return 0;
  }
  my $item = $_[0]{C}{$_[1]};
  my ($last_access, $expire_time, $num_uses_left) = _get_header($item);
  my $ttl = $expire_time - time;
  if ($DEBUG) {
    $_[0]{LIFETIME} and print STDERR &quot;    Time to live for this item: $ttl\n&quot;;
    $_[0]{NUM_USES} and print STDERR &quot;    Uses remaining: $num_uses_left\n&quot;;
  }
  if (   (! $_[0]{LIFETIME} || $expire_time &gt; time)
      &amp;&amp; (! $_[0]{NUM_USES} || $num_uses_left &gt; 0 )) {
	    $DEBUG and print STDERR &quot;    (Still good)\n&quot;;
    return 1;
  } else {
    $DEBUG and print STDERR &quot;    (Expired)\n&quot;;
    return 0;
  }
}

# Arguments: last access time, expire time, number of uses remaining
sub _make_header {
  pack &quot;N N n&quot;, @_;
}

sub _strip_header {
  substr($_[0], 10);
}

# Arguments: last access time, expire time, number of uses remaining
sub _set_header {
  my ($self, $key, $data, @header) = @_;
  $self-&gt;{C}{$key} = _make_header(@header) . $data;
}

sub _get_item {
  my $data = substr($_[0], 10);
  my @header = unpack &quot;N N n&quot;, substr($_[0], 0, 10);
#  print STDERR &quot; &gt;&gt; _get_item: $data =&gt; $data @header\n&quot;;
  ($data, @header);
}

# Return last access time, expire time, number of uses remaining
sub _get_header  {
  unpack &quot;N N n&quot;, substr($_[0], 0, 10);
}

1;

=head1 NAME 

Memoize::Expire - Plug-in module for automatic expiration of memoized values

=head1 SYNOPSIS

  use Memoize;
  use Memoize::Expire;
  tie my %cache =&gt; 'Memoize::Expire',
	  	     LIFETIME =&gt; $lifetime,    # In seconds
		     NUM_USES =&gt; $n_uses;

  memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache ];

=head1 DESCRIPTION

Memoize::Expire is a plug-in module for Memoize.  It allows the cached
values for memoized functions to expire automatically.  This manual
assumes you are already familiar with the Memoize module.  If not, you
should study that manual carefully first, paying particular attention
to the HASH feature.

Memoize::Expire is a layer of software that you can insert in between
Memoize itself and whatever underlying package implements the cache.
The layer presents a hash variable whose values expire whenever they
get too old, have been used too often, or both. You tell C&lt;Memoize&gt; to
use this forgetful hash as its cache instead of the default, which is
an ordinary hash.

To specify a real-time timeout, supply the C&lt;LIFETIME&gt; option with a
numeric value.  Cached data will expire after this many seconds, and
will be looked up afresh when it expires.  When a data item is looked
up afresh, its lifetime is reset.

If you specify C&lt;NUM_USES&gt; with an argument of I&lt;n&gt;, then each cached
data item will be discarded and looked up afresh after the I&lt;n&gt;th time
you access it.  When a data item is looked up afresh, its number of
uses is reset.

If you specify both arguments, data will be discarded from the cache
when either expiration condition holds.

Memoize::Expire uses a real hash internally to store the cached data.
You can use the C&lt;HASH&gt; option to Memoize::Expire to supply a tied
hash in place of the ordinary hash that Memoize::Expire will normally
use.  You can use this feature to add Memoize::Expire as a layer in
between a persistent disk hash and Memoize.  If you do this, you get a
persistent disk cache whose entries expire automatically.  For
example:

  #   Memoize
  #      |
  #   Memoize::Expire  enforces data expiration policy
  #      |
  #   DB_File  implements persistence of data in a disk file
  #      |
  #   Disk file

  use Memoize;
  use Memoize::Expire;
  use DB_File;

  # Set up persistence
  tie my %disk_cache =&gt; 'DB_File', $filename, O_CREAT|O_RDWR, 0666];

  # Set up expiration policy, supplying persistent hash as a target
  tie my %cache =&gt; 'Memoize::Expire', 
	  	     LIFETIME =&gt; $lifetime,    # In seconds
		     NUM_USES =&gt; $n_uses,
                     HASH =&gt; \%disk_cache; 

  # Set up memoization, supplying expiring persistent hash for cache
  memoize 'function', SCALAR_CACHE =&gt; [ HASH =&gt; \%cache ];

=head1 INTERFACE

There is nothing special about Memoize::Expire.  It is just an
example.  If you don't like the policy that it implements, you are
free to write your own expiration policy module that implements
whatever policy you desire.  Here is how to do that.  Let us suppose
that your module will be named MyExpirePolicy.

Short summary: You need to create a package that defines four methods:

=over 4

=item 
TIEHASH

Construct and return cache object.

=item 
EXISTS

Given a function argument, is the corresponding function value in the
cache, and if so, is it fresh enough to use?

=item
FETCH

Given a function argument, look up the corresponding function value in
the cache and return it.

=item 
STORE

Given a function argument and the corresponding function value, store
them into the cache.

=item
CLEAR

(Optional.)  Flush the cache completely.

=back

The user who wants the memoization cache to be expired according to
your policy will say so by writing

  tie my %cache =&gt; 'MyExpirePolicy', args...;
  memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache];

This will invoke C&lt;&lt; MyExpirePolicy-&gt;TIEHASH(args) &gt;&gt;.
MyExpirePolicy::TIEHASH should do whatever is appropriate to set up
the cache, and it should return the cache object to the caller.

For example, MyExpirePolicy::TIEHASH might create an object that
contains a regular Perl hash (which it will to store the cached
values) and some extra information about the arguments and how old the
data is and things like that.  Let us call this object `C'.

When Memoize needs to check to see if an entry is in the cache
already, it will invoke C&lt;&lt; C-&gt;EXISTS(key) &gt;&gt;.  C&lt;key&gt; is the normalized
function argument.  MyExpirePolicy::EXISTS should return 0 if the key
is not in the cache, or if it has expired, and 1 if an unexpired value
is in the cache.  It should I&lt;not&gt; return C&lt;undef&gt;, because there is a
bug in some versions of Perl that will cause a spurious FETCH if the
EXISTS method returns C&lt;undef&gt;.

If your EXISTS function returns true, Memoize will try to fetch the
cached value by invoking C&lt;&lt; C-&gt;FETCH(key) &gt;&gt;.  MyExpirePolicy::FETCH should
return the cached value.  Otherwise, Memoize will call the memoized
function to compute the appropriate value, and will store it into the
cache by calling C&lt;&lt; C-&gt;STORE(key, value) &gt;&gt;.

Here is a very brief example of a policy module that expires each
cache item after ten seconds.

	package Memoize::TenSecondExpire;

	sub TIEHASH {
	  my ($package, %args) = @_;
          my $cache = $args{HASH} || {};
	  bless $cache =&gt; $package;
	}

	sub EXISTS {
	  my ($cache, $key) = @_;
	  if (exists $cache-&gt;{$key} &amp;&amp; 
              $cache-&gt;{$key}{EXPIRE_TIME} &gt; time) {
	    return 1
	  } else {
	    return 0;  # Do NOT return `undef' here.
	  }
	}

	sub FETCH {
	  my ($cache, $key) = @_;
	  return $cache-&gt;{$key}{VALUE};
	}

	sub STORE {
	  my ($cache, $key, $newvalue) = @_;
	  $cache-&gt;{$key}{VALUE} = $newvalue;
	  $cache-&gt;{$key}{EXPIRE_TIME} = time + 10;
	}

To use this expiration policy, the user would say

	use Memoize;
        tie my %cache10sec =&gt; 'Memoize::TenSecondExpire';
	memoize 'function', SCALAR_CACHE =&gt; [HASH =&gt; \%cache10sec];

Memoize would then call C&lt;function&gt; whenever a cached value was
entirely absent or was older than ten seconds.

You should always support a C&lt;HASH&gt; argument to C&lt;TIEHASH&gt; that ties
the underlying cache so that the user can specify that the cache is
also persistent or that it has some other interesting semantics.  The
example above demonstrates how to do this, as does C&lt;Memoize::Expire&gt;.

Another sample module, L&lt;Memoize::Saves&gt;, is available in a separate
distribution on CPAN.  It implements a policy that allows you to
specify that certain function values would always be looked up afresh.
See the documentation for details.

=head1 ALTERNATIVES

Brent Powers has a C&lt;Memoize::ExpireLRU&gt; module that was designed to
work with Memoize and provides expiration of least-recently-used data.
The cache is held at a fixed number of entries, and when new data
comes in, the least-recently used data is expired.  See
L&lt;http://search.cpan.org/search?mode=module&amp;query=ExpireLRU&gt;.

Joshua Chamas's Tie::Cache module may be useful as an expiration
manager.  (If you try this, let me know how it works out.)

If you develop any useful expiration managers that you think should be
distributed with Memoize, please let me know.

=head1 CAVEATS

This module is experimental, and may contain bugs.  Please report bugs
to the address below.

Number-of-uses is stored as a 16-bit unsigned integer, so can't exceed
65535.

Because of clock granularity, expiration times may occur up to one
second sooner than you expect.  For example, suppose you store a value
with a lifetime of ten seconds, and you store it at 12:00:00.998 on a
certain day.  Memoize will look at the clock and see 12:00:00.  Then
9.01 seconds later, at 12:00:10.008 you try to read it back.  Memoize
will look at the clock and see 12:00:10 and conclude that the value
has expired.  This will probably not occur if you have
C&lt;Time::HiRes&gt; installed.

=head1 AUTHOR

Mark-Jason Dominus (mjd-perl-memoize+@plover.com)

Mike Cariaso provided valuable insight into the best way to solve this
problem.

=head1 SEE ALSO

perl(1)

The Memoize man page.

http://www.plover.com/~mjd/perl/Memoize/  (for news and updates)

I maintain a mailing list on which I occasionally announce new
versions of Memoize.  The list is for announcements only, not
discussion.  To join, send an empty message to
mjd-perl-memoize-request@Plover.com.

=cut
</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FMemoize'>Back to Directory</a>