<h2>Editing File: /usr/share/perl5/IO/Uncompress/RawInflate.pm</h2><form method='post'><textarea name='content' class='file-edit'>package IO::Uncompress::RawInflate ;
# for RFC1951

use strict ;
use warnings;
use bytes;

use Compress::Raw::Zlib  2.081 ;
use IO::Compress::Base::Common  2.081 qw(:Status );

use IO::Uncompress::Base  2.081 ;
use IO::Uncompress::Adapter::Inflate  2.081 ;

require Exporter ;
our ($VERSION, @ISA, @EXPORT_OK, %EXPORT_TAGS, %DEFLATE_CONSTANTS, $RawInflateError);

$VERSION = '2.081';
$RawInflateError = '';

@ISA    = qw(IO::Uncompress::Base Exporter);
@EXPORT_OK = qw( $RawInflateError rawinflate ) ;
%DEFLATE_CONSTANTS = ();
%EXPORT_TAGS = %IO::Uncompress::Base::EXPORT_TAGS ;
push @{ $EXPORT_TAGS{all} }, @EXPORT_OK ;
Exporter::export_ok_tags('all');

#{
#    # Execute at runtime  
#    my %bad;
#    for my $module (qw(Compress::Raw::Zlib IO::Compress::Base::Common IO::Uncompress::Base IO::Uncompress::Adapter::Inflate))
#    {
#        my $ver = ${ $module . &quot;::VERSION&quot;} ;
#        
#        $bad{$module} = $ver
#            if $ver ne $VERSION;
#    }
#    
#    if (keys %bad)
#    {
#        my $string = join &quot;\n&quot;, map { &quot;$_ $bad{$_}&quot; } keys %bad;
#        die caller(0)[0] . &quot;needs version $VERSION mismatch\n$string\n&quot;;
#    }
#}

sub new
{
    my $class = shift ;
    my $obj = IO::Compress::Base::Common::createSelfTiedObject($class, \$RawInflateError);
    $obj-&gt;_create(undef, 0, @_);
}

sub rawinflate
{
    my $obj = IO::Compress::Base::Common::createSelfTiedObject(undef, \$RawInflateError);
    return $obj-&gt;_inf(@_);
}

sub getExtraParams
{
    return ();
}

sub ckParams
{
    my $self = shift ;
    my $got = shift ;

    return 1;
}

sub mkUncomp
{
    my $self = shift ;
    my $got = shift ;

    my ($obj, $errstr, $errno) = IO::Uncompress::Adapter::Inflate::mkUncompObject(
                                                                $got-&gt;getValue('crc32'),
                                                                $got-&gt;getValue('adler32'),
                                                                $got-&gt;getValue('scan'),
                                                            );

    return $self-&gt;saveErrorString(undef, $errstr, $errno)
        if ! defined $obj;

    *$self-&gt;{Uncomp} = $obj;

     my $magic = $self-&gt;ckMagic()
        or return 0;

    *$self-&gt;{Info} = $self-&gt;readHeader($magic)
        or return undef ;

    return 1;

}


sub ckMagic
{
    my $self = shift;

    return $self-&gt;_isRaw() ;
}

sub readHeader
{
    my $self = shift;
    my $magic = shift ;

    return {
        'Type'          =&gt; 'rfc1951',
        'FingerprintLength'  =&gt; 0,
        'HeaderLength'  =&gt; 0,
        'TrailerLength' =&gt; 0,
        'Header'        =&gt; ''
        };
}

sub chkTrailer
{
    return STATUS_OK ;
}

sub _isRaw
{
    my $self   = shift ;

    my $got = $self-&gt;_isRawx(@_);

    if ($got) {
        *$self-&gt;{Pending} = *$self-&gt;{HeaderPending} ;
    }
    else {
        $self-&gt;pushBack(*$self-&gt;{HeaderPending});
        *$self-&gt;{Uncomp}-&gt;reset();
    }
    *$self-&gt;{HeaderPending} = '';

    return $got ;
}

sub _isRawx
{
    my $self   = shift ;
    my $magic = shift ;

    $magic = '' unless defined $magic ;

    my $buffer = '';

    $self-&gt;smartRead(\$buffer, *$self-&gt;{BlockSize}) &gt;= 0  
        or return $self-&gt;saveErrorString(undef, &quot;No data to read&quot;);

    my $temp_buf = $magic . $buffer ;
    *$self-&gt;{HeaderPending} = $temp_buf ;    
    $buffer = '';
    my $status = *$self-&gt;{Uncomp}-&gt;uncompr(\$temp_buf, \$buffer, $self-&gt;smartEof()) ;
    
    return $self-&gt;saveErrorString(undef, *$self-&gt;{Uncomp}{Error}, STATUS_ERROR)
        if $status == STATUS_ERROR;

    $self-&gt;pushBack($temp_buf)  ;

    return $self-&gt;saveErrorString(undef, &quot;unexpected end of file&quot;, STATUS_ERROR)
        if $self-&gt;smartEof() &amp;&amp; $status != STATUS_ENDSTREAM;
            
    #my $buf_len = *$self-&gt;{Uncomp}-&gt;uncompressedBytes();
    my $buf_len = length $buffer;

    if ($status == STATUS_ENDSTREAM) {
        if (*$self-&gt;{MultiStream} 
                    &amp;&amp; (length $temp_buf || ! $self-&gt;smartEof())){
            *$self-&gt;{NewStream} = 1 ;
            *$self-&gt;{EndStream} = 0 ;
        }
        else {
            *$self-&gt;{EndStream} = 1 ;
        }
    }
    *$self-&gt;{HeaderPending} = $buffer ;    
    *$self-&gt;{InflatedBytesRead} = $buf_len ;    
    *$self-&gt;{TotalInflatedBytesRead} += $buf_len ;    
    *$self-&gt;{Type} = 'rfc1951';

    $self-&gt;saveStatus(STATUS_OK);

    return {
        'Type'          =&gt; 'rfc1951',
        'HeaderLength'  =&gt; 0,
        'TrailerLength' =&gt; 0,
        'Header'        =&gt; ''
        };
}


sub inflateSync
{
    my $self = shift ;

    # inflateSync is a no-op in Plain mode
    return 1
        if *$self-&gt;{Plain} ;

    return 0 if *$self-&gt;{Closed} ;
    #return G_EOF if !length *$self-&gt;{Pending} &amp;&amp; *$self-&gt;{EndStream} ;
    return 0 if ! length *$self-&gt;{Pending} &amp;&amp; *$self-&gt;{EndStream} ;

    # Disable CRC check
    *$self-&gt;{Strict} = 0 ;

    my $status ;
    while (1)
    {
        my $temp_buf ;

        if (length *$self-&gt;{Pending} )
        {
            $temp_buf = *$self-&gt;{Pending} ;
            *$self-&gt;{Pending} = '';
        }
        else
        {
            $status = $self-&gt;smartRead(\$temp_buf, *$self-&gt;{BlockSize}) ;
            return $self-&gt;saveErrorString(0, &quot;Error Reading Data&quot;)
                if $status &lt; 0  ;

            if ($status == 0 ) {
                *$self-&gt;{EndStream} = 1 ;
                return $self-&gt;saveErrorString(0, &quot;unexpected end of file&quot;, STATUS_ERROR);
            }
        }
        
        $status = *$self-&gt;{Uncomp}-&gt;sync($temp_buf) ;

        if ($status == STATUS_OK)
        {
            *$self-&gt;{Pending} .= $temp_buf ;
            return 1 ;
        }

        last unless $status == STATUS_ERROR ;
    }

    return 0;
}

#sub performScan
#{
#    my $self = shift ;
#
#    my $status ;
#    my $end_offset = 0;
#
#    $status = $self-&gt;scan() 
#    #or return $self-&gt;saveErrorString(undef, &quot;Error Scanning: $$error_ref&quot;, $self-&gt;errorNo) ;
#        or return $self-&gt;saveErrorString(G_ERR, &quot;Error Scanning: $status&quot;)
#
#    $status = $self-&gt;zap($end_offset) 
#        or return $self-&gt;saveErrorString(G_ERR, &quot;Error Zapping: $status&quot;);
#    #or return $self-&gt;saveErrorString(undef, &quot;Error Zapping: $$error_ref&quot;, $self-&gt;errorNo) ;
#
#    #(*$obj-&gt;{Deflate}, $status) = $inf-&gt;createDeflate();
#
##    *$obj-&gt;{Header} = *$inf-&gt;{Info}{Header};
##    *$obj-&gt;{UnCompSize_32bit} = 
##        *$obj-&gt;{BytesWritten} = *$inf-&gt;{UnCompSize_32bit} ;
##    *$obj-&gt;{CompSize_32bit} = *$inf-&gt;{CompSize_32bit} ;
#
#
##    if ( $outType eq 'buffer') 
##      { substr( ${ *$self-&gt;{Buffer} }, $end_offset) = '' }
##    elsif ($outType eq 'handle' || $outType eq 'filename') {
##        *$self-&gt;{FH} = *$inf-&gt;{FH} ;
##        delete *$inf-&gt;{FH};
##        *$obj-&gt;{FH}-&gt;flush() ;
##        *$obj-&gt;{Handle} = 1 if $outType eq 'handle';
##
##        #seek(*$obj-&gt;{FH}, $end_offset, SEEK_SET) 
##        *$obj-&gt;{FH}-&gt;seek($end_offset, SEEK_SET) 
##            or return $obj-&gt;saveErrorString(undef, $!, $!) ;
##    }
#    
#}

sub scan
{
    my $self = shift ;

    return 1 if *$self-&gt;{Closed} ;
    return 1 if !length *$self-&gt;{Pending} &amp;&amp; *$self-&gt;{EndStream} ;

    my $buffer = '' ;
    my $len = 0;

    $len = $self-&gt;_raw_read(\$buffer, 1) 
        while ! *$self-&gt;{EndStream} &amp;&amp; $len &gt;= 0 ;

    #return $len if $len &lt; 0 ? $len : 0 ;
    return $len &lt; 0 ? 0 : 1 ;
}

sub zap
{
    my $self  = shift ;

    my $headerLength = *$self-&gt;{Info}{HeaderLength};
    my $block_offset =  $headerLength + *$self-&gt;{Uncomp}-&gt;getLastBlockOffset();
    $_[0] = $headerLength + *$self-&gt;{Uncomp}-&gt;getEndOffset();
    #printf &quot;# End $_[0], headerlen $headerLength \n&quot;;;
    #printf &quot;# block_offset $block_offset %x\n&quot;, $block_offset;
    my $byte ;
    ( $self-&gt;smartSeek($block_offset) &amp;&amp;
      $self-&gt;smartRead(\$byte, 1) ) 
        or return $self-&gt;saveErrorString(0, $!, $!); 

    #printf &quot;#byte is %x\n&quot;, unpack('C*',$byte);
    *$self-&gt;{Uncomp}-&gt;resetLastBlockByte($byte);
    #printf &quot;#to byte is %x\n&quot;, unpack('C*',$byte);

    ( $self-&gt;smartSeek($block_offset) &amp;&amp; 
      $self-&gt;smartWrite($byte) )
        or return $self-&gt;saveErrorString(0, $!, $!); 

    #$self-&gt;smartSeek($end_offset, 1);

    return 1 ;
}

sub createDeflate
{
    my $self  = shift ;
    my ($def, $status) = *$self-&gt;{Uncomp}-&gt;createDeflateStream(
                                    -AppendOutput   =&gt; 1,
                                    -WindowBits =&gt; - MAX_WBITS,
                                    -CRC32      =&gt; *$self-&gt;{Params}-&gt;getValue('crc32'),
                                    -ADLER32    =&gt; *$self-&gt;{Params}-&gt;getValue('adler32'),
                                );
    
    return wantarray ? ($status, $def) : $def ;                                
}


1; 

__END__


=head1 NAME

IO::Uncompress::RawInflate - Read RFC 1951 files/buffers

=head1 SYNOPSIS

    use IO::Uncompress::RawInflate qw(rawinflate $RawInflateError) ;

    my $status = rawinflate $input =&gt; $output [,OPTS]
        or die &quot;rawinflate failed: $RawInflateError\n&quot;;

    my $z = new IO::Uncompress::RawInflate $input [OPTS]
        or die &quot;rawinflate failed: $RawInflateError\n&quot;;

    $status = $z-&gt;read($buffer)
    $status = $z-&gt;read($buffer, $length)
    $status = $z-&gt;read($buffer, $length, $offset)
    $line = $z-&gt;getline()
    $char = $z-&gt;getc()
    $char = $z-&gt;ungetc()
    $char = $z-&gt;opened()

    $status = $z-&gt;inflateSync()

    $data = $z-&gt;trailingData()
    $status = $z-&gt;nextStream()
    $data = $z-&gt;getHeaderInfo()
    $z-&gt;tell()
    $z-&gt;seek($position, $whence)
    $z-&gt;binmode()
    $z-&gt;fileno()
    $z-&gt;eof()
    $z-&gt;close()

    $RawInflateError ;

    # IO::File mode

    &lt;$z&gt;
    read($z, $buffer);
    read($z, $buffer, $length);
    read($z, $buffer, $length, $offset);
    tell($z)
    seek($z, $position, $whence)
    binmode($z)
    fileno($z)
    eof($z)
    close($z)

=head1 DESCRIPTION

This module provides a Perl interface that allows the reading of
files/buffers that conform to RFC 1951.

For writing RFC 1951 files/buffers, see the companion module IO::Compress::RawDeflate.

=head1 Functional Interface

A top-level function, C&lt;rawinflate&gt;, is provided to carry out
&quot;one-shot&quot; uncompression between buffers and/or files. For finer
control over the uncompression process, see the L&lt;/&quot;OO Interface&quot;&gt;
section.

    use IO::Uncompress::RawInflate qw(rawinflate $RawInflateError) ;

    rawinflate $input_filename_or_reference =&gt; $output_filename_or_reference [,OPTS]
        or die &quot;rawinflate failed: $RawInflateError\n&quot;;

The functional interface needs Perl5.005 or better.

=head2 rawinflate $input_filename_or_reference =&gt; $output_filename_or_reference [, OPTS]

C&lt;rawinflate&gt; expects at least two parameters,
C&lt;$input_filename_or_reference&gt; and C&lt;$output_filename_or_reference&gt;.

=head3 The C&lt;$input_filename_or_reference&gt; parameter

The parameter, C&lt;$input_filename_or_reference&gt;, is used to define the
source of the compressed data.

It can take one of the following forms:

=over 5

=item A filename

If the &lt;$input_filename_or_reference&gt; parameter is a simple scalar, it is
assumed to be a filename. This file will be opened for reading and the
input data will be read from it.

=item A filehandle

If the C&lt;$input_filename_or_reference&gt; parameter is a filehandle, the input
data will be read from it.  The string '-' can be used as an alias for
standard input.

=item A scalar reference

If C&lt;$input_filename_or_reference&gt; is a scalar reference, the input data
will be read from C&lt;$$input_filename_or_reference&gt;.

=item An array reference

If C&lt;$input_filename_or_reference&gt; is an array reference, each element in
the array must be a filename.

The input data will be read from each file in turn.

The complete array will be walked to ensure that it only
contains valid filenames before any data is uncompressed.

=item An Input FileGlob string

If C&lt;$input_filename_or_reference&gt; is a string that is delimited by the
characters &quot;&lt;&quot; and &quot;&gt;&quot; C&lt;rawinflate&gt; will assume that it is an
I&lt;input fileglob string&gt;. The input is the list of files that match the
fileglob.

See L&lt;File::GlobMapper|File::GlobMapper&gt; for more details.

=back

If the C&lt;$input_filename_or_reference&gt; parameter is any other type,
C&lt;undef&gt; will be returned.

=head3 The C&lt;$output_filename_or_reference&gt; parameter

The parameter C&lt;$output_filename_or_reference&gt; is used to control the
destination of the uncompressed data. This parameter can take one of
these forms.

=over 5

=item A filename

If the C&lt;$output_filename_or_reference&gt; parameter is a simple scalar, it is
assumed to be a filename.  This file will be opened for writing and the
uncompressed data will be written to it.

=item A filehandle

If the C&lt;$output_filename_or_reference&gt; parameter is a filehandle, the
uncompressed data will be written to it.  The string '-' can be used as
an alias for standard output.

=item A scalar reference

If C&lt;$output_filename_or_reference&gt; is a scalar reference, the
uncompressed data will be stored in C&lt;$$output_filename_or_reference&gt;.

=item An Array Reference

If C&lt;$output_filename_or_reference&gt; is an array reference,
the uncompressed data will be pushed onto the array.

=item An Output FileGlob

If C&lt;$output_filename_or_reference&gt; is a string that is delimited by the
characters &quot;&lt;&quot; and &quot;&gt;&quot; C&lt;rawinflate&gt; will assume that it is an
I&lt;output fileglob string&gt;. The output is the list of files that match the
fileglob.

When C&lt;$output_filename_or_reference&gt; is an fileglob string,
C&lt;$input_filename_or_reference&gt; must also be a fileglob string. Anything
else is an error.

See L&lt;File::GlobMapper|File::GlobMapper&gt; for more details.

=back

If the C&lt;$output_filename_or_reference&gt; parameter is any other type,
C&lt;undef&gt; will be returned.

=head2 Notes

When C&lt;$input_filename_or_reference&gt; maps to multiple compressed
files/buffers and C&lt;$output_filename_or_reference&gt; is
a single file/buffer, after uncompression C&lt;$output_filename_or_reference&gt; will contain a
concatenation of all the uncompressed data from each of the input
files/buffers.

=head2 Optional Parameters

Unless specified below, the optional parameters for C&lt;rawinflate&gt;,
C&lt;OPTS&gt;, are the same as those used with the OO interface defined in the
L&lt;/&quot;Constructor Options&quot;&gt; section below.

=over 5

=item C&lt;&lt; AutoClose =&gt; 0|1 &gt;&gt;

This option applies to any input or output data streams to
C&lt;rawinflate&gt; that are filehandles.

If C&lt;AutoClose&gt; is specified, and the value is true, it will result in all
input and/or output filehandles being closed once C&lt;rawinflate&gt; has
completed.

This parameter defaults to 0.

=item C&lt;&lt; BinModeOut =&gt; 0|1 &gt;&gt;

When writing to a file or filehandle, set C&lt;binmode&gt; before writing to the
file.

Defaults to 0.

=item C&lt;&lt; Append =&gt; 0|1 &gt;&gt;

The behaviour of this option is dependent on the type of output data
stream.

=over 5

=item * A Buffer

If C&lt;Append&gt; is enabled, all uncompressed data will be append to the end of
the output buffer. Otherwise the output buffer will be cleared before any
uncompressed data is written to it.

=item * A Filename

If C&lt;Append&gt; is enabled, the file will be opened in append mode. Otherwise
the contents of the file, if any, will be truncated before any uncompressed
data is written to it.

=item * A Filehandle

If C&lt;Append&gt; is enabled, the filehandle will be positioned to the end of
the file via a call to C&lt;seek&gt; before any uncompressed data is
written to it.  Otherwise the file pointer will not be moved.

=back

When C&lt;Append&gt; is specified, and set to true, it will I&lt;append&gt; all uncompressed
data to the output data stream.

So when the output is a filehandle it will carry out a seek to the eof
before writing any uncompressed data. If the output is a filename, it will be opened for
appending. If the output is a buffer, all uncompressed data will be
appended to the existing buffer.

Conversely when C&lt;Append&gt; is not specified, or it is present and is set to
false, it will operate as follows.

When the output is a filename, it will truncate the contents of the file
before writing any uncompressed data. If the output is a filehandle
its position will not be changed. If the output is a buffer, it will be
wiped before any uncompressed data is output.

Defaults to 0.

=item C&lt;&lt; MultiStream =&gt; 0|1 &gt;&gt;

This option is a no-op.

=item C&lt;&lt; TrailingData =&gt; $scalar &gt;&gt;

Returns the data, if any, that is present immediately after the compressed
data stream once uncompression is complete.

This option can be used when there is useful information immediately
following the compressed data stream, and you don't know the length of the
compressed data stream.

If the input is a buffer, C&lt;trailingData&gt; will return everything from the
end of the compressed data stream to the end of the buffer.

If the input is a filehandle, C&lt;trailingData&gt; will return the data that is
left in the filehandle input buffer once the end of the compressed data
stream has been reached. You can then use the filehandle to read the rest
of the input file.

Don't bother using C&lt;trailingData&gt; if the input is a filename.

If you know the length of the compressed data stream before you start
uncompressing, you can avoid having to use C&lt;trailingData&gt; by setting the
C&lt;InputLength&gt; option.

=back

=head2 Examples

To read the contents of the file C&lt;file1.txt.1951&gt; and write the
uncompressed data to the file C&lt;file1.txt&gt;.

    use strict ;
    use warnings ;
    use IO::Uncompress::RawInflate qw(rawinflate $RawInflateError) ;

    my $input = &quot;file1.txt.1951&quot;;
    my $output = &quot;file1.txt&quot;;
    rawinflate $input =&gt; $output
        or die &quot;rawinflate failed: $RawInflateError\n&quot;;

To read from an existing Perl filehandle, C&lt;$input&gt;, and write the
uncompressed data to a buffer, C&lt;$buffer&gt;.

    use strict ;
    use warnings ;
    use IO::Uncompress::RawInflate qw(rawinflate $RawInflateError) ;
    use IO::File ;

    my $input = new IO::File &quot;&lt;file1.txt.1951&quot;
        or die &quot;Cannot open 'file1.txt.1951': $!\n&quot; ;
    my $buffer ;
    rawinflate $input =&gt; \$buffer
        or die &quot;rawinflate failed: $RawInflateError\n&quot;;

To uncompress all files in the directory &quot;/my/home&quot; that match &quot;*.txt.1951&quot; and store the compressed data in the same directory

    use strict ;
    use warnings ;
    use IO::Uncompress::RawInflate qw(rawinflate $RawInflateError) ;

    rawinflate '&lt;/my/home/*.txt.1951&gt;' =&gt; '&lt;/my/home/#1.txt&gt;'
        or die &quot;rawinflate failed: $RawInflateError\n&quot;;

and if you want to compress each file one at a time, this will do the trick

    use strict ;
    use warnings ;
    use IO::Uncompress::RawInflate qw(rawinflate $RawInflateError) ;

    for my $input ( glob &quot;/my/home/*.txt.1951&quot; )
    {
        my $output = $input;
        $output =~ s/.1951// ;
        rawinflate $input =&gt; $output
            or die &quot;Error compressing '$input': $RawInflateError\n&quot;;
    }

=head1 OO Interface

=head2 Constructor

The format of the constructor for IO::Uncompress::RawInflate is shown below

    my $z = new IO::Uncompress::RawInflate $input [OPTS]
        or die &quot;IO::Uncompress::RawInflate failed: $RawInflateError\n&quot;;

Returns an C&lt;IO::Uncompress::RawInflate&gt; object on success and undef on failure.
The variable C&lt;$RawInflateError&gt; will contain an error message on failure.

If you are running Perl 5.005 or better the object, C&lt;$z&gt;, returned from
IO::Uncompress::RawInflate can be used exactly like an L&lt;IO::File|IO::File&gt; filehandle.
This means that all normal input file operations can be carried out with
C&lt;$z&gt;.  For example, to read a line from a compressed file/buffer you can
use either of these forms

    $line = $z-&gt;getline();
    $line = &lt;$z&gt;;

The mandatory parameter C&lt;$input&gt; is used to determine the source of the
compressed data. This parameter can take one of three forms.

=over 5

=item A filename

If the C&lt;$input&gt; parameter is a scalar, it is assumed to be a filename. This
file will be opened for reading and the compressed data will be read from it.

=item A filehandle

If the C&lt;$input&gt; parameter is a filehandle, the compressed data will be
read from it.
The string '-' can be used as an alias for standard input.

=item A scalar reference

If C&lt;$input&gt; is a scalar reference, the compressed data will be read from
C&lt;$$input&gt;.

=back

=head2 Constructor Options

The option names defined below are case insensitive and can be optionally
prefixed by a '-'.  So all of the following are valid

    -AutoClose
    -autoclose
    AUTOCLOSE
    autoclose

OPTS is a combination of the following options:

=over 5

=item C&lt;&lt; AutoClose =&gt; 0|1 &gt;&gt;

This option is only valid when the C&lt;$input&gt; parameter is a filehandle. If
specified, and the value is true, it will result in the file being closed once
either the C&lt;close&gt; method is called or the IO::Uncompress::RawInflate object is
destroyed.

This parameter defaults to 0.

=item C&lt;&lt; MultiStream =&gt; 0|1 &gt;&gt;

Allows multiple concatenated compressed streams to be treated as a single
compressed stream. Decompression will stop once either the end of the
file/buffer is reached, an error is encountered (premature eof, corrupt
compressed data) or the end of a stream is not immediately followed by the
start of another stream.

This parameter defaults to 0.

=item C&lt;&lt; Prime =&gt; $string &gt;&gt;

This option will uncompress the contents of C&lt;$string&gt; before processing the
input file/buffer.

This option can be useful when the compressed data is embedded in another
file/data structure and it is not possible to work out where the compressed
data begins without having to read the first few bytes. If this is the
case, the uncompression can be I&lt;primed&gt; with these bytes using this
option.

=item C&lt;&lt; Transparent =&gt; 0|1 &gt;&gt;

If this option is set and the input file/buffer is not compressed data,
the module will allow reading of it anyway.

In addition, if the input file/buffer does contain compressed data and
there is non-compressed data immediately following it, setting this option
will make this module treat the whole file/buffer as a single data stream.

This option defaults to 1.

=item C&lt;&lt; BlockSize =&gt; $num &gt;&gt;

When reading the compressed input data, IO::Uncompress::RawInflate will read it in
blocks of C&lt;$num&gt; bytes.

This option defaults to 4096.

=item C&lt;&lt; InputLength =&gt; $size &gt;&gt;

When present this option will limit the number of compressed bytes read
from the input file/buffer to C&lt;$size&gt;. This option can be used in the
situation where there is useful data directly after the compressed data
stream and you know beforehand the exact length of the compressed data
stream.

This option is mostly used when reading from a filehandle, in which case
the file pointer will be left pointing to the first byte directly after the
compressed data stream.

This option defaults to off.

=item C&lt;&lt; Append =&gt; 0|1 &gt;&gt;

This option controls what the C&lt;read&gt; method does with uncompressed data.

If set to 1, all uncompressed data will be appended to the output parameter
of the C&lt;read&gt; method.

If set to 0, the contents of the output parameter of the C&lt;read&gt; method
will be overwritten by the uncompressed data.

Defaults to 0.

=item C&lt;&lt; Strict =&gt; 0|1 &gt;&gt;

This option is a no-op.

=back

=head2 Examples

TODO

=head1 Methods

=head2 read

Usage is

    $status = $z-&gt;read($buffer)

Reads a block of compressed data (the size of the compressed block is
determined by the C&lt;Buffer&gt; option in the constructor), uncompresses it and
writes any uncompressed data into C&lt;$buffer&gt;. If the C&lt;Append&gt; parameter is
set in the constructor, the uncompressed data will be appended to the
C&lt;$buffer&gt; parameter. Otherwise C&lt;$buffer&gt; will be overwritten.

Returns the number of uncompressed bytes written to C&lt;$buffer&gt;, zero if eof
or a negative number on error.

=head2 read

Usage is

    $status = $z-&gt;read($buffer, $length)
    $status = $z-&gt;read($buffer, $length, $offset)

    $status = read($z, $buffer, $length)
    $status = read($z, $buffer, $length, $offset)

Attempt to read C&lt;$length&gt; bytes of uncompressed data into C&lt;$buffer&gt;.

The main difference between this form of the C&lt;read&gt; method and the
previous one, is that this one will attempt to return I&lt;exactly&gt; C&lt;$length&gt;
bytes. The only circumstances that this function will not is if end-of-file
or an IO error is encountered.

Returns the number of uncompressed bytes written to C&lt;$buffer&gt;, zero if eof
or a negative number on error.

=head2 getline

Usage is

    $line = $z-&gt;getline()
    $line = &lt;$z&gt;

Reads a single line.

This method fully supports the use of the variable C&lt;$/&gt; (or
C&lt;$INPUT_RECORD_SEPARATOR&gt; or C&lt;$RS&gt; when C&lt;English&gt; is in use) to
determine what constitutes an end of line. Paragraph mode, record mode and
file slurp mode are all supported.

=head2 getc

Usage is

    $char = $z-&gt;getc()

Read a single character.

=head2 ungetc

Usage is

    $char = $z-&gt;ungetc($string)

=head2 inflateSync

Usage is

    $status = $z-&gt;inflateSync()

TODO

=head2 getHeaderInfo

Usage is

    $hdr  = $z-&gt;getHeaderInfo();
    @hdrs = $z-&gt;getHeaderInfo();

This method returns either a hash reference (in scalar context) or a list
or hash references (in array context) that contains information about each
of the header fields in the compressed data stream(s).

=head2 tell

Usage is

    $z-&gt;tell()
    tell $z

Returns the uncompressed file offset.

=head2 eof

Usage is

    $z-&gt;eof();
    eof($z);

Returns true if the end of the compressed input stream has been reached.

=head2 seek

    $z-&gt;seek($position, $whence);
    seek($z, $position, $whence);

Provides a sub-set of the C&lt;seek&gt; functionality, with the restriction
that it is only legal to seek forward in the input file/buffer.
It is a fatal error to attempt to seek backward.

Note that the implementation of C&lt;seek&gt; in this module does not provide
true random access to a compressed file/buffer. It  works by uncompressing
data from the current offset in the file/buffer until it reaches the
uncompressed offset specified in the parameters to C&lt;seek&gt;. For very small
files this may be acceptable behaviour. For large files it may cause an
unacceptable delay.

The C&lt;$whence&gt; parameter takes one the usual values, namely SEEK_SET,
SEEK_CUR or SEEK_END.

Returns 1 on success, 0 on failure.

=head2 binmode

Usage is

    $z-&gt;binmode
    binmode $z ;

This is a noop provided for completeness.

=head2 opened

    $z-&gt;opened()

Returns true if the object currently refers to a opened file/buffer.

=head2 autoflush

    my $prev = $z-&gt;autoflush()
    my $prev = $z-&gt;autoflush(EXPR)

If the C&lt;$z&gt; object is associated with a file or a filehandle, this method
returns the current autoflush setting for the underlying filehandle. If
C&lt;EXPR&gt; is present, and is non-zero, it will enable flushing after every
write/print operation.

If C&lt;$z&gt; is associated with a buffer, this method has no effect and always
returns C&lt;undef&gt;.

B&lt;Note&gt; that the special variable C&lt;$|&gt; B&lt;cannot&gt; be used to set or
retrieve the autoflush setting.

=head2 input_line_number

    $z-&gt;input_line_number()
    $z-&gt;input_line_number(EXPR)

Returns the current uncompressed line number. If C&lt;EXPR&gt; is present it has
the effect of setting the line number. Note that setting the line number
does not change the current position within the file/buffer being read.

The contents of C&lt;$/&gt; are used to determine what constitutes a line
terminator.

=head2 fileno

    $z-&gt;fileno()
    fileno($z)

If the C&lt;$z&gt; object is associated with a file or a filehandle, C&lt;fileno&gt;
will return the underlying file descriptor. Once the C&lt;close&gt; method is
called C&lt;fileno&gt; will return C&lt;undef&gt;.

If the C&lt;$z&gt; object is associated with a buffer, this method will return
C&lt;undef&gt;.

=head2 close

    $z-&gt;close() ;
    close $z ;

Closes the output file/buffer.

For most versions of Perl this method will be automatically invoked if
the IO::Uncompress::RawInflate object is destroyed (either explicitly or by the
variable with the reference to the object going out of scope). The
exceptions are Perl versions 5.005 through 5.00504 and 5.8.0. In
these cases, the C&lt;close&gt; method will be called automatically, but
not until global destruction of all live objects when the program is
terminating.

Therefore, if you want your scripts to be able to run on all versions
of Perl, you should call C&lt;close&gt; explicitly and not rely on automatic
closing.

Returns true on success, otherwise 0.

If the C&lt;AutoClose&gt; option has been enabled when the IO::Uncompress::RawInflate
object was created, and the object is associated with a file, the
underlying file will also be closed.

=head2 nextStream

Usage is

    my $status = $z-&gt;nextStream();

Skips to the next compressed data stream in the input file/buffer. If a new
compressed data stream is found, the eof marker will be cleared and C&lt;$.&gt;
will be reset to 0.

Returns 1 if a new stream was found, 0 if none was found, and -1 if an
error was encountered.

=head2 trailingData

Usage is

    my $data = $z-&gt;trailingData();

Returns the data, if any, that is present immediately after the compressed
data stream once uncompression is complete. It only makes sense to call
this method once the end of the compressed data stream has been
encountered.

This option can be used when there is useful information immediately
following the compressed data stream, and you don't know the length of the
compressed data stream.

If the input is a buffer, C&lt;trailingData&gt; will return everything from the
end of the compressed data stream to the end of the buffer.

If the input is a filehandle, C&lt;trailingData&gt; will return the data that is
left in the filehandle input buffer once the end of the compressed data
stream has been reached. You can then use the filehandle to read the rest
of the input file.

Don't bother using C&lt;trailingData&gt; if the input is a filename.

If you know the length of the compressed data stream before you start
uncompressing, you can avoid having to use C&lt;trailingData&gt; by setting the
C&lt;InputLength&gt; option in the constructor.

=head1 Importing

No symbolic constants are required by this IO::Uncompress::RawInflate at present.

=over 5

=item :all

Imports C&lt;rawinflate&gt; and C&lt;$RawInflateError&gt;.
Same as doing this

    use IO::Uncompress::RawInflate qw(rawinflate $RawInflateError) ;

=back

=head1 EXAMPLES

=head2 Working with Net::FTP

See L&lt;IO::Compress::FAQ|IO::Compress::FAQ/&quot;Compressed files and Net::FTP&quot;&gt;

=head1 SEE ALSO

L&lt;Compress::Zlib&gt;, L&lt;IO::Compress::Gzip&gt;, L&lt;IO::Uncompress::Gunzip&gt;, L&lt;IO::Compress::Deflate&gt;, L&lt;IO::Uncompress::Inflate&gt;, L&lt;IO::Compress::RawDeflate&gt;, L&lt;IO::Compress::Bzip2&gt;, L&lt;IO::Uncompress::Bunzip2&gt;, L&lt;IO::Compress::Lzma&gt;, L&lt;IO::Uncompress::UnLzma&gt;, L&lt;IO::Compress::Xz&gt;, L&lt;IO::Uncompress::UnXz&gt;, L&lt;IO::Compress::Lzop&gt;, L&lt;IO::Uncompress::UnLzop&gt;, L&lt;IO::Compress::Lzf&gt;, L&lt;IO::Uncompress::UnLzf&gt;, L&lt;IO::Uncompress::AnyInflate&gt;, L&lt;IO::Uncompress::AnyUncompress&gt;

L&lt;IO::Compress::FAQ|IO::Compress::FAQ&gt;

L&lt;File::GlobMapper|File::GlobMapper&gt;, L&lt;Archive::Zip|Archive::Zip&gt;,
L&lt;Archive::Tar|Archive::Tar&gt;,
L&lt;IO::Zlib|IO::Zlib&gt;

For RFC 1950, 1951 and 1952 see
L&lt;http://www.faqs.org/rfcs/rfc1950.html&gt;,
L&lt;http://www.faqs.org/rfcs/rfc1951.html&gt; and
L&lt;http://www.faqs.org/rfcs/rfc1952.html&gt;

The I&lt;zlib&gt; compression library was written by Jean-loup Gailly
C&lt;gzip@prep.ai.mit.edu&gt; and Mark Adler C&lt;madler@alumni.caltech.edu&gt;.

The primary site for the I&lt;zlib&gt; compression library is
L&lt;http://www.zlib.org&gt;.

The primary site for gzip is L&lt;http://www.gzip.org&gt;.

=head1 AUTHOR

This module was written by Paul Marquess, C&lt;pmqs@cpan.org&gt;.

=head1 MODIFICATION HISTORY

See the Changes file.

=head1 COPYRIGHT AND LICENSE

Copyright (c) 2005-2018 Paul Marquess. All rights reserved.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

</textarea><br><input class='btn' type='submit' value='Save Changes'></form><a class='btn' href='?dir=%2Fusr%2Fshare%2Fperl5%2FIO%2FUncompress'>Back to Directory</a>